cgit.sxemacs.org Git - gnus/blob - lisp/gnus-art.el

   1 ;;; gnus-art.el --- article mode commands for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-sum)
  30 (require 'article)
  31 (require 'gnus-spec)
  32 (require 'gnus-int)
  33 (require 'browse-url)
  34
  35 (defcustom gnus-article-save-directory gnus-directory
  36   "*Name of the directory articles will be saved in (default \"~/News\")."
  37   :group 'article
  38   :type 'directory)
  39
  40 (defcustom gnus-save-all-headers t
  41   "*If non-nil, don't remove any headers before saving."
  42   :group 'article
  43   :type 'boolean)
  44
  45 (defcustom gnus-prompt-before-saving 'always
  46   "*This variable says how much prompting is to be done when saving articles.
  47 If it is nil, no prompting will be done, and the articles will be
  48 saved to the default files.  If this variable is `always', each and
  49 every article that is saved will be preceded by a prompt, even when
  50 saving large batches of articles.  If this variable is neither nil not
  51 `always', there the user will be prompted once for a file name for
  52 each invocation of the saving commands."
  53   :group 'article
  54   :type '(choice (item always)
  55                  (item :tag "never" nil)
  56                  (sexp :tag "once" :format "%t")))
  57
  58 (defcustom gnus-saved-headers gnus-visible-headers
  59   "Headers to keep if `gnus-save-all-headers' is nil.
  60 If `gnus-save-all-headers' is non-nil, this variable will be ignored.
  61 If that variable is nil, however, all headers that match this regexp
  62 will be kept while the rest will be deleted before saving."
  63   :group 'article
  64   :type '(repeat string))
  65
  66 (defcustom gnus-default-article-saver 'gnus-summary-save-in-rmail
  67   "A function to save articles in your favourite format.
  68 The function must be interactively callable (in other words, it must
  69 be an Emacs command).
  70
  71 Gnus provides the following functions:
  72
  73 * gnus-summary-save-in-rmail (Rmail format)
  74 * gnus-summary-save-in-mail (Unix mail format)
  75 * gnus-summary-save-in-folder (MH folder)
  76 * gnus-summary-save-in-file (article format)
  77 * gnus-summary-save-in-vm (use VM's folder format)
  78 * gnus-summary-write-to-file (article format -- overwrite)."
  79   :group 'article
  80   :type '(radio (function-item gnus-summary-save-in-rmail)
  81                 (function-item gnus-summary-save-in-mail)
  82                 (function-item gnus-summary-save-in-folder)
  83                 (function-item gnus-summary-save-in-file)
  84                 (function-item gnus-summary-save-in-vm)
  85                 (function-item gnus-summary-write-to-file)))
  86
  87 (defcustom gnus-rmail-save-name 'gnus-plain-save-name
  88   "A function generating a file name to save articles in Rmail format.
  89 The function is called with NEWSGROUP, HEADERS, and optional LAST-FILE."
  90   :group 'article
  91   :type 'function)
  92
  93 (defcustom gnus-mail-save-name 'gnus-plain-save-name
  94   "A function generating a file name to save articles in Unix mail format.
  95 The function is called with NEWSGROUP, HEADERS, and optional LAST-FILE."
  96   :group 'article
  97   :type 'function)
  98
  99 (defcustom gnus-folder-save-name 'gnus-folder-save-name
 100   "A function generating a file name to save articles in MH folder.
 101 The function is called with NEWSGROUP, HEADERS, and optional LAST-FOLDER."
 102   :group 'article
 103   :type 'function)
 104
 105 (defcustom gnus-file-save-name 'gnus-numeric-save-name
 106   "A function generating a file name to save articles in article format.
 107 The function is called with NEWSGROUP, HEADERS, and optional
 108 LAST-FILE."
 109   :group 'article
 110   :type 'function)
 111
 112 (defcustom gnus-split-methods
 113   '((gnus-article-archive-name))
 114   "Variable used to suggest where articles are to be saved.
 115 For instance, if you would like to save articles related to Gnus in
 116 the file \"gnus-stuff\", and articles related to VM in \"vm-stuff\",
 117 you could set this variable to something like:
 118
 119  '((\"^Subject:.*gnus\\|^Newsgroups:.*gnus\" \"gnus-stuff\")
 120    (\"^Subject:.*vm\\|^Xref:.*vm\" \"vm-stuff\"))
 121
 122 This variable is an alist where the where the key is the match and the
 123 value is a list of possible files to save in if the match is non-nil.
 124
 125 If the match is a string, it is used as a regexp match on the
 126 article.  If the match is a symbol, that symbol will be funcalled
 127 from the buffer of the article to be saved with the newsgroup as the
 128 parameter.  If it is a list, it will be evaled in the same buffer.
 129
 130 If this form or function returns a string, this string will be used as
 131 a possible file name; and if it returns a non-nil list, that list will
 132 be used as possible file names."
 133   :group 'article
 134   :type '(repeat (choice (list function)
 135                          (cons regexp (repeat string))
 136                          sexp)))
 137
 138 (defcustom gnus-strict-mime t
 139   "*If nil, MIME-decode even if there is no Mime-Version header."
 140   :group 'article
 141   :type 'boolean)
 142
 143 (defcustom gnus-show-mime-method 'metamail-buffer
 144   "Function to process a MIME message.
 145 The function is called from the article buffer."
 146   :group 'article
 147   :type 'function)
 148
 149 (defcustom gnus-decode-encoded-word-method (lambda ())
 150   "*Function to decode a MIME encoded-words.
 151 The function is called from the article buffer."
 152   :group 'article
 153   :type 'function)
 154
 155 (defcustom gnus-page-delimiter "^\^L"
 156   "*Regexp describing what to use as article page delimiters.
 157 The default value is \"^\^L\", which is a form linefeed at the
 158 beginning of a line."
 159   :type 'regexp
 160   :group 'article)
 161
 162 (defcustom gnus-article-mode-line-format "Gnus: %%b %S"
 163   "*The format specification for the article mode line.
 164 See `gnus-summary-mode-line-format' for a closer description."
 165   :type 'string
 166   :group 'article)
 167
 168 (defcustom gnus-article-mode-hook nil
 169   "*A hook for Gnus article mode."
 170   :type 'hook
 171   :group 'article)
 172
 173 (defcustom gnus-article-menu-hook nil
 174   "*Hook run after the creation of the article mode menu."
 175   :type 'hook
 176   :group 'article)
 177
 178 (defcustom gnus-article-prepare-hook nil
 179   "*A hook called after an article has been prepared in the article buffer.
 180 If you want to run a special decoding program like nkf, use this hook."
 181   :type 'hook
 182   :group 'article)
 183
 184 (defcustom gnus-article-button-face 'bold
 185   "Face used for highlighting buttons in the article buffer.
 186
 187 An article button is a piece of text that you can activate by pressing
 188 `RET' or `mouse-2' above it."
 189   :type 'face
 190   :group 'article)
 191
 192 (defcustom gnus-article-mouse-face 'highlight
 193   "Face used for mouse highlighting in the article buffer.
 194
 195 Article buttons will be displayed in this face when the cursor is
 196 above them."
 197   :type 'face
 198   :group 'article)
 199
 200 (defcustom gnus-signature-face 'italic
 201   "Face used for highlighting a signature in the article buffer."
 202   :type 'face
 203   :group 'article)
 204
 205 (defface gnus-header-from-face
 206   '((((class color)
 207       (background dark))
 208      (:foreground "light blue" :bold t :italic t))
 209     (((class color)
 210       (background light))
 211      (:foreground "MidnightBlue" :bold t :italic t))
 212     (t
 213      (:bold t :italic t)))
 214   "Face used for displaying from headers."
 215   :group 'article)
 216
 217 (defface gnus-header-subject-face
 218   '((((class color)
 219       (background dark))
 220      (:foreground "pink" :bold t :italic t))
 221     (((class color)
 222       (background light))
 223      (:foreground "firebrick" :bold t :italic t))
 224     (t
 225      (:bold t :italic t)))
 226   "Face used for displaying subject headers."
 227   :group 'article)
 228
 229 (defface gnus-header-newsgroups-face
 230   '((((class color)
 231       (background dark))
 232      (:foreground "yellow" :bold t :italic t))
 233     (((class color)
 234       (background light))
 235      (:foreground "indianred" :bold t :italic t))
 236     (t
 237      (:bold t :italic t)))
 238   "Face used for displaying newsgroups headers."
 239   :group 'article)
 240
 241 (defface gnus-header-name-face
 242   '((((class color)
 243       (background dark))
 244      (:foreground "cyan" :bold t))
 245     (((class color)
 246       (background light))
 247      (:foreground "DarkGreen" :bold t))
 248     (t
 249      (:bold t)))
 250   "Face used for displaying header names."
 251   :group 'article)
 252
 253 (defface gnus-header-content-face
 254   '((((class color)
 255       (background dark))
 256      (:foreground "forest green" :italic t))
 257     (((class color)
 258       (background light))
 259      (:foreground "DarkGreen" :italic t))
 260     (t
 261      (:italic t)))  "Face used for displaying header content."
 262   :group 'article)
 263
 264 (defcustom gnus-header-face-alist
 265   '(("From" nil gnus-header-from-face)
 266     ("Subject" nil gnus-header-subject-face)
 267     ("Newsgroups:.*," nil gnus-header-newsgroups-face)
 268     ("" gnus-header-name-face gnus-header-content-face))
 269   "Controls highlighting of article header.
 270
 271 An alist of the form (HEADER NAME CONTENT).
 272
 273 HEADER is a regular expression which should match the name of an
 274 header header and NAME and CONTENT are either face names or nil.
 275
 276 The name of each header field will be displayed using the face
 277 specified by the first element in the list where HEADER match the
 278 header name and NAME is non-nil.  Similarly, the content will be
 279 displayed by the first non-nil matching CONTENT face."
 280   :group 'article
 281   :type '(repeat (list (regexp :tag "Header")
 282                        (choice :tag "Name"
 283                                (item :tag "skip" nil)
 284                                (face :value default))
 285                        (choice :tag "Content"
 286                                (item :tag "skip" nil)
 287                                (face :value default)))))
 288
 289 (defvar gnus-article-mode-syntax-table
 290   (let ((table (copy-syntax-table text-mode-syntax-table)))
 291     ;;(modify-syntax-entry ?_ "w" table)
 292     table)
 293   "Syntax table used in article mode buffers.
 294 Initialized from `text-mode-syntax-table.")
 295
 296 ;;; Internal variables
 297
 298 (defvar gnus-save-article-buffer nil)
 299
 300 (defvar gnus-article-mode-line-format-alist
 301     (nconc '((?w (gnus-article-wash-status) ?s))
 302            gnus-summary-mode-line-format-alist))
 303
 304 (defvar gnus-number-of-articles-to-be-saved nil)
 305
 306 ;;; Provide a mapping from `gnus-*' commands to Article commands.
 307
 308 (eval-and-compile
 309   (mapcar
 310    (lambda (func)
 311      (let (afunc gfunc)
 312        (if (consp func)
 313            (setq afunc (car func)
 314                  gfunc (cdr func))
 315          (setq afunc func
 316                gfunc (intern (format "gnus-%s" func))))
 317        (fset gfunc
 318              `(lambda (&optional interactive &rest args)
 319                 ,(documentation afunc t)
 320                 (interactive (list t))
 321                 (save-excursion
 322                   (set-buffer gnus-article-buffer)
 323                   (if interactive
 324                       (call-interactively ',afunc)
 325                     (apply ',afunc args)))))))
 326    '(article-hide-headers
 327      article-hide-boring-headers
 328      article-treat-overstrike
 329      (article-fill . gnus-article-word-wrap)
 330      article-remove-cr
 331      article-display-x-face
 332      article-de-quoted-unreadable
 333      article-mime-decode-quoted-printable
 334      article-hide-pgp
 335      article-hide-pem
 336      article-hide-signature
 337      article-remove-trailing-blank-lines
 338      article-strip-leading-blank-lines
 339      article-strip-multiple-blank-lines
 340      article-strip-blank-lines
 341      article-date-local
 342      article-date-original
 343      article-date-lapsed
 344      article-emphasize
 345      (article-show-all . gnus-article-show-all-headers))))
 346
 347 (defalias 'gnus-decode-rfc1522 'article-decode-rfc1522)
 348
 349 ;;; Saving functions.
 350
 351 (defun gnus-article-save (save-buffer file &optional num)
 352   "Save the currently selected article."
 353   (unless gnus-save-all-headers
 354     ;; Remove headers according to `gnus-saved-headers'.
 355     (let ((gnus-visible-headers
 356            (or gnus-saved-headers gnus-visible-headers))
 357           (gnus-article-buffer save-buffer))
 358       (gnus-article-hide-headers 1 t)))
 359   (save-window-excursion
 360     (if (not gnus-default-article-saver)
 361         (error "No default saver is defined.")
 362       ;; !!! Magic!  The saving functions all save
 363       ;; `gnus-original-article-buffer' (or so they think), but we
 364       ;; bind that variable to our save-buffer.
 365       (set-buffer gnus-article-buffer)
 366       (let* ((gnus-save-article-buffer save-buffer)
 367              (filename
 368               (cond
 369                ((not gnus-prompt-before-saving) 'default)
 370                ((eq gnus-prompt-before-saving 'always) nil)
 371                (t file)))
 372              (gnus-number-of-articles-to-be-saved
 373               (when (eq gnus-prompt-before-saving t)
 374                 num)))                  ; Magic
 375         (set-buffer gnus-summary-buffer)
 376         (funcall gnus-default-article-saver filename)))))
 377
 378 (defun gnus-read-save-file-name (prompt default-name &optional filename)
 379   (cond
 380    ((eq filename 'default)
 381     default-name)
 382    (filename filename)
 383    (t
 384     (let* ((split-name (gnus-get-split-value gnus-split-methods))
 385            (prompt
 386             (format prompt (if (and gnus-number-of-articles-to-be-saved
 387                                     (> gnus-number-of-articles-to-be-saved 1))
 388                                (format "these %d articles"
 389                                        gnus-number-of-articles-to-be-saved)
 390                              "this article")))
 391            (file
 392             ;; Let the split methods have their say.
 393             (cond
 394              ;; No split name was found.
 395              ((null split-name)
 396               (read-file-name
 397                (concat prompt " (default "
 398                        (file-name-nondirectory default-name) ") ")
 399                (file-name-directory default-name)
 400                default-name))
 401              ;; A single split name was found
 402              ((= 1 (length split-name))
 403               (let* ((name (car split-name))
 404                      (dir (cond ((file-directory-p name)
 405                                  (file-name-as-directory name))
 406                                 ((file-exists-p name) name)
 407                                 (t gnus-article-save-directory))))
 408                 (read-file-name
 409                  (concat prompt " (default " name ") ")
 410                  dir name)))
 411              ;; A list of splits was found.
 412              (t
 413               (setq split-name (nreverse split-name))
 414               (let (result)
 415                 (let ((file-name-history (nconc split-name file-name-history)))
 416                   (setq result
 417                         (read-file-name
 418                          (concat prompt " (`M-p' for defaults) ")
 419                          gnus-article-save-directory
 420                          (car split-name))))
 421                 (car (push result file-name-history)))))))
 422       ;; Create the directory.
 423       (gnus-make-directory (file-name-directory file))
 424       ;; If we have read a directory, we append the default file name.
 425       (when (file-directory-p file)
 426         (setq file (concat (file-name-as-directory file)
 427                            (file-name-nondirectory default-name))))
 428       ;; Possibly translate some characters.
 429       (nnheader-translate-file-chars file)))))
 430
 431 (defun gnus-article-archive-name (group)
 432   "Return the first instance of an \"Archive-name\" in the current buffer."
 433   (let ((case-fold-search t))
 434     (when (re-search-forward "archive-name: *\\([^ \n\t]+\\)[ \t]*$" nil t)
 435       (nnheader-concat gnus-article-save-directory
 436                        (match-string 1)))))
 437
 438 (defun gnus-summary-save-in-rmail (&optional filename)
 439   "Append this article to Rmail file.
 440 Optional argument FILENAME specifies file name.
 441 Directory to save to is default to `gnus-article-save-directory'."
 442   (interactive)
 443   (gnus-set-global-variables)
 444   (let ((default-name
 445           (funcall gnus-rmail-save-name gnus-newsgroup-name
 446                    gnus-current-headers gnus-newsgroup-last-rmail)))
 447     (setq filename (gnus-read-save-file-name
 448                     "Save %s in rmail file:" default-name filename))
 449     (gnus-make-directory (file-name-directory filename))
 450     (gnus-eval-in-buffer-window gnus-save-article-buffer
 451       (save-excursion
 452         (save-restriction
 453           (widen)
 454           (gnus-output-to-rmail filename))))
 455     ;; Remember the directory name to save articles
 456     (setq gnus-newsgroup-last-rmail filename)))
 457
 458 (defun gnus-summary-save-in-mail (&optional filename)
 459   "Append this article to Unix mail file.
 460 Optional argument FILENAME specifies file name.
 461 Directory to save to is default to `gnus-article-save-directory'."
 462   (interactive)
 463   (gnus-set-global-variables)
 464   (let ((default-name
 465           (funcall gnus-mail-save-name gnus-newsgroup-name
 466                    gnus-current-headers gnus-newsgroup-last-mail)))
 467     (setq filename (gnus-read-save-file-name
 468                     "Save %s in Unix mail file:" default-name filename))
 469     (setq filename
 470           (expand-file-name filename
 471                             (and default-name
 472                                  (file-name-directory default-name))))
 473     (gnus-make-directory (file-name-directory filename))
 474     (gnus-eval-in-buffer-window gnus-save-article-buffer
 475       (save-excursion
 476         (save-restriction
 477           (widen)
 478           (if (and (file-readable-p filename) (mail-file-babyl-p filename))
 479               (gnus-output-to-rmail filename)
 480             (let ((mail-use-rfc822 t))
 481               (rmail-output filename 1 t t))))))
 482     ;; Remember the directory name to save articles.
 483     (setq gnus-newsgroup-last-mail filename)))
 484
 485 (defun gnus-summary-save-in-file (&optional filename overwrite)
 486   "Append this article to file.
 487 Optional argument FILENAME specifies file name.
 488 Directory to save to is default to `gnus-article-save-directory'."
 489   (interactive)
 490   (gnus-set-global-variables)
 491   (let ((default-name
 492           (funcall gnus-file-save-name gnus-newsgroup-name
 493                    gnus-current-headers gnus-newsgroup-last-file)))
 494     (setq filename (gnus-read-save-file-name
 495                     "Save %s in file:" default-name filename))
 496     (gnus-make-directory (file-name-directory filename))
 497     (gnus-eval-in-buffer-window gnus-save-article-buffer
 498       (save-excursion
 499         (save-restriction
 500           (widen)
 501           (when (and overwrite
 502                      (file-exists-p filename))
 503             (delete-file filename))
 504           (gnus-output-to-file filename))))
 505     ;; Remember the directory name to save articles.
 506     (setq gnus-newsgroup-last-file filename)))
 507
 508 (defun gnus-summary-write-to-file (&optional filename)
 509   "Write this article to a file.
 510 Optional argument FILENAME specifies file name.
 511 The directory to save in defaults to `gnus-article-save-directory'."
 512   (interactive)
 513   (gnus-summary-save-in-file nil t))
 514
 515 (defun gnus-summary-save-body-in-file (&optional filename)
 516   "Append this article body to a file.
 517 Optional argument FILENAME specifies file name.
 518 The directory to save in defaults to `gnus-article-save-directory'."
 519   (interactive)
 520   (gnus-set-global-variables)
 521   (let ((default-name
 522           (funcall gnus-file-save-name gnus-newsgroup-name
 523                    gnus-current-headers gnus-newsgroup-last-file)))
 524     (setq filename (gnus-read-save-file-name
 525                     "Save %s body in file:" default-name filename))
 526     (gnus-make-directory (file-name-directory filename))
 527     (gnus-eval-in-buffer-window gnus-save-article-buffer
 528       (save-excursion
 529         (save-restriction
 530           (widen)
 531           (goto-char (point-min))
 532           (when (search-forward "\n\n" nil t)
 533             (narrow-to-region (point) (point-max)))
 534           (gnus-output-to-file filename))))
 535     ;; Remember the directory name to save articles.
 536     (setq gnus-newsgroup-last-file filename)))
 537
 538 (defun gnus-summary-save-in-pipe (&optional command)
 539   "Pipe this article to subprocess."
 540   (interactive)
 541   (gnus-set-global-variables)
 542   (setq command
 543         (cond ((eq command 'default)
 544                gnus-last-shell-command)
 545               (command command)
 546               (t (read-string "Shell command on article: "
 547                               gnus-last-shell-command))))
 548   (when (string-equal command "")
 549     (setq command gnus-last-shell-command))
 550   (gnus-eval-in-buffer-window gnus-article-buffer
 551     (save-restriction
 552       (widen)
 553       (shell-command-on-region (point-min) (point-max) command nil)))
 554   (setq gnus-last-shell-command command))
 555
 556 ;;; Article file names when saving.
 557
 558 (defun gnus-capitalize-newsgroup (newsgroup)
 559   "Capitalize NEWSGROUP name."
 560   (when (not (zerop (length newsgroup)))
 561     (concat (char-to-string (upcase (aref newsgroup 0)))
 562             (substring newsgroup 1))))
 563
 564 (defun gnus-Numeric-save-name (newsgroup headers &optional last-file)
 565   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 566 If variable `gnus-use-long-file-name' is nil, it is ~/News/News.group/num.
 567 Otherwise, it is like ~/News/news/group/num."
 568   (let ((default
 569           (expand-file-name
 570            (concat (if (gnus-use-long-file-name 'not-save)
 571                        (gnus-capitalize-newsgroup newsgroup)
 572                      (gnus-newsgroup-directory-form newsgroup))
 573                    "/" (int-to-string (mail-header-number headers)))
 574            gnus-article-save-directory)))
 575     (if (and last-file
 576              (string-equal (file-name-directory default)
 577                            (file-name-directory last-file))
 578              (string-match "^[0-9]+$" (file-name-nondirectory last-file)))
 579         default
 580       (or last-file default))))
 581
 582 (defun gnus-numeric-save-name (newsgroup headers &optional last-file)
 583   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 584 If variable `gnus-use-long-file-name' is non-nil, it is
 585 ~/News/news.group/num.  Otherwise, it is like ~/News/news/group/num."
 586   (let ((default
 587           (expand-file-name
 588            (concat (if (gnus-use-long-file-name 'not-save)
 589                        newsgroup
 590                      (gnus-newsgroup-directory-form newsgroup))
 591                    "/" (int-to-string (mail-header-number headers)))
 592            gnus-article-save-directory)))
 593     (if (and last-file
 594              (string-equal (file-name-directory default)
 595                            (file-name-directory last-file))
 596              (string-match "^[0-9]+$" (file-name-nondirectory last-file)))
 597         default
 598       (or last-file default))))
 599
 600 (defun gnus-Plain-save-name (newsgroup headers &optional last-file)
 601   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 602 If variable `gnus-use-long-file-name' is non-nil, it is
 603 ~/News/News.group.  Otherwise, it is like ~/News/news/group/news."
 604   (or last-file
 605       (expand-file-name
 606        (if (gnus-use-long-file-name 'not-save)
 607            (gnus-capitalize-newsgroup newsgroup)
 608          (concat (gnus-newsgroup-directory-form newsgroup) "/news"))
 609        gnus-article-save-directory)))
 610
 611 (defun gnus-plain-save-name (newsgroup headers &optional last-file)
 612   "Generate file name from NEWSGROUP, HEADERS, and optional LAST-FILE.
 613 If variable `gnus-use-long-file-name' is non-nil, it is
 614 ~/News/news.group.  Otherwise, it is like ~/News/news/group/news."
 615   (or last-file
 616       (expand-file-name
 617        (if (gnus-use-long-file-name 'not-save)
 618            newsgroup
 619          (concat (gnus-newsgroup-directory-form newsgroup) "/news"))
 620        gnus-article-save-directory)))
 621
 622 \f
 623 ;;;
 624 ;;; Gnus article mode
 625 ;;;
 626
 627 (put 'gnus-article-mode 'mode-class 'special)
 628
 629 (when t
 630   (gnus-define-keys gnus-article-mode-map
 631     " " gnus-article-goto-next-page
 632     "\177" gnus-article-goto-prev-page
 633     [delete] gnus-article-goto-prev-page
 634     "\C-c^" gnus-article-refer-article
 635     "h" gnus-article-show-summary
 636     "s" gnus-article-show-summary
 637     "\C-c\C-m" gnus-article-mail
 638     "?" gnus-article-describe-briefly
 639     gnus-mouse-2 gnus-article-push-button
 640     "\r" gnus-article-press-button
 641     "\t" gnus-article-next-button
 642     "\M-\t" gnus-article-prev-button
 643     "e" gnus-article-edit
 644     "<" beginning-of-buffer
 645     ">" end-of-buffer
 646     "\C-c\C-i" gnus-info-find-node
 647     "\C-c\C-b" gnus-bug
 648
 649     "\C-d" gnus-article-read-summary-keys
 650     "\M-*" gnus-article-read-summary-keys
 651     "\M-g" gnus-article-read-summary-keys)
 652
 653   (substitute-key-definition
 654    'undefined 'gnus-article-read-summary-keys gnus-article-mode-map))
 655
 656 (defun gnus-article-make-menu-bar ()
 657   (gnus-turn-off-edit-menu 'article)
 658   (unless (boundp 'gnus-article-article-menu)
 659     (easy-menu-define
 660      gnus-article-article-menu gnus-article-mode-map ""
 661      '("Article"
 662        ["Scroll forwards" gnus-article-goto-next-page t]
 663        ["Scroll backwards" gnus-article-goto-prev-page t]
 664        ["Show summary" gnus-article-show-summary t]
 665        ["Fetch Message-ID at point" gnus-article-refer-article t]
 666        ["Mail to address at point" gnus-article-mail t]))
 667
 668     (easy-menu-define
 669      gnus-article-treatment-menu gnus-article-mode-map ""
 670      '("Treatment"
 671        ["Hide headers" gnus-article-hide-headers t]
 672        ["Hide signature" gnus-article-hide-signature t]
 673        ["Hide citation" gnus-article-hide-citation t]
 674        ["Treat overstrike" gnus-article-treat-overstrike t]
 675        ["Remove carriage return" gnus-article-remove-cr t]
 676        ["Remove quoted-unreadable" gnus-article-de-quoted-unreadable t]))
 677
 678     (when nil
 679     (define-key gnus-article-mode-map
 680       (vector 'menu-bar (car gnus-summary-article-menu))
 681       gnus-summary-article-menu))
 682
 683     (run-hooks 'gnus-article-menu-hook)))
 684
 685 (defun gnus-article-mode ()
 686   "Major mode for displaying an article.
 687
 688 All normal editing commands are switched off.
 689
 690 The following commands are available in addition to all summary mode
 691 commands:
 692 \\<gnus-article-mode-map>
 693 \\[gnus-article-next-page]\t Scroll the article one page forwards
 694 \\[gnus-article-prev-page]\t Scroll the article one page backwards
 695 \\[gnus-article-refer-article]\t Go to the article referred to by an article id near point
 696 \\[gnus-article-show-summary]\t Display the summary buffer
 697 \\[gnus-article-mail]\t Send a reply to the address near point
 698 \\[gnus-article-describe-briefly]\t Describe the current mode briefly
 699 \\[gnus-info-find-node]\t Go to the Gnus info node"
 700   (interactive)
 701   (when (and menu-bar-mode
 702              (gnus-visual-p 'article-menu 'menu))
 703     (gnus-article-make-menu-bar))
 704   (kill-all-local-variables)
 705   (gnus-simplify-mode-line)
 706   (setq mode-name "Article")
 707   (setq major-mode 'gnus-article-mode)
 708   (make-local-variable 'minor-mode-alist)
 709   (unless (assq 'gnus-show-mime minor-mode-alist)
 710     (push (list 'gnus-show-mime " MIME") minor-mode-alist))
 711   (use-local-map gnus-article-mode-map)
 712   (gnus-update-format-specifications nil 'article-mode)
 713   (set (make-local-variable 'page-delimiter) gnus-page-delimiter)
 714   (gnus-set-default-directory)
 715   (buffer-disable-undo (current-buffer))
 716   (setq buffer-read-only t)
 717   (set-syntax-table gnus-article-mode-syntax-table)
 718   (run-hooks 'gnus-article-mode-hook))
 719
 720 (defun gnus-article-setup-buffer ()
 721   "Initialize the article buffer."
 722   (let* ((name (if gnus-single-article-buffer "*Article*"
 723                  (concat "*Article " gnus-newsgroup-name "*")))
 724          (original
 725           (progn (string-match "\\*Article" name)
 726                  (concat " *Original Article"
 727                          (substring name (match-end 0))))))
 728     (setq gnus-article-buffer name)
 729     (setq gnus-original-article-buffer original)
 730     ;; This might be a variable local to the summary buffer.
 731     (unless gnus-single-article-buffer
 732       (save-excursion
 733         (set-buffer gnus-summary-buffer)
 734         (setq gnus-article-buffer name)
 735         (setq gnus-original-article-buffer original)
 736         (gnus-set-global-variables)))
 737     ;; Init original article buffer.
 738     (save-excursion
 739       (set-buffer (get-buffer-create gnus-original-article-buffer))
 740       (buffer-disable-undo (current-buffer))
 741       (setq major-mode 'gnus-original-article-mode)
 742       (gnus-add-current-to-buffer-list)
 743       (make-local-variable 'gnus-original-article))
 744     (if (get-buffer name)
 745         (save-excursion
 746           (set-buffer name)
 747           (buffer-disable-undo (current-buffer))
 748           (setq buffer-read-only t)
 749           (gnus-add-current-to-buffer-list)
 750           (unless (eq major-mode 'gnus-article-mode)
 751             (gnus-article-mode))
 752           (current-buffer))
 753       (save-excursion
 754         (set-buffer (get-buffer-create name))
 755         (gnus-add-current-to-buffer-list)
 756         (gnus-article-mode)
 757         (make-local-variable 'gnus-summary-buffer)
 758         (current-buffer)))))
 759
 760 ;; Set article window start at LINE, where LINE is the number of lines
 761 ;; from the head of the article.
 762 (defun gnus-article-set-window-start (&optional line)
 763   (set-window-start
 764    (get-buffer-window gnus-article-buffer t)
 765    (save-excursion
 766      (set-buffer gnus-article-buffer)
 767      (goto-char (point-min))
 768      (if (not line)
 769          (point-min)
 770        (gnus-message 6 "Moved to bookmark")
 771        (search-forward "\n\n" nil t)
 772        (forward-line line)
 773        (point)))))
 774
 775 (defun gnus-article-prepare (article &optional all-headers header)
 776   "Prepare ARTICLE in article mode buffer.
 777 ARTICLE should either be an article number or a Message-ID.
 778 If ARTICLE is an id, HEADER should be the article headers.
 779 If ALL-HEADERS is non-nil, no headers are hidden."
 780   (save-excursion
 781     ;; Make sure we start in a summary buffer.
 782     (unless (eq major-mode 'gnus-summary-mode)
 783       (set-buffer gnus-summary-buffer))
 784     (setq gnus-summary-buffer (current-buffer))
 785     ;; Make sure the connection to the server is alive.
 786     (unless (gnus-server-opened
 787              (gnus-find-method-for-group gnus-newsgroup-name))
 788       (gnus-check-server (gnus-find-method-for-group gnus-newsgroup-name))
 789       (gnus-request-group gnus-newsgroup-name t))
 790     (let* ((article (if header (mail-header-number header) article))
 791            (summary-buffer (current-buffer))
 792            (internal-hook gnus-article-internal-prepare-hook)
 793            (group gnus-newsgroup-name)
 794            result)
 795       (save-excursion
 796         (gnus-article-setup-buffer)
 797         (set-buffer gnus-article-buffer)
 798         ;; Deactivate active regions.
 799         (when (and (boundp 'transient-mark-mode)
 800                    transient-mark-mode)
 801           (setq mark-active nil))
 802         (if (not (setq result (let ((buffer-read-only nil))
 803                                 (gnus-request-article-this-buffer
 804                                  article group))))
 805             ;; There is no such article.
 806             (save-excursion
 807               (when (and (numberp article)
 808                          (not (memq article gnus-newsgroup-sparse)))
 809                 (setq gnus-article-current
 810                       (cons gnus-newsgroup-name article))
 811                 (set-buffer gnus-summary-buffer)
 812                 (setq gnus-current-article article)
 813                 (gnus-summary-mark-article article gnus-canceled-mark))
 814               (unless (memq article gnus-newsgroup-sparse)
 815                 (gnus-error
 816                  1 "No such article (may have expired or been canceled)")))
 817           (if (or (eq result 'pseudo) (eq result 'nneething))
 818               (progn
 819                 (save-excursion
 820                   (set-buffer summary-buffer)
 821                   (setq gnus-last-article gnus-current-article
 822                         gnus-newsgroup-history (cons gnus-current-article
 823                                                      gnus-newsgroup-history)
 824                         gnus-current-article 0
 825                         gnus-current-headers nil
 826                         gnus-article-current nil)
 827                   (if (eq result 'nneething)
 828                       (gnus-configure-windows 'summary)
 829                     (gnus-configure-windows 'article))
 830                   (gnus-set-global-variables))
 831                 (gnus-set-mode-line 'article))
 832             ;; The result from the `request' was an actual article -
 833             ;; or at least some text that is now displayed in the
 834             ;; article buffer.
 835             (when (and (numberp article)
 836                        (not (eq article gnus-current-article)))
 837               ;; Seems like a new article has been selected.
 838               ;; `gnus-current-article' must be an article number.
 839               (save-excursion
 840                 (set-buffer summary-buffer)
 841                 (setq gnus-last-article gnus-current-article
 842                       gnus-newsgroup-history (cons gnus-current-article
 843                                                    gnus-newsgroup-history)
 844                       gnus-current-article article
 845                       gnus-current-headers
 846                       (gnus-summary-article-header gnus-current-article)
 847                       gnus-article-current
 848                       (cons gnus-newsgroup-name gnus-current-article))
 849                 (unless (vectorp gnus-current-headers)
 850                   (setq gnus-current-headers nil))
 851                 (gnus-summary-show-thread)
 852                 (run-hooks 'gnus-mark-article-hook)
 853                 (gnus-set-mode-line 'summary)
 854                 (when (gnus-visual-p 'article-highlight 'highlight)
 855                   (run-hooks 'gnus-visual-mark-article-hook))
 856                 ;; Set the global newsgroup variables here.
 857                 ;; Suggested by Jim Sisolak
 858                 ;; <sisolak@trans4.neep.wisc.edu>.
 859                 (gnus-set-global-variables)
 860                 (setq gnus-have-all-headers
 861                       (or all-headers gnus-show-all-headers))
 862                 (and gnus-use-cache
 863                      (vectorp (gnus-summary-article-header article))
 864                      (gnus-cache-possibly-enter-article
 865                       group article
 866                       (gnus-summary-article-header article)
 867                       (memq article gnus-newsgroup-marked)
 868                       (memq article gnus-newsgroup-dormant)
 869                       (memq article gnus-newsgroup-unreads)))))
 870             (when (or (numberp article)
 871                       (stringp article))
 872               ;; Hooks for getting information from the article.
 873               ;; This hook must be called before being narrowed.
 874               (let (buffer-read-only)
 875                 (run-hooks 'internal-hook)
 876                 (run-hooks 'gnus-article-prepare-hook)
 877                 ;; Decode MIME message.
 878                 (when gnus-show-mime
 879                   (if (or (not gnus-strict-mime)
 880                           (gnus-fetch-field "Mime-Version"))
 881                       (funcall gnus-show-mime-method)
 882                     (funcall gnus-decode-encoded-word-method)))
 883                 ;; Perform the article display hooks.
 884                 (run-hooks 'gnus-article-display-hook))
 885               ;; Do page break.
 886               (goto-char (point-min))
 887               (when gnus-break-pages
 888                 (gnus-narrow-to-page)))
 889             (gnus-set-mode-line 'article)
 890             (gnus-configure-windows 'article)
 891             (goto-char (point-min))
 892             t))))))
 893
 894 (defun gnus-article-wash-status ()
 895   "Return a string which display status of article washing."
 896   (save-excursion
 897     (set-buffer gnus-article-buffer)
 898     (let ((cite (article-hidden-text-p 'cite))
 899           (headers (article-hidden-text-p 'headers))
 900           (boring (article-hidden-text-p 'boring-headers))
 901           (pgp (article-hidden-text-p 'pgp))
 902           (pem (article-hidden-text-p 'pem))
 903           (signature (article-hidden-text-p 'signature))
 904           (overstrike (article-hidden-text-p 'overstrike))
 905           (emphasis (article-hidden-text-p 'emphasis))
 906           (mime gnus-show-mime))
 907       (format "%c%c%c%c%c%c%c"
 908               (if cite ?c ? )
 909               (if (or headers boring) ?h ? )
 910               (if (or pgp pem) ?p ? )
 911               (if signature ?s ? )
 912               (if overstrike ?o ? )
 913               (if mime ?m ? )
 914               (if emphasis ?e ? )))))
 915
 916 (defun gnus-article-hide-headers-if-wanted ()
 917   "Hide unwanted headers if `gnus-have-all-headers' is nil.
 918 Provided for backwards compatibility."
 919   (or (save-excursion (set-buffer gnus-summary-buffer) gnus-have-all-headers)
 920       gnus-inhibit-hiding
 921       (gnus-article-hide-headers)))
 922
 923 ;;; Article savers.
 924
 925 (defun gnus-output-to-rmail (file-name)
 926   "Append the current article to an Rmail file named FILE-NAME."
 927   (require 'rmail)
 928   ;; Most of these codes are borrowed from rmailout.el.
 929   (setq file-name (expand-file-name file-name))
 930   (setq rmail-default-rmail-file file-name)
 931   (let ((artbuf (current-buffer))
 932         (tmpbuf (get-buffer-create " *Gnus-output*")))
 933     (save-excursion
 934       (or (get-file-buffer file-name)
 935           (file-exists-p file-name)
 936           (if (gnus-yes-or-no-p
 937                (concat "\"" file-name "\" does not exist, create it? "))
 938               (let ((file-buffer (create-file-buffer file-name)))
 939                 (save-excursion
 940                   (set-buffer file-buffer)
 941                   (rmail-insert-rmail-file-header)
 942                   (let ((require-final-newline nil))
 943                     (gnus-write-buffer file-name)))
 944                 (kill-buffer file-buffer))
 945             (error "Output file does not exist")))
 946       (set-buffer tmpbuf)
 947       (buffer-disable-undo (current-buffer))
 948       (erase-buffer)
 949       (insert-buffer-substring artbuf)
 950       (gnus-convert-article-to-rmail)
 951       ;; Decide whether to append to a file or to an Emacs buffer.
 952       (let ((outbuf (get-file-buffer file-name)))
 953         (if (not outbuf)
 954             (append-to-file (point-min) (point-max) file-name)
 955           ;; File has been visited, in buffer OUTBUF.
 956           (set-buffer outbuf)
 957           (let ((buffer-read-only nil)
 958                 (msg (and (boundp 'rmail-current-message)
 959                           (symbol-value 'rmail-current-message))))
 960             ;; If MSG is non-nil, buffer is in RMAIL mode.
 961             (when msg
 962               (widen)
 963               (narrow-to-region (point-max) (point-max)))
 964             (insert-buffer-substring tmpbuf)
 965             (when msg
 966               (goto-char (point-min))
 967               (widen)
 968               (search-backward "\^_")
 969               (narrow-to-region (point) (point-max))
 970               (goto-char (1+ (point-min)))
 971               (rmail-count-new-messages t)
 972               (rmail-show-message msg))))))
 973     (kill-buffer tmpbuf)))
 974
 975 (defun gnus-output-to-file (file-name)
 976   "Append the current article to a file named FILE-NAME."
 977   (let ((artbuf (current-buffer)))
 978     (nnheader-temp-write nil
 979       (insert-buffer-substring artbuf)
 980       ;; Append newline at end of the buffer as separator, and then
 981       ;; save it to file.
 982       (goto-char (point-max))
 983       (insert "\n")
 984       (append-to-file (point-min) (point-max) file-name))))
 985
 986 (defun gnus-convert-article-to-rmail ()
 987   "Convert article in current buffer to Rmail message format."
 988   (let ((buffer-read-only nil))
 989     ;; Convert article directly into Babyl format.
 990     ;; Suggested by Rob Austein <sra@lcs.mit.edu>
 991     (goto-char (point-min))
 992     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 993     (while (search-forward "\n\^_" nil t) ;single char
 994       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 995     (goto-char (point-max))
 996     (insert "\^_")))
 997
 998 (defun gnus-narrow-to-page (&optional arg)
 999   "Narrow the article buffer to a page.
1000 If given a numerical ARG, move forward ARG pages."
1001   (interactive "P")
1002   (setq arg (if arg (prefix-numeric-value arg) 0))
1003   (save-excursion
1004     (set-buffer gnus-article-buffer)
1005     (goto-char (point-min))
1006     (widen)
1007     ;; Remove any old next/prev buttons.
1008     (when (gnus-visual-p 'page-marker)
1009       (let ((buffer-read-only nil))
1010         (gnus-remove-text-with-property 'gnus-prev)
1011         (gnus-remove-text-with-property 'gnus-next)))
1012     (when
1013         (cond ((< arg 0)
1014                (re-search-backward page-delimiter nil 'move (1+ (abs arg))))
1015               ((> arg 0)
1016                (re-search-forward page-delimiter nil 'move arg)))
1017       (goto-char (match-end 0)))
1018     (narrow-to-region
1019      (point)
1020      (if (re-search-forward page-delimiter nil 'move)
1021          (match-beginning 0)
1022        (point)))
1023     (when (and (gnus-visual-p 'page-marker)
1024                (not (= (point-min) 1)))
1025       (save-excursion
1026         (goto-char (point-min))
1027         (gnus-insert-prev-page-button)))
1028     (when (and (gnus-visual-p 'page-marker)
1029                (< (+ (point-max) 2) (buffer-size)))
1030       (save-excursion
1031         (goto-char (point-max))
1032         (gnus-insert-next-page-button)))))
1033
1034 ;; Article mode commands
1035
1036 (defun gnus-article-goto-next-page ()
1037   "Show the next page of the article."
1038   (interactive)
1039   (when (gnus-article-next-page)
1040     (gnus-article-read-summary-keys nil (gnus-character-to-event ?n))))
1041
1042 (defun gnus-article-goto-prev-page ()
1043   "Show the next page of the article."
1044   (interactive)
1045   (if (bobp) (gnus-article-read-summary-keys nil (gnus-character-to-event ?n))
1046     (gnus-article-prev-page nil)))
1047
1048 (defun gnus-article-next-page (&optional lines)
1049   "Show the next page of the current article.
1050 If end of article, return non-nil.  Otherwise return nil.
1051 Argument LINES specifies lines to be scrolled up."
1052   (interactive "p")
1053   (move-to-window-line -1)
1054   (if (save-excursion
1055         (end-of-line)
1056         (and (pos-visible-in-window-p)  ;Not continuation line.
1057              (eobp)))
1058       ;; Nothing in this page.
1059       (if (or (not gnus-break-pages)
1060               (save-excursion
1061                 (save-restriction
1062                   (widen) (forward-line 1) (eobp)))) ;Real end-of-buffer?
1063           t                             ;Nothing more.
1064         (gnus-narrow-to-page 1)         ;Go to next page.
1065         nil)
1066     ;; More in this page.
1067     (condition-case ()
1068         (scroll-up lines)
1069       (end-of-buffer
1070        ;; Long lines may cause an end-of-buffer error.
1071        (goto-char (point-max))))
1072     (move-to-window-line 0)
1073     nil))
1074
1075 (defun gnus-article-prev-page (&optional lines)
1076   "Show previous page of current article.
1077 Argument LINES specifies lines to be scrolled down."
1078   (interactive "p")
1079   (move-to-window-line 0)
1080   (if (and gnus-break-pages
1081            (bobp)
1082            (not (save-restriction (widen) (bobp)))) ;Real beginning-of-buffer?
1083       (progn
1084         (gnus-narrow-to-page -1)        ;Go to previous page.
1085         (goto-char (point-max))
1086         (recenter -1))
1087     (prog1
1088         (ignore-errors
1089           (scroll-down lines))
1090       (move-to-window-line 0))))
1091
1092 (defun gnus-article-refer-article ()
1093   "Read article specified by message-id around point."
1094   (interactive)
1095   (let ((point (point)))
1096     (search-forward ">" nil t)          ;Move point to end of "<....>".
1097     (if (re-search-backward "\\(<[^<> \t\n]+>\\)" nil t)
1098         (let ((message-id (match-string 1)))
1099           (goto-char point)
1100           (set-buffer gnus-summary-buffer)
1101           (gnus-summary-refer-article message-id))
1102       (goto-char (point))
1103       (error "No references around point"))))
1104
1105 (defun gnus-article-show-summary ()
1106   "Reconfigure windows to show summary buffer."
1107   (interactive)
1108   (gnus-configure-windows 'article)
1109   (gnus-summary-goto-subject gnus-current-article))
1110
1111 (defun gnus-article-describe-briefly ()
1112   "Describe article mode commands briefly."
1113   (interactive)
1114   (gnus-message 6
1115                 (substitute-command-keys "\\<gnus-article-mode-map>\\[gnus-article-goto-next-page]:Next page     \\[gnus-article-goto-prev-page]:Prev page  \\[gnus-article-show-summary]:Show summary  \\[gnus-info-find-node]:Run Info  \\[gnus-article-describe-briefly]:This help")))
1116
1117 (defun gnus-article-summary-command ()
1118   "Execute the last keystroke in the summary buffer."
1119   (interactive)
1120   (let ((obuf (current-buffer))
1121         (owin (current-window-configuration))
1122         func)
1123     (switch-to-buffer gnus-summary-buffer 'norecord)
1124     (setq func (lookup-key (current-local-map) (this-command-keys)))
1125     (call-interactively func)
1126     (set-buffer obuf)
1127     (set-window-configuration owin)
1128     (set-window-point (get-buffer-window (current-buffer)) (point))))
1129
1130 (defun gnus-article-summary-command-nosave ()
1131   "Execute the last keystroke in the summary buffer."
1132   (interactive)
1133   (let (func)
1134     (pop-to-buffer gnus-summary-buffer 'norecord)
1135     (setq func (lookup-key (current-local-map) (this-command-keys)))
1136     (call-interactively func)))
1137
1138 (defun gnus-article-read-summary-keys (&optional arg key not-restore-window)
1139   "Read a summary buffer key sequence and execute it from the article buffer."
1140   (interactive "P")
1141   (let ((nosaves
1142          '("q" "Q"  "c" "r" "R" "\C-c\C-f" "m"  "a" "f" "F"
1143            "Zc" "ZC" "ZE" "ZQ" "ZZ" "Zn" "ZR" "ZG" "ZN" "ZP"
1144            "=" "^" "\M-^" "|"))
1145         (nosave-but-article
1146          '("A\r"))
1147         (nosave-in-article
1148          '("\C-d"))
1149         keys)
1150     (save-excursion
1151       (set-buffer gnus-summary-buffer)
1152       (push (or key last-command-event) unread-command-events)
1153       (setq keys (read-key-sequence nil)))
1154     (message "")
1155
1156     (if (or (member keys nosaves)
1157             (member keys nosave-but-article)
1158             (member keys nosave-in-article))
1159         (let (func)
1160           (save-window-excursion
1161             (pop-to-buffer gnus-summary-buffer 'norecord)
1162             (setq func (lookup-key (current-local-map) keys)))
1163           (if (not func)
1164               (ding)
1165             (unless (member keys nosave-in-article)
1166               (set-buffer gnus-summary-buffer))
1167             (call-interactively func))
1168           (when (member keys nosave-but-article)
1169             (pop-to-buffer gnus-article-buffer 'norecord)))
1170       ;; These commands should restore window configuration.
1171       (let ((obuf (current-buffer))
1172             (owin (current-window-configuration))
1173             (opoint (point))
1174             func in-buffer)
1175         (if not-restore-window
1176             (pop-to-buffer gnus-summary-buffer 'norecord)
1177           (switch-to-buffer gnus-summary-buffer 'norecord))
1178         (setq in-buffer (current-buffer))
1179         (if (setq func (lookup-key (current-local-map) keys))
1180             (call-interactively func)
1181           (ding))
1182         (when (eq in-buffer (current-buffer))
1183           (set-buffer obuf)
1184           (unless not-restore-window
1185             (set-window-configuration owin))
1186           (set-window-point (get-buffer-window (current-buffer)) opoint))))))
1187
1188 (defun gnus-article-hide (&optional arg force)
1189   "Hide all the gruft in the current article.
1190 This means that PGP stuff, signatures, cited text and (some)
1191 headers will be hidden.
1192 If given a prefix, show the hidden text instead."
1193   (interactive (list current-prefix-arg 'force))
1194   (gnus-article-hide-headers arg)
1195   (gnus-article-hide-pgp arg)
1196   (gnus-article-hide-citation-maybe arg force)
1197   (gnus-article-hide-signature arg))
1198
1199 (defun gnus-article-maybe-highlight ()
1200   "Do some article highlighting if `article-visual' is non-nil."
1201   (when (gnus-visual-p 'article-highlight 'highlight)
1202     (gnus-article-highlight-some)))
1203
1204 (defun gnus-request-article-this-buffer (article group)
1205   "Get an article and insert it into this buffer."
1206   (let (do-update-line)
1207     (prog1
1208         (save-excursion
1209           (erase-buffer)
1210           (gnus-kill-all-overlays)
1211           (setq group (or group gnus-newsgroup-name))
1212
1213           ;; Open server if it has closed.
1214           (gnus-check-server (gnus-find-method-for-group group))
1215
1216           ;; Using `gnus-request-article' directly will insert the article into
1217           ;; `nntp-server-buffer' - so we'll save some time by not having to
1218           ;; copy it from the server buffer into the article buffer.
1219
1220           ;; We only request an article by message-id when we do not have the
1221           ;; headers for it, so we'll have to get those.
1222           (when (stringp article)
1223             (let ((gnus-override-method gnus-refer-article-method))
1224               (gnus-read-header article)))
1225
1226           ;; If the article number is negative, that means that this article
1227           ;; doesn't belong in this newsgroup (possibly), so we find its
1228           ;; message-id and request it by id instead of number.
1229           (when (and (numberp article)
1230                      gnus-summary-buffer
1231                      (get-buffer gnus-summary-buffer)
1232                      (buffer-name (get-buffer gnus-summary-buffer)))
1233             (save-excursion
1234               (set-buffer gnus-summary-buffer)
1235               (let ((header (gnus-summary-article-header article)))
1236                 (when (< article 0)
1237                   (cond
1238                    ((memq article gnus-newsgroup-sparse)
1239                     ;; This is a sparse gap article.
1240                     (setq do-update-line article)
1241                     (setq article (mail-header-id header))
1242                     (let ((gnus-override-method gnus-refer-article-method))
1243                       (gnus-read-header article))
1244                     (setq gnus-newsgroup-sparse
1245                           (delq article gnus-newsgroup-sparse)))
1246                    ((vectorp header)
1247                     ;; It's a real article.
1248                     (setq article (mail-header-id header)))
1249                    (t
1250                     ;; It is an extracted pseudo-article.
1251                     (setq article 'pseudo)
1252                     (gnus-request-pseudo-article header))))
1253
1254                 (let ((method (gnus-find-method-for-group
1255                                gnus-newsgroup-name)))
1256                   (if (not (eq (car method) 'nneething))
1257                       ()
1258                     (let ((dir (concat (file-name-as-directory (nth 1 method))
1259                                        (mail-header-subject header))))
1260                       (when (file-directory-p dir)
1261                         (setq article 'nneething)
1262                         (gnus-group-enter-directory dir))))))))
1263
1264           (cond
1265            ;; Refuse to select canceled articles.
1266            ((and (numberp article)
1267                  gnus-summary-buffer
1268                  (get-buffer gnus-summary-buffer)
1269                  (buffer-name (get-buffer gnus-summary-buffer))
1270                  (eq (cdr (save-excursion
1271                             (set-buffer gnus-summary-buffer)
1272                             (assq article gnus-newsgroup-reads)))
1273                      gnus-canceled-mark))
1274             nil)
1275            ;; We first check `gnus-original-article-buffer'.
1276            ((and (get-buffer gnus-original-article-buffer)
1277                  (numberp article)
1278                  (save-excursion
1279                    (set-buffer gnus-original-article-buffer)
1280                    (and (equal (car gnus-original-article) group)
1281                         (eq (cdr gnus-original-article) article))))
1282             (insert-buffer-substring gnus-original-article-buffer)
1283             'article)
1284            ;; Check the backlog.
1285            ((and gnus-keep-backlog
1286                  (gnus-backlog-request-article group article (current-buffer)))
1287             'article)
1288            ;; Check asynchronous pre-fetch.
1289            ((gnus-async-request-fetched-article group article (current-buffer))
1290             (gnus-async-prefetch-next group article gnus-summary-buffer)
1291             'article)
1292            ;; Check the cache.
1293            ((and gnus-use-cache
1294                  (numberp article)
1295                  (gnus-cache-request-article article group))
1296             'article)
1297            ;; Get the article and put into the article buffer.
1298            ((or (stringp article) (numberp article))
1299             (let ((gnus-override-method
1300                    (and (stringp article) gnus-refer-article-method))
1301                   (buffer-read-only nil))
1302               (erase-buffer)
1303               (gnus-kill-all-overlays)
1304               (when (gnus-request-article article group (current-buffer))
1305                 (when (numberp article)
1306                   (gnus-async-prefetch-next group article gnus-summary-buffer)
1307                   (when gnus-keep-backlog
1308                     (gnus-backlog-enter-article
1309                      group article (current-buffer))))
1310                 'article)))
1311            ;; It was a pseudo.
1312            (t article)))
1313
1314       ;; Take the article from the original article buffer
1315       ;; and place it in the buffer it's supposed to be in.
1316       (when (and (get-buffer gnus-article-buffer)
1317                  ;;(numberp article)
1318                  (equal (buffer-name (current-buffer))
1319                         (buffer-name (get-buffer gnus-article-buffer))))
1320         (save-excursion
1321           (if (get-buffer gnus-original-article-buffer)
1322               (set-buffer (get-buffer gnus-original-article-buffer))
1323             (set-buffer (get-buffer-create gnus-original-article-buffer))
1324             (buffer-disable-undo (current-buffer))
1325             (setq major-mode 'gnus-original-article-mode)
1326             (setq buffer-read-only t)
1327             (gnus-add-current-to-buffer-list))
1328           (let (buffer-read-only)
1329             (erase-buffer)
1330             (insert-buffer-substring gnus-article-buffer))
1331           (setq gnus-original-article (cons group article))))
1332
1333       ;; Update sparse articles.
1334       (when (and do-update-line
1335                  (or (numberp article)
1336                      (stringp article)))
1337         (let ((buf (current-buffer)))
1338           (set-buffer gnus-summary-buffer)
1339           (gnus-summary-update-article do-update-line)
1340           (gnus-summary-goto-subject do-update-line nil t)
1341           (set-window-point (get-buffer-window (current-buffer) t)
1342                             (point))
1343           (set-buffer buf))))))
1344
1345 (defun gnus-article-date-ut (&optional type highlight)
1346   "Convert DATE date to universal time in the current article.
1347 If TYPE is `local', convert to local time; if it is `lapsed', output
1348 how much time has lapsed since DATE."
1349   (interactive (list 'ut t))
1350   (let ((headers (or gnus-current-headers (gnus-summary-article-header))))
1351     (save-excursion
1352       (set-buffer gnus-article-buffer)
1353       (article-date-ut type highlight headers))))
1354
1355 ;;;
1356 ;;; Article editing
1357 ;;;
1358
1359 (defcustom gnus-article-edit-mode-hook nil
1360   "Hook run in article edit mode buffers."
1361   :group 'article
1362   :type 'hook)
1363
1364 (defvar gnus-article-edit-done-function nil)
1365
1366 (defvar gnus-article-edit-mode-map nil)
1367
1368 (unless gnus-article-edit-mode-map
1369   (setq gnus-article-edit-mode-map (copy-keymap text-mode-map))
1370
1371   (gnus-define-keys gnus-article-edit-mode-map
1372     "\C-c\C-c" gnus-article-edit-done
1373     "\C-c\C-k" gnus-article-edit-exit)
1374
1375   (gnus-define-keys (gnus-article-edit-wash-map
1376                      "\C-c\C-w" gnus-article-edit-mode-map)
1377     "f" gnus-article-edit-full-stops))
1378
1379 (defun gnus-article-edit-mode ()
1380   "Major mode for editing articles.
1381 This is an extended text-mode.
1382
1383 \\{gnus-article-edit-mode-map}"
1384   (interactive)
1385   (kill-all-local-variables)
1386   (setq major-mode 'gnus-article-edit-mode)
1387   (setq mode-name "Article Edit")
1388   (use-local-map gnus-article-edit-mode-map)
1389   (make-local-variable 'gnus-article-edit-done-function)
1390   (make-local-variable 'gnus-prev-winconf)
1391   (setq buffer-read-only nil)
1392   (buffer-enable-undo)
1393   (widen)
1394   (run-hooks 'text-mode 'gnus-article-edit-mode-hook))
1395
1396 (defun gnus-article-edit (&optional force)
1397   "Edit the current article.
1398 This will have permanent effect only in mail groups.
1399 If FORCE is non-nil, allow editing of articles even in read-only
1400 groups."
1401   (interactive "P")
1402   (when (and (not force)
1403              (gnus-group-read-only-p))
1404     (error "The current newsgroup does not support article editing."))
1405   (gnus-article-edit-article
1406    `(lambda ()
1407       (gnus-summary-edit-article-done
1408        ,(or (mail-header-references gnus-current-headers) "")
1409        ,(gnus-group-read-only-p) ,gnus-summary-buffer))))
1410
1411 (defun gnus-article-edit-article (exit-func)
1412   "Start editing the contents of the current article buffer."
1413   (let ((winconf (current-window-configuration)))
1414     (set-buffer gnus-article-buffer)
1415     (gnus-article-edit-mode)
1416     (set-text-properties (point-min) (point-max) nil)
1417     (gnus-configure-windows 'edit-article)
1418     (setq gnus-article-edit-done-function exit-func)
1419     (setq gnus-prev-winconf winconf)
1420     (gnus-message 6 "C-c C-c to end edits")))
1421
1422 (defun gnus-article-edit-done ()
1423   "Update the article edits and exit."
1424   (interactive)
1425   (let ((func gnus-article-edit-done-function)
1426         (buf (current-buffer))
1427         (start (window-start)))
1428     (gnus-article-edit-exit)
1429     (save-excursion
1430       (set-buffer buf)
1431       (let ((buffer-read-only nil))
1432         (funcall func)))
1433     (set-buffer buf)
1434     (set-window-start (get-buffer-window buf) start)
1435     (set-window-point (get-buffer-window buf) (point))))
1436
1437 (defun gnus-article-edit-exit ()
1438   "Exit the article editing without updating."
1439   (interactive)
1440   ;; We remove all text props from the article buffer.
1441   (let ((buf (format "%s" (buffer-string)))
1442         (curbuf (current-buffer))
1443         (p (point))
1444         (window-start (window-start)))
1445     (erase-buffer)
1446     (insert buf)
1447     (let ((winconf gnus-prev-winconf))
1448       (gnus-article-mode)
1449       ;; The cache and backlog have to be flushed somewhat.
1450       (when gnus-use-cache
1451         (gnus-cache-update-article
1452          (car gnus-article-current) (cdr gnus-article-current)))
1453       (when gnus-keep-backlog
1454         (gnus-backlog-remove-article
1455          (car gnus-article-current) (cdr gnus-article-current)))
1456       ;; Flush original article as well.
1457       (save-excursion
1458         (when (get-buffer gnus-original-article-buffer)
1459           (set-buffer gnus-original-article-buffer)
1460           (setq gnus-original-article nil)))
1461       (set-window-configuration winconf)
1462       ;; Tippy-toe some to make sure that point remains where it was.
1463       (let ((buf (current-buffer)))
1464         (set-buffer curbuf)
1465         (set-window-start (get-buffer-window (current-buffer)) window-start)
1466         (goto-char p)
1467         (set-buffer buf)))))
1468
1469 (defun gnus-article-edit-full-stops ()
1470   "Interactively repair spacing at end of sentences."
1471   (interactive)
1472   (save-excursion
1473     (goto-char (point-min))
1474     (search-forward-regexp "^$" nil t)
1475     (let ((case-fold-search nil))
1476       (query-replace-regexp "\\([.!?][])}]* \\)\\([[({A-Z]\\)" "\\1 \\2"))))
1477
1478 ;;;
1479 ;;; Article highlights
1480 ;;;
1481
1482 ;; Written by Per Abrahamsen <abraham@iesd.auc.dk>.
1483
1484 ;;; Internal Variables:
1485
1486 (defcustom gnus-button-url-regexp "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|telnet\\|wais\\|mailto\\):\\(//[-a-zA-Z0-9_.]+:[0-9]*\\)?[-\\wa-zA-Z0-9_=!?#$@~`%&*+|\\/:;.,]*[-\\wa-zA-Z0-9_=#$@~`%&*+|\\/]"
1487   "Regular expression that matches URLs."
1488   :group 'article
1489   :type 'regexp)
1490
1491 (defcustom gnus-button-alist
1492   `(("\\bin\\( +article\\)? +\\(<\\([^\n @<>]+@[^\n @<>]+\\)>\\)" 2
1493      t gnus-button-message-id 3)
1494     ("\\(<?\\(url: ?\\)?news://\\([^>\n\t ]*\\)>?\\)" 1 t
1495      gnus-button-fetch-group 3)
1496     ("\\(<?\\(url: ?\\)?news:\\([^>\n\t ]*\\)>?\\)" 1 t
1497      gnus-button-message-id 3)
1498     ("\\(<URL: *\\)?mailto: *\\([^> \n\t]+\\)>?" 0 t gnus-url-mailto 2)
1499     ;; This is how URLs _should_ be embedded in text...
1500     ("<URL: *\\([^\n\r>]*\\)>" 0 t gnus-button-url 1)
1501     ;; Next regexp stolen from highlight-headers.el.
1502     ;; Modified by Vladimir Alexiev.
1503     (,gnus-button-url-regexp 0 t gnus-button-url 0))
1504   "Alist of regexps matching buttons in article bodies.
1505
1506 Each entry has the form (REGEXP BUTTON FORM CALLBACK PAR...), where
1507 REGEXP: is the string matching text around the button,
1508 BUTTON: is the number of the regexp grouping actually matching the button,
1509 FORM: is a lisp expression which must eval to true for the button to
1510 be added,
1511 CALLBACK: is the function to call when the user push this button, and each
1512 PAR: is a number of a regexp grouping whose text will be passed to CALLBACK.
1513
1514 CALLBACK can also be a variable, in that case the value of that
1515 variable it the real callback function."
1516   :group 'article
1517   :type '(repeat (list regexp
1518                        (integer :tag "Button")
1519                        (sexp :tag "Form")
1520                        (function :tag "Callback")
1521                        (repeat :tag "Par"
1522                                :inline t
1523                                (integer :tag "Regexp group")))))
1524
1525 (defcustom gnus-header-button-alist
1526   `(("^\\(References\\|Message-I[Dd]\\):" "<[^>]+>"
1527      0 t gnus-button-message-id 0)
1528     ("^\\(From\\|Reply-To\\):" ": *\\(.+\\)$" 1 t gnus-button-reply 1)
1529     ("^\\(Cc\\|To\\):" "[^ \t\n<>,()\"]+@[^ \t\n<>,()\"]+"
1530      0 t gnus-button-mailto 0)
1531     ("^X-[Uu][Rr][Ll]:" ,gnus-button-url-regexp 0 t gnus-button-url 0)
1532     ("^[^:]+:" ,gnus-button-url-regexp 0 t gnus-button-url 0)
1533     ("^[^:]+:" "\\(<\\(url: \\)?news:\\([^>\n ]*\\)>\\)" 1 t
1534      gnus-button-message-id 3))
1535   "Alist of headers and regexps to match buttons in article heads.
1536
1537 This alist is very similar to `gnus-button-alist', except that each
1538 alist has an additional HEADER element first in each entry:
1539
1540 \(HEADER REGEXP BUTTON FORM CALLBACK PAR)
1541
1542 HEADER is a regexp to match a header.  For a fuller explanation, see
1543 `gnus-button-alist'."
1544   :group 'article
1545   :type '(repeat (list (regexp :tag "Header")
1546                        regexp
1547                        (integer :tag "Button")
1548                        (sexp :tag "Form")
1549                        (function :tag "Callback")
1550                        (repeat :tag "Par"
1551                                :inline t
1552                                (integer :tag "Regexp group")))))
1553
1554 (defvar gnus-button-regexp nil)
1555 (defvar gnus-button-marker-list nil)
1556 ;; Regexp matching any of the regexps from `gnus-button-alist'.
1557
1558 (defvar gnus-button-last nil)
1559 ;; The value of `gnus-button-alist' when `gnus-button-regexp' was build.
1560
1561 ;;; Commands:
1562
1563 (defun gnus-article-push-button (event)
1564   "Check text under the mouse pointer for a callback function.
1565 If the text under the mouse pointer has a `gnus-callback' property,
1566 call it with the value of the `gnus-data' text property."
1567   (interactive "e")
1568   (set-buffer (window-buffer (posn-window (event-start event))))
1569   (let* ((pos (posn-point (event-start event)))
1570          (data (get-text-property pos 'gnus-data))
1571          (fun (get-text-property pos 'gnus-callback)))
1572     (when fun
1573       (funcall fun data))))
1574
1575 (defun gnus-article-press-button ()
1576   "Check text at point for a callback function.
1577 If the text at point has a `gnus-callback' property,
1578 call it with the value of the `gnus-data' text property."
1579   (interactive)
1580   (let* ((data (get-text-property (point) 'gnus-data))
1581          (fun (get-text-property (point) 'gnus-callback)))
1582     (when fun
1583       (funcall fun data))))
1584
1585 (defun gnus-article-prev-button (n)
1586   "Move point to N buttons backward.
1587 If N is negative, move forward instead."
1588   (interactive "p")
1589   (gnus-article-next-button (- n)))
1590
1591 (defun gnus-article-next-button (n)
1592   "Move point to N buttons forward.
1593 If N is negative, move backward instead."
1594   (interactive "p")
1595   (let ((function (if (< n 0) 'previous-single-property-change
1596                     'next-single-property-change))
1597         (inhibit-point-motion-hooks t)
1598         (backward (< n 0))
1599         (limit (if (< n 0) (point-min) (point-max))))
1600     (setq n (abs n))
1601     (while (and (not (= limit (point)))
1602                 (> n 0))
1603       ;; Skip past the current button.
1604       (when (get-text-property (point) 'gnus-callback)
1605         (goto-char (funcall function (point) 'gnus-callback nil limit)))
1606       ;; Go to the next (or previous) button.
1607       (gnus-goto-char (funcall function (point) 'gnus-callback nil limit))
1608       ;; Put point at the start of the button.
1609       (when (and backward (not (get-text-property (point) 'gnus-callback)))
1610         (goto-char (funcall function (point) 'gnus-callback nil limit)))
1611       ;; Skip past intangible buttons.
1612       (when (get-text-property (point) 'intangible)
1613         (incf n))
1614       (decf n))
1615     (unless (zerop n)
1616       (gnus-message 5 "No more buttons"))
1617     n))
1618
1619 (defun gnus-article-highlight (&optional force)
1620   "Highlight current article.
1621 This function calls `gnus-article-highlight-headers',
1622 `gnus-article-highlight-citation',
1623 `gnus-article-highlight-signature', and `gnus-article-add-buttons' to
1624 do the highlighting.  See the documentation for those functions."
1625   (interactive (list 'force))
1626   (gnus-article-highlight-headers)
1627   (gnus-article-highlight-citation force)
1628   (gnus-article-highlight-signature)
1629   (gnus-article-add-buttons force)
1630   (gnus-article-add-buttons-to-head))
1631
1632 (defun gnus-article-highlight-some (&optional force)
1633   "Highlight current article.
1634 This function calls `gnus-article-highlight-headers',
1635 `gnus-article-highlight-signature', and `gnus-article-add-buttons' to
1636 do the highlighting.  See the documentation for those functions."
1637   (interactive (list 'force))
1638   (gnus-article-highlight-headers)
1639   (gnus-article-highlight-signature)
1640   (gnus-article-add-buttons))
1641
1642 (defun gnus-article-highlight-headers ()
1643   "Highlight article headers as specified by `gnus-header-face-alist'."
1644   (interactive)
1645   (save-excursion
1646     (set-buffer gnus-article-buffer)
1647     (save-restriction
1648       (let ((alist gnus-header-face-alist)
1649             (buffer-read-only nil)
1650             (case-fold-search t)
1651             (inhibit-point-motion-hooks t)
1652             entry regexp header-face field-face from hpoints fpoints)
1653         (goto-char (point-min))
1654         (when (search-forward "\n\n" nil t)
1655           (narrow-to-region (1- (point)) (point-min))
1656           (while (setq entry (pop alist))
1657             (goto-char (point-min))
1658             (setq regexp (concat "^\\("
1659                                  (if (string-equal "" (nth 0 entry))
1660                                      "[^\t ]"
1661                                    (nth 0 entry))
1662                                  "\\)")
1663                   header-face (nth 1 entry)
1664                   field-face (nth 2 entry))
1665             (while (and (re-search-forward regexp nil t)
1666                         (not (eobp)))
1667               (beginning-of-line)
1668               (setq from (point))
1669               (unless (search-forward ":" nil t)
1670                 (forward-char 1))
1671               (when (and header-face
1672                          (not (memq (point) hpoints)))
1673                 (push (point) hpoints)
1674                 (gnus-put-text-property from (point) 'face header-face))
1675               (when (and field-face
1676                          (not (memq (setq from (point)) fpoints)))
1677                 (push from fpoints)
1678                 (if (re-search-forward "^[^ \t]" nil t)
1679                     (forward-char -2)
1680                   (goto-char (point-max)))
1681                 (gnus-put-text-property from (point) 'face field-face)))))))))
1682
1683 (defun gnus-article-highlight-signature ()
1684   "Highlight the signature in an article.
1685 It does this by highlighting everything after
1686 `gnus-signature-separator' using `gnus-signature-face'."
1687   (interactive)
1688   (save-excursion
1689     (set-buffer gnus-article-buffer)
1690     (let ((buffer-read-only nil)
1691           (inhibit-point-motion-hooks t))
1692       (save-restriction
1693         (when (and gnus-signature-face
1694                    (article-narrow-to-signature))
1695           (gnus-overlay-put (gnus-make-overlay (point-min) (point-max))
1696                             'face gnus-signature-face)
1697           (widen)
1698           (article-search-signature)
1699           (let ((start (match-beginning 0))
1700                 (end (set-marker (make-marker) (1+ (match-end 0)))))
1701             (gnus-article-add-button start (1- end) 'gnus-signature-toggle
1702                                      end)))))))
1703
1704 (defun gnus-article-add-buttons (&optional force)
1705   "Find external references in the article and make buttons of them.
1706 \"External references\" are things like Message-IDs and URLs, as
1707 specified by `gnus-button-alist'."
1708   (interactive (list 'force))
1709   (save-excursion
1710     (set-buffer gnus-article-buffer)
1711     ;; Remove all old markers.
1712     (while gnus-button-marker-list
1713       (set-marker (pop gnus-button-marker-list) nil))
1714     (let ((buffer-read-only nil)
1715           (inhibit-point-motion-hooks t)
1716           (case-fold-search t)
1717           (alist gnus-button-alist)
1718           beg entry regexp)
1719       (goto-char (point-min))
1720       ;; We skip the headers.
1721       (unless (search-forward "\n\n" nil t)
1722         (goto-char (point-max)))
1723       (setq beg (point))
1724       (while (setq entry (pop alist))
1725         (setq regexp (car entry))
1726         (goto-char beg)
1727         (while (re-search-forward regexp nil t)
1728           (let* ((start (and entry (match-beginning (nth 1 entry))))
1729                  (end (and entry (match-end (nth 1 entry))))
1730                  (from (match-beginning 0)))
1731             (when (or (eq t (nth 1 entry))
1732                       (eval (nth 1 entry)))
1733               ;; That optional form returned non-nil, so we add the
1734               ;; button.
1735               (gnus-article-add-button
1736                start end 'gnus-button-push
1737                (car (push (set-marker (make-marker) from)
1738                           gnus-button-marker-list))))))))))
1739
1740 ;; Add buttons to the head of an article.
1741 (defun gnus-article-add-buttons-to-head ()
1742   "Add buttons to the head of the article."
1743   (interactive)
1744   (save-excursion
1745     (set-buffer gnus-article-buffer)
1746     (let ((buffer-read-only nil)
1747           (inhibit-point-motion-hooks t)
1748           (case-fold-search t)
1749           (alist gnus-header-button-alist)
1750           entry beg end)
1751       (nnheader-narrow-to-headers)
1752       (while alist
1753         ;; Each alist entry.
1754         (setq entry (car alist)
1755               alist (cdr alist))
1756         (goto-char (point-min))
1757         (while (re-search-forward (car entry) nil t)
1758           ;; Each header matching the entry.
1759           (setq beg (match-beginning 0))
1760           (setq end (or (and (re-search-forward "^[^ \t]" nil t)
1761                              (match-beginning 0))
1762                         (point-max)))
1763           (goto-char beg)
1764           (while (re-search-forward (nth 1 entry) end t)
1765             ;; Each match within a header.
1766             (let* ((entry (cdr entry))
1767                    (start (match-beginning (nth 1 entry)))
1768                    (end (match-end (nth 1 entry)))
1769                    (form (nth 2 entry)))
1770               (goto-char (match-end 0))
1771               (when (eval form)
1772                 (gnus-article-add-button
1773                  start end (nth 3 entry)
1774                  (buffer-substring (match-beginning (nth 4 entry))
1775                                    (match-end (nth 4 entry)))))))
1776           (goto-char end))))
1777     (widen)))
1778
1779 ;;; External functions:
1780
1781 (defun gnus-article-add-button (from to fun &optional data)
1782   "Create a button between FROM and TO with callback FUN and data DATA."
1783   (when gnus-article-button-face
1784     (gnus-overlay-put (gnus-make-overlay from to)
1785                       'face gnus-article-button-face))
1786   (gnus-add-text-properties
1787    from to
1788    (nconc (and gnus-article-mouse-face
1789                (list gnus-mouse-face-prop gnus-article-mouse-face))
1790           (list 'gnus-callback fun)
1791           (and data (list 'gnus-data data)))))
1792
1793 ;;; Internal functions:
1794
1795 (defun gnus-signature-toggle (end)
1796   (save-excursion
1797     (set-buffer gnus-article-buffer)
1798     (let ((buffer-read-only nil)
1799           (inhibit-point-motion-hooks t))
1800       (if (get-text-property end 'invisible)
1801           (article-unhide-text end (point-max))
1802         (article-hide-text end (point-max) gnus-hidden-properties)))))
1803
1804 (defun gnus-button-entry ()
1805   ;; Return the first entry in `gnus-button-alist' matching this place.
1806   (let ((alist gnus-button-alist)
1807         (entry nil))
1808     (while alist
1809       (setq entry (pop alist))
1810       (if (looking-at (car entry))
1811           (setq alist nil)
1812         (setq entry nil)))
1813     entry))
1814
1815 (defun gnus-button-push (marker)
1816   ;; Push button starting at MARKER.
1817   (save-excursion
1818     (set-buffer gnus-article-buffer)
1819     (goto-char marker)
1820     (let* ((entry (gnus-button-entry))
1821            (inhibit-point-motion-hooks t)
1822            (fun (nth 3 entry))
1823            (args (mapcar (lambda (group)
1824                            (let ((string (buffer-substring
1825                                           (match-beginning group)
1826                                           (match-end group))))
1827                              (gnus-set-text-properties
1828                               0 (length string) nil string)
1829                              string))
1830                          (nthcdr 4 entry))))
1831       (cond
1832        ((fboundp fun)
1833         (apply fun args))
1834        ((and (boundp fun)
1835              (fboundp (symbol-value fun)))
1836         (apply (symbol-value fun) args))
1837        (t
1838         (gnus-message 1 "You must define `%S' to use this button"
1839                       (cons fun args)))))))
1840
1841 (defun gnus-button-message-id (message-id)
1842   "Fetch MESSAGE-ID."
1843   (save-excursion
1844     (set-buffer gnus-summary-buffer)
1845     (gnus-summary-refer-article message-id)))
1846
1847 (defun gnus-button-fetch-group (address)
1848   "Fetch GROUP specified by ADDRESS."
1849   (if (not (string-match "^\\([^:/]+\\)\\(:\\([^/]+\\)\\)?/\\(.*\\)$" address))
1850       (error "Can't parse %s" address)
1851     (gnus-group-read-ephemeral-group
1852      (match-string 4 address)
1853      `(nntp ,(match-string 1 address) (nntp-address ,(match-string 1 address))
1854             (nntp-port-number ,(if (match-end 3)
1855                                    (match-string 3 address)
1856                                  "nntp"))))))
1857
1858 (defun gnus-split-string (string pattern)
1859   "Return a list of substrings of STRING which are separated by PATTERN."
1860   (let (parts (start 0))
1861     (while (string-match pattern string start)
1862       (setq parts (cons (substring string start (match-beginning 0)) parts)
1863             start (match-end 0)))
1864     (nreverse (cons (substring string start) parts))))
1865
1866 (defun gnus-url-parse-query-string (query &optional downcase)
1867   (let (retval pairs cur key val)
1868     (setq pairs (gnus-split-string query "&"))
1869     (while pairs
1870       (setq cur (car pairs)
1871             pairs (cdr pairs))
1872       (if (not (string-match "=" cur))
1873           nil                           ; Grace
1874         (setq key (gnus-url-unhex-string (substring cur 0 (match-beginning 0)))
1875               val (gnus-url-unhex-string (substring cur (match-end 0) nil)))
1876         (if downcase
1877             (setq key (downcase key)))
1878         (setq cur (assoc key retval))
1879         (if cur
1880             (setcdr cur (cons val (cdr cur)))
1881           (setq retval (cons (list key val) retval)))))
1882     retval))
1883
1884 (defun gnus-url-unhex (x)
1885   (if (> x ?9)
1886       (if (>= x ?a)
1887           (+ 10 (- x ?a))
1888         (+ 10 (- x ?A)))
1889     (- x ?0)))
1890
1891 (defun gnus-url-unhex-string (str &optional allow-newlines)
1892   "Remove %XXX embedded spaces, etc in a url.
1893 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1894 decoding of carriage returns and line feeds in the string, which is normally
1895 forbidden in URL encoding."
1896   (setq str (or str ""))
1897   (let ((tmp "")
1898         (case-fold-search t))
1899     (while (string-match "%[0-9a-f][0-9a-f]" str)
1900       (let* ((start (match-beginning 0))
1901              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1902              (code (+ (* 16 ch1)
1903                       (gnus-url-unhex (elt str (+ start 2))))))
1904         (setq tmp (concat
1905                    tmp (substring str 0 start)
1906                    (cond
1907                     (allow-newlines
1908                      (char-to-string code))
1909                     ((or (= code ?\n) (= code ?\r))
1910                      " ")
1911                     (t (char-to-string code))))
1912               str (substring str (match-end 0)))))
1913     (setq tmp (concat tmp str))
1914     tmp))
1915
1916 (defun gnus-url-mailto (url)
1917   ;; Send mail to someone
1918   (if (not (string-match "mailto:/*\\(.*\\)" url))
1919       (error "Malformed mailto link: %s" url))
1920   (setq url (substring url (match-beginning 1) nil))
1921   (let (to args source-url subject func)
1922     (if (string-match (regexp-quote "?") url)
1923         (setq to (gnus-url-unhex-string (substring url 0 (match-beginning 0)))
1924               args (gnus-url-parse-query-string
1925                     (substring url (match-end 0) nil) t))
1926       (setq to (gnus-url-unhex-string url)))
1927     (setq args (cons (list "to" to) args)
1928           subject (cdr-safe (assoc "subject" args)))
1929     (message-mail)
1930     (while args
1931       (setq func (intern-soft (concat "message-goto-" (downcase (caar args)))))
1932       (if (fboundp func)
1933           (funcall func)
1934         (message-position-on-field (caar args)))
1935       (insert (mapconcat 'identity (cdar args) ", "))
1936       (setq args (cdr args)))
1937     (if subject
1938         (message-goto-body)
1939       (message-goto-subject))))
1940
1941 (defun gnus-button-mailto (address)
1942   ;; Mail to ADDRESS.
1943   (set-buffer (gnus-copy-article-buffer))
1944   (message-reply address))
1945
1946 (defun gnus-button-reply (address)
1947   ;; Reply to ADDRESS.
1948   (message-reply address))
1949
1950 (defun gnus-button-url (address)
1951   "Browse ADDRESS."
1952   (funcall browse-url-browser-function address))
1953
1954 ;;; Next/prev buttons in the article buffer.
1955
1956 (defvar gnus-next-page-line-format "%{%(Next page...%)%}\n")
1957 (defvar gnus-prev-page-line-format "%{%(Previous page...%)%}\n")
1958
1959 (defvar gnus-prev-page-map nil)
1960 (unless gnus-prev-page-map
1961   (setq gnus-prev-page-map (make-sparse-keymap))
1962   (define-key gnus-prev-page-map gnus-mouse-2 'gnus-button-prev-page)
1963   (define-key gnus-prev-page-map "\r" 'gnus-button-prev-page))
1964
1965 (defun gnus-insert-prev-page-button ()
1966   (let ((buffer-read-only nil))
1967     (gnus-eval-format
1968      gnus-prev-page-line-format nil
1969      `(gnus-prev t local-map ,gnus-prev-page-map
1970                  gnus-callback gnus-article-button-prev-page))))
1971
1972 (defvar gnus-next-page-map nil)
1973 (unless gnus-next-page-map
1974   (setq gnus-next-page-map (make-keymap))
1975   (suppress-keymap gnus-prev-page-map)
1976   (define-key gnus-next-page-map gnus-mouse-2 'gnus-button-next-page)
1977   (define-key gnus-next-page-map "\r" 'gnus-button-next-page))
1978
1979 (defun gnus-button-next-page ()
1980   "Go to the next page."
1981   (interactive)
1982   (let ((win (selected-window)))
1983     (select-window (get-buffer-window gnus-article-buffer t))
1984     (gnus-article-next-page)
1985     (select-window win)))
1986
1987 (defun gnus-button-prev-page ()
1988   "Go to the prev page."
1989   (interactive)
1990   (let ((win (selected-window)))
1991     (select-window (get-buffer-window gnus-article-buffer t))
1992     (gnus-article-prev-page)
1993     (select-window win)))
1994
1995 (defun gnus-insert-next-page-button ()
1996   (let ((buffer-read-only nil))
1997     (gnus-eval-format gnus-next-page-line-format nil
1998                       `(gnus-next t local-map ,gnus-next-page-map
1999                                   gnus-callback
2000                                   gnus-article-button-next-page))))
2001
2002 (defun gnus-article-button-next-page (arg)
2003   "Go to the next page."
2004   (interactive "P")
2005   (let ((win (selected-window)))
2006     (select-window (get-buffer-window gnus-article-buffer t))
2007     (gnus-article-next-page)
2008     (select-window win)))
2009
2010 (defun gnus-article-button-prev-page (arg)
2011   "Go to the prev page."
2012   (interactive "P")
2013   (let ((win (selected-window)))
2014     (select-window (get-buffer-window gnus-article-buffer t))
2015     (gnus-article-prev-page)
2016     (select-window win)))
2017
2018 (provide 'gnus-art)
2019
2020 (run-hooks 'gnus-art-load-hook)
2021
2022 ;;; gnus-art.el ends here