cgit.sxemacs.org Git - gnus/blob - lisp/gnus-agent.el

   1 ;;; gnus-agent.el --- unplugged support for Gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'gnus)
  27 (require 'gnus-cache)
  28 (require 'nnvirtual)
  29 (require 'gnus-sum)
  30 (eval-when-compile
  31   (require 'cl)
  32   (require 'gnus-score))
  33
  34 (defcustom gnus-agent-directory (nnheader-concat gnus-directory "agent/")
  35   "Where the Gnus agent will store its files."
  36   :group 'gnus-agent
  37   :type 'directory)
  38
  39 (defcustom gnus-agent-plugged-hook nil
  40   "Hook run when plugging into the network."
  41   :group 'gnus-agent
  42   :type 'hook)
  43
  44 (defcustom gnus-agent-unplugged-hook nil
  45   "Hook run when unplugging from the network."
  46   :group 'gnus-agent
  47   :type 'hook)
  48
  49 (defcustom gnus-agent-handle-level gnus-level-subscribed
  50   "Groups on levels higher than this variable will be ignored by the Agent."
  51   :group 'gnus-agent
  52   :type 'integer)
  53
  54 (defcustom gnus-agent-expire-days 7
  55   "Read articles older than this will be expired."
  56   :group 'gnus-agent
  57   :type 'integer)
  58
  59 (defcustom gnus-agent-expire-all nil
  60   "If non-nil, also expire unread, ticked and dormant articles.
  61 If nil, only read articles will be expired."
  62   :group 'gnus-agent
  63   :type 'boolean)
  64
  65 (defcustom gnus-agent-group-mode-hook nil
  66   "Hook run in Agent group minor modes."
  67   :group 'gnus-agent
  68   :type 'hook)
  69
  70 (defcustom gnus-agent-summary-mode-hook nil
  71   "Hook run in Agent summary minor modes."
  72   :group 'gnus-agent
  73   :type 'hook)
  74
  75 (defcustom gnus-agent-server-mode-hook nil
  76   "Hook run in Agent summary minor modes."
  77   :group 'gnus-agent
  78   :type 'hook)
  79
  80 ;;; Internal variables
  81
  82 (defvar gnus-agent-history-buffers nil)
  83 (defvar gnus-agent-buffer-alist nil)
  84 (defvar gnus-agent-article-alist nil)
  85 (defvar gnus-agent-group-alist nil)
  86 (defvar gnus-agent-covered-methods nil)
  87 (defvar gnus-category-alist nil)
  88 (defvar gnus-agent-current-history nil)
  89 (defvar gnus-agent-overview-buffer nil)
  90 (defvar gnus-category-predicate-cache nil)
  91 (defvar gnus-category-group-cache nil)
  92 (defvar gnus-agent-spam-hashtb nil)
  93 (defvar gnus-agent-file-name nil)
  94 (defvar gnus-agent-send-mail-function nil)
  95 (defvar gnus-agent-file-coding-system 'no-conversion)
  96
  97 (defconst gnus-agent-scoreable-headers
  98   (list
  99    "subject" "from" "date" "message-id"
 100    "references" "chars" "lines" "xref")
 101   "Headers that are considered when scoring articles
 102 for download via the Agent.")
 103
 104 ;; Dynamic variables
 105 (defvar gnus-headers)
 106 (defvar gnus-score)
 107
 108 ;;;
 109 ;;; Setup
 110 ;;;
 111
 112 (defun gnus-open-agent ()
 113   (setq gnus-agent t)
 114   (gnus-agent-read-servers)
 115   (gnus-category-read)
 116   (setq gnus-agent-overview-buffer
 117         (gnus-get-buffer-create " *Gnus agent overview*"))
 118   (with-current-buffer gnus-agent-overview-buffer
 119     (mm-enable-multibyte))
 120   (add-hook 'gnus-group-mode-hook 'gnus-agent-mode)
 121   (add-hook 'gnus-summary-mode-hook 'gnus-agent-mode)
 122   (add-hook 'gnus-server-mode-hook 'gnus-agent-mode))
 123
 124 (gnus-add-shutdown 'gnus-close-agent 'gnus)
 125
 126 (defun gnus-close-agent ()
 127   (setq gnus-agent-covered-methods nil
 128         gnus-category-predicate-cache nil
 129         gnus-category-group-cache nil
 130         gnus-agent-spam-hashtb nil)
 131   (gnus-kill-buffer gnus-agent-overview-buffer))
 132
 133 ;;;
 134 ;;; Utility functions
 135 ;;;
 136
 137 (defun gnus-agent-read-file (file)
 138   "Load FILE and do a `read' there."
 139   (with-temp-buffer
 140     (ignore-errors
 141       (nnheader-insert-file-contents file)
 142       (goto-char (point-min))
 143       (read (current-buffer)))))
 144
 145 (defsubst gnus-agent-method ()
 146   (concat (symbol-name (car gnus-command-method)) "/"
 147           (if (equal (cadr gnus-command-method) "")
 148               "unnamed"
 149             (cadr gnus-command-method))))
 150
 151 (defsubst gnus-agent-directory ()
 152   "Path of the Gnus agent directory."
 153   (nnheader-concat gnus-agent-directory
 154                    (nnheader-translate-file-chars (gnus-agent-method)) "/"))
 155
 156 (defun gnus-agent-lib-file (file)
 157   "The full path of the Gnus agent library FILE."
 158   (concat (gnus-agent-directory) "agent.lib/" file))
 159
 160 ;;; Fetching setup functions.
 161
 162 (defun gnus-agent-start-fetch ()
 163   "Initialize data structures for efficient fetching."
 164   (gnus-agent-open-history)
 165   (setq gnus-agent-current-history (gnus-agent-history-buffer)))
 166
 167 (defun gnus-agent-stop-fetch ()
 168   "Save all data structures and clean up."
 169   (gnus-agent-save-history)
 170   (gnus-agent-close-history)
 171   (setq gnus-agent-spam-hashtb nil)
 172   (save-excursion
 173     (set-buffer nntp-server-buffer)
 174     (widen)))
 175
 176 (defmacro gnus-agent-with-fetch (&rest forms)
 177   "Do FORMS safely."
 178   `(unwind-protect
 179        (progn
 180          (gnus-agent-start-fetch)
 181          ,@forms)
 182      (gnus-agent-stop-fetch)))
 183
 184 (put 'gnus-agent-with-fetch 'lisp-indent-function 0)
 185 (put 'gnus-agent-with-fetch 'edebug-form-spec '(body))
 186
 187 ;;;
 188 ;;; Mode infestation
 189 ;;;
 190
 191 (defvar gnus-agent-mode-hook nil
 192   "Hook run when installing agent mode.")
 193
 194 (defvar gnus-agent-mode nil)
 195 (defvar gnus-agent-mode-status '(gnus-agent-mode " Plugged"))
 196
 197 (defun gnus-agent-mode ()
 198   "Minor mode for providing a agent support in Gnus buffers."
 199   (let* ((buffer (progn (string-match "^gnus-\\(.*\\)-mode$"
 200                                       (symbol-name major-mode))
 201                         (match-string 1 (symbol-name major-mode))))
 202          (mode (intern (format "gnus-agent-%s-mode" buffer))))
 203     (set (make-local-variable 'gnus-agent-mode) t)
 204     (set mode nil)
 205     (set (make-local-variable mode) t)
 206     ;; Set up the menu.
 207     (when (gnus-visual-p 'agent-menu 'menu)
 208       (funcall (intern (format "gnus-agent-%s-make-menu-bar" buffer))))
 209     (unless (assq 'gnus-agent-mode minor-mode-alist)
 210       (push gnus-agent-mode-status minor-mode-alist))
 211     (unless (assq mode minor-mode-map-alist)
 212       (push (cons mode (symbol-value (intern (format "gnus-agent-%s-mode-map"
 213                                                      buffer))))
 214             minor-mode-map-alist))
 215     (when (eq major-mode 'gnus-group-mode)
 216       (gnus-agent-toggle-plugged gnus-plugged))
 217     (gnus-run-hooks 'gnus-agent-mode-hook
 218                     (intern (format "gnus-agent-%s-mode-hook" buffer)))))
 219
 220 (defvar gnus-agent-group-mode-map (make-sparse-keymap))
 221 (gnus-define-keys gnus-agent-group-mode-map
 222   "Ju" gnus-agent-fetch-groups
 223   "Jc" gnus-enter-category-buffer
 224   "Jj" gnus-agent-toggle-plugged
 225   "Js" gnus-agent-fetch-session
 226   "JS" gnus-group-send-drafts
 227   "Ja" gnus-agent-add-group)
 228
 229 (defun gnus-agent-group-make-menu-bar ()
 230   (unless (boundp 'gnus-agent-group-menu)
 231     (easy-menu-define
 232      gnus-agent-group-menu gnus-agent-group-mode-map ""
 233      '("Agent"
 234        ["Toggle plugged" gnus-agent-toggle-plugged t]
 235        ["List categories" gnus-enter-category-buffer t]
 236        ["Send drafts" gnus-group-send-drafts gnus-plugged]
 237        ("Fetch"
 238         ["All" gnus-agent-fetch-session gnus-plugged]
 239         ["Group" gnus-agent-fetch-group gnus-plugged])))))
 240
 241 (defvar gnus-agent-summary-mode-map (make-sparse-keymap))
 242 (gnus-define-keys gnus-agent-summary-mode-map
 243   "Jj" gnus-agent-toggle-plugged
 244   "J#" gnus-agent-mark-article
 245   "J\M-#" gnus-agent-unmark-article
 246   "@" gnus-agent-toggle-mark
 247   "Jc" gnus-agent-catchup)
 248
 249 (defun gnus-agent-summary-make-menu-bar ()
 250   (unless (boundp 'gnus-agent-summary-menu)
 251     (easy-menu-define
 252      gnus-agent-summary-menu gnus-agent-summary-mode-map ""
 253      '("Agent"
 254        ["Toggle plugged" gnus-agent-toggle-plugged t]
 255        ["Mark as downloadable" gnus-agent-mark-article t]
 256        ["Unmark as downloadable" gnus-agent-unmark-article t]
 257        ["Toggle mark" gnus-agent-toggle-mark t]
 258        ["Catchup undownloaded" gnus-agent-catchup t]))))
 259
 260 (defvar gnus-agent-server-mode-map (make-sparse-keymap))
 261 (gnus-define-keys gnus-agent-server-mode-map
 262   "Jj" gnus-agent-toggle-plugged
 263   "Ja" gnus-agent-add-server
 264   "Jr" gnus-agent-remove-server)
 265
 266 (defun gnus-agent-server-make-menu-bar ()
 267   (unless (boundp 'gnus-agent-server-menu)
 268     (easy-menu-define
 269      gnus-agent-server-menu gnus-agent-server-mode-map ""
 270      '("Agent"
 271        ["Toggle plugged" gnus-agent-toggle-plugged t]
 272        ["Add" gnus-agent-add-server t]
 273        ["Remove" gnus-agent-remove-server t]))))
 274
 275 (defun gnus-agent-toggle-plugged (plugged)
 276   "Toggle whether Gnus is unplugged or not."
 277   (interactive (list (not gnus-plugged)))
 278   (if plugged
 279       (progn
 280         (setq gnus-plugged plugged)
 281         (gnus-run-hooks 'gnus-agent-plugged-hook)
 282         (setcar (cdr gnus-agent-mode-status) " Plugged"))
 283     (gnus-agent-close-connections)
 284     (setq gnus-plugged plugged)
 285     (gnus-run-hooks 'gnus-agent-unplugged-hook)
 286     (setcar (cdr gnus-agent-mode-status) " Unplugged"))
 287   (set-buffer-modified-p t))
 288
 289 (defun gnus-agent-close-connections ()
 290   "Close all methods covered by the Gnus agent."
 291   (let ((methods gnus-agent-covered-methods))
 292     (while methods
 293       (gnus-close-server (pop methods)))))
 294
 295 ;;;###autoload
 296 (defun gnus-unplugged ()
 297   "Start Gnus unplugged."
 298   (interactive)
 299   (setq gnus-plugged nil)
 300   (gnus))
 301
 302 ;;;###autoload
 303 (defun gnus-plugged ()
 304   "Start Gnus plugged."
 305   (interactive)
 306   (setq gnus-plugged t)
 307   (gnus))
 308
 309 ;;;###autoload
 310 (defun gnus-agentize ()
 311   "Allow Gnus to be an offline newsreader.
 312 The normal usage of this command is to put the following as the
 313 last form in your `.gnus.el' file:
 314
 315 \(gnus-agentize)
 316
 317 This will modify the `gnus-before-startup-hook', `gnus-post-method',
 318 and `message-send-mail-function' variables, and install the Gnus
 319 agent minor mode in all Gnus buffers."
 320   (interactive)
 321   (gnus-open-agent)
 322   (add-hook 'gnus-setup-news-hook 'gnus-agent-queue-setup)
 323   (unless gnus-agent-send-mail-function
 324     (setq gnus-agent-send-mail-function message-send-mail-function
 325           message-send-mail-function 'gnus-agent-send-mail))
 326   (unless gnus-agent-covered-methods
 327     (setq gnus-agent-covered-methods (list gnus-select-method))))
 328
 329 (defun gnus-agent-queue-setup ()
 330   "Make sure the queue group exists."
 331   (unless (gnus-gethash "nndraft:queue" gnus-newsrc-hashtb)
 332     (gnus-request-create-group "queue" '(nndraft ""))
 333     (let ((gnus-level-default-subscribed 1))
 334       (gnus-subscribe-group "nndraft:queue" nil '(nndraft "")))
 335     (gnus-group-set-parameter
 336      "nndraft:queue" 'gnus-dummy '((gnus-draft-mode)))))
 337
 338 (defun gnus-agent-send-mail ()
 339   (if gnus-plugged
 340       (funcall gnus-agent-send-mail-function)
 341     (goto-char (point-min))
 342     (re-search-forward
 343      (concat "^" (regexp-quote mail-header-separator) "\n"))
 344     (replace-match "\n")
 345     (gnus-agent-insert-meta-information 'mail)
 346     (gnus-request-accept-article "nndraft:queue" nil t t)))
 347
 348 (defun gnus-agent-insert-meta-information (type &optional method)
 349   "Insert meta-information into the message that says how it's to be posted.
 350 TYPE can be either `mail' or `news'.  If the latter METHOD can
 351 be a select method."
 352   (save-excursion
 353     (message-remove-header gnus-agent-meta-information-header)
 354     (goto-char (point-min))
 355     (insert gnus-agent-meta-information-header ": "
 356             (symbol-name type) " " (format "%S" method)
 357             "\n")
 358     (forward-char -1)
 359     (while (search-backward "\n" nil t)
 360       (replace-match "\\n" t t))))
 361
 362 ;;;
 363 ;;; Group mode commands
 364 ;;;
 365
 366 (defun gnus-agent-fetch-groups (n)
 367   "Put all new articles in the current groups into the Agent."
 368   (interactive "P")
 369   (gnus-group-iterate n 'gnus-agent-fetch-group))
 370
 371 (defun gnus-agent-fetch-group (group)
 372   "Put all new articles in GROUP into the Agent."
 373   (interactive (list (gnus-group-group-name)))
 374   (unless group
 375     (error "No group on the current line"))
 376   (let ((gnus-command-method (gnus-find-method-for-group group)))
 377     (gnus-agent-with-fetch
 378       (gnus-agent-fetch-group-1 group gnus-command-method)
 379       (gnus-message 5 "Fetching %s...done" group))))
 380
 381 (defun gnus-agent-add-group (category arg)
 382   "Add the current group to an agent category."
 383   (interactive
 384    (list
 385     (intern
 386      (completing-read
 387       "Add to category: "
 388       (mapcar (lambda (cat) (list (symbol-name (car cat))))
 389               gnus-category-alist)
 390       nil t))
 391     current-prefix-arg))
 392   (let ((cat (assq category gnus-category-alist))
 393         c groups)
 394     (gnus-group-iterate arg
 395       (lambda (group)
 396         (when (cadddr (setq c (gnus-group-category group)))
 397           (setf (cadddr c) (delete group (cadddr c))))
 398         (push group groups)))
 399     (setf (cadddr cat) (nconc (cadddr cat) groups))
 400     (gnus-category-write)))
 401
 402 ;;;
 403 ;;; Server mode commands
 404 ;;;
 405
 406 (defun gnus-agent-add-server (server)
 407   "Enroll SERVER in the agent program."
 408   (interactive (list (gnus-server-server-name)))
 409   (unless server
 410     (error "No server on the current line"))
 411   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 412     (when (member method gnus-agent-covered-methods)
 413       (error "Server already in the agent program"))
 414     (push method gnus-agent-covered-methods)
 415     (gnus-agent-write-servers)
 416     (message "Entered %s into the Agent" server)))
 417
 418 (defun gnus-agent-remove-server (server)
 419   "Remove SERVER from the agent program."
 420   (interactive (list (gnus-server-server-name)))
 421   (unless server
 422     (error "No server on the current line"))
 423   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 424     (unless (member method gnus-agent-covered-methods)
 425       (error "Server not in the agent program"))
 426     (setq gnus-agent-covered-methods
 427           (delete method gnus-agent-covered-methods))
 428     (gnus-agent-write-servers)
 429     (message "Removed %s from the agent" server)))
 430
 431 (defun gnus-agent-read-servers ()
 432   "Read the alist of covered servers."
 433   (setq gnus-agent-covered-methods
 434         (gnus-agent-read-file
 435          (nnheader-concat gnus-agent-directory "lib/servers"))))
 436
 437 (defun gnus-agent-write-servers ()
 438   "Write the alist of covered servers."
 439   (with-temp-file (nnheader-concat gnus-agent-directory "lib/servers")
 440     (prin1 gnus-agent-covered-methods (current-buffer))))
 441
 442 ;;;
 443 ;;; Summary commands
 444 ;;;
 445
 446 (defun gnus-agent-mark-article (n &optional unmark)
 447   "Mark the next N articles as downloadable.
 448 If N is negative, mark backward instead.  If UNMARK is non-nil, remove
 449 the mark instead.  The difference between N and the actual number of
 450 articles marked is returned."
 451   (interactive "p")
 452   (let ((backward (< n 0))
 453         (n (abs n)))
 454     (while (and
 455             (> n 0)
 456             (progn
 457               (gnus-summary-set-agent-mark
 458                (gnus-summary-article-number) unmark)
 459               (zerop (gnus-summary-next-subject (if backward -1 1) nil t))))
 460       (setq n (1- n)))
 461     (when (/= 0 n)
 462       (gnus-message 7 "No more articles"))
 463     (gnus-summary-recenter)
 464     (gnus-summary-position-point)
 465     n))
 466
 467 (defun gnus-agent-unmark-article (n)
 468   "Remove the downloadable mark from the next N articles.
 469 If N is negative, unmark backward instead.  The difference between N and
 470 the actual number of articles unmarked is returned."
 471   (interactive "p")
 472   (gnus-agent-mark-article n t))
 473
 474 (defun gnus-agent-toggle-mark (n)
 475   "Toggle the downloadable mark from the next N articles.
 476 If N is negative, toggle backward instead.  The difference between N and
 477 the actual number of articles toggled is returned."
 478   (interactive "p")
 479   (gnus-agent-mark-article n 'toggle))
 480
 481 (defun gnus-summary-set-agent-mark (article &optional unmark)
 482   "Mark ARTICLE as downloadable."
 483   (let ((unmark (if (and (not (null unmark)) (not (eq t unmark)))
 484                     (memq article gnus-newsgroup-downloadable)
 485                   unmark)))
 486     (if unmark
 487         (progn
 488           (setq gnus-newsgroup-downloadable
 489                 (delq article gnus-newsgroup-downloadable))
 490           (push article gnus-newsgroup-undownloaded))
 491       (setq gnus-newsgroup-undownloaded
 492             (delq article gnus-newsgroup-undownloaded))
 493       (push article gnus-newsgroup-downloadable))
 494     (gnus-summary-update-mark
 495      (if unmark gnus-undownloaded-mark gnus-downloadable-mark)
 496      'unread)))
 497
 498 (defun gnus-agent-get-undownloaded-list ()
 499   "Mark all unfetched articles as read."
 500   (let ((gnus-command-method (gnus-find-method-for-group gnus-newsgroup-name)))
 501     (when (and (not gnus-plugged)
 502                (gnus-agent-method-p gnus-command-method))
 503       (gnus-agent-load-alist gnus-newsgroup-name)
 504       (let ((articles gnus-newsgroup-unreads)
 505             article)
 506         (while (setq article (pop articles))
 507           (unless (or (cdr (assq article gnus-agent-article-alist))
 508                   (memq article gnus-newsgroup-downloadable))
 509             (push article gnus-newsgroup-undownloaded)))))))
 510
 511 (defun gnus-agent-catchup ()
 512   "Mark all undownloaded articles as read."
 513   (interactive)
 514   (save-excursion
 515     (while gnus-newsgroup-undownloaded
 516       (gnus-summary-mark-article
 517        (pop gnus-newsgroup-undownloaded) gnus-catchup-mark)))
 518   (gnus-summary-position-point))
 519
 520 ;;;
 521 ;;; Internal functions
 522 ;;;
 523
 524 (defun gnus-agent-save-active (method)
 525   (when (gnus-agent-method-p method)
 526     (let* ((gnus-command-method method)
 527            (file (gnus-agent-lib-file "active")))
 528       (gnus-make-directory (file-name-directory file))
 529       (let ((coding-system-for-write gnus-agent-file-coding-system))
 530         (write-region (point-min) (point-max) file nil 'silent))
 531       (when (file-exists-p (gnus-agent-lib-file "groups"))
 532         (delete-file (gnus-agent-lib-file "groups"))))))
 533
 534 (defun gnus-agent-save-groups (method)
 535   (let* ((gnus-command-method method)
 536          (file (gnus-agent-lib-file "groups")))
 537     (gnus-make-directory (file-name-directory file))
 538     (let ((coding-system-for-write gnus-agent-file-coding-system))
 539       (write-region (point-min) (point-max) file nil 'silent))
 540     (when (file-exists-p (gnus-agent-lib-file "active"))
 541       (delete-file (gnus-agent-lib-file "active")))))
 542
 543 (defun gnus-agent-save-group-info (method group active)
 544   (when (gnus-agent-method-p method)
 545     (let* ((gnus-command-method method)
 546            (file (if nntp-server-list-active-group
 547                      (gnus-agent-lib-file "active")
 548                    (gnus-agent-lib-file "groups"))))
 549       (gnus-make-directory (file-name-directory file))
 550       (with-temp-file file
 551         (when (file-exists-p file)
 552           (nnheader-insert-file-contents file))
 553         (goto-char (point-min))
 554         (if nntp-server-list-active-group
 555             (progn
 556               (when (re-search-forward
 557                      (concat "^" (regexp-quote group) " ") nil t)
 558                 (gnus-delete-line))
 559               (insert group " " (number-to-string (cdr active)) " "
 560                       (number-to-string (car active)) " y\n"))
 561           (when (re-search-forward (concat (regexp-quote group) " ") nil t)
 562             (gnus-delete-line))
 563           (insert-buffer-substring nntp-server-buffer))))))
 564
 565 (defun gnus-agent-group-path (group)
 566   "Translate GROUP into a path."
 567   (if nnmail-use-long-file-names
 568       (gnus-group-real-name group)
 569     (nnheader-replace-chars-in-string
 570      (nnheader-translate-file-chars (gnus-group-real-name group))
 571      ?. ?/)))
 572
 573 \f
 574
 575 (defun gnus-agent-method-p (method)
 576   "Say whether METHOD is covered by the agent."
 577   (member method gnus-agent-covered-methods))
 578
 579 (defun gnus-agent-get-function (method)
 580   (if (and (not gnus-plugged)
 581            (gnus-agent-method-p method))
 582       (progn
 583         (require 'nnagent)
 584         'nnagent)
 585     (car method)))
 586
 587 ;;; History functions
 588
 589 (defun gnus-agent-history-buffer ()
 590   (cdr (assoc (gnus-agent-method) gnus-agent-history-buffers)))
 591
 592 (defun gnus-agent-open-history ()
 593   (save-excursion
 594     (push (cons (gnus-agent-method)
 595                 (set-buffer (gnus-get-buffer-create
 596                              (format " *Gnus agent %s history*"
 597                                      (gnus-agent-method)))))
 598           gnus-agent-history-buffers)
 599     (erase-buffer)
 600     (insert "\n")
 601     (let ((file (gnus-agent-lib-file "history")))
 602       (when (file-exists-p file)
 603         (insert-file file))
 604       (set (make-local-variable 'gnus-agent-file-name) file))))
 605
 606 (defun gnus-agent-save-history ()
 607   (save-excursion
 608     (set-buffer gnus-agent-current-history)
 609     (gnus-make-directory (file-name-directory gnus-agent-file-name))
 610     (let ((coding-system-for-write gnus-agent-file-coding-system))
 611       (write-region (1+ (point-min)) (point-max)
 612                     gnus-agent-file-name nil 'silent))))
 613
 614 (defun gnus-agent-close-history ()
 615   (when (gnus-buffer-live-p gnus-agent-current-history)
 616     (kill-buffer gnus-agent-current-history)
 617     (setq gnus-agent-history-buffers
 618           (delq (assoc (gnus-agent-method) gnus-agent-history-buffers)
 619                 gnus-agent-history-buffers))))
 620
 621 (defun gnus-agent-enter-history (id group-arts date)
 622   (save-excursion
 623     (set-buffer gnus-agent-current-history)
 624     (goto-char (point-max))
 625     (insert id "\t" (number-to-string date) "\t")
 626     (while group-arts
 627       (insert (caar group-arts) " " (number-to-string (cdr (pop group-arts)))
 628               " "))
 629     (insert "\n")))
 630
 631 (defun gnus-agent-article-in-history-p (id)
 632   (save-excursion
 633     (set-buffer (gnus-agent-history-buffer))
 634     (goto-char (point-min))
 635     (search-forward (concat "\n" id "\t") nil t)))
 636
 637 (defun gnus-agent-history-path (id)
 638   (save-excursion
 639     (set-buffer (gnus-agent-history-buffer))
 640     (goto-char (point-min))
 641     (when (search-forward (concat "\n" id "\t") nil t)
 642       (let ((method (gnus-agent-method)))
 643         (let (paths group)
 644           (while (not (numberp (setq group (read (current-buffer)))))
 645             (push (concat method "/" group) paths))
 646           (nreverse paths))))))
 647
 648 ;;;
 649 ;;; Fetching
 650 ;;;
 651
 652 (defun gnus-agent-fetch-articles (group articles)
 653   "Fetch ARTICLES from GROUP and put them into the Agent."
 654   (when articles
 655     ;; Prune off articles that we have already fetched.
 656     (while (and articles
 657                 (cdr (assq (car articles) gnus-agent-article-alist)))
 658      (pop articles))
 659     (let ((arts articles))
 660       (while (cdr arts)
 661         (if (cdr (assq (cadr arts) gnus-agent-article-alist))
 662             (setcdr arts (cddr arts))
 663           (setq arts (cdr arts)))))
 664     (when articles
 665       (let ((dir (concat
 666                   (gnus-agent-directory)
 667                   (gnus-agent-group-path group) "/"))
 668             (date (time-to-days (current-time)))
 669             (case-fold-search t)
 670             pos crosses id elem)
 671         (gnus-make-directory dir)
 672         (gnus-message 7 "Fetching articles for %s..." group)
 673         ;; Fetch the articles from the backend.
 674         (if (gnus-check-backend-function 'retrieve-articles group)
 675             (setq pos (gnus-retrieve-articles articles group))
 676           (with-temp-file nil
 677             (let (article)
 678               (while (setq article (pop articles))
 679                 (when (gnus-request-article article group)
 680                   (goto-char (point-max))
 681                   (push (cons article (point)) pos)
 682                   (insert-buffer-substring nntp-server-buffer)))
 683               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 684               (setq pos (nreverse pos)))))
 685         ;; Then save these articles into the Agent.
 686         (save-excursion
 687           (set-buffer nntp-server-buffer)
 688           (while pos
 689             (narrow-to-region (cdar pos) (or (cdadr pos) (point-max)))
 690             (goto-char (point-min))
 691             (when (search-forward "\n\n" nil t)
 692               (when (search-backward "\nXrefs: " nil t)
 693                 ;; Handle crossposting.
 694                 (skip-chars-forward "^ ")
 695                 (skip-chars-forward " ")
 696                 (setq crosses nil)
 697                 (while (looking-at "\\([^: \n]+\\):\\([0-9]+\\) +")
 698                   (push (cons (buffer-substring (match-beginning 1)
 699                                                 (match-end 1))
 700                               (buffer-substring (match-beginning 2)
 701                                                 (match-end 2)))
 702                         crosses)
 703                   (goto-char (match-end 0)))
 704                 (gnus-agent-crosspost crosses (caar pos))))
 705             (goto-char (point-min))
 706             (if (not (re-search-forward "^Message-ID: *<\\([^>\n]+\\)>" nil t))
 707                 (setq id "No-Message-ID-in-article")
 708               (setq id (buffer-substring (match-beginning 1) (match-end 1))))
 709             (let ((coding-system-for-write
 710                    gnus-agent-file-coding-system))
 711               (write-region (point-min) (point-max)
 712                             (concat dir (number-to-string (caar pos)))
 713                             nil 'silent))
 714             (when (setq elem (assq (caar pos) gnus-agent-article-alist))
 715               (setcdr elem t))
 716             (gnus-agent-enter-history
 717              id (or crosses (list (cons group (caar pos)))) date)
 718             (widen)
 719             (pop pos)))
 720         (gnus-agent-save-alist group)))))
 721
 722 (defun gnus-agent-crosspost (crosses article)
 723   (let (gnus-agent-article-alist group alist beg end)
 724     (save-excursion
 725       (set-buffer gnus-agent-overview-buffer)
 726       (when (nnheader-find-nov-line article)
 727         (forward-word 1)
 728         (setq beg (point))
 729         (setq end (progn (forward-line 1) (point)))))
 730     (while crosses
 731       (setq group (caar crosses))
 732       (unless (setq alist (assoc group gnus-agent-group-alist))
 733         (push (setq alist (list group (gnus-agent-load-alist (caar crosses))))
 734               gnus-agent-group-alist))
 735       (setcdr alist (cons (cons (cdar crosses) t) (cdr alist)))
 736       (save-excursion
 737         (set-buffer (gnus-get-buffer-create (format " *Gnus agent overview %s*"
 738                                                group)))
 739         (when (= (point-max) (point-min))
 740           (push (cons group (current-buffer)) gnus-agent-buffer-alist)
 741           (ignore-errors
 742             (nnheader-insert-file-contents
 743              (gnus-agent-article-name ".overview" group))))
 744         (nnheader-find-nov-line (string-to-number (cdar crosses)))
 745         (insert (string-to-number (cdar crosses)))
 746         (insert-buffer-substring gnus-agent-overview-buffer beg end))
 747       (pop crosses))))
 748
 749 (defun gnus-agent-flush-cache ()
 750   (save-excursion
 751     (while gnus-agent-buffer-alist
 752       (set-buffer (cdar gnus-agent-buffer-alist))
 753       (let ((coding-system-for-write
 754              gnus-agent-file-coding-system))
 755         (write-region (point-min) (point-max)
 756                       (gnus-agent-article-name ".overview"
 757                                                (caar gnus-agent-buffer-alist))
 758                       nil 'silent))
 759       (pop gnus-agent-buffer-alist))
 760     (while gnus-agent-group-alist
 761       (with-temp-file (caar gnus-agent-group-alist)
 762         (princ (cdar gnus-agent-group-alist))
 763         (insert "\n"))
 764       (pop gnus-agent-group-alist))))
 765
 766 (defun gnus-agent-fetch-headers (group &optional force)
 767   (let ((articles (if (gnus-agent-load-alist group)
 768                       (gnus-sorted-intersection
 769                        (gnus-list-of-unread-articles group)
 770                        (gnus-uncompress-range
 771                         (cons (1+ (caar (last gnus-agent-article-alist)))
 772                               (cdr (gnus-active group)))))
 773                     (gnus-list-of-unread-articles group)))
 774         (gnus-decode-encoded-word-function 'identity))
 775     ;; Fetch them.
 776     (when articles
 777       (gnus-message 7 "Fetching headers for %s..." group)
 778       (save-excursion
 779         (set-buffer nntp-server-buffer)
 780         (unless (eq 'nov (gnus-retrieve-headers articles group))
 781           (nnvirtual-convert-headers))
 782         ;; Save these headers for later processing.
 783         (copy-to-buffer gnus-agent-overview-buffer (point-min) (point-max))
 784         (let (file)
 785           (when (file-exists-p
 786                  (setq file (gnus-agent-article-name ".overview" group)))
 787             (gnus-agent-braid-nov group articles file))
 788           (gnus-make-directory (nnheader-translate-file-chars
 789                                 (file-name-directory file)))
 790           (let ((coding-system-for-write
 791                  gnus-agent-file-coding-system))
 792             (write-region (point-min) (point-max) file nil 'silent))
 793           (gnus-agent-save-alist group articles nil)
 794           (gnus-agent-enter-history
 795            "last-header-fetched-for-session"
 796            (list (cons group (nth (- (length  articles) 1) articles)))
 797            (time-to-days (current-time)))
 798           articles)))))
 799
 800 (defsubst gnus-agent-copy-nov-line (article)
 801   (let (b e)
 802     (set-buffer gnus-agent-overview-buffer)
 803     (setq b (point))
 804     (if (eq article (read (current-buffer)))
 805         (setq e (progn (forward-line 1) (point)))
 806       (progn
 807         (beginning-of-line)
 808         (setq e b)))
 809     (set-buffer nntp-server-buffer)
 810     (insert-buffer-substring gnus-agent-overview-buffer b e)))
 811
 812 (defun gnus-agent-braid-nov (group articles file)
 813   (set-buffer gnus-agent-overview-buffer)
 814   (goto-char (point-min))
 815   (set-buffer nntp-server-buffer)
 816   (erase-buffer)
 817   (nnheader-insert-file-contents file)
 818   (goto-char (point-max))
 819   (if (or (= (point-min) (point-max))
 820           (progn
 821             (forward-line -1)
 822             (< (read (current-buffer)) (car articles))))
 823       ;; We have only headers that are after the older headers,
 824       ;; so we just append them.
 825       (progn
 826         (goto-char (point-max))
 827         (insert-buffer-substring gnus-agent-overview-buffer))
 828     ;; We do it the hard way.
 829     (nnheader-find-nov-line (car articles))
 830     (gnus-agent-copy-nov-line (car articles))
 831     (pop articles)
 832     (while (and articles
 833                 (not (eobp)))
 834       (while (and (not (eobp))
 835                   (< (read (current-buffer)) (car articles)))
 836         (forward-line 1))
 837       (beginning-of-line)
 838       (unless (eobp)
 839         (gnus-agent-copy-nov-line (car articles))
 840         (setq articles (cdr articles))))
 841     (when articles
 842       (let (b e)
 843         (set-buffer gnus-agent-overview-buffer)
 844         (setq b (point)
 845               e (point-max))
 846         (set-buffer nntp-server-buffer)
 847         (insert-buffer-substring gnus-agent-overview-buffer b e)))))
 848
 849 (defun gnus-agent-load-alist (group &optional dir)
 850   "Load the article-state alist for GROUP."
 851   (setq gnus-agent-article-alist
 852         (gnus-agent-read-file
 853          (if dir
 854              (concat dir ".agentview")
 855            (gnus-agent-article-name ".agentview" group)))))
 856
 857 (defun gnus-agent-save-alist (group &optional articles state dir)
 858   "Save the article-state alist for GROUP."
 859   (with-temp-file (if dir
 860                       (concat dir ".agentview")
 861                     (gnus-agent-article-name ".agentview" group))
 862     (princ (setq gnus-agent-article-alist
 863                  (nconc gnus-agent-article-alist
 864                         (mapcar (lambda (article) (cons article state))
 865                                 articles)))
 866            (current-buffer))
 867     (insert "\n")))
 868
 869 (defun gnus-agent-article-name (article group)
 870   (concat (gnus-agent-directory) (gnus-agent-group-path group) "/"
 871           (if (stringp article) article (string-to-number article))))
 872
 873 ;;;###autoload
 874 (defun gnus-agent-batch-fetch ()
 875   "Start Gnus and fetch session."
 876   (interactive)
 877   (gnus)
 878   (gnus-agent-fetch-session)
 879   (gnus-group-exit))
 880
 881 (defun gnus-agent-fetch-session ()
 882   "Fetch all articles and headers that are eligible for fetching."
 883   (interactive)
 884   (unless gnus-agent-covered-methods
 885     (error "No servers are covered by the Gnus agent"))
 886   (unless gnus-plugged
 887     (error "Can't fetch articles while Gnus is unplugged"))
 888   (let ((methods gnus-agent-covered-methods)
 889         groups group gnus-command-method)
 890     (save-excursion
 891       (while methods
 892         (setq gnus-command-method (car methods))
 893         (when (or (gnus-server-opened gnus-command-method)
 894                   (gnus-open-server gnus-command-method))
 895           (setq groups (gnus-groups-from-server (car methods)))
 896           (gnus-agent-with-fetch
 897             (while (setq group (pop groups))
 898               (when (<= (gnus-group-level group) gnus-agent-handle-level)
 899                 (gnus-agent-fetch-group-1 group gnus-command-method)))))
 900         (pop methods))
 901       (gnus-message 6 "Finished fetching articles into the Gnus agent"))))
 902
 903 (defun gnus-agent-fetch-group-1 (group method)
 904   "Fetch GROUP."
 905   (let ((gnus-command-method method)
 906         gnus-newsgroup-dependencies gnus-newsgroup-headers
 907         gnus-newsgroup-scored gnus-headers gnus-score
 908         gnus-use-cache articles arts
 909         category predicate info marks score-param)
 910     ;; Fetch headers.
 911     (when (and (or (gnus-active group) (gnus-activate-group group))
 912                (setq articles (gnus-agent-fetch-headers group)))
 913       ;; Parse them and see which articles we want to fetch.
 914       (setq gnus-newsgroup-dependencies
 915             (make-vector (length articles) 0))
 916       ;; No need to call `gnus-get-newsgroup-headers-xover' with
 917       ;; the entire .overview for group as we still have the just
 918       ;; downloaded headers in `gnus-agent-overview-buffer'.
 919       (let ((nntp-server-buffer gnus-agent-overview-buffer))
 920         (setq gnus-newsgroup-headers
 921               (gnus-get-newsgroup-headers-xover articles nil nil group)))
 922       (setq category (gnus-group-category group))
 923       (setq predicate
 924             (gnus-get-predicate
 925              (or (gnus-group-get-parameter group 'agent-predicate t)
 926                  (cadr category))))
 927       ;; Do we want to download everything, or nothing?
 928       (if (or (eq (caaddr predicate) 'gnus-agent-true)
 929               (eq (caaddr predicate) 'gnus-agent-false))
 930           ;; Yes.
 931           (setq arts (symbol-value
 932                       (cadr (assoc (caaddr predicate)
 933                                    '((gnus-agent-true articles)
 934                                      (gnus-agent-false nil))))))
 935         ;; No, we need to decide what we want.
 936         (setq score-param
 937               (let ((score-method
 938                      (or
 939                       (gnus-group-get-parameter group 'agent-score t)
 940                       (caddr category))))
 941                 (when score-method
 942                   (require 'gnus-score)
 943                   (if (eq score-method 'file)
 944                       (let ((entries
 945                              (gnus-score-load-files
 946                               (gnus-all-score-files group)))
 947                             list score-file)
 948                         (while (setq list (car entries))
 949                           (push (car list) score-file)
 950                           (setq list (cdr list))
 951                           (while list
 952                             (when (member (caar list)
 953                                           gnus-agent-scoreable-headers)
 954                               (push (car list) score-file))
 955                             (setq list (cdr list)))
 956                           (setq score-param
 957                                 (append score-param (list (nreverse score-file)))
 958                                 score-file nil entries (cdr entries)))
 959                         (list score-param))
 960                     (if (stringp (car score-method))
 961                         score-method
 962                       (list (list score-method)))))))
 963         (when score-param
 964           (gnus-score-headers score-param))
 965         (setq arts nil)
 966         (while (setq gnus-headers (pop gnus-newsgroup-headers))
 967           (setq gnus-score
 968                 (or (cdr (assq (mail-header-number gnus-headers)
 969                                gnus-newsgroup-scored))
 970                     gnus-summary-default-score))
 971           (when (funcall predicate)
 972             (push (mail-header-number gnus-headers)
 973                   arts))))
 974       ;; Fetch the articles.
 975       (when arts
 976         (gnus-agent-fetch-articles group arts)))
 977     ;; Perhaps we have some additional articles to fetch.
 978     (setq arts (assq 'download (gnus-info-marks
 979                                 (setq info (gnus-get-info group)))))
 980     (when (cdr arts)
 981       (gnus-agent-fetch-articles
 982        group (gnus-uncompress-range (cdr arts)))
 983       (setq marks (delq arts (gnus-info-marks info)))
 984       (gnus-info-set-marks info marks))))
 985
 986 ;;;
 987 ;;; Agent Category Mode
 988 ;;;
 989
 990 (defvar gnus-category-mode-hook nil
 991   "Hook run in `gnus-category-mode' buffers.")
 992
 993 (defvar gnus-category-line-format "     %(%20c%): %g\n"
 994   "Format of category lines.")
 995
 996 (defvar gnus-category-mode-line-format "Gnus: %%b"
 997   "The format specification for the category mode line.")
 998
 999 (defvar gnus-agent-short-article 100
1000   "Articles that have fewer lines than this are short.")
1001
1002 (defvar gnus-agent-long-article 200
1003   "Articles that have more lines than this are long.")
1004
1005 (defvar gnus-agent-low-score 0
1006   "Articles that have a score lower than this have a low score.")
1007
1008 (defvar gnus-agent-high-score 0
1009   "Articles that have a score higher than this have a high score.")
1010
1011
1012 ;;; Internal variables.
1013
1014 (defvar gnus-category-buffer "*Agent Category*")
1015
1016 (defvar gnus-category-line-format-alist
1017   `((?c gnus-tmp-name ?s)
1018     (?g gnus-tmp-groups ?d)))
1019
1020 (defvar gnus-category-mode-line-format-alist
1021   `((?u user-defined ?s)))
1022
1023 (defvar gnus-category-line-format-spec nil)
1024 (defvar gnus-category-mode-line-format-spec nil)
1025
1026 (defvar gnus-category-mode-map nil)
1027 (put 'gnus-category-mode 'mode-class 'special)
1028
1029 (unless gnus-category-mode-map
1030   (setq gnus-category-mode-map (make-sparse-keymap))
1031   (suppress-keymap gnus-category-mode-map)
1032
1033   (gnus-define-keys gnus-category-mode-map
1034     "q" gnus-category-exit
1035     "k" gnus-category-kill
1036     "c" gnus-category-copy
1037     "a" gnus-category-add
1038     "p" gnus-category-edit-predicate
1039     "g" gnus-category-edit-groups
1040     "s" gnus-category-edit-score
1041     "l" gnus-category-list
1042
1043     "\C-c\C-i" gnus-info-find-node
1044     "\C-c\C-b" gnus-bug))
1045
1046 (defvar gnus-category-menu-hook nil
1047   "*Hook run after the creation of the menu.")
1048
1049 (defun gnus-category-make-menu-bar ()
1050   (gnus-turn-off-edit-menu 'category)
1051   (unless (boundp 'gnus-category-menu)
1052     (easy-menu-define
1053      gnus-category-menu gnus-category-mode-map ""
1054      '("Categories"
1055        ["Add" gnus-category-add t]
1056        ["Kill" gnus-category-kill t]
1057        ["Copy" gnus-category-copy t]
1058        ["Edit predicate" gnus-category-edit-predicate t]
1059        ["Edit score" gnus-category-edit-score t]
1060        ["Edit groups" gnus-category-edit-groups t]
1061        ["Exit" gnus-category-exit t]))
1062
1063     (gnus-run-hooks 'gnus-category-menu-hook)))
1064
1065 (defun gnus-category-mode ()
1066   "Major mode for listing and editing agent categories.
1067
1068 All normal editing commands are switched off.
1069 \\<gnus-category-mode-map>
1070 For more in-depth information on this mode, read the manual
1071 (`\\[gnus-info-find-node]').
1072
1073 The following commands are available:
1074
1075 \\{gnus-category-mode-map}"
1076   (interactive)
1077   (when (gnus-visual-p 'category-menu 'menu)
1078     (gnus-category-make-menu-bar))
1079   (kill-all-local-variables)
1080   (gnus-simplify-mode-line)
1081   (setq major-mode 'gnus-category-mode)
1082   (setq mode-name "Category")
1083   (gnus-set-default-directory)
1084   (setq mode-line-process nil)
1085   (use-local-map gnus-category-mode-map)
1086   (buffer-disable-undo)
1087   (setq truncate-lines t)
1088   (setq buffer-read-only t)
1089   (gnus-run-hooks 'gnus-category-mode-hook))
1090
1091 (defalias 'gnus-category-position-point 'gnus-goto-colon)
1092
1093 (defun gnus-category-insert-line (category)
1094   (let* ((gnus-tmp-name (car category))
1095          (gnus-tmp-groups (length (cadddr category))))
1096     (beginning-of-line)
1097     (gnus-add-text-properties
1098      (point)
1099      (prog1 (1+ (point))
1100        ;; Insert the text.
1101        (eval gnus-category-line-format-spec))
1102      (list 'gnus-category gnus-tmp-name))))
1103
1104 (defun gnus-enter-category-buffer ()
1105   "Go to the Category buffer."
1106   (interactive)
1107   (gnus-category-setup-buffer)
1108   (gnus-configure-windows 'category)
1109   (gnus-category-prepare))
1110
1111 (defun gnus-category-setup-buffer ()
1112   (unless (get-buffer gnus-category-buffer)
1113     (save-excursion
1114       (set-buffer (gnus-get-buffer-create gnus-category-buffer))
1115       (gnus-category-mode))))
1116
1117 (defun gnus-category-prepare ()
1118   (gnus-set-format 'category-mode)
1119   (gnus-set-format 'category t)
1120   (let ((alist gnus-category-alist)
1121         (buffer-read-only nil))
1122     (erase-buffer)
1123     (while alist
1124       (gnus-category-insert-line (pop alist)))
1125     (goto-char (point-min))
1126     (gnus-category-position-point)))
1127
1128 (defun gnus-category-name ()
1129   (or (get-text-property (gnus-point-at-bol) 'gnus-category)
1130       (error "No category on the current line")))
1131
1132 (defun gnus-category-read ()
1133   "Read the category alist."
1134   (setq gnus-category-alist
1135         (or (gnus-agent-read-file
1136              (nnheader-concat gnus-agent-directory "lib/categories"))
1137             (list (list 'default 'short nil nil)))))
1138
1139 (defun gnus-category-write ()
1140   "Write the category alist."
1141   (setq gnus-category-predicate-cache nil
1142         gnus-category-group-cache nil)
1143   (with-temp-file (nnheader-concat gnus-agent-directory "lib/categories")
1144     (prin1 gnus-category-alist (current-buffer))))
1145
1146 (defun gnus-category-edit-predicate (category)
1147   "Edit the predicate for CATEGORY."
1148   (interactive (list (gnus-category-name)))
1149   (let ((info (assq category gnus-category-alist)))
1150     (gnus-edit-form
1151      (cadr info) (format "Editing the predicate for category %s" category)
1152      `(lambda (predicate)
1153         (setf (cadr (assq ',category gnus-category-alist)) predicate)
1154         (gnus-category-write)
1155         (gnus-category-list)))))
1156
1157 (defun gnus-category-edit-score (category)
1158   "Edit the score expression for CATEGORY."
1159   (interactive (list (gnus-category-name)))
1160   (let ((info (assq category gnus-category-alist)))
1161     (gnus-edit-form
1162      (caddr info)
1163      (format "Editing the score expression for category %s" category)
1164      `(lambda (groups)
1165         (setf (caddr (assq ',category gnus-category-alist)) groups)
1166         (gnus-category-write)
1167         (gnus-category-list)))))
1168
1169 (defun gnus-category-edit-groups (category)
1170   "Edit the group list for CATEGORY."
1171   (interactive (list (gnus-category-name)))
1172   (let ((info (assq category gnus-category-alist)))
1173     (gnus-edit-form
1174      (cadddr info) (format "Editing the group list for category %s" category)
1175      `(lambda (groups)
1176         (setf (cadddr (assq ',category gnus-category-alist)) groups)
1177         (gnus-category-write)
1178         (gnus-category-list)))))
1179
1180 (defun gnus-category-kill (category)
1181   "Kill the current category."
1182   (interactive (list (gnus-category-name)))
1183   (let ((info (assq category gnus-category-alist))
1184         (buffer-read-only nil))
1185     (gnus-delete-line)
1186     (gnus-category-write)
1187     (setq gnus-category-alist (delq info gnus-category-alist))))
1188
1189 (defun gnus-category-copy (category to)
1190   "Copy the current category."
1191   (interactive (list (gnus-category-name) (intern (read-string "New name: "))))
1192   (let ((info (assq category gnus-category-alist)))
1193     (push (list to (gnus-copy-sequence (cadr info))
1194                 (gnus-copy-sequence (caddr info)) nil)
1195           gnus-category-alist)
1196     (gnus-category-write)
1197     (gnus-category-list)))
1198
1199 (defun gnus-category-add (category)
1200   "Create a new category."
1201   (interactive "SCategory name: ")
1202   (when (assq category gnus-category-alist)
1203     (error "Category %s already exists" category))
1204   (push (list category 'false nil nil)
1205         gnus-category-alist)
1206   (gnus-category-write)
1207   (gnus-category-list))
1208
1209 (defun gnus-category-list ()
1210   "List all categories."
1211   (interactive)
1212   (gnus-category-prepare))
1213
1214 (defun gnus-category-exit ()
1215   "Return to the group buffer."
1216   (interactive)
1217   (kill-buffer (current-buffer))
1218   (gnus-configure-windows 'group t))
1219
1220 ;; To avoid having 8-bit characters in the source file.
1221 (defvar gnus-category-not (list '! 'not (intern (format "%c" 172))))
1222
1223 (defvar gnus-category-predicate-alist
1224   '((spam . gnus-agent-spam-p)
1225     (short . gnus-agent-short-p)
1226     (long . gnus-agent-long-p)
1227     (low . gnus-agent-low-scored-p)
1228     (high . gnus-agent-high-scored-p)
1229     (true . gnus-agent-true)
1230     (false . gnus-agent-false))
1231   "Mapping from short score predicate symbols to predicate functions.")
1232
1233 (defun gnus-agent-spam-p ()
1234   "Say whether an article is spam or not."
1235   (unless gnus-agent-spam-hashtb
1236     (setq gnus-agent-spam-hashtb (gnus-make-hashtable 1000)))
1237   (if (not (equal (mail-header-references gnus-headers) ""))
1238       nil
1239     (let ((string (gnus-simplify-subject (mail-header-subject gnus-headers))))
1240       (prog1
1241           (gnus-gethash string gnus-agent-spam-hashtb)
1242         (gnus-sethash string t gnus-agent-spam-hashtb)))))
1243
1244 (defun gnus-agent-short-p ()
1245   "Say whether an article is short or not."
1246   (< (mail-header-lines gnus-headers) gnus-agent-short-article))
1247
1248 (defun gnus-agent-long-p ()
1249   "Say whether an article is long or not."
1250   (> (mail-header-lines gnus-headers) gnus-agent-long-article))
1251
1252 (defun gnus-agent-low-scored-p ()
1253   "Say whether an article has a low score or not."
1254   (< gnus-score gnus-agent-low-score))
1255
1256 (defun gnus-agent-high-scored-p ()
1257   "Say whether an article has a high score or not."
1258   (> gnus-score gnus-agent-high-score))
1259
1260 (defun gnus-category-make-function (cat)
1261   "Make a function from category CAT."
1262   `(lambda () ,(gnus-category-make-function-1 cat)))
1263
1264 (defun gnus-agent-true ()
1265   "Return t."
1266   t)
1267
1268 (defun gnus-agent-false ()
1269   "Return nil."
1270   nil)
1271
1272 (defun gnus-category-make-function-1 (cat)
1273   "Make a function from category CAT."
1274   (cond
1275    ;; Functions are just returned as is.
1276    ((or (symbolp cat)
1277         (gnus-functionp cat))
1278     `(,(or (cdr (assq cat gnus-category-predicate-alist))
1279            cat)))
1280    ;; More complex category.
1281    ((consp cat)
1282     `(,(cond
1283         ((memq (car cat) '(& and))
1284          'and)
1285         ((memq (car cat) '(| or))
1286          'or)
1287         ((memq (car cat) gnus-category-not)
1288          'not))
1289       ,@(mapcar 'gnus-category-make-function-1 (cdr cat))))
1290    (t
1291     (error "Unknown category type: %s" cat))))
1292
1293 (defun gnus-get-predicate (predicate)
1294   "Return the predicate for CATEGORY."
1295   (or (cdr (assoc predicate gnus-category-predicate-cache))
1296       (cdar (push (cons predicate
1297                         (gnus-category-make-function predicate))
1298                   gnus-category-predicate-cache))))
1299
1300 (defun gnus-group-category (group)
1301   "Return the category GROUP belongs to."
1302   (unless gnus-category-group-cache
1303     (setq gnus-category-group-cache (gnus-make-hashtable 1000))
1304     (let ((cs gnus-category-alist)
1305           groups cat)
1306       (while (setq cat (pop cs))
1307         (setq groups (cadddr cat))
1308         (while groups
1309           (gnus-sethash (pop groups) cat gnus-category-group-cache)))))
1310   (or (gnus-gethash group gnus-category-group-cache)
1311       (assq 'default gnus-category-alist)))
1312
1313 (defun gnus-agent-expire ()
1314   "Expire all old articles."
1315   (interactive)
1316   (let ((methods gnus-agent-covered-methods)
1317         (day (- (time-to-days (current-time)) gnus-agent-expire-days))
1318         gnus-command-method sym group articles
1319         history overview file histories elem art nov-file low info
1320         unreads marked article)
1321     (save-excursion
1322       (setq overview (gnus-get-buffer-create " *expire overview*"))
1323       (while (setq gnus-command-method (pop methods))
1324         (let ((expiry-hashtb (gnus-make-hashtable 1023)))
1325         (gnus-agent-open-history)
1326         (set-buffer
1327          (setq gnus-agent-current-history
1328                (setq history (gnus-agent-history-buffer))))
1329         (goto-char (point-min))
1330         (when (> (buffer-size) 1)
1331           (goto-char (point-min))
1332           (while (not (eobp))
1333             (skip-chars-forward "^\t")
1334             (if (> (read (current-buffer)) day)
1335                 ;; New article; we don't expire it.
1336                 (forward-line 1)
1337               ;; Old article.  Schedule it for possible nuking.
1338               (while (not (eolp))
1339                 (setq sym (let ((obarray expiry-hashtb))
1340                             (read (current-buffer))))
1341                 (if (boundp sym)
1342                     (set sym (cons (cons (read (current-buffer)) (point))
1343                                    (symbol-value sym)))
1344                   (set sym (list (cons (read (current-buffer)) (point)))))
1345                 (skip-chars-forward " "))
1346               (forward-line 1)))
1347           ;; We now have all articles that can possibly be expired.
1348           (mapatoms
1349            (lambda (sym)
1350              (setq group (symbol-name sym)
1351                    articles (sort (symbol-value sym) 'car-less-than-car)
1352                    low (car (gnus-active group))
1353                    info (gnus-get-info group)
1354                    unreads (ignore-errors (gnus-list-of-unread-articles group))
1355                    marked (nconc (gnus-uncompress-range
1356                                   (cdr (assq 'tick (gnus-info-marks info))))
1357                                  (gnus-uncompress-range
1358                                   (cdr (assq 'dormant
1359                                              (gnus-info-marks info)))))
1360                    nov-file (gnus-agent-article-name ".overview" group))
1361              (gnus-agent-load-alist group)
1362              (gnus-message 5 "Expiring articles in %s" group)
1363              (set-buffer overview)
1364              (erase-buffer)
1365              (when (file-exists-p nov-file)
1366                (nnheader-insert-file-contents nov-file))
1367              (goto-char (point-min))
1368              (setq article 0)
1369              (while (setq elem (pop articles))
1370                (setq article (car elem))
1371                (when (or (null low)
1372                          (< article low)
1373                          gnus-agent-expire-all
1374                          (and (not (memq article unreads))
1375                               (not (memq article marked))))
1376                  ;; Find and nuke the NOV line.
1377                  (while (and (not (eobp))
1378                              (or (not (numberp
1379                                        (setq art (read (current-buffer)))))
1380                                  (< art article)))
1381                    (if (file-exists-p
1382                         (gnus-agent-article-name
1383                          (number-to-string art) group))
1384                        (forward-line 1)
1385                      ;; Remove old NOV lines that have no articles.
1386                      (gnus-delete-line)))
1387                  (if (or (eobp)
1388                          (/= art article))
1389                      (beginning-of-line)
1390                    (gnus-delete-line))
1391                  ;; Nuke the article.
1392                  (when (file-exists-p (setq file (gnus-agent-article-name
1393                                                   (number-to-string article)
1394                                                   group)))
1395                    (delete-file file))
1396                  ;; Schedule the history line for nuking.
1397                  (push (cdr elem) histories)))
1398              (gnus-make-directory (file-name-directory nov-file))
1399              (let ((coding-system-for-write
1400                     gnus-agent-file-coding-system))
1401                (write-region (point-min) (point-max) nov-file nil 'silent))
1402              ;; Delete the unwanted entries in the alist.
1403              (setq gnus-agent-article-alist
1404                    (sort gnus-agent-article-alist 'car-less-than-car))
1405              (let* ((alist gnus-agent-article-alist)
1406                     (prev (cons nil alist))
1407                     (first prev)
1408                     expired)
1409                (while (and alist
1410                            (<= (caar alist) article))
1411                  (if (or (not (cdar alist))
1412                          (not (file-exists-p
1413                                (gnus-agent-article-name
1414                                 (number-to-string
1415                                  (caar alist))
1416                                 group))))
1417                      (progn
1418                        (push (caar alist) expired)
1419                        (setcdr prev (setq alist (cdr alist))))
1420                    (setq prev alist
1421                          alist (cdr alist))))
1422                (setq gnus-agent-article-alist (cdr first))
1423                (gnus-agent-save-alist group)
1424                ;; Mark all articles up to the first article
1425                ;; in `gnus-article-alist' as read.
1426                (when (and info (caar gnus-agent-article-alist))
1427                  (setcar (nthcdr 2 info)
1428                          (gnus-range-add
1429                           (nth 2 info)
1430                           (cons 1 (- (caar gnus-agent-article-alist) 1)))))
1431                ;; Maybe everything has been expired from `gnus-article-alist'
1432                ;; and so the above marking as read could not be conducted,
1433                ;; or there are expired article within the range of the alist.
1434                (when (and info
1435                           expired
1436                           (or (not (caar gnus-agent-article-alist))
1437                               (> (car expired)
1438                                  (caar gnus-agent-article-alist))))
1439                  (setcar (nthcdr 2 info)
1440                          (gnus-add-to-range
1441                           (nth 2 info)
1442                           (nreverse expired))))
1443                (gnus-dribble-enter
1444                 (concat "(gnus-group-set-info '"
1445                         (gnus-prin1-to-string info)
1446                         ")"))))
1447            expiry-hashtb)
1448           (set-buffer history)
1449           (setq histories (nreverse (sort histories '<)))
1450           (while histories
1451             (goto-char (pop histories))
1452             (gnus-delete-line))
1453           (gnus-agent-save-history)
1454           (gnus-agent-close-history))
1455         (gnus-message 4 "Expiry...done"))))))
1456
1457 ;;;###autoload
1458 (defun gnus-agent-batch ()
1459   (interactive)
1460   (let ((init-file-user "")
1461         (gnus-always-read-dribble-file t))
1462     (gnus))
1463   (gnus-group-send-drafts)
1464   (gnus-agent-fetch-session))
1465
1466 (provide 'gnus-agent)
1467
1468 ;;; gnus-agent.el ends here