cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-int)
  33 (require 'gnus-range)
  34 (require 'gnus-start)
  35 (eval-when-compile
  36   (require 'gnus-sum))
  37
  38 (defcustom gnus-cache-active-file
  39   (expand-file-name "active" gnus-cache-directory)
  40   "*The cache active file."
  41   :group 'gnus-cache
  42   :type 'file)
  43
  44 (defcustom gnus-cache-enter-articles '(ticked dormant)
  45   "Classes of articles to enter into the cache."
  46   :group 'gnus-cache
  47   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  48
  49 (defcustom gnus-cache-remove-articles '(read)
  50   "Classes of articles to remove from the cache."
  51   :group 'gnus-cache
  52   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  53
  54 (defcustom gnus-cacheable-groups nil
  55   "*Groups that match this regexp will be cached.
  56
  57 If you only want to cache your nntp groups, you could set this
  58 variable to \"^nntp\".
  59
  60 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  61 it's not cached."
  62   :group 'gnus-cache
  63   :type '(choice (const :tag "off" nil)
  64                  regexp))
  65
  66 (defcustom gnus-uncacheable-groups nil
  67   "*Groups that match this regexp will not be cached.
  68
  69 If you want to avoid caching your nnml groups, you could set this
  70 variable to \"^nnml\".
  71
  72 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
  73 it's not cached."
  74   :group 'gnus-cache
  75   :type '(choice (const :tag "off" nil)
  76                  regexp))
  77
  78 (defvar gnus-cache-overview-coding-system 'raw-text
  79   "Coding system used on Gnus cache files.")
  80
  81 (defvar gnus-cache-coding-system 'raw-text
  82   "Coding system used on Gnus cache files.")
  83
  84 \f
  85
  86 ;;; Internal variables.
  87
  88 (defvar gnus-cache-removable-articles nil)
  89 (defvar gnus-cache-buffer nil)
  90 (defvar gnus-cache-active-hashtb nil)
  91 (defvar gnus-cache-active-altered nil)
  92
  93 (eval-and-compile
  94   (autoload 'nnml-generate-nov-databases-1 "nnml")
  95   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  96
  97 \f
  98
  99 ;;; Functions called from Gnus.
 100
 101 (defun gnus-cache-open ()
 102   "Initialize the cache."
 103   (when (or (file-exists-p gnus-cache-directory)
 104             (and gnus-use-cache
 105                  (not (eq gnus-use-cache 'passive))))
 106     (gnus-cache-read-active)))
 107
 108 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
 109 (ignore-errors
 110   (gnus-add-shutdown 'gnus-cache-close 'gnus))
 111
 112 (defun gnus-cache-close ()
 113   "Shut down the cache."
 114   (gnus-cache-write-active)
 115   (gnus-cache-save-buffers)
 116   (setq gnus-cache-active-hashtb nil))
 117
 118 (defun gnus-cache-save-buffers ()
 119   ;; save the overview buffer if it exists and has been modified
 120   ;; delete empty cache subdirectories
 121   (when gnus-cache-buffer
 122     (let ((buffer (cdr gnus-cache-buffer))
 123           (overview-file (gnus-cache-file-name
 124                           (car gnus-cache-buffer) ".overview")))
 125       ;; write the overview only if it was modified
 126       (when (buffer-modified-p buffer)
 127         (save-excursion
 128           (set-buffer buffer)
 129           (if (> (buffer-size) 0)
 130               ;; Non-empty overview, write it to a file.
 131               (let ((coding-system-for-write
 132                      gnus-cache-overview-coding-system))
 133                 (gnus-write-buffer overview-file))
 134             ;; Empty overview file, remove it
 135             (when (file-exists-p overview-file)
 136               (delete-file overview-file))
 137             ;; If possible, remove group's cache subdirectory.
 138             (condition-case nil
 139                 ;; FIXME: we can detect the error type and warn the user
 140                 ;; of any inconsistencies (articles w/o nov entries?).
 141                 ;; for now, just be conservative...delete only if safe -- sj
 142                 (delete-directory (file-name-directory overview-file))
 143               (error nil)))))
 144       ;; Kill the buffer -- it's either unmodified or saved.
 145       (gnus-kill-buffer buffer)
 146       (setq gnus-cache-buffer nil))))
 147
 148 (defun gnus-cache-possibly-enter-article
 149   (group article ticked dormant unread &optional force)
 150   (when (and (or force (not (eq gnus-use-cache 'passive)))
 151              (numberp article)
 152              (> article 0))             ; This might be a dummy article.
 153     (let ((number article) file headers)
 154       ;; If this is a virtual group, we find the real group.
 155       (when (gnus-virtual-group-p group)
 156         (let ((result (nnvirtual-find-group-art
 157                        (gnus-group-real-name group) article)))
 158           (setq group (car result)
 159                 number (cdr result))))
 160       (when (and number
 161                  (> number 0)           ; Reffed article.
 162                  (or force
 163                      (and (gnus-cache-fully-p group)
 164                           (gnus-cache-member-of-class
 165                            gnus-cache-enter-articles ticked dormant unread)))
 166                  (not (file-exists-p (setq file (gnus-cache-file-name
 167                                                  group number)))))
 168         ;; Possibly create the cache directory.
 169         (gnus-make-directory (file-name-directory file))
 170         ;; Save the article in the cache.
 171         (if (file-exists-p file)
 172             t                           ; The article already is saved.
 173           (save-excursion
 174             (set-buffer nntp-server-buffer)
 175             (require 'gnus-art)
 176             (let ((gnus-use-cache nil)
 177                   (gnus-article-decode-hook nil))
 178               (gnus-request-article-this-buffer number group))
 179             (when (> (buffer-size) 0)
 180               (let ((coding-system-for-write gnus-cache-coding-system))
 181                 (gnus-write-buffer file))
 182               (setq headers (nnheader-parse-head t))
 183               (mail-header-set-number headers number)
 184               (gnus-cache-change-buffer group)
 185               (set-buffer (cdr gnus-cache-buffer))
 186               (goto-char (point-max))
 187               (forward-line -1)
 188               (while (condition-case ()
 189                          (when (not (bobp))
 190                            (> (read (current-buffer)) number))
 191                        (error
 192                         ;; The line was malformed, so we just remove it!!
 193                         (gnus-delete-line)
 194                         t))
 195                 (forward-line -1))
 196               (if (bobp)
 197                   (if (not (eobp))
 198                       (progn
 199                         (beginning-of-line)
 200                         (when (< (read (current-buffer)) number)
 201                           (forward-line 1)))
 202                     (beginning-of-line))
 203                 (forward-line 1))
 204               (beginning-of-line)
 205               (nnheader-insert-nov headers)
 206               ;; Update the active info.
 207               (set-buffer gnus-summary-buffer)
 208               (gnus-cache-possibly-update-active group (cons number number))
 209               (push article gnus-newsgroup-cached)
 210               (gnus-summary-update-secondary-mark article))
 211             t))))))
 212
 213 (defun gnus-cache-enter-remove-article (article)
 214   "Mark ARTICLE for later possible removal."
 215   (when article
 216     (push article gnus-cache-removable-articles)))
 217
 218 (defun gnus-cache-possibly-remove-articles ()
 219   "Possibly remove some of the removable articles."
 220   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 221       (gnus-cache-possibly-remove-articles-1)
 222     (let ((arts gnus-cache-removable-articles)
 223           ga)
 224       (while arts
 225         (when (setq ga (nnvirtual-find-group-art
 226                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 227           (let ((gnus-cache-removable-articles (list (cdr ga)))
 228                 (gnus-newsgroup-name (car ga)))
 229             (gnus-cache-possibly-remove-articles-1)))))
 230     (setq gnus-cache-removable-articles nil)))
 231
 232 (defun gnus-cache-possibly-remove-articles-1 ()
 233   "Possibly remove some of the removable articles."
 234   (when (gnus-cache-fully-p gnus-newsgroup-name)
 235     (let ((articles gnus-cache-removable-articles)
 236           (cache-articles gnus-newsgroup-cached)
 237           article)
 238       (gnus-cache-change-buffer gnus-newsgroup-name)
 239       (while articles
 240         (when (memq (setq article (pop articles)) cache-articles)
 241           ;; The article was in the cache, so we see whether we are
 242           ;; supposed to remove it from the cache.
 243           (gnus-cache-possibly-remove-article
 244            article (memq article gnus-newsgroup-marked)
 245            (memq article gnus-newsgroup-dormant)
 246            (or (memq article gnus-newsgroup-unreads)
 247                (memq article gnus-newsgroup-unselected))))))
 248     ;; The overview file might have been modified, save it
 249     ;; safe because we're only called at group exit anyway.
 250     (gnus-cache-save-buffers)))
 251
 252 (defun gnus-cache-request-article (article group)
 253   "Retrieve ARTICLE in GROUP from the cache."
 254   (let ((file (gnus-cache-file-name group article))
 255         (buffer-read-only nil))
 256     (when (file-exists-p file)
 257       (erase-buffer)
 258       (gnus-kill-all-overlays)
 259       (let ((coding-system-for-read gnus-cache-coding-system))
 260         (insert-file-contents file))
 261       t)))
 262
 263 (defun gnus-cache-possibly-alter-active (group active)
 264   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 265   (when gnus-cache-active-hashtb
 266     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 267       (when cache-active
 268         (when (< (car cache-active) (car active))
 269           (setcar active (car cache-active)))
 270         (when (> (cdr cache-active) (cdr active))
 271           (setcdr active (cdr cache-active)))))))
 272
 273 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 274   "Retrieve the headers for ARTICLES in GROUP."
 275   (let ((cached
 276          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 277     (if (not cached)
 278         ;; No cached articles here, so we just retrieve them
 279         ;; the normal way.
 280         (let ((gnus-use-cache nil))
 281           (gnus-retrieve-headers articles group fetch-old))
 282       (let ((uncached-articles (gnus-sorted-difference articles cached))
 283             (cache-file (gnus-cache-file-name group ".overview"))
 284             type)
 285         ;; We first retrieve all the headers that we don't have in
 286         ;; the cache.
 287         (let ((gnus-use-cache nil))
 288           (when uncached-articles
 289             (setq type (and articles
 290                             (gnus-retrieve-headers
 291                              uncached-articles group fetch-old)))))
 292         (gnus-cache-save-buffers)
 293         ;; Then we insert the cached headers.
 294         (save-excursion
 295           (cond
 296            ((not (file-exists-p cache-file))
 297             ;; There are no cached headers.
 298             type)
 299            ((null type)
 300             ;; There were no uncached headers (or retrieval was
 301             ;; unsuccessful), so we use the cached headers exclusively.
 302             (set-buffer nntp-server-buffer)
 303             (erase-buffer)
 304             (let ((coding-system-for-read
 305                    gnus-cache-overview-coding-system))
 306               (insert-file-contents cache-file))
 307             'nov)
 308            ((eq type 'nov)
 309             ;; We have both cached and uncached NOV headers, so we
 310             ;; braid them.
 311             (gnus-cache-braid-nov group cached)
 312             type)
 313            (t
 314             ;; We braid HEADs.
 315             (gnus-cache-braid-heads group (gnus-sorted-intersection
 316                                            cached articles))
 317             type)))))))
 318
 319 (defun gnus-cache-enter-article (&optional n)
 320   "Enter the next N articles into the cache.
 321 If not given a prefix, use the process marked articles instead.
 322 Returns the list of articles entered."
 323   (interactive "P")
 324   (let ((articles (gnus-summary-work-articles n))
 325         article out)
 326     (while (setq article (pop articles))
 327       (gnus-summary-remove-process-mark article)
 328       (if (natnump article)
 329           (when (gnus-cache-possibly-enter-article
 330                  gnus-newsgroup-name article
 331                  nil nil nil t)
 332             (push article out))
 333         (gnus-message 2 "Can't cache article %d" article))
 334       (gnus-summary-update-secondary-mark article))
 335     (gnus-summary-next-subject 1)
 336     (gnus-summary-position-point)
 337     (nreverse out)))
 338
 339 (defun gnus-cache-remove-article (n)
 340   "Remove the next N articles from the cache.
 341 If not given a prefix, use the process marked articles instead.
 342 Returns the list of articles removed."
 343   (interactive "P")
 344   (gnus-cache-change-buffer gnus-newsgroup-name)
 345   (let ((articles (gnus-summary-work-articles n))
 346         article out)
 347     (while articles
 348       (setq article (pop articles))
 349       (gnus-summary-remove-process-mark article)
 350       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 351         (push article out))
 352       (gnus-summary-update-secondary-mark article))
 353     (gnus-summary-next-subject 1)
 354     (gnus-summary-position-point)
 355     (nreverse out)))
 356
 357 (defun gnus-cached-article-p (article)
 358   "Say whether ARTICLE is cached in the current group."
 359   (memq article gnus-newsgroup-cached))
 360
 361 (defun gnus-summary-insert-cached-articles ()
 362   "Insert all the articles cached for this group into the current buffer."
 363   (interactive)
 364   (let ((cached (sort (copy-sequence gnus-newsgroup-cached) '>))
 365         (gnus-verbose (max 6 gnus-verbose)))
 366     (if (not cached)
 367         (gnus-message 3 "No cached articles for this group")
 368       (save-excursion
 369         (while cached
 370           (gnus-summary-goto-subject (pop cached) t)))
 371       (gnus-summary-limit (append gnus-newsgroup-cached gnus-newsgroup-limit))
 372       (gnus-summary-position-point))))
 373
 374 (defun gnus-summary-limit-include-cached ()
 375   "Limit the summary buffer to articles that are cached."
 376   (interactive)
 377   (let ((cached (sort (copy-sequence gnus-newsgroup-cached) '>))
 378         (gnus-verbose (max 6 gnus-verbose)))
 379     (if cached
 380         (progn
 381           (gnus-summary-limit cached)
 382           (gnus-summary-position-point))
 383         (gnus-message 3 "No cached articles for this group"))))
 384
 385 ;;; Internal functions.
 386
 387 (defun gnus-cache-change-buffer (group)
 388   (and gnus-cache-buffer
 389        ;; See if the current group's overview cache has been loaded.
 390        (or (string= group (car gnus-cache-buffer))
 391            ;; Another overview cache is current, save it.
 392            (gnus-cache-save-buffers)))
 393   ;; if gnus-cache buffer is nil, create it
 394   (unless gnus-cache-buffer
 395     ;; Create cache buffer
 396     (save-excursion
 397       (setq gnus-cache-buffer
 398             (cons group
 399                   (set-buffer (gnus-get-buffer-create
 400                                " *gnus-cache-overview*"))))
 401       ;; Insert the contents of this group's cache overview.
 402       (erase-buffer)
 403       (let ((file (gnus-cache-file-name group ".overview")))
 404         (when (file-exists-p file)
 405           (nnheader-insert-file-contents file)))
 406       ;; We have a fresh (empty/just loaded) buffer,
 407       ;; mark it as unmodified to save a redundant write later.
 408       (set-buffer-modified-p nil))))
 409
 410 ;; Return whether an article is a member of a class.
 411 (defun gnus-cache-member-of-class (class ticked dormant unread)
 412   (or (and ticked (memq 'ticked class))
 413       (and dormant (memq 'dormant class))
 414       (and unread (memq 'unread class))
 415       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 416
 417 (defun gnus-cache-file-name (group article)
 418   (expand-file-name
 419    (if (stringp article) article (int-to-string article))
 420    (file-name-as-directory
 421     (expand-file-name
 422      (nnheader-translate-file-chars
 423       (if (gnus-use-long-file-name 'not-cache)
 424           group
 425         (let ((group (nnheader-replace-duplicate-chars-in-string
 426                       (nnheader-replace-chars-in-string group ?/ ?_)
 427                       ?. ?_)))
 428           ;; Translate the first colon into a slash.
 429           (when (string-match ":" group)
 430                   (setq group (concat (substring group 0 (match-beginning 0))
 431                                       "/" (substring group (match-end 0)))))
 432           (nnheader-replace-chars-in-string group ?. ?/)))
 433       t)
 434      gnus-cache-directory))))
 435
 436 (defun gnus-cache-update-article (group article)
 437   "If ARTICLE is in the cache, remove it and re-enter it."
 438   (gnus-cache-change-buffer group)
 439   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 440     (let ((gnus-use-cache nil))
 441       (gnus-cache-possibly-enter-article
 442        gnus-newsgroup-name article
 443        nil nil nil t))))
 444
 445 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 446                                                    &optional force)
 447   "Possibly remove ARTICLE from the cache."
 448   (let ((group gnus-newsgroup-name)
 449         (number article)
 450         file)
 451     ;; If this is a virtual group, we find the real group.
 452     (when (gnus-virtual-group-p group)
 453       (let ((result (nnvirtual-find-group-art
 454                      (gnus-group-real-name group) article)))
 455         (setq group (car result)
 456               number (cdr result))))
 457     (setq file (gnus-cache-file-name group number))
 458     (when (and (file-exists-p file)
 459                (or force
 460                    (gnus-cache-member-of-class
 461                     gnus-cache-remove-articles ticked dormant unread)))
 462       (save-excursion
 463         (delete-file file)
 464         (set-buffer (cdr gnus-cache-buffer))
 465         (goto-char (point-min))
 466         (when (or (looking-at (concat (int-to-string number) "\t"))
 467                   (search-forward (concat "\n" (int-to-string number) "\t")
 468                                   (point-max) t))
 469           (delete-region (progn (beginning-of-line) (point))
 470                          (progn (forward-line 1) (point)))))
 471       (setq gnus-newsgroup-cached
 472             (delq article gnus-newsgroup-cached))
 473       (gnus-summary-update-secondary-mark article)
 474       t)))
 475
 476 (defun gnus-cache-articles-in-group (group)
 477   "Return a sorted list of cached articles in GROUP."
 478   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
 479         articles)
 480     (when (file-exists-p dir)
 481       (setq articles
 482             (sort (mapcar (lambda (name) (string-to-int name))
 483                           (directory-files dir nil "^[0-9]+$" t))
 484                   '<))
 485       ;; Update the cache active file, just to synch more.
 486       (when articles
 487         (gnus-cache-update-active group (car articles) t)
 488         (gnus-cache-update-active group (car (last articles))))
 489       articles)))
 490
 491 (defun gnus-cache-braid-nov (group cached &optional file)
 492   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
 493         beg end)
 494     (gnus-cache-save-buffers)
 495     (save-excursion
 496       (set-buffer cache-buf)
 497       (erase-buffer)
 498       (let ((coding-system-for-read
 499              gnus-cache-overview-coding-system))
 500         (insert-file-contents
 501          (or file (gnus-cache-file-name group ".overview"))))
 502       (goto-char (point-min))
 503       (insert "\n")
 504       (goto-char (point-min)))
 505     (set-buffer nntp-server-buffer)
 506     (goto-char (point-min))
 507     (while cached
 508       (while (and (not (eobp))
 509                   (< (read (current-buffer)) (car cached)))
 510         (forward-line 1))
 511       (beginning-of-line)
 512       (save-excursion
 513         (set-buffer cache-buf)
 514         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 515                             nil t)
 516             (setq beg (progn (beginning-of-line) (point))
 517                   end (progn (end-of-line) (point)))
 518           (setq beg nil)))
 519       (when beg
 520         (insert-buffer-substring cache-buf beg end)
 521         (insert "\n"))
 522       (setq cached (cdr cached)))
 523     (kill-buffer cache-buf)))
 524
 525 (defun gnus-cache-braid-heads (group cached)
 526   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
 527     (save-excursion
 528       (set-buffer cache-buf)
 529       (erase-buffer))
 530     (set-buffer nntp-server-buffer)
 531     (goto-char (point-min))
 532     (while cached
 533       (while (and (not (eobp))
 534                   (looking-at "2.. +\\([0-9]+\\) ")
 535                   (< (progn (goto-char (match-beginning 1))
 536                             (read (current-buffer)))
 537                      (car cached)))
 538         (search-forward "\n.\n" nil 'move))
 539       (beginning-of-line)
 540       (save-excursion
 541         (set-buffer cache-buf)
 542         (erase-buffer)
 543         (let ((coding-system-for-read
 544                gnus-cache-coding-system))
 545           (insert-file-contents (gnus-cache-file-name group (car cached))))
 546         (goto-char (point-min))
 547         (insert "220 ")
 548         (princ (car cached) (current-buffer))
 549         (insert " Article retrieved.\n")
 550         (search-forward "\n\n" nil 'move)
 551         (delete-region (point) (point-max))
 552         (forward-char -1)
 553         (insert "."))
 554       (insert-buffer-substring cache-buf)
 555       (setq cached (cdr cached)))
 556     (kill-buffer cache-buf)))
 557
 558 ;;;###autoload
 559 (defun gnus-jog-cache ()
 560   "Go through all groups and put the articles into the cache.
 561
 562 Usage:
 563 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 564   (interactive)
 565   (let ((gnus-mark-article-hook nil)
 566         (gnus-expert-user t)
 567         (nnmail-spool-file nil)
 568         (mail-sources nil)
 569         (gnus-use-dribble-file nil)
 570         (gnus-novice-user nil)
 571         (gnus-large-newsgroup nil))
 572     ;; Start Gnus.
 573     (gnus)
 574     ;; Go through all groups...
 575     (gnus-group-mark-buffer)
 576     (gnus-group-iterate nil
 577       (lambda (group)
 578         (let (gnus-auto-select-next)
 579           (gnus-summary-read-group group nil t)
 580           ;; ... and enter the articles into the cache.
 581           (when (eq major-mode 'gnus-summary-mode)
 582             (gnus-uu-mark-buffer)
 583             (gnus-cache-enter-article)
 584             (kill-buffer (current-buffer))))))))
 585
 586 (defun gnus-cache-read-active (&optional force)
 587   "Read the cache active file."
 588   (gnus-make-directory gnus-cache-directory)
 589   (if (or (not (file-exists-p gnus-cache-active-file))
 590           (zerop (nth 7 (file-attributes gnus-cache-active-file)))
 591           force)
 592       ;; There is no active file, so we generate one.
 593       (gnus-cache-generate-active)
 594     ;; We simply read the active file.
 595     (save-excursion
 596       (gnus-set-work-buffer)
 597       (nnheader-insert-file-contents gnus-cache-active-file)
 598       (gnus-active-to-gnus-format
 599        nil (setq gnus-cache-active-hashtb
 600                  (gnus-make-hashtable
 601                   (count-lines (point-min) (point-max)))))
 602       (setq gnus-cache-active-altered nil))))
 603
 604 (defun gnus-cache-write-active (&optional force)
 605   "Write the active hashtb to the active file."
 606   (when (or force
 607             (and gnus-cache-active-hashtb
 608                  gnus-cache-active-altered))
 609     (gnus-write-active-file gnus-cache-active-file gnus-cache-active-hashtb t)
 610     ;; Mark the active hashtb as unaltered.
 611     (setq gnus-cache-active-altered nil)))
 612
 613 (defun gnus-cache-possibly-update-active (group active)
 614   "Update active info bounds of GROUP with ACTIVE if necessary.
 615 The update is performed if ACTIVE contains a higher or lower bound
 616 than the current."
 617   (let ((lower t) (higher t))
 618     (if gnus-cache-active-hashtb
 619         (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 620           (when cache-active
 621             (unless (< (car active) (car cache-active))
 622               (setq lower nil))
 623             (unless (> (cdr active) (cdr cache-active))
 624               (setq higher nil))))
 625       (gnus-cache-read-active))
 626     (when lower
 627       (gnus-cache-update-active group (car active) t))
 628     (when higher
 629       (gnus-cache-update-active group (cdr active)))))
 630
 631 (defun gnus-cache-update-active (group number &optional low)
 632   "Update the upper bound of the active info of GROUP to NUMBER.
 633 If LOW, update the lower bound instead."
 634   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 635     (if (null active)
 636         ;; We just create a new active entry for this group.
 637         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 638       ;; Update the lower or upper bound.
 639       (if low
 640           (setcar active number)
 641         (setcdr active number)))
 642     ;; Mark the active hashtb as altered.
 643     (setq gnus-cache-active-altered t)))
 644
 645 ;;;###autoload
 646 (defun gnus-cache-generate-active (&optional directory)
 647   "Generate the cache active file."
 648   (interactive)
 649   (let* ((top (null directory))
 650          (directory (expand-file-name (or directory gnus-cache-directory)))
 651          (files (directory-files directory 'full))
 652          (group
 653           (if top
 654               ""
 655             (string-match
 656              (concat "^" (regexp-quote
 657                           (file-name-as-directory
 658                            (expand-file-name gnus-cache-directory))))
 659              (directory-file-name directory))
 660             (nnheader-replace-chars-in-string
 661              (substring (directory-file-name directory) (match-end 0))
 662              ?/ ?.)))
 663          nums alphs)
 664     (when top
 665       (gnus-message 5 "Generating the cache active file...")
 666       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 667     (when (string-match "^\\(nn[^_]+\\)_" group)
 668       (setq group (replace-match "\\1:" t t group)))
 669     ;; Separate articles from all other files and directories.
 670     (while files
 671       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 672           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 673         (push (pop files) alphs)))
 674     ;; If we have nums, then this is probably a valid group.
 675     (when (setq nums (sort nums '<))
 676       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 677                     gnus-cache-active-hashtb))
 678     ;; Go through all the other files.
 679     (while alphs
 680       (when (and (file-directory-p (car alphs))
 681                  (not (string-match "^\\."
 682                                     (file-name-nondirectory (car alphs)))))
 683         ;; We descend directories.
 684         (gnus-cache-generate-active (car alphs)))
 685       (setq alphs (cdr alphs)))
 686     ;; Write the new active file.
 687     (when top
 688       (gnus-cache-write-active t)
 689       (gnus-message 5 "Generating the cache active file...done"))))
 690
 691 ;;;###autoload
 692 (defun gnus-cache-generate-nov-databases (dir)
 693   "Generate NOV files recursively starting in DIR."
 694   (interactive (list gnus-cache-directory))
 695   (gnus-cache-close)
 696   (let ((nnml-generate-active-function 'identity))
 697     (nnml-generate-nov-databases-1 dir))
 698   (gnus-cache-open))
 699
 700 (defun gnus-cache-move-cache (dir)
 701   "Move the cache tree to somewhere else."
 702   (interactive "FMove the cache tree to: ")
 703   (rename-file gnus-cache-directory dir))
 704
 705 (defun gnus-cache-fully-p (&optional group)
 706   "Returns non-nil if the cache should be fully used.
 707 If GROUP is non-nil, also cater to `gnus-cacheable-groups' and
 708 `gnus-uncacheable-groups'."
 709   (and gnus-use-cache
 710        (not (eq gnus-use-cache 'passive))
 711        (if (null group)
 712            t
 713          (and (or (not gnus-cacheable-groups)
 714                   (string-match gnus-cacheable-groups group))
 715               (or (not gnus-uncacheable-groups)
 716                   (not (string-match gnus-uncacheable-groups group)))))))
 717
 718
 719 (provide 'gnus-cache)
 720
 721 ;;; gnus-cache.el ends here