cgit.sxemacs.org Git - gnus/blob - lisp/auth-source.el

   1 ;;; auth-source.el --- authentication sources for Gnus and Emacs
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the auth-source.el package.  It lets users tell Gnus how to
  26 ;; authenticate in a single place.  Simplicity is the goal.  Instead
  27 ;; of providing 5000 options, we'll stick to simple, easy to
  28 ;; understand options.
  29
  30 ;; See the auth.info Info documentation for details.
  31
  32 ;; TODO:
  33
  34 ;; - never decode the backend file unless it's necessary
  35 ;; - a more generic way to match backends and search backend contents
  36 ;; - absorb netrc.el and simplify it
  37 ;; - protect passwords better
  38 ;; - allow creating and changing netrc lines (not files) e.g. change a password
  39
  40 ;;; Code:
  41
  42 (require 'password-cache)
  43 (require 'mm-util)
  44 (require 'gnus-util)
  45 (require 'assoc)
  46
  47 (eval-when-compile (require 'cl))
  48 (eval-and-compile
  49   (or (ignore-errors (require 'eieio))
  50       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  51       (ignore-errors
  52         (let ((load-path (cons (expand-file-name
  53                                 "gnus-fallback-lib/eieio"
  54                                 (file-name-directory (locate-library "gnus")))
  55                                load-path)))
  56           (require 'eieio)))
  57       (error
  58        "eieio not found in `load-path' or gnus-fallback-lib/ directory.")))
  59
  60 (autoload 'secrets-create-item "secrets")
  61 (autoload 'secrets-delete-item "secrets")
  62 (autoload 'secrets-get-alias "secrets")
  63 (autoload 'secrets-get-attributes "secrets")
  64 (autoload 'secrets-get-secret "secrets")
  65 (autoload 'secrets-list-collections "secrets")
  66 (autoload 'secrets-search-items "secrets")
  67
  68 (autoload 'rfc2104-hash "rfc2104")
  69
  70 (autoload 'plstore-open "plstore")
  71 (autoload 'plstore-find "plstore")
  72 (autoload 'plstore-put "plstore")
  73 (autoload 'plstore-delete "plstore")
  74 (autoload 'plstore-save "plstore")
  75 (autoload 'plstore-get-file "plstore")
  76
  77 (autoload 'epg-make-context "epg")
  78 (autoload 'epg-context-set-passphrase-callback "epg")
  79 (autoload 'epg-decrypt-string "epg")
  80 (autoload 'epg-context-set-armor "epg")
  81 (autoload 'epg-encrypt-string "epg")
  82
  83 (autoload 'help-mode "help-mode" nil t)
  84
  85 (defvar secrets-enabled)
  86
  87 (defgroup auth-source nil
  88   "Authentication sources."
  89   :version "23.1" ;; No Gnus
  90   :group 'gnus)
  91
  92 ;;;###autoload
  93 (defcustom auth-source-cache-expiry 7200
  94   "How many seconds passwords are cached, or nil to disable
  95 expiring.  Overrides `password-cache-expiry' through a
  96 let-binding."
  97   :group 'auth-source
  98   :type '(choice (const :tag "Never" nil)
  99                  (const :tag "All Day" 86400)
 100                  (const :tag "2 Hours" 7200)
 101                  (const :tag "30 Minutes" 1800)
 102                  (integer :tag "Seconds")))
 103
 104 ;;; The slots below correspond with the `auth-source-search' spec,
 105 ;;; so a backend with :host set, for instance, would match only
 106 ;;; searches for that host.  Normally they are nil.
 107 (defclass auth-source-backend ()
 108   ((type :initarg :type
 109          :initform 'netrc
 110          :type symbol
 111          :custom symbol
 112          :documentation "The backend type.")
 113    (source :initarg :source
 114            :type string
 115            :custom string
 116            :documentation "The backend source.")
 117    (host :initarg :host
 118          :initform t
 119          :type t
 120          :custom string
 121          :documentation "The backend host.")
 122    (user :initarg :user
 123          :initform t
 124          :type t
 125          :custom string
 126          :documentation "The backend user.")
 127    (port :initarg :port
 128          :initform t
 129          :type t
 130          :custom string
 131          :documentation "The backend protocol.")
 132    (data :initarg :data
 133          :initform nil
 134          :documentation "Internal backend data.")
 135    (create-function :initarg :create-function
 136                     :initform ignore
 137                     :type function
 138                     :custom function
 139                     :documentation "The create function.")
 140    (search-function :initarg :search-function
 141                     :initform ignore
 142                     :type function
 143                     :custom function
 144                     :documentation "The search function.")))
 145
 146 (defcustom auth-source-protocols '((imap "imap" "imaps" "143" "993")
 147                                    (pop3 "pop3" "pop" "pop3s" "110" "995")
 148                                    (ssh  "ssh" "22")
 149                                    (sftp "sftp" "115")
 150                                    (smtp "smtp" "25"))
 151   "List of authentication protocols and their names"
 152
 153   :group 'auth-source
 154   :version "23.2" ;; No Gnus
 155   :type '(repeat :tag "Authentication Protocols"
 156                  (cons :tag "Protocol Entry"
 157                        (symbol :tag "Protocol")
 158                        (repeat :tag "Names"
 159                                (string :tag "Name")))))
 160
 161 ;;; generate all the protocols in a format Customize can use
 162 ;;; TODO: generate on the fly from auth-source-protocols
 163 (defconst auth-source-protocols-customize
 164   (mapcar (lambda (a)
 165             (let ((p (car-safe a)))
 166               (list 'const
 167                     :tag (upcase (symbol-name p))
 168                     p)))
 169           auth-source-protocols))
 170
 171 (defvar auth-source-creation-defaults nil
 172   "Defaults for creating token values.  Usually let-bound.")
 173
 174 (defvar auth-source-creation-prompts nil
 175   "Default prompts for token values.  Usually let-bound.")
 176
 177 (make-obsolete 'auth-source-hide-passwords nil "Emacs 24.1")
 178
 179 (defcustom auth-source-save-behavior 'ask
 180   "If set, auth-source will respect it for save behavior."
 181   :group 'auth-source
 182   :version "23.2" ;; No Gnus
 183   :type `(choice
 184           :tag "auth-source new token save behavior"
 185           (const :tag "Always save" t)
 186           (const :tag "Never save" nil)
 187           (const :tag "Ask" ask)))
 188
 189 ;; TODO: make the default (setq auth-source-netrc-use-gpg-tokens `((,(if (boundp 'epa-file-auto-mode-alist-entry) (car (symbol-value 'epa-file-auto-mode-alist-entry)) "\\.gpg\\'") never) (t gpg)))
 190 ;; TODO: or maybe leave as (setq auth-source-netrc-use-gpg-tokens 'never)
 191
 192 (defcustom auth-source-netrc-use-gpg-tokens 'never
 193   "Set this to tell auth-source when to create GPG password
 194 tokens in netrc files.  It's either an alist or `never'.
 195 Note that if EPA/EPG is not available, this should NOT be used."
 196   :group 'auth-source
 197   :version "23.2" ;; No Gnus
 198   :type `(choice
 199           (const :tag "Always use GPG password tokens" (t gpg))
 200           (const :tag "Never use GPG password tokens" never)
 201           (repeat :tag "Use a lookup list"
 202                   (list
 203                    (choice :tag "Matcher"
 204                            (const :tag "Match anything" t)
 205                            (const :tag "The EPA encrypted file extensions"
 206                                   ,(if (boundp 'epa-file-auto-mode-alist-entry)
 207                                        (car (symbol-value
 208                                              'epa-file-auto-mode-alist-entry))
 209                                      "\\.gpg\\'"))
 210                            (regexp :tag "Regular expression"))
 211                    (choice :tag "What to do"
 212                            (const :tag "Save GPG-encrypted password tokens" gpg)
 213                            (const :tag "Don't encrypt tokens" never))))))
 214
 215 (defvar auth-source-magic "auth-source-magic ")
 216
 217 (defcustom auth-source-do-cache t
 218   "Whether auth-source should cache information with `password-cache'."
 219   :group 'auth-source
 220   :version "23.2" ;; No Gnus
 221   :type `boolean)
 222
 223 (defcustom auth-source-debug nil
 224   "Whether auth-source should log debug messages.
 225
 226 If the value is nil, debug messages are not logged.
 227
 228 If the value is t, debug messages are logged with `message'.  In
 229 that case, your authentication data will be in the clear (except
 230 for passwords).
 231
 232 If the value is a function, debug messages are logged by calling
 233  that function using the same arguments as `message'."
 234   :group 'auth-source
 235   :version "23.2" ;; No Gnus
 236   :type `(choice
 237           :tag "auth-source debugging mode"
 238           (const :tag "Log using `message' to the *Messages* buffer" t)
 239           (const :tag "Log all trivia with `message' to the *Messages* buffer"
 240                  trivia)
 241           (function :tag "Function that takes arguments like `message'")
 242           (const :tag "Don't log anything" nil)))
 243
 244 (defcustom auth-sources '("~/.authinfo" "~/.authinfo.gpg" "~/.netrc")
 245   "List of authentication sources.
 246
 247 The default will get login and password information from
 248 \"~/.authinfo.gpg\", which you should set up with the EPA/EPG
 249 packages to be encrypted.  If that file doesn't exist, it will
 250 try the unencrypted version \"~/.authinfo\" and the famous
 251 \"~/.netrc\" file.
 252
 253 See the auth.info manual for details.
 254
 255 Each entry is the authentication type with optional properties.
 256
 257 It's best to customize this with `M-x customize-variable' because the choices
 258 can get pretty complex."
 259   :group 'auth-source
 260   :version "24.1" ;; No Gnus
 261   :type `(repeat :tag "Authentication Sources"
 262                  (choice
 263                   (string :tag "Just a file")
 264                   (const :tag "Default Secrets API Collection" 'default)
 265                   (const :tag "Login Secrets API Collection" "secrets:Login")
 266                   (const :tag "Temp Secrets API Collection" "secrets:session")
 267                   (list :tag "Source definition"
 268                         (const :format "" :value :source)
 269                         (choice :tag "Authentication backend choice"
 270                                 (string :tag "Authentication Source (file)")
 271                                 (list
 272                                  :tag "Secret Service API/KWallet/GNOME Keyring"
 273                                  (const :format "" :value :secrets)
 274                                  (choice :tag "Collection to use"
 275                                          (string :tag "Collection name")
 276                                          (const :tag "Default" 'default)
 277                                          (const :tag "Login" "Login")
 278                                          (const
 279                                           :tag "Temporary" "session"))))
 280                         (repeat :tag "Extra Parameters" :inline t
 281                                 (choice :tag "Extra parameter"
 282                                         (list
 283                                          :tag "Host"
 284                                          (const :format "" :value :host)
 285                                          (choice :tag "Host (machine) choice"
 286                                                  (const :tag "Any" t)
 287                                                  (regexp
 288                                                   :tag "Regular expression")))
 289                                         (list
 290                                          :tag "Protocol"
 291                                          (const :format "" :value :port)
 292                                          (choice
 293                                           :tag "Protocol"
 294                                           (const :tag "Any" t)
 295                                           ,@auth-source-protocols-customize))
 296                                         (list :tag "User" :inline t
 297                                               (const :format "" :value :user)
 298                                               (choice
 299                                                :tag "Personality/Username"
 300                                                (const :tag "Any" t)
 301                                                (string
 302                                                 :tag "Name")))))))))
 303
 304 (defcustom auth-source-gpg-encrypt-to t
 305   "List of recipient keys that `authinfo.gpg' encrypted to.
 306 If the value is not a list, symmetric encryption will be used."
 307   :group 'auth-source
 308   :version "24.1" ;; No Gnus
 309   :type '(choice (const :tag "Symmetric encryption" t)
 310                  (repeat :tag "Recipient public keys"
 311                          (string :tag "Recipient public key"))))
 312
 313 ;; temp for debugging
 314 ;; (unintern 'auth-source-protocols)
 315 ;; (unintern 'auth-sources)
 316 ;; (customize-variable 'auth-sources)
 317 ;; (setq auth-sources nil)
 318 ;; (format "%S" auth-sources)
 319 ;; (customize-variable 'auth-source-protocols)
 320 ;; (setq auth-source-protocols nil)
 321 ;; (format "%S" auth-source-protocols)
 322 ;; (auth-source-pick nil :host "a" :port 'imap)
 323 ;; (auth-source-user-or-password "login" "imap.myhost.com" 'imap)
 324 ;; (auth-source-user-or-password "password" "imap.myhost.com" 'imap)
 325 ;; (auth-source-user-or-password-imap "login" "imap.myhost.com")
 326 ;; (auth-source-user-or-password-imap "password" "imap.myhost.com")
 327 ;; (auth-source-protocol-defaults 'imap)
 328
 329 ;; (let ((auth-source-debug 'debug)) (auth-source-do-debug "hello"))
 330 ;; (let ((auth-source-debug t)) (auth-source-do-debug "hello"))
 331 ;; (let ((auth-source-debug nil)) (auth-source-do-debug "hello"))
 332 (defun auth-source-do-debug (&rest msg)
 333   (when auth-source-debug
 334     (apply 'auth-source-do-warn msg)))
 335
 336 (defun auth-source-do-trivia (&rest msg)
 337   (when (or (eq auth-source-debug 'trivia)
 338             (functionp auth-source-debug))
 339     (apply 'auth-source-do-warn msg)))
 340
 341 (defun auth-source-do-warn (&rest msg)
 342   (apply
 343    ;; set logger to either the function in auth-source-debug or 'message
 344    ;; note that it will be 'message if auth-source-debug is nil
 345    (if (functionp auth-source-debug)
 346        auth-source-debug
 347      'message)
 348    msg))
 349
 350
 351 ;;; (auth-source-read-char-choice "enter choice? " '(?a ?b ?q))
 352 (defun auth-source-read-char-choice (prompt choices)
 353   "Read one of CHOICES by `read-char-choice', or `read-char'.
 354 `dropdown-list' support is disabled because it doesn't work reliably.
 355 Only one of CHOICES will be returned.  The PROMPT is augmented
 356 with \"[a/b/c] \" if CHOICES is '\(?a ?b ?c\)."
 357   (when choices
 358     (let* ((prompt-choices
 359             (apply 'concat (loop for c in choices
 360                                  collect (format "%c/" c))))
 361            (prompt-choices (concat "[" (substring prompt-choices 0 -1) "] "))
 362            (full-prompt (concat prompt prompt-choices))
 363            k)
 364
 365       (while (not (memq k choices))
 366         (setq k (cond
 367                  ((fboundp 'read-char-choice)
 368                   (read-char-choice full-prompt choices))
 369                  (t (message "%s" full-prompt)
 370                     (setq k (read-char))))))
 371       k)))
 372
 373 ;; (auth-source-pick nil :host "any" :port 'imap :user "joe")
 374 ;; (auth-source-pick t :host "any" :port 'imap :user "joe")
 375 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 376 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 377 ;;                   (:source (:secrets "Login") :host t :port t)
 378 ;;                   (:source "~/.authinfo.gpg" :host t :port t)))
 379
 380 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 381 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 382 ;;                   (:source (:secrets "Login") :host t :port t)
 383 ;;                   ))
 384
 385 ;; (setq auth-sources '((:source "~/.authinfo.gpg" :host t :port t)))
 386
 387 ;; (auth-source-backend-parse "myfile.gpg")
 388 ;; (auth-source-backend-parse 'default)
 389 ;; (auth-source-backend-parse "secrets:Login")
 390
 391 (defun auth-source-backend-parse (entry)
 392   "Creates an auth-source-backend from an ENTRY in `auth-sources'."
 393   (auth-source-backend-parse-parameters
 394    entry
 395    (cond
 396     ;; take 'default and recurse to get it as a Secrets API default collection
 397     ;; matching any user, host, and protocol
 398     ((eq entry 'default)
 399      (auth-source-backend-parse '(:source (:secrets default))))
 400     ;; take secrets:XYZ and recurse to get it as Secrets API collection "XYZ"
 401     ;; matching any user, host, and protocol
 402     ((and (stringp entry) (string-match "^secrets:\\(.+\\)" entry))
 403      (auth-source-backend-parse `(:source (:secrets ,(match-string 1 entry)))))
 404     ;; take just a file name and recurse to get it as a netrc file
 405     ;; matching any user, host, and protocol
 406     ((stringp entry)
 407      (auth-source-backend-parse `(:source ,entry)))
 408
 409     ;; a file name with parameters
 410     ((stringp (plist-get entry :source))
 411      (if (equal (file-name-extension (plist-get entry :source)) "plist")
 412          (auth-source-backend
 413           (plist-get entry :source)
 414           :source (plist-get entry :source)
 415           :type 'plstore
 416           :search-function 'auth-source-plstore-search
 417           :create-function 'auth-source-plstore-create
 418           :data (plstore-open (plist-get entry :source)))
 419        (auth-source-backend
 420         (plist-get entry :source)
 421         :source (plist-get entry :source)
 422         :type 'netrc
 423         :search-function 'auth-source-netrc-search
 424         :create-function 'auth-source-netrc-create)))
 425
 426     ;; the Secrets API.  We require the package, in order to have a
 427     ;; defined value for `secrets-enabled'.
 428     ((and
 429       (not (null (plist-get entry :source))) ; the source must not be nil
 430       (listp (plist-get entry :source))      ; and it must be a list
 431       (require 'secrets nil t)               ; and we must load the Secrets API
 432       secrets-enabled)                       ; and that API must be enabled
 433
 434      ;; the source is either the :secrets key in ENTRY or
 435      ;; if that's missing or nil, it's "session"
 436      (let ((source (or (plist-get (plist-get entry :source) :secrets)
 437                        "session")))
 438
 439        ;; if the source is a symbol, we look for the alias named so,
 440        ;; and if that alias is missing, we use "Login"
 441        (when (symbolp source)
 442          (setq source (or (secrets-get-alias (symbol-name source))
 443                           "Login")))
 444
 445        (if (featurep 'secrets)
 446            (auth-source-backend
 447             (format "Secrets API (%s)" source)
 448             :source source
 449             :type 'secrets
 450             :search-function 'auth-source-secrets-search
 451             :create-function 'auth-source-secrets-create)
 452          (auth-source-do-warn
 453           "auth-source-backend-parse: no Secrets API, ignoring spec: %S" entry)
 454          (auth-source-backend
 455           (format "Ignored Secrets API (%s)" source)
 456           :source ""
 457           :type 'ignore))))
 458
 459     ;; none of them
 460     (t
 461      (auth-source-do-warn
 462       "auth-source-backend-parse: invalid backend spec: %S" entry)
 463      (auth-source-backend
 464       "Empty"
 465       :source ""
 466       :type 'ignore)))))
 467
 468 (defun auth-source-backend-parse-parameters (entry backend)
 469   "Fills in the extra auth-source-backend parameters of ENTRY.
 470 Using the plist ENTRY, get the :host, :port, and :user search
 471 parameters."
 472   (let ((entry (if (stringp entry)
 473                    nil
 474                  entry))
 475         val)
 476     (when (setq val (plist-get entry :host))
 477       (oset backend host val))
 478     (when (setq val (plist-get entry :user))
 479       (oset backend user val))
 480     (when (setq val (plist-get entry :port))
 481       (oset backend port val)))
 482   backend)
 483
 484 ;; (mapcar 'auth-source-backend-parse auth-sources)
 485
 486 (defun* auth-source-search (&rest spec
 487                                   &key type max host user port secret
 488                                   require create delete
 489                                   &allow-other-keys)
 490   "Search or modify authentication backends according to SPEC.
 491
 492 This function parses `auth-sources' for matches of the SPEC
 493 plist.  It can optionally create or update an authentication
 494 token if requested.  A token is just a standard Emacs property
 495 list with a :secret property that can be a function; all the
 496 other properties will always hold scalar values.
 497
 498 Typically the :secret property, if present, contains a password.
 499
 500 Common search keys are :max, :host, :port, and :user.  In
 501 addition, :create specifies how tokens will be or created.
 502 Finally, :type can specify which backend types you want to check.
 503
 504 A string value is always matched literally.  A symbol is matched
 505 as its string value, literally.  All the SPEC values can be
 506 single values (symbol or string) or lists thereof (in which case
 507 any of the search terms matches).
 508
 509 :create t means to create a token if possible.
 510
 511 A new token will be created if no matching tokens were found.
 512 The new token will have only the keys the backend requires.  For
 513 the netrc backend, for instance, that's the user, host, and
 514 port keys.
 515
 516 Here's an example:
 517
 518 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 519                                         (A    . \"default A\"))))
 520   (auth-source-search :host \"mine\" :type 'netrc :max 1
 521                       :P \"pppp\" :Q \"qqqq\"
 522                       :create t))
 523
 524 which says:
 525
 526 \"Search for any entry matching host 'mine' in backends of type
 527  'netrc', maximum one result.
 528
 529  Create a new entry if you found none.  The netrc backend will
 530  automatically require host, user, and port.  The host will be
 531  'mine'.  We prompt for the user with default 'defaultUser' and
 532  for the port without a default.  We will not prompt for A, Q,
 533  or P.  The resulting token will only have keys user, host, and
 534  port.\"
 535
 536 :create '(A B C) also means to create a token if possible.
 537
 538 The behavior is like :create t but if the list contains any
 539 parameter, that parameter will be required in the resulting
 540 token.  The value for that parameter will be obtained from the
 541 search parameters or from user input.  If any queries are needed,
 542 the alist `auth-source-creation-defaults' will be checked for the
 543 default value.  If the user, host, or port are missing, the alist
 544 `auth-source-creation-prompts' will be used to look up the
 545 prompts IN THAT ORDER (so the 'user prompt will be queried first,
 546 then 'host, then 'port, and finally 'secret).  Each prompt string
 547 can use %u, %h, and %p to show the user, host, and port.
 548
 549 Here's an example:
 550
 551 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 552                                         (A    . \"default A\")))
 553        (auth-source-creation-prompts
 554         '((password . \"Enter IMAP password for %h:%p: \"))))
 555   (auth-source-search :host '(\"nonesuch\" \"twosuch\") :type 'netrc :max 1
 556                       :P \"pppp\" :Q \"qqqq\"
 557                       :create '(A B Q)))
 558
 559 which says:
 560
 561 \"Search for any entry matching host 'nonesuch'
 562  or 'twosuch' in backends of type 'netrc', maximum one result.
 563
 564  Create a new entry if you found none.  The netrc backend will
 565  automatically require host, user, and port.  The host will be
 566  'nonesuch' and Q will be 'qqqq'.  We prompt for the password
 567  with the shown prompt.  We will not prompt for Q.  The resulting
 568  token will have keys user, host, port, A, B, and Q.  It will not
 569  have P with any value, even though P is used in the search to
 570  find only entries that have P set to 'pppp'.\"
 571
 572 When multiple values are specified in the search parameter, the
 573 user is prompted for which one.  So :host (X Y Z) would ask the
 574 user to choose between X, Y, and Z.
 575
 576 This creation can fail if the search was not specific enough to
 577 create a new token (it's up to the backend to decide that).  You
 578 should `catch' the backend-specific error as usual.  Some
 579 backends (netrc, at least) will prompt the user rather than throw
 580 an error.
 581
 582 :require (A B C) means that only results that contain those
 583 tokens will be returned.  Thus for instance requiring :secret
 584 will ensure that any results will actually have a :secret
 585 property.
 586
 587 :delete t means to delete any found entries.  nil by default.
 588 Use `auth-source-delete' in ELisp code instead of calling
 589 `auth-source-search' directly with this parameter.
 590
 591 :type (X Y Z) will check only those backend types.  'netrc and
 592 'secrets are the only ones supported right now.
 593
 594 :max N means to try to return at most N items (defaults to 1).
 595 When 0 the function will return just t or nil to indicate if any
 596 matches were found.  More than N items may be returned, depending
 597 on the search and the backend.
 598
 599 :host (X Y Z) means to match only hosts X, Y, or Z according to
 600 the match rules above.  Defaults to t.
 601
 602 :user (X Y Z) means to match only users X, Y, or Z according to
 603 the match rules above.  Defaults to t.
 604
 605 :port (P Q R) means to match only protocols P, Q, or R.
 606 Defaults to t.
 607
 608 :K (V1 V2 V3) for any other key K will match values V1, V2, or
 609 V3 (note the match rules above).
 610
 611 The return value is a list with at most :max tokens.  Each token
 612 is a plist with keys :backend :host :port :user, plus any other
 613 keys provided by the backend (notably :secret).  But note the
 614 exception for :max 0, which see above.
 615
 616 The token can hold a :save-function key.  If you call that, the
 617 user will be prompted to save the data to the backend.  You can't
 618 request that this should happen right after creation, because
 619 `auth-source-search' has no way of knowing if the token is
 620 actually useful.  So the caller must arrange to call this function.
 621
 622 The token's :secret key can hold a function.  In that case you
 623 must call it to obtain the actual value."
 624   (let* ((backends (mapcar 'auth-source-backend-parse auth-sources))
 625          (max (or max 1))
 626          (ignored-keys '(:require :create :delete :max))
 627          (keys (loop for i below (length spec) by 2
 628                      unless (memq (nth i spec) ignored-keys)
 629                      collect (nth i spec)))
 630          (cached (auth-source-remembered-p spec))
 631          ;; note that we may have cached results but found is still nil
 632          ;; (there were no results from the search)
 633          (found (auth-source-recall spec))
 634          filtered-backends accessor-key backend)
 635
 636     (if (and cached auth-source-do-cache)
 637         (auth-source-do-debug
 638          "auth-source-search: found %d CACHED results matching %S"
 639          (length found) spec)
 640
 641       (assert
 642        (or (eq t create) (listp create)) t
 643        "Invalid auth-source :create parameter (must be t or a list): %s %s")
 644
 645       (assert
 646        (listp require) t
 647        "Invalid auth-source :require parameter (must be a list): %s")
 648
 649       (setq filtered-backends (copy-sequence backends))
 650       (dolist (backend backends)
 651         (dolist (key keys)
 652           ;; ignore invalid slots
 653           (condition-case signal
 654               (unless (eval `(auth-source-search-collection
 655                               (plist-get spec key)
 656                               (oref backend ,key)))
 657                 (setq filtered-backends (delq backend filtered-backends))
 658                 (return))
 659             (invalid-slot-name))))
 660
 661       (auth-source-do-trivia
 662        "auth-source-search: found %d backends matching %S"
 663        (length filtered-backends) spec)
 664
 665       ;; (debug spec "filtered" filtered-backends)
 666       ;; First go through all the backends without :create, so we can
 667       ;; query them all.
 668       (setq found (auth-source-search-backends filtered-backends
 669                                                spec
 670                                                ;; to exit early
 671                                                max
 672                                                ;; create is always nil here
 673                                                nil delete
 674                                                require))
 675
 676       (auth-source-do-debug
 677        "auth-source-search: found %d results (max %d) matching %S"
 678        (length found) max spec)
 679
 680       ;; If we didn't find anything, then we allow the backend(s) to
 681       ;; create the entries.
 682       (when (and create
 683                  (not found))
 684         (setq found (auth-source-search-backends filtered-backends
 685                                                  spec
 686                                                  ;; to exit early
 687                                                  max
 688                                                  create delete
 689                                                  require))
 690         (auth-source-do-debug
 691          "auth-source-search: CREATED %d results (max %d) matching %S"
 692          (length found) max spec))
 693
 694       ;; note we remember the lack of result too, if it's applicable
 695       (when auth-source-do-cache
 696         (auth-source-remember spec found)))
 697
 698     found))
 699
 700 (defun auth-source-search-backends (backends spec max create delete require)
 701   (let (matches)
 702     (dolist (backend backends)
 703       (when (> max (length matches))   ; when we need more matches...
 704         (let* ((bmatches (apply
 705                           (slot-value backend 'search-function)
 706                           :backend backend
 707                           ;; note we're overriding whatever the spec
 708                           ;; has for :require, :create, and :delete
 709                           :require require
 710                           :create create
 711                           :delete delete
 712                           spec)))
 713           (when bmatches
 714             (auth-source-do-trivia
 715              "auth-source-search-backend: got %d (max %d) in %s:%s matching %S"
 716              (length bmatches) max
 717              (slot-value backend :type)
 718              (slot-value backend :source)
 719              spec)
 720             (setq matches (append matches bmatches))))))
 721     matches))
 722
 723 ;;; (auth-source-search :max 1)
 724 ;;; (funcall (plist-get (nth 0 (auth-source-search :max 1)) :secret))
 725 ;;; (auth-source-search :host "nonesuch" :type 'netrc :K 1)
 726 ;;; (auth-source-search :host "nonesuch" :type 'secrets)
 727
 728 (defun* auth-source-delete (&rest spec
 729                                   &key delete
 730                                   &allow-other-keys)
 731   "Delete entries from the authentication backends according to SPEC.
 732 Calls `auth-source-search' with the :delete property in SPEC set to t.
 733 The backend may not actually delete the entries.
 734
 735 Returns the deleted entries."
 736   (auth-source-search (plist-put spec :delete t)))
 737
 738 (defun auth-source-search-collection (collection value)
 739   "Returns t is VALUE is t or COLLECTION is t or contains VALUE."
 740   (when (and (atom collection) (not (eq t collection)))
 741     (setq collection (list collection)))
 742
 743   ;; (debug :collection collection :value value)
 744   (or (eq collection t)
 745       (eq value t)
 746       (equal collection value)
 747       (member value collection)))
 748
 749 (defvar auth-source-netrc-cache nil)
 750
 751 (defun auth-source-forget-all-cached ()
 752   "Forget all cached auth-source data."
 753   (interactive)
 754   (loop for sym being the symbols of password-data
 755         ;; when the symbol name starts with auth-source-magic
 756         when (string-match (concat "^" auth-source-magic)
 757                            (symbol-name sym))
 758         ;; remove that key
 759         do (password-cache-remove (symbol-name sym)))
 760   (setq auth-source-netrc-cache nil))
 761
 762 (defun auth-source-format-cache-entry (spec)
 763   "Format SPEC entry to put it in the password cache."
 764   (concat auth-source-magic (format "%S" spec)))
 765
 766 (defun auth-source-remember (spec found)
 767   "Remember FOUND search results for SPEC."
 768   (let ((password-cache-expiry auth-source-cache-expiry))
 769     (password-cache-add
 770      (auth-source-format-cache-entry spec) found)))
 771
 772 (defun auth-source-recall (spec)
 773   "Recall FOUND search results for SPEC."
 774   (password-read-from-cache (auth-source-format-cache-entry spec)))
 775
 776 (defun auth-source-remembered-p (spec)
 777   "Check if SPEC is remembered."
 778   (password-in-cache-p
 779    (auth-source-format-cache-entry spec)))
 780
 781 (defun auth-source-forget (spec)
 782   "Forget any cached data matching SPEC exactly.
 783
 784 This is the same SPEC you passed to `auth-source-search'.
 785 Returns t or nil for forgotten or not found."
 786   (password-cache-remove (auth-source-format-cache-entry spec)))
 787
 788 ;;; (loop for sym being the symbols of password-data when (string-match (concat "^" auth-source-magic) (symbol-name sym)) collect (symbol-name sym))
 789
 790 ;;; (auth-source-remember '(:host "wedd") '(4 5 6))
 791 ;;; (auth-source-remembered-p '(:host "wedd"))
 792 ;;; (auth-source-remember '(:host "xedd") '(1 2 3))
 793 ;;; (auth-source-remembered-p '(:host "xedd"))
 794 ;;; (auth-source-remembered-p '(:host "zedd"))
 795 ;;; (auth-source-recall '(:host "xedd"))
 796 ;;; (auth-source-recall '(:host t))
 797 ;;; (auth-source-forget+ :host t)
 798
 799 (defun* auth-source-forget+ (&rest spec &allow-other-keys)
 800   "Forget any cached data matching SPEC.  Returns forgotten count.
 801
 802 This is not a full `auth-source-search' spec but works similarly.
 803 For instance, \(:host \"myhost\" \"yourhost\") would find all the
 804 cached data that was found with a search for those two hosts,
 805 while \(:host t) would find all host entries."
 806   (let ((count 0)
 807         sname)
 808     (loop for sym being the symbols of password-data
 809           ;; when the symbol name matches with auth-source-magic
 810           when (and (setq sname (symbol-name sym))
 811                     (string-match (concat "^" auth-source-magic "\\(.+\\)")
 812                                   sname)
 813                     ;; and the spec matches what was stored in the cache
 814                     (auth-source-specmatchp spec (read (match-string 1 sname))))
 815           ;; remove that key
 816           do (progn
 817                (password-cache-remove sname)
 818                (incf count)))
 819     count))
 820
 821 (defun auth-source-specmatchp (spec stored)
 822   (let ((keys (loop for i below (length spec) by 2
 823                     collect (nth i spec))))
 824     (not (eq
 825           (dolist (key keys)
 826             (unless (auth-source-search-collection (plist-get stored key)
 827                                                    (plist-get spec key))
 828               (return 'no)))
 829           'no))))
 830
 831 ;;; (auth-source-pick-first-password :host "z.lifelogs.com")
 832 ;;; (auth-source-pick-first-password :port "imap")
 833 (defun auth-source-pick-first-password (&rest spec)
 834   "Pick the first secret found from applying SPEC to `auth-source-search'."
 835   (let* ((result (nth 0 (apply 'auth-source-search (plist-put spec :max 1))))
 836          (secret (plist-get result :secret)))
 837
 838     (if (functionp secret)
 839         (funcall secret)
 840       secret)))
 841
 842 ;; (auth-source-format-prompt "test %u %h %p" '((?u "user") (?h "host")))
 843 (defun auth-source-format-prompt (prompt alist)
 844   "Format PROMPT using %x (for any character x) specifiers in ALIST."
 845   (dolist (cell alist)
 846     (let ((c (nth 0 cell))
 847           (v (nth 1 cell)))
 848       (when (and c v)
 849         (setq prompt (replace-regexp-in-string (format "%%%c" c)
 850                                                (format "%s" v)
 851                                                prompt)))))
 852   prompt)
 853
 854 (defun auth-source-ensure-strings (values)
 855   (unless (listp values)
 856     (setq values (list values)))
 857   (mapcar (lambda (value)
 858             (if (numberp value)
 859                 (format "%s" value)
 860               value))
 861           values))
 862
 863 ;;; Backend specific parsing: netrc/authinfo backend
 864
 865 ;;; (auth-source-netrc-parse "~/.authinfo.gpg")
 866 (defun* auth-source-netrc-parse (&rest
 867                                  spec
 868                                  &key file max host user port delete require
 869                                  &allow-other-keys)
 870   "Parse FILE and return a list of all entries in the file.
 871 Note that the MAX parameter is used so we can exit the parse early."
 872   (if (listp file)
 873       ;; We got already parsed contents; just return it.
 874       file
 875     (when (file-exists-p file)
 876       (setq port (auth-source-ensure-strings port))
 877       (with-temp-buffer
 878         (let* ((tokens '("machine" "host" "default" "login" "user"
 879                          "password" "account" "macdef" "force"
 880                          "port" "protocol"))
 881                (max (or max 5000))       ; sanity check: default to stop at 5K
 882                (modified 0)
 883                (cached (cdr-safe (assoc file auth-source-netrc-cache)))
 884                (cached-mtime (plist-get cached :mtime))
 885                (cached-secrets (plist-get cached :secret))
 886                alist elem result pair)
 887
 888           (if (and (functionp cached-secrets)
 889                    (equal cached-mtime
 890                           (nth 5 (file-attributes file))))
 891               (progn
 892                 (auth-source-do-trivia
 893                  "auth-source-netrc-parse: using CACHED file data for %s"
 894                  file)
 895                 (insert (funcall cached-secrets)))
 896             (insert-file-contents file)
 897             ;; cache all netrc files (used to be just .gpg files)
 898             ;; Store the contents of the file heavily encrypted in memory.
 899             ;; (note for the irony-impaired: they are just obfuscated)
 900             (aput 'auth-source-netrc-cache file
 901                   (list :mtime (nth 5 (file-attributes file))
 902                         :secret (lexical-let ((v (mapcar '1+ (buffer-string))))
 903                                   (lambda () (apply 'string (mapcar '1- v)))))))
 904           (goto-char (point-min))
 905           ;; Go through the file, line by line.
 906           (while (and (not (eobp))
 907                       (> max 0))
 908
 909             (narrow-to-region (point) (point-at-eol))
 910             ;; For each line, get the tokens and values.
 911             (while (not (eobp))
 912               (skip-chars-forward "\t ")
 913               ;; Skip lines that begin with a "#".
 914               (if (eq (char-after) ?#)
 915                   (goto-char (point-max))
 916                 (unless (eobp)
 917                   (setq elem
 918                         (if (= (following-char) ?\")
 919                             (read (current-buffer))
 920                           (buffer-substring
 921                            (point) (progn (skip-chars-forward "^\t ")
 922                                           (point)))))
 923                   (cond
 924                    ((equal elem "macdef")
 925                     ;; We skip past the macro definition.
 926                     (widen)
 927                     (while (and (zerop (forward-line 1))
 928                                 (looking-at "$")))
 929                     (narrow-to-region (point) (point)))
 930                    ((member elem tokens)
 931                     ;; Tokens that don't have a following value are ignored,
 932                     ;; except "default".
 933                     (when (and pair (or (cdr pair)
 934                                         (equal (car pair) "default")))
 935                       (push pair alist))
 936                     (setq pair (list elem)))
 937                    (t
 938                     ;; Values that haven't got a preceding token are ignored.
 939                     (when pair
 940                       (setcdr pair elem)
 941                       (push pair alist)
 942                       (setq pair nil)))))))
 943
 944             (when (and alist
 945                        (> max 0)
 946                        (auth-source-search-collection
 947                         host
 948                         (or
 949                          (aget alist "machine")
 950                          (aget alist "host")
 951                          t))
 952                        (auth-source-search-collection
 953                         user
 954                         (or
 955                          (aget alist "login")
 956                          (aget alist "account")
 957                          (aget alist "user")
 958                          t))
 959                        (auth-source-search-collection
 960                         port
 961                         (or
 962                          (aget alist "port")
 963                          (aget alist "protocol")
 964                          t))
 965                        (or
 966                         ;; the required list of keys is nil, or
 967                         (null require)
 968                         ;; every element of require is in the normalized list
 969                         (let ((normalized (nth 0 (auth-source-netrc-normalize
 970                                                   (list alist) file))))
 971                           (loop for req in require
 972                                 always (plist-get normalized req)))))
 973               (decf max)
 974               (push (nreverse alist) result)
 975               ;; to delete a line, we just comment it out
 976               (when delete
 977                 (goto-char (point-min))
 978                 (insert "#")
 979                 (incf modified)))
 980             (setq alist nil
 981                   pair nil)
 982             (widen)
 983             (forward-line 1))
 984
 985           (when (< 0 modified)
 986             (when auth-source-gpg-encrypt-to
 987               ;; (see bug#7487) making `epa-file-encrypt-to' local to
 988               ;; this buffer lets epa-file skip the key selection query
 989               ;; (see the `local-variable-p' check in
 990               ;; `epa-file-write-region').
 991               (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 992                 (make-local-variable 'epa-file-encrypt-to))
 993               (if (listp auth-source-gpg-encrypt-to)
 994                   (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 995
 996             ;; ask AFTER we've successfully opened the file
 997             (when (y-or-n-p (format "Save file %s? (%d deletions)"
 998                                     file modified))
 999               (write-region (point-min) (point-max) file nil 'silent)
1000               (auth-source-do-debug
1001                "auth-source-netrc-parse: modified %d lines in %s"
1002                modified file)))
1003
1004           (nreverse result))))))
1005
1006 (defvar auth-source-passphrase-alist nil)
1007
1008 (defun auth-source-token-passphrase-callback-function (context key-id file)
1009   (let* ((file (file-truename file))
1010          (entry (assoc file auth-source-passphrase-alist))
1011          passphrase)
1012     ;; return the saved passphrase, calling a function if needed
1013     (or (copy-sequence (if (functionp (cdr entry))
1014                            (funcall (cdr entry))
1015                          (cdr entry)))
1016         (progn
1017           (unless entry
1018             (setq entry (list file))
1019             (push entry auth-source-passphrase-alist))
1020           (setq passphrase
1021                 (read-passwd
1022                  (format "Passphrase for %s tokens: " file)
1023                  t))
1024           (setcdr entry (lexical-let ((p (copy-sequence passphrase)))
1025                           (lambda () p)))
1026           passphrase))))
1027
1028 ;; (auth-source-epa-extract-gpg-token "gpg:LS0tLS1CRUdJTiBQR1AgTUVTU0FHRS0tLS0tClZlcnNpb246IEdudVBHIHYxLjQuMTEgKEdOVS9MaW51eCkKCmpBMEVBd01DT25qMjB1ak9rZnRneVI3K21iNm9aZWhuLzRad3cySkdlbnVaKzRpeEswWDY5di9icDI1U1dsQT0KPS9yc2wKLS0tLS1FTkQgUEdQIE1FU1NBR0UtLS0tLQo=" "~/.netrc")
1029 (defun auth-source-epa-extract-gpg-token (secret file)
1030   "Pass either the decoded SECRET or the gpg:BASE64DATA version.
1031 FILE is the file from which we obtained this token."
1032   (when (string-match "^gpg:\\(.+\\)" secret)
1033     (setq secret (base64-decode-string (match-string 1 secret))))
1034   (let ((context (epg-make-context 'OpenPGP))
1035         plain)
1036     (epg-context-set-passphrase-callback
1037      context
1038      (cons #'auth-source-token-passphrase-callback-function
1039            file))
1040     (epg-decrypt-string context secret)))
1041
1042 ;; (insert (auth-source-epa-make-gpg-token "mysecret" "~/.netrc"))
1043 (defun auth-source-epa-make-gpg-token (secret file)
1044   (let ((context (epg-make-context 'OpenPGP))
1045         (pp-escape-newlines nil)
1046         cipher)
1047     (epg-context-set-armor context t)
1048     (epg-context-set-passphrase-callback
1049      context
1050      (cons #'auth-source-token-passphrase-callback-function
1051            file))
1052     (setq cipher (epg-encrypt-string context secret nil))
1053     (with-temp-buffer
1054       (insert cipher)
1055       (base64-encode-region (point-min) (point-max) t)
1056       (concat "gpg:" (buffer-substring-no-properties
1057                       (point-min)
1058                       (point-max))))))
1059
1060 (defun auth-source-netrc-normalize (alist filename)
1061   (mapcar (lambda (entry)
1062             (let (ret item)
1063               (while (setq item (pop entry))
1064                 (let ((k (car item))
1065                       (v (cdr item)))
1066
1067                   ;; apply key aliases
1068                   (setq k (cond ((member k '("machine")) "host")
1069                                 ((member k '("login" "account")) "user")
1070                                 ((member k '("protocol")) "port")
1071                                 ((member k '("password")) "secret")
1072                                 (t k)))
1073
1074                   ;; send back the secret in a function (lexical binding)
1075                   (when (equal k "secret")
1076                     (setq v (lexical-let ((lexv v)
1077                                           (token-decoder nil))
1078                               (when (string-match "^gpg:" lexv)
1079                                 ;; it's a GPG token: create a token decoder
1080                                 ;; which unsets itself once
1081                                 (setq token-decoder
1082                                       (lambda (val)
1083                                         (prog1
1084                                             (auth-source-epa-extract-gpg-token
1085                                              val
1086                                              filename)
1087                                           (setq token-decoder nil)))))
1088                               (lambda ()
1089                                 (when token-decoder
1090                                   (setq lexv (funcall token-decoder lexv)))
1091                                 lexv))))
1092                   (setq ret (plist-put ret
1093                                        (intern (concat ":" k))
1094                                        v))))
1095               ret))
1096           alist))
1097
1098 ;;; (setq secret (plist-get (nth 0 (auth-source-search :host t :type 'netrc :K 1 :max 1)) :secret))
1099 ;;; (funcall secret)
1100
1101 (defun* auth-source-netrc-search (&rest
1102                                   spec
1103                                   &key backend require create delete
1104                                   type max host user port
1105                                   &allow-other-keys)
1106   "Given a property list SPEC, return search matches from the :backend.
1107 See `auth-source-search' for details on SPEC."
1108   ;; just in case, check that the type is correct (null or same as the backend)
1109   (assert (or (null type) (eq type (oref backend type)))
1110           t "Invalid netrc search: %s %s")
1111
1112   (let ((results (auth-source-netrc-normalize
1113                   (auth-source-netrc-parse
1114                    :max max
1115                    :require require
1116                    :delete delete
1117                    :file (oref backend source)
1118                    :host (or host t)
1119                    :user (or user t)
1120                    :port (or port t))
1121                   (oref backend source))))
1122
1123     ;; if we need to create an entry AND none were found to match
1124     (when (and create
1125                (not results))
1126
1127       ;; create based on the spec and record the value
1128       (setq results (or
1129                      ;; if the user did not want to create the entry
1130                      ;; in the file, it will be returned
1131                      (apply (slot-value backend 'create-function) spec)
1132                      ;; if not, we do the search again without :create
1133                      ;; to get the updated data.
1134
1135                      ;; the result will be returned, even if the search fails
1136                      (apply 'auth-source-netrc-search
1137                             (plist-put spec :create nil)))))
1138     results))
1139
1140 (defun auth-source-netrc-element-or-first (v)
1141   (if (listp v)
1142       (nth 0 v)
1143     v))
1144
1145 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t)
1146 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t :create-extra-keys '((A "default A") (B)))
1147
1148 (defun* auth-source-netrc-create (&rest spec
1149                                         &key backend
1150                                         secret host user port create
1151                                         &allow-other-keys)
1152   (let* ((base-required '(host user port secret))
1153          ;; we know (because of an assertion in auth-source-search) that the
1154          ;; :create parameter is either t or a list (which includes nil)
1155          (create-extra (if (eq t create) nil create))
1156          (current-data (car (auth-source-search :max 1
1157                                                 :host host
1158                                                 :port port)))
1159          (required (append base-required create-extra))
1160          (file (oref backend source))
1161          (add "")
1162          ;; `valist' is an alist
1163          valist
1164          ;; `artificial' will be returned if no creation is needed
1165          artificial)
1166
1167     ;; only for base required elements (defined as function parameters):
1168     ;; fill in the valist with whatever data we may have from the search
1169     ;; we complete the first value if it's a list and use the value otherwise
1170     (dolist (br base-required)
1171       (when (symbol-value br)
1172         (let ((br-choice (cond
1173                           ;; all-accepting choice (predicate is t)
1174                           ((eq t (symbol-value br)) nil)
1175                           ;; just the value otherwise
1176                           (t (symbol-value br)))))
1177           (when br-choice
1178             (aput 'valist br br-choice)))))
1179
1180     ;; for extra required elements, see if the spec includes a value for them
1181     (dolist (er create-extra)
1182       (let ((name (concat ":" (symbol-name er)))
1183             (keys (loop for i below (length spec) by 2
1184                         collect (nth i spec))))
1185         (dolist (k keys)
1186           (when (equal (symbol-name k) name)
1187             (aput 'valist er (plist-get spec k))))))
1188
1189     ;; for each required element
1190     (dolist (r required)
1191       (if (eq r 'secret)
1192           (debug))
1193       (let* ((data (aget valist r))
1194              ;; take the first element if the data is a list
1195              (data (or (auth-source-netrc-element-or-first data)
1196                        (plist-get current-data
1197                                   (intern (format ":%s" r) obarray))))
1198              ;; this is the default to be offered
1199              (given-default (aget auth-source-creation-defaults r))
1200              ;; the default supplementals are simple:
1201              ;; for the user, try `given-default' and then (user-login-name);
1202              ;; otherwise take `given-default'
1203              (default (cond
1204