cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (defvar gnus-demon-handlers nil
  32   "Alist of daemonic handlers to be run at intervals.
  33 Each handler is a list on the form
  34
  35 \(FUNCTION TIME IDLE)
  36
  37 FUNCTION is the function to be called.
  38 TIME is the number of `gnus-demon-timestep's between each call.
  39 If nil, never call.  If t, call each `gnus-demon-timestep'.
  40 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  41 is a number, only call when Emacs has been idle more than this number
  42 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  43 idleness.  If IDLE is a number and TIME is nil, then call once each
  44 time Emacs has been idle for IDLE `gnus-demon-timestep's.")
  45
  46 (defvar gnus-demon-timestep 60
  47   "*Number of seconds in each demon timestep.")
  48
  49 ;;; Internal variables.
  50
  51 (defvar gnus-demon-timer nil)
  52 (defvar gnus-demon-idle-has-been-called nil)
  53 (defvar gnus-demon-idle-time 0)
  54 (defvar gnus-demon-handler-state nil)
  55 (defvar gnus-demon-is-idle nil)
  56 (defvar gnus-demon-last-keys nil)
  57
  58 (eval-and-compile
  59   (autoload 'cancel-timer "timer")
  60   (autoload 'timezone-parse-date "timezone")
  61   (autoload 'timezone-make-arpa-date "timezone"))
  62
  63 ;;; Functions.
  64
  65 (defun gnus-demon-add-handler (function time idle)
  66   "Add the handler FUNCTION to be run at TIME and IDLE."
  67   ;; First remove any old handlers that use this function.
  68   (gnus-demon-remove-handler function)
  69   ;; Then add the new one.
  70   (push (list function time idle) gnus-demon-handlers)
  71   (gnus-demon-init))
  72
  73 (defun gnus-demon-remove-handler (function &optional no-init)
  74   "Remove the handler FUNCTION from the list of handlers."
  75   (setq gnus-demon-handlers
  76         (delq (assq function gnus-demon-handlers)
  77               gnus-demon-handlers))
  78   (or no-init (gnus-demon-init)))
  79
  80 (defun gnus-demon-init ()
  81   "Initialize the Gnus daemon."
  82   (interactive)
  83   (gnus-demon-cancel)
  84   (if (null gnus-demon-handlers)
  85       () ; Nothing to do.
  86     ;; Set up timer.
  87     (setq gnus-demon-timer
  88           (run-at-time
  89            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
  90     ;; Reset control variables.
  91     (setq gnus-demon-handler-state
  92           (mapcar
  93            (lambda (handler)
  94              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
  95                    (nth 2 handler)))
  96            gnus-demon-handlers))
  97     (setq gnus-demon-idle-time 0)
  98     (setq gnus-demon-idle-has-been-called nil)
  99     (setq gnus-use-demon t)))
 100
 101 (defun gnus-demon-cancel ()
 102   "Cancel any Gnus daemons."
 103   (interactive)
 104   (and gnus-demon-timer
 105        (cancel-timer gnus-demon-timer))
 106   (setq gnus-demon-timer nil
 107         gnus-use-demon nil))
 108
 109 (defun gnus-demon-is-idle-p ()
 110   "Whether Emacs is idle or not."
 111   ;; We do this simply by comparing the 100 most recent keystrokes
 112   ;; with the ones we had last time.  If they are the same, one might
 113   ;; guess that Emacs is indeed idle.  This only makes sense if one
 114   ;; calls this function seldom -- like once a minute, which is what
 115   ;; we do here.
 116   (let ((keys (recent-keys)))
 117     (or (equal keys gnus-demon-last-keys)
 118         (progn
 119           (setq gnus-demon-last-keys keys)
 120           nil))))
 121
 122 (defun gnus-demon-time-to-step (time)
 123   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 124   (if (not (stringp time))
 125       time
 126     (let* ((date (current-time-string))
 127            (dv (timezone-parse-date date))
 128            (tdate (timezone-make-arpa-date
 129                    (string-to-number (aref dv 0))
 130                    (string-to-number (aref dv 1))
 131                    (string-to-number (aref dv 2)) time
 132                    (or (aref dv 4) "UT")))
 133            (nseconds (gnus-time-minus
 134                       (gnus-encode-date tdate) (gnus-encode-date date))))
 135       (round
 136        (/ (if (< nseconds 0)
 137               (+ nseconds (* 60 60 24))
 138             nseconds) gnus-demon-timestep)))))
 139
 140 (defun gnus-demon ()
 141   "The Gnus daemon that takes care of running all Gnus handlers."
 142   ;; Increase or reset the time Emacs has been idle.
 143   (if (gnus-demon-is-idle-p)
 144       (incf gnus-demon-idle-time)
 145     (setq gnus-demon-idle-time 0)
 146     (setq gnus-demon-idle-has-been-called nil))
 147   ;; Then we go through all the handler and call those that are
 148   ;; sufficiently ripe.
 149   (let ((handlers gnus-demon-handler-state)
 150         handler time idle)
 151     (while handlers
 152       (setq handler (pop handlers))
 153       (cond
 154        ((numberp (setq time (nth 1 handler)))
 155         ;; These handlers use a regular timeout mechanism.  We decrease
 156         ;; the timer if it hasn't reached zero yet.
 157         (or (zerop time)
 158             (setcar (nthcdr 1 handler) (decf time)))
 159         (and (zerop time)               ; If the timer now is zero...
 160              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 161                  (and (numberp idle)    ; Numerical idle...
 162                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 163                  gnus-demon-is-idle)    ; Or just need to be idle.
 164              ;; So we call the handler.
 165              (progn
 166                (funcall (car handler))
 167                ;; And reset the timer.
 168                (setcar (nthcdr 1 handler)
 169                        (gnus-demon-time-to-step
 170                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 171        ;; These are only supposed to be called when Emacs is idle.
 172        ((null (setq idle (nth 2 handler)))
 173         ;; We do nothing.
 174         )
 175        ((not (numberp idle))
 176         ;; We want to call this handler each and every time that
 177         ;; Emacs is idle.
 178         (funcall (car handler)))
 179        (t
 180         ;; We want to call this handler only if Emacs has been idle
 181         ;; for a specified number of timesteps.
 182         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 183              (< idle gnus-demon-idle-time)
 184              (progn
 185                (funcall (car handler))
 186                ;; Make sure the handler won't be called once more in
 187                ;; this idle-cycle.
 188                (push (car handler) gnus-demon-idle-has-been-called))))))))
 189
 190 (defun gnus-demon-add-nocem ()
 191   "Add daemonic NoCeM handling to Gnus."
 192   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 193
 194 (defun gnus-demon-scan-nocem ()
 195   (gnus-nocem-scan-groups))
 196
 197 (defun gnus-demon-add-disconnection ()
 198   "Add daemonic server disconnection to Gnus."
 199   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 200
 201 (defun gnus-demon-close-connections ()
 202   (gnus-close-backends))
 203
 204 (defun gnus-demon-add-scanmail ()
 205   "Add daemonic scanning of mail from the mail backends."
 206   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 207
 208 (defun gnus-demon-scan-mail ()
 209   (let ((servers gnus-opened-servers)
 210         server)
 211     (while servers
 212       (setq server (car (pop servers)))
 213       (and (gnus-check-backend-function 'request-scan (car server))
 214            (gnus-request-scan nil server)))))
 215
 216 (provide 'gnus-demon)
 217
 218 ;;; gnus-demon.el ends here