cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-int)
  30 (require 'nnheader)
  31 (eval-and-compile
  32   (if (string-match "XEmacs" (emacs-version))
  33       (require 'itimer)
  34     (require 'timer)))
  35
  36 (defgroup gnus-demon nil
  37   "Demonic behaviour."
  38   :group 'gnus)
  39
  40 (defcustom gnus-demon-handlers nil
  41   "Alist of daemonic handlers to be run at intervals.
  42 Each handler is a list on the form
  43
  44 \(FUNCTION TIME IDLE)
  45
  46 FUNCTION is the function to be called.
  47 TIME is the number of `gnus-demon-timestep's between each call.
  48 If nil, never call.  If t, call each `gnus-demon-timestep'.
  49 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  50 is a number, only call when Emacs has been idle more than this number
  51 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  52 idleness.  If IDLE is a number and TIME is nil, then call once each
  53 time Emacs has been idle for IDLE `gnus-demon-timestep's."
  54   :group 'gnus-demon
  55   :type '(repeat (list function
  56                        (choice :tag "Time"
  57                                (const :tag "never" nil)
  58                                (const :tag "one" t)
  59                                (integer :tag "steps" 1))
  60                        (choice :tag "Idle"
  61                                (const :tag "don't care" nil)
  62                                (const :tag "for a while" t)
  63                                (integer :tag "steps" 1)))))
  64
  65 (defcustom gnus-demon-timestep 60
  66   "*Number of seconds in each demon timestep."
  67   :group 'gnus-demon
  68   :type 'integer)
  69
  70 ;;; Internal variables.
  71
  72 (defvar gnus-demon-timer nil)
  73 (defvar gnus-demon-idle-has-been-called nil)
  74 (defvar gnus-demon-idle-time 0)
  75 (defvar gnus-demon-handler-state nil)
  76 (defvar gnus-demon-is-idle nil)
  77 (defvar gnus-demon-last-keys nil)
  78
  79 (eval-and-compile
  80   (autoload 'timezone-parse-date "timezone")
  81   (autoload 'timezone-make-arpa-date "timezone"))
  82
  83 ;;; Functions.
  84
  85 (defun gnus-demon-add-handler (function time idle)
  86   "Add the handler FUNCTION to be run at TIME and IDLE."
  87   ;; First remove any old handlers that use this function.
  88   (gnus-demon-remove-handler function)
  89   ;; Then add the new one.
  90   (push (list function time idle) gnus-demon-handlers)
  91   (gnus-demon-init))
  92
  93 (defun gnus-demon-remove-handler (function &optional no-init)
  94   "Remove the handler FUNCTION from the list of handlers."
  95   (setq gnus-demon-handlers
  96         (delq (assq function gnus-demon-handlers)
  97               gnus-demon-handlers))
  98   (unless no-init
  99     (gnus-demon-init)))
 100
 101 (defun gnus-demon-init ()
 102   "Initialize the Gnus daemon."
 103   (interactive)
 104   (gnus-demon-cancel)
 105   (if (null gnus-demon-handlers)
 106       ()                                ; Nothing to do.
 107     ;; Set up timer.
 108     (setq gnus-demon-timer
 109           (nnheader-run-at-time
 110            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
 111     ;; Reset control variables.
 112     (setq gnus-demon-handler-state
 113           (mapcar
 114            (lambda (handler)
 115              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 116                    (nth 2 handler)))
 117            gnus-demon-handlers))
 118     (setq gnus-demon-idle-time 0)
 119     (setq gnus-demon-idle-has-been-called nil)
 120     (setq gnus-use-demon t)))
 121
 122 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 123
 124 (defun gnus-demon-cancel ()
 125   "Cancel any Gnus daemons."
 126   (interactive)
 127   (when gnus-demon-timer
 128     (nnheader-cancel-timer gnus-demon-timer))
 129   (setq gnus-demon-timer nil
 130         gnus-use-demon nil)
 131   (condition-case ()
 132       (nnheader-cancel-function-timers 'gnus-demon)
 133     (error t)))
 134
 135 (defun gnus-demon-is-idle-p ()
 136   "Whether Emacs is idle or not."
 137   ;; We do this simply by comparing the 100 most recent keystrokes
 138   ;; with the ones we had last time.  If they are the same, one might
 139   ;; guess that Emacs is indeed idle.  This only makes sense if one
 140   ;; calls this function seldom -- like once a minute, which is what
 141   ;; we do here.
 142   (let ((keys (recent-keys)))
 143     (or (equal keys gnus-demon-last-keys)
 144         (progn
 145           (setq gnus-demon-last-keys keys)
 146           nil))))
 147
 148 (defun gnus-demon-time-to-step (time)
 149   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 150   (if (not (stringp time))
 151       time
 152     (let* ((date (current-time-string))
 153            (dv (timezone-parse-date date))
 154            (tdate (timezone-make-arpa-date
 155                    (string-to-number (aref dv 0))
 156                    (string-to-number (aref dv 1))
 157                    (string-to-number (aref dv 2)) time
 158                    (or (aref dv 4) "UT")))
 159            (nseconds (gnus-time-minus
 160                       (gnus-encode-date tdate) (gnus-encode-date date))))
 161       (round
 162        (/ (+ (if (< (car nseconds) 0)
 163                  86400 0)
 164              (* 65536 (car nseconds))
 165              (nth 1 nseconds))
 166           gnus-demon-timestep)))))
 167
 168 (defun gnus-demon ()
 169   "The Gnus daemon that takes care of running all Gnus handlers."
 170   ;; Increase or reset the time Emacs has been idle.
 171   (if (gnus-demon-is-idle-p)
 172       (incf gnus-demon-idle-time)
 173     (setq gnus-demon-idle-time 0)
 174     (setq gnus-demon-idle-has-been-called nil))
 175   ;; Then we go through all the handler and call those that are
 176   ;; sufficiently ripe.
 177   (let ((handlers gnus-demon-handler-state)
 178         handler time idle)
 179     (while handlers
 180       (setq handler (pop handlers))
 181       (cond
 182        ((numberp (setq time (nth 1 handler)))
 183         ;; These handlers use a regular timeout mechanism.  We decrease
 184         ;; the timer if it hasn't reached zero yet.
 185         (unless (zerop time)
 186           (setcar (nthcdr 1 handler) (decf time)))
 187         (and (zerop time)               ; If the timer now is zero...
 188              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 189                  (and (numberp idle)    ; Numerical idle...
 190                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 191                  gnus-demon-is-idle)    ; Or just need to be idle.
 192              ;; So we call the handler.
 193              (progn
 194                (funcall (car handler))
 195                ;; And reset the timer.
 196                (setcar (nthcdr 1 handler)
 197                        (gnus-demon-time-to-step
 198                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 199        ;; These are only supposed to be called when Emacs is idle.
 200        ((null (setq idle (nth 2 handler)))
 201         ;; We do nothing.
 202         )
 203        ((not (numberp idle))
 204         ;; We want to call this handler each and every time that
 205         ;; Emacs is idle.
 206         (funcall (car handler)))
 207        (t
 208         ;; We want to call this handler only if Emacs has been idle
 209         ;; for a specified number of timesteps.
 210         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 211              (< idle gnus-demon-idle-time)
 212              (progn
 213                (funcall (car handler))
 214                ;; Make sure the handler won't be called once more in
 215                ;; this idle-cycle.
 216                (push (car handler) gnus-demon-idle-has-been-called))))))))
 217
 218 (defun gnus-demon-add-nocem ()
 219   "Add daemonic NoCeM handling to Gnus."
 220   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 221
 222 (defun gnus-demon-scan-nocem ()
 223   "Scan NoCeM groups for NoCeM messages."
 224   (save-window-excursion
 225     (gnus-nocem-scan-groups)))
 226
 227 (defun gnus-demon-add-disconnection ()
 228   "Add daemonic server disconnection to Gnus."
 229   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 230
 231 (defun gnus-demon-close-connections ()
 232   (save-window-excursion
 233     (gnus-close-backends)))
 234
 235 (defun gnus-demon-add-scanmail ()
 236   "Add daemonic scanning of mail from the mail backends."
 237   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 238
 239 (defun gnus-demon-scan-mail ()
 240   (save-window-excursion
 241     (let ((servers gnus-opened-servers)
 242           server)
 243       (while (setq server (car (pop servers)))
 244         (and (gnus-check-backend-function 'request-scan (car server))
 245              (or (gnus-server-opened server)
 246                  (gnus-open-server server))
 247              (gnus-request-scan nil server))))))
 248
 249 (defun gnus-demon-add-rescan ()
 250   "Add daemonic scanning of new articles from all backends."
 251   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 252
 253 (defun gnus-demon-scan-news ()
 254   (save-window-excursion
 255     (when (gnus-alive-p)
 256       (save-excursion
 257         (set-buffer gnus-group-buffer)
 258         (gnus-group-get-new-news)))))
 259
 260 (defun gnus-demon-add-scan-timestamps ()
 261   "Add daemonic updating of timestamps in empty newgroups."
 262   (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
 263
 264 (defun gnus-demon-scan-timestamps ()
 265   "Set the timestamp on all newsgroups with no unread and no ticked articles."
 266   (when (gnus-alive-p)
 267     (let ((cur-time (current-time))
 268           (newsrc (cdr gnus-newsrc-alist))
 269           info group unread has-ticked)
 270       (while (setq info (pop newsrc))
 271         (setq group (gnus-info-group info)
 272               unread (gnus-group-unread group)
 273               has-ticked (cdr (assq 'tick (gnus-info-marks info))))
 274         (when (and (numberp unread)
 275                    (= unread 0)
 276                    (not has-ticked))
 277           (gnus-group-set-parameter group 'timestamp cur-time))))))
 278
 279 (provide 'gnus-demon)
 280
 281 ;;; gnus-demon.el ends here