cgit.sxemacs.org Git - gnus/blob - lisp/auth-source.el

   1 ;;; auth-source.el --- authentication sources for Gnus and Emacs
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the auth-source.el package.  It lets users tell Gnus how to
  26 ;; authenticate in a single place.  Simplicity is the goal.  Instead
  27 ;; of providing 5000 options, we'll stick to simple, easy to
  28 ;; understand options.
  29
  30 ;; See the auth.info Info documentation for details.
  31
  32 ;; TODO:
  33
  34 ;; - never decode the backend file unless it's necessary
  35 ;; - a more generic way to match backends and search backend contents
  36 ;; - absorb netrc.el and simplify it
  37 ;; - protect passwords better
  38 ;; - allow creating and changing netrc lines (not files) e.g. change a password
  39
  40 ;;; Code:
  41
  42 (require 'password-cache)
  43 (require 'mm-util)
  44 (require 'gnus-util)
  45 (require 'netrc)
  46 (require 'assoc)
  47 (eval-when-compile (require 'cl))
  48 (eval-and-compile
  49   (or (ignore-errors (require 'eieio))
  50       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  51       (ignore-errors
  52         (let ((load-path (cons (expand-file-name
  53                                 "gnus-fallback-lib/eieio"
  54                                 (file-name-directory (locate-library "gnus")))
  55                                load-path)))
  56           (require 'eieio)))
  57       (error
  58        "eieio not found in `load-path' or gnus-fallback-lib/ directory.")))
  59
  60 (autoload 'secrets-create-item "secrets")
  61 (autoload 'secrets-delete-item "secrets")
  62 (autoload 'secrets-get-alias "secrets")
  63 (autoload 'secrets-get-attributes "secrets")
  64 (autoload 'secrets-get-secret "secrets")
  65 (autoload 'secrets-list-collections "secrets")
  66 (autoload 'secrets-search-items "secrets")
  67
  68 (defvar secrets-enabled)
  69
  70 (defgroup auth-source nil
  71   "Authentication sources."
  72   :version "23.1" ;; No Gnus
  73   :group 'gnus)
  74
  75 ;;;###autoload
  76 (defcustom auth-source-cache-expiry 7200
  77   "How many seconds passwords are cached, or nil to disable
  78 expiring.  Overrides `password-cache-expiry' through a
  79 let-binding."
  80   :group 'auth-source
  81   :type '(choice (const :tag "Never" nil)
  82                  (const :tag "All Day" 86400)
  83                  (const :tag "2 Hours" 7200)
  84                  (const :tag "30 Minutes" 1800)
  85                  (integer :tag "Seconds")))
  86
  87 (defclass auth-source-backend ()
  88   ((type :initarg :type
  89          :initform 'netrc
  90          :type symbol
  91          :custom symbol
  92          :documentation "The backend type.")
  93    (source :initarg :source
  94            :type string
  95            :custom string
  96            :documentation "The backend source.")
  97    (host :initarg :host
  98          :initform t
  99          :type t
 100          :custom string
 101          :documentation "The backend host.")
 102    (user :initarg :user
 103          :initform t
 104          :type t
 105          :custom string
 106          :documentation "The backend user.")
 107    (port :initarg :port
 108          :initform t
 109          :type t
 110          :custom string
 111          :documentation "The backend protocol.")
 112    (create-function :initarg :create-function
 113                     :initform ignore
 114                     :type function
 115                     :custom function
 116                     :documentation "The create function.")
 117    (search-function :initarg :search-function
 118                     :initform ignore
 119                     :type function
 120                     :custom function
 121                     :documentation "The search function.")))
 122
 123 (defcustom auth-source-protocols '((imap "imap" "imaps" "143" "993")
 124                                    (pop3 "pop3" "pop" "pop3s" "110" "995")
 125                                    (ssh  "ssh" "22")
 126                                    (sftp "sftp" "115")
 127                                    (smtp "smtp" "25"))
 128   "List of authentication protocols and their names"
 129
 130   :group 'auth-source
 131   :version "23.2" ;; No Gnus
 132   :type '(repeat :tag "Authentication Protocols"
 133                  (cons :tag "Protocol Entry"
 134                        (symbol :tag "Protocol")
 135                        (repeat :tag "Names"
 136                                (string :tag "Name")))))
 137
 138 ;;; generate all the protocols in a format Customize can use
 139 ;;; TODO: generate on the fly from auth-source-protocols
 140 (defconst auth-source-protocols-customize
 141   (mapcar (lambda (a)
 142             (let ((p (car-safe a)))
 143               (list 'const
 144                     :tag (upcase (symbol-name p))
 145                     p)))
 146           auth-source-protocols))
 147
 148 (defvar auth-source-creation-defaults nil
 149   "Defaults for creating token values.  Usually let-bound.")
 150
 151 (make-obsolete 'auth-source-hide-passwords nil "Emacs 24.1")
 152
 153 (defvar auth-source-magic "auth-source-magic ")
 154
 155 (defcustom auth-source-do-cache t
 156   "Whether auth-source should cache information with `password-cache'."
 157   :group 'auth-source
 158   :version "23.2" ;; No Gnus
 159   :type `boolean)
 160
 161 (defcustom auth-source-debug nil
 162   "Whether auth-source should log debug messages.
 163
 164 If the value is nil, debug messages are not logged.
 165
 166 If the value is t, debug messages are logged with `message'.  In
 167 that case, your authentication data will be in the clear (except
 168 for passwords).
 169
 170 If the value is a function, debug messages are logged by calling
 171  that function using the same arguments as `message'."
 172   :group 'auth-source
 173   :version "23.2" ;; No Gnus
 174   :type `(choice
 175           :tag "auth-source debugging mode"
 176           (const :tag "Log using `message' to the *Messages* buffer" t)
 177           (function :tag "Function that takes arguments like `message'")
 178           (const :tag "Don't log anything" nil)))
 179
 180 (defcustom auth-sources '("~/.authinfo.gpg" "~/.authinfo")
 181   "List of authentication sources.
 182
 183 The default will get login and password information from
 184 \"~/.authinfo.gpg\", which you should set up with the EPA/EPG
 185 packages to be encrypted.  If that file doesn't exist, it will
 186 try the unencrypted version \"~/.authinfo\".
 187
 188 See the auth.info manual for details.
 189
 190 Each entry is the authentication type with optional properties.
 191
 192 It's best to customize this with `M-x customize-variable' because the choices
 193 can get pretty complex."
 194   :group 'auth-source
 195   :version "24.1" ;; No Gnus
 196   :type `(repeat :tag "Authentication Sources"
 197                  (choice
 198                   (string :tag "Just a file")
 199                   (const :tag "Default Secrets API Collection" 'default)
 200                   (const :tag "Login Secrets API Collection" "secrets:Login")
 201                   (const :tag "Temp Secrets API Collection" "secrets:session")
 202                   (list :tag "Source definition"
 203                         (const :format "" :value :source)
 204                         (choice :tag "Authentication backend choice"
 205                                 (string :tag "Authentication Source (file)")
 206                                 (list
 207                                  :tag "Secret Service API/KWallet/GNOME Keyring"
 208                                  (const :format "" :value :secrets)
 209                                  (choice :tag "Collection to use"
 210                                          (string :tag "Collection name")
 211                                          (const :tag "Default" 'default)
 212                                          (const :tag "Login" "Login")
 213                                          (const
 214                                           :tag "Temporary" "session"))))
 215                         (repeat :tag "Extra Parameters" :inline t
 216                                 (choice :tag "Extra parameter"
 217                                         (list
 218                                          :tag "Host"
 219                                          (const :format "" :value :host)
 220                                          (choice :tag "Host (machine) choice"
 221                                                  (const :tag "Any" t)
 222                                                  (regexp
 223                                                   :tag "Regular expression")))
 224                                         (list
 225                                          :tag "Protocol"
 226                                          (const :format "" :value :port)
 227                                          (choice
 228                                           :tag "Protocol"
 229                                           (const :tag "Any" t)
 230                                           ,@auth-source-protocols-customize))
 231                                         (list :tag "User" :inline t
 232                                               (const :format "" :value :user)
 233                                               (choice :tag "Personality/Username"
 234                                                       (const :tag "Any" t)
 235                                                       (string :tag "Name")))))))))
 236
 237 (defcustom auth-source-gpg-encrypt-to t
 238   "List of recipient keys that `authinfo.gpg' encrypted to.
 239 If the value is not a list, symmetric encryption will be used."
 240   :group 'auth-source
 241   :version "24.1" ;; No Gnus
 242   :type '(choice (const :tag "Symmetric encryption" t)
 243                  (repeat :tag "Recipient public keys"
 244                          (string :tag "Recipient public key"))))
 245
 246 ;; temp for debugging
 247 ;; (unintern 'auth-source-protocols)
 248 ;; (unintern 'auth-sources)
 249 ;; (customize-variable 'auth-sources)
 250 ;; (setq auth-sources nil)
 251 ;; (format "%S" auth-sources)
 252 ;; (customize-variable 'auth-source-protocols)
 253 ;; (setq auth-source-protocols nil)
 254 ;; (format "%S" auth-source-protocols)
 255 ;; (auth-source-pick nil :host "a" :port 'imap)
 256 ;; (auth-source-user-or-password "login" "imap.myhost.com" 'imap)
 257 ;; (auth-source-user-or-password "password" "imap.myhost.com" 'imap)
 258 ;; (auth-source-user-or-password-imap "login" "imap.myhost.com")
 259 ;; (auth-source-user-or-password-imap "password" "imap.myhost.com")
 260 ;; (auth-source-protocol-defaults 'imap)
 261
 262 ;; (let ((auth-source-debug 'debug)) (auth-source-do-debug "hello"))
 263 ;; (let ((auth-source-debug t)) (auth-source-do-debug "hello"))
 264 ;; (let ((auth-source-debug nil)) (auth-source-do-debug "hello"))
 265 (defun auth-source-do-debug (&rest msg)
 266   (when auth-source-debug
 267     (apply 'auth-source-do-warn msg)))
 268
 269 (defun auth-source-do-warn (&rest msg)
 270   (apply
 271     ;; set logger to either the function in auth-source-debug or 'message
 272     ;; note that it will be 'message if auth-source-debug is nil
 273    (if (functionp auth-source-debug)
 274        auth-source-debug
 275      'message)
 276    msg))
 277
 278
 279 ;; (auth-source-pick nil :host "any" :port 'imap :user "joe")
 280 ;; (auth-source-pick t :host "any" :port 'imap :user "joe")
 281 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 282 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 283 ;;                   (:source (:secrets "Login") :host t :port t)
 284 ;;                   (:source "~/.authinfo.gpg" :host t :port t)))
 285
 286 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 287 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 288 ;;                   (:source (:secrets "Login") :host t :port t)
 289 ;;                   ))
 290
 291 ;; (setq auth-sources '((:source "~/.authinfo.gpg" :host t :port t)))
 292
 293 ;; (auth-source-backend-parse "myfile.gpg")
 294 ;; (auth-source-backend-parse 'default)
 295 ;; (auth-source-backend-parse "secrets:Login")
 296
 297 (defun auth-source-backend-parse (entry)
 298   "Creates an auth-source-backend from an ENTRY in `auth-sources'."
 299   (auth-source-backend-parse-parameters
 300    entry
 301    (cond
 302     ;; take 'default and recurse to get it as a Secrets API default collection
 303     ;; matching any user, host, and protocol
 304     ((eq entry 'default)
 305      (auth-source-backend-parse '(:source (:secrets default))))
 306     ;; take secrets:XYZ and recurse to get it as Secrets API collection "XYZ"
 307     ;; matching any user, host, and protocol
 308     ((and (stringp entry) (string-match "^secrets:\\(.+\\)" entry))
 309      (auth-source-backend-parse `(:source (:secrets ,(match-string 1 entry)))))
 310     ;; take just a file name and recurse to get it as a netrc file
 311     ;; matching any user, host, and protocol
 312     ((stringp entry)
 313      (auth-source-backend-parse `(:source ,entry)))
 314
 315     ;; a file name with parameters
 316     ((stringp (plist-get entry :source))
 317      (auth-source-backend
 318       (plist-get entry :source)
 319       :source (plist-get entry :source)
 320       :type 'netrc
 321       :search-function 'auth-source-netrc-search
 322       :create-function 'auth-source-netrc-create))
 323
 324     ;; the Secrets API.  We require the package, in order to have a
 325     ;; defined value for `secrets-enabled'.
 326     ((and
 327       (not (null (plist-get entry :source))) ; the source must not be nil
 328       (listp (plist-get entry :source))      ; and it must be a list
 329       (require 'secrets nil t)               ; and we must load the Secrets API
 330       secrets-enabled)                       ; and that API must be enabled
 331
 332      ;; the source is either the :secrets key in ENTRY or
 333      ;; if that's missing or nil, it's "session"
 334      (let ((source (or (plist-get (plist-get entry :source) :secrets)
 335                        "session")))
 336
 337        ;; if the source is a symbol, we look for the alias named so,
 338        ;; and if that alias is missing, we use "Login"
 339        (when (symbolp source)
 340          (setq source (or (secrets-get-alias (symbol-name source))
 341                           "Login")))
 342
 343        (if (featurep 'secrets)
 344            (auth-source-backend
 345             (format "Secrets API (%s)" source)
 346             :source source
 347             :type 'secrets
 348             :search-function 'auth-source-secrets-search
 349             :create-function 'auth-source-secrets-create)
 350          (auth-source-do-warn
 351           "auth-source-backend-parse: no Secrets API, ignoring spec: %S" entry)
 352          (auth-source-backend
 353           (format "Ignored Secrets API (%s)" source)
 354           :source ""
 355           :type 'ignore))))
 356
 357     ;; none of them
 358     (t
 359      (auth-source-do-warn
 360       "auth-source-backend-parse: invalid backend spec: %S" entry)
 361      (auth-source-backend
 362       "Empty"
 363       :source ""
 364       :type 'ignore)))))
 365
 366 (defun auth-source-backend-parse-parameters (entry backend)
 367   "Fills in the extra auth-source-backend parameters of ENTRY.
 368 Using the plist ENTRY, get the :host, :port, and :user search
 369 parameters."
 370   (let ((entry (if (stringp entry)
 371                    nil
 372                  entry))
 373         val)
 374     (when (setq val (plist-get entry :host))
 375       (oset backend host val))
 376     (when (setq val (plist-get entry :user))
 377       (oset backend user val))
 378     (when (setq val (plist-get entry :port))
 379       (oset backend port val)))
 380   backend)
 381
 382 ;; (mapcar 'auth-source-backend-parse auth-sources)
 383
 384 (defun* auth-source-search (&rest spec
 385                                   &key type max host user port secret
 386                                   create delete
 387                                   &allow-other-keys)
 388   "Search or modify authentication backends according to SPEC.
 389
 390 This function parses `auth-sources' for matches of the SPEC
 391 plist.  It can optionally create or update an authentication
 392 token if requested.  A token is just a standard Emacs property
 393 list with a :secret property that can be a function; all the
 394 other properties will always hold scalar values.
 395
 396 Typically the :secret property, if present, contains a password.
 397
 398 Common search keys are :max, :host, :port, and :user.  In
 399 addition, :create specifies how tokens will be or created.
 400 Finally, :type can specify which backend types you want to check.
 401
 402 A string value is always matched literally.  A symbol is matched
 403 as its string value, literally.  All the SPEC values can be
 404 single values (symbol or string) or lists thereof (in which case
 405 any of the search terms matches).
 406
 407 :create t means to create a token if possible.
 408
 409 A new token will be created if no matching tokens were found.
 410 The new token will have only the keys the backend requires.  For
 411 the netrc backend, for instance, that's the user, host, and
 412 port keys.
 413
 414 Here's an example:
 415
 416 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 417                                         (A    . \"default A\"))))
 418   (auth-source-search :host \"mine\" :type 'netrc :max 1
 419                       :P \"pppp\" :Q \"qqqq\"
 420                       :create t))
 421
 422 which says:
 423
 424 \"Search for any entry matching host 'mine' in backends of type
 425  'netrc', maximum one result.
 426
 427  Create a new entry if you found none.  The netrc backend will
 428  automatically require host, user, and port.  The host will be
 429  'mine'.  We prompt for the user with default 'defaultUser' and
 430  for the port without a default.  We will not prompt for A, Q,
 431  or P.  The resulting token will only have keys user, host, and
 432  port.\"
 433
 434 :create '(A B C) also means to create a token if possible.
 435
 436 The behavior is like :create t but if the list contains any
 437 parameter, that parameter will be required in the resulting
 438 token.  The value for that parameter will be obtained from the
 439 search parameters or from user input.  If any queries are needed,
 440 the alist `auth-source-creation-defaults' will be checked for the
 441 default prompt.
 442
 443 Here's an example:
 444
 445 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 446                                         (A    . \"default A\"))))
 447   (auth-source-search :host '(\"nonesuch\" \"twosuch\") :type 'netrc :max 1
 448                       :P \"pppp\" :Q \"qqqq\"
 449                       :create '(A B Q)))
 450
 451 which says:
 452
 453 \"Search for any entry matching host 'nonesuch'
 454  or 'twosuch' in backends of type 'netrc', maximum one result.
 455
 456  Create a new entry if you found none.  The netrc backend will
 457  automatically require host, user, and port.  The host will be
 458  'nonesuch' and Q will be 'qqqq'.  We prompt for A with default
 459  'default A', for B and port with default nil, and for the
 460  user with default 'defaultUser'.  We will not prompt for Q.  The
 461  resulting token will have keys user, host, port, A, B, and Q.
 462  It will not have P with any value, even though P is used in the
 463  search to find only entries that have P set to 'pppp'.\"
 464
 465 When multiple values are specified in the search parameter, the
 466 first one is used for creation.  So :host (X Y Z) would create a
 467 token for host X, for instance.
 468
 469 This creation can fail if the search was not specific enough to
 470 create a new token (it's up to the backend to decide that).  You
 471 should `catch' the backend-specific error as usual.  Some
 472 backends (netrc, at least) will prompt the user rather than throw
 473 an error.
 474
 475 :delete t means to delete any found entries.  nil by default.
 476 Use `auth-source-delete' in ELisp code instead of calling
 477 `auth-source-search' directly with this parameter.
 478
 479 :type (X Y Z) will check only those backend types.  'netrc and
 480 'secrets are the only ones supported right now.
 481
 482 :max N means to try to return at most N items (defaults to 1).
 483 When 0 the function will return just t or nil to indicate if any
 484 matches were found.  More than N items may be returned, depending
 485 on the search and the backend.
 486
 487 :host (X Y Z) means to match only hosts X, Y, or Z according to
 488 the match rules above.  Defaults to t.
 489
 490 :user (X Y Z) means to match only users X, Y, or Z according to
 491 the match rules above.  Defaults to t.
 492
 493 :port (P Q R) means to match only protocols P, Q, or R.
 494 Defaults to t.
 495
 496 :K (V1 V2 V3) for any other key K will match values V1, V2, or
 497 V3 (note the match rules above).
 498
 499 The return value is a list with at most :max tokens.  Each token
 500 is a plist with keys :backend :host :port :user, plus any other
 501 keys provided by the backend (notably :secret).  But note the
 502 exception for :max 0, which see above.
 503
 504 The token's :secret key can hold a function.  In that case you
 505 must call it to obtain the actual value."
 506   (let* ((backends (mapcar 'auth-source-backend-parse auth-sources))
 507          (max (or max 1))
 508          (ignored-keys '(:create :delete :max))
 509          (keys (loop for i below (length spec) by 2
 510                      unless (memq (nth i spec) ignored-keys)
 511                      collect (nth i spec)))
 512          (found (auth-source-recall spec))
 513          filtered-backends accessor-key found-here goal)
 514
 515     (if (and found auth-source-do-cache)
 516         (auth-source-do-debug
 517          "auth-source-search: found %d CACHED results matching %S"
 518          (length found) spec)
 519
 520       (assert
 521        (or (eq t create) (listp create)) t
 522        "Invalid auth-source :create parameter (must be nil, t, or a list): %s %s")
 523
 524       (setq filtered-backends (copy-sequence backends))
 525       (dolist (backend backends)
 526         (dolist (key keys)
 527           ;; ignore invalid slots
 528           (condition-case signal
 529               (unless (eval `(auth-source-search-collection
 530                               (plist-get spec key)
 531                               (oref backend ,key)))
 532                 (setq filtered-backends (delq backend filtered-backends))
 533                 (return))
 534             (invalid-slot-name))))
 535
 536       (auth-source-do-debug
 537        "auth-source-search: found %d backends matching %S"
 538        (length filtered-backends) spec)
 539
 540       ;; (debug spec "filtered" filtered-backends)
 541       (setq goal max)
 542       (dolist (backend filtered-backends)
 543         (setq found-here (apply
 544                           (slot-value backend 'search-function)
 545                           :backend backend
 546                           :create create
 547                           :delete delete
 548                           spec))
 549
 550         ;; if max is 0, as soon as we find something, return it
 551         (when (and (zerop max) (> 0 (length found-here)))
 552           (return t))
 553
 554         ;; decrement the goal by the number of new results
 555         (decf goal (length found-here))
 556         ;; and append the new results to the full list
 557         (setq found (append found found-here))
 558
 559         (auth-source-do-debug
 560          "auth-source-search: found %d results (max %d/%d) in %S matching %S"
 561          (length found-here) max goal backend spec)
 562
 563         ;; return full list if the goal is 0 or negative
 564         (when (zerop (max 0 goal))
 565           (return found))
 566
 567         ;; change the :max parameter in the spec to the goal
 568         (setq spec (plist-put spec :max goal)))
 569
 570       (when (and found auth-source-do-cache)
 571         (auth-source-remember spec found)))
 572
 573       found))
 574
 575 ;;; (auth-source-search :max 1)
 576 ;;; (funcall (plist-get (nth 0 (auth-source-search :max 1)) :secret))
 577 ;;; (auth-source-search :host "nonesuch" :type 'netrc :K 1)
 578 ;;; (auth-source-search :host "nonesuch" :type 'secrets)
 579
 580 (defun* auth-source-delete (&rest spec
 581                                   &key delete
 582                                   &allow-other-keys)
 583   "Delete entries from the authentication backends according to SPEC.
 584 Calls `auth-source-search' with the :delete property in SPEC set to t.
 585 The backend may not actually delete the entries.
 586
 587 Returns the deleted entries."
 588   (auth-source-search (plist-put spec :delete t)))
 589
 590 (defun auth-source-search-collection (collection value)
 591   "Returns t is VALUE is t or COLLECTION is t or contains VALUE."
 592   (when (and (atom collection) (not (eq t collection)))
 593     (setq collection (list collection)))
 594
 595   ;; (debug :collection collection :value value)
 596   (or (eq collection t)
 597       (eq value t)
 598       (equal collection value)
 599       (member value collection)))
 600
 601 (defun auth-source-forget-all-cached ()
 602   "Forget all cached auth-source data."
 603   (interactive)
 604   (loop for sym being the symbols of password-data
 605         ;; when the symbol name starts with auth-source-magic
 606         when (string-match (concat "^" auth-source-magic)
 607                            (symbol-name sym))
 608         ;; remove that key
 609         do (password-cache-remove (symbol-name sym))))
 610
 611 (defun auth-source-remember (spec found)
 612   "Remember FOUND search results for SPEC."
 613   (let ((password-cache-expiry auth-source-cache-expiry))
 614     (password-cache-add
 615      (concat auth-source-magic (format "%S" spec)) found)))
 616
 617 (defun auth-source-recall (spec)
 618   "Recall FOUND search results for SPEC."
 619   (password-read-from-cache
 620    (concat auth-source-magic (format "%S" spec))))
 621
 622 (defun auth-source-forget (spec)
 623   "Forget any cached data matching SPEC exactly.
 624
 625 This is the same SPEC you passed to `auth-source-search'.
 626 Returns t or nil for forgotten or not found."
 627   (password-cache-remove (concat auth-source-magic (format "%S" spec))))
 628
 629 ;;; (loop for sym being the symbols of password-data when (string-match (concat "^" auth-source-magic) (symbol-name sym)) collect (symbol-name sym))
 630
 631 ;;; (auth-source-remember '(:host "wedd") '(4 5 6))
 632 ;;; (auth-source-remember '(:host "xedd") '(1 2 3))
 633 ;;; (auth-source-recall '(:host "xedd"))
 634 ;;; (auth-source-recall '(:host t))
 635 ;;; (auth-source-forget+ :host t)
 636
 637 (defun* auth-source-forget+ (&rest spec &allow-other-keys)
 638   "Forget any cached data matching SPEC.  Returns forgotten count.
 639
 640 This is not a full `auth-source-search' spec but works similarly.
 641 For instance, \(:host \"myhost\" \"yourhost\") would find all the
 642 cached data that was found with a search for those two hosts,
 643 while \(:host t) would find all host entries."
 644   (let ((count 0)
 645         sname)
 646     (loop for sym being the symbols of password-data
 647           ;; when the symbol name matches with auth-source-magic
 648           when (and (setq sname (symbol-name sym))
 649                     (string-match (concat "^" auth-source-magic "\\(.+\\)")
 650                                   sname)
 651                     ;; and the spec matches what was stored in the cache
 652                     (auth-source-specmatchp spec (read (match-string 1 sname))))
 653           ;; remove that key
 654           do (progn
 655                (password-cache-remove sname)
 656                (incf count)))
 657     count))
 658
 659 (defun auth-source-specmatchp (spec stored)
 660   (let ((keys (loop for i below (length spec) by 2
 661                    collect (nth i spec))))
 662     (not (eq
 663           (dolist (key keys)
 664             (unless (auth-source-search-collection (plist-get stored key)
 665                                                    (plist-get spec key))
 666               (return 'no)))
 667           'no))))
 668
 669 ;;; Backend specific parsing: netrc/authinfo backend
 670
 671 ;;; (auth-source-netrc-parse "~/.authinfo.gpg")
 672 (defun* auth-source-netrc-parse (&rest
 673                                  spec
 674                                  &key file max host user port delete
 675                                  &allow-other-keys)
 676   "Parse FILE and return a list of all entries in the file.
 677 Note that the MAX parameter is used so we can exit the parse early."
 678   (if (listp file)
 679       ;; We got already parsed contents; just return it.
 680       file
 681     (when (file-exists-p file)
 682       (with-temp-buffer
 683         (let ((tokens '("machine" "host" "default" "login" "user"
 684                         "password" "account" "macdef" "force"
 685                         "port" "protocol"))
 686               (max (or max 5000))       ; sanity check: default to stop at 5K
 687               (modified 0)
 688               alist elem result pair)
 689           (insert-file-contents file)
 690           (goto-char (point-min))
 691           ;; Go through the file, line by line.
 692           (while (and (not (eobp))
 693                       (> max 0))
 694
 695             (narrow-to-region (point) (point-at-eol))
 696             ;; For each line, get the tokens and values.
 697             (while (not (eobp))
 698               (skip-chars-forward "\t ")
 699               ;; Skip lines that begin with a "#".
 700               (if (eq (char-after) ?#)
 701                   (goto-char (point-max))
 702                 (unless (eobp)
 703                   (setq elem
 704                         (if (= (following-char) ?\")
 705                             (read (current-buffer))
 706                           (buffer-substring
 707                            (point) (progn (skip-chars-forward "^\t ")
 708                                           (point)))))
 709                   (cond
 710                    ((equal elem "macdef")
 711                     ;; We skip past the macro definition.
 712                     (widen)
 713                     (while (and (zerop (forward-line 1))
 714                                 (looking-at "$")))
 715                     (narrow-to-region (point) (point)))
 716                    ((member elem tokens)
 717                     ;; Tokens that don't have a following value are ignored,
 718                     ;; except "default".
 719                     (when (and pair (or (cdr pair)
 720                                         (equal (car pair) "default")))
 721                       (push pair alist))
 722                     (setq pair (list elem)))
 723                    (t
 724                     ;; Values that haven't got a preceding token are ignored.
 725                     (when pair
 726                       (setcdr pair elem)
 727                       (push pair alist)
 728                       (setq pair nil)))))))
 729
 730             (when (and alist
 731                        (> max 0)
 732                        (auth-source-search-collection
 733                         host
 734                         (or
 735                          (aget alist "machine")
 736                          (aget alist "host")
 737                          t))
 738                        (auth-source-search-collection
 739                         user
 740                         (or
 741                          (aget alist "login")
 742                          (aget alist "account")
 743                          (aget alist "user")
 744                          t))
 745                        (auth-source-search-collection
 746                         port
 747                         (or
 748                          (aget alist "port")
 749                          (aget alist "protocol")
 750                          t)))
 751               (decf max)
 752               (push (nreverse alist) result)
 753               ;; to delete a line, we just comment it out
 754               (when delete
 755                 (goto-char (point-min))
 756                 (insert "#")
 757                 (incf modified)))
 758             (setq alist nil
 759                   pair nil)
 760             (widen)
 761             (forward-line 1))
 762
 763           (when (< 0 modified)
 764             (when auth-source-gpg-encrypt-to
 765               ;; (see bug#7487) making `epa-file-encrypt-to' local to
 766               ;; this buffer lets epa-file skip the key selection query
 767               ;; (see the `local-variable-p' check in
 768               ;; `epa-file-write-region').
 769               (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 770                 (make-local-variable 'epa-file-encrypt-to))
 771               (if (listp auth-source-gpg-encrypt-to)
 772                   (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 773
 774             ;; ask AFTER we've successfully opened the file
 775             (when (y-or-n-p (format "Save file %s? (%d modifications)"
 776                                     file modified))
 777               (write-region (point-min) (point-max) file nil 'silent)
 778               (auth-source-do-debug
 779                "auth-source-netrc-parse: modified %d lines in %s"
 780                modified file)))
 781
 782           (nreverse result))))))
 783
 784 (defun auth-source-netrc-normalize (alist)
 785   (mapcar (lambda (entry)
 786             (let (ret item)
 787               (while (setq item (pop entry))
 788                 (let ((k (car item))
 789                       (v (cdr item)))
 790
 791                   ;; apply key aliases
 792                   (setq k (cond ((member k '("machine")) "host")
 793                                 ((member k '("login" "account")) "user")
 794                                 ((member k '("protocol")) "port")
 795                                 ((member k '("password")) "secret")
 796                                 (t k)))
 797
 798                   ;; send back the secret in a function (lexical binding)
 799                   (when (equal k "secret")
 800                     (setq v (lexical-let ((v v))
 801                               (lambda () v))))
 802
 803                   (setq ret (plist-put ret
 804                                        (intern (concat ":" k))
 805                                        v))
 806                   ))
 807               ret))
 808           alist))
 809
 810 ;;; (setq secret (plist-get (nth 0 (auth-source-search :host t :type 'netrc :K 1 :max 1)) :secret))
 811 ;;; (funcall secret)
 812
 813 (defun* auth-source-netrc-search (&rest
 814                                   spec
 815                                   &key backend create delete
 816                                   type max host user port
 817                                   &allow-other-keys)
 818 "Given a property list SPEC, return search matches from the :backend.
 819 See `auth-source-search' for details on SPEC."
 820   ;; just in case, check that the type is correct (null or same as the backend)
 821   (assert (or (null type) (eq type (oref backend type)))
 822           t "Invalid netrc search: %s %s")
 823
 824   (let ((results (auth-source-netrc-normalize
 825                   (auth-source-netrc-parse
 826                    :max max
 827                    :delete delete
 828                    :file (oref backend source)
 829                    :host (or host t)
 830                    :user (or user t)
 831                    :port (or port t)))))
 832
 833     ;; if we need to create an entry AND none were found to match
 834     (when (and create
 835                (= 0 (length results)))
 836
 837       ;; create based on the spec and record the value
 838       (setq results (or
 839                      ;; if the user did not want to create the entry
 840                      ;; in the file, it will be returned
 841                      (apply (slot-value backend 'create-function) spec)
 842                      ;; if not, we do the search again without :create
 843                      ;; to get the updated data.
 844
 845                      ;; the result will be returned, even if the search fails
 846                      (apply 'auth-source-netrc-search
 847                             (plist-put spec :create nil)))))
 848     results))
 849
 850 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t)
 851 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t :create-extra-keys '((A "default A") (B)))
 852
 853 (defun* auth-source-netrc-create (&rest spec
 854                                         &key backend
 855                                         secret host user port create
 856                                         &allow-other-keys)
 857   (let* ((base-required '(host user port secret))
 858          ;; we know (because of an assertion in auth-source-search) that the
 859          ;; :create parameter is either t or a list (which includes nil)
 860          (create-extra (if (eq t create) nil create))
 861          (required (append base-required create-extra))
 862          (file (oref backend source))
 863          (add "")
 864          ;; `valist' is an alist
 865          valist
 866          ;; `artificial' will be returned if no creation is needed
 867          artificial)
 868
 869     ;; only for base required elements (defined as function parameters):
 870     ;; fill in the valist with whatever data we may have from the search
 871     ;; we take the first value if it's a list, the whole value otherwise
 872     (dolist (br base-required)
 873       (when (symbol-value br)
 874         (aput 'valist br (if (listp (symbol-value br))
 875                              (nth 0 (symbol-value br))
 876                            (symbol-value br)))))
 877
 878     ;; for extra required elements, see if the spec includes a value for them
 879     (dolist (er create-extra)
 880       (let ((name (concat ":" (symbol-name er)))
 881             (keys (loop for i below (length spec) by 2
 882                         collect (nth i spec))))
 883         (dolist (k keys)
 884           (when (equal (symbol-name k) name)
 885             (aput 'valist er (plist-get spec k))))))
 886
 887     ;; for each required element
 888     (dolist (r required)
 889       (let* ((data (aget valist r))
 890              (given-default (aget auth-source-creation-defaults r))
 891              ;; the defaults are simple
 892              (default (cond
 893                        ((and (not given-default) (eq r 'user))
 894                         (user-login-name))
 895                        ;; note we need this empty string
 896                        ((and (not given-default) (eq r 'port))
 897                         "")
 898                        (t given-default)))
 899              ;; the prompt's default string depends on the data so far
 900              (default-string (if (and default (< 0 (length default)))
 901                                  (format " (default %s)" default)
 902                                " (no default)"))
 903              ;; the prompt should also show what's entered so far
 904              (user-value (aget valist 'user))
 905              (host-value (aget valist 'host))
 906              (port-value (aget valist 'port))
 907              (info-so-far (concat (if user-value
 908                                       (format "%s@" user-value)
 909                                     "[USER?]")
 910                                   (if host-value
 911                                       (format "%s" host-value)
 912                                     "[HOST?]")
 913                                   (if port-value
 914                                       ;; this distinguishes protocol between
 915                                       (if (zerop (length port-value))
 916                                           "" ; 'entered as "no default"' vs.
 917                                         (format ":%s" port-value)) ; given
 918                                     ;; and this is when the protocol is unknown
 919                                     "[PORT?]"))))
 920
 921         ;; now prompt if the search SPEC did not include a required key;
 922         ;; take the result and put it in `data' AND store it in `valist'
 923         (aput 'valist r
 924               (setq data
 925                     (cond
 926                      ((and (null data) (eq r 'secret))
 927                       ;; special case prompt for passwords
 928                       (read-passwd (format "Password for %s: " info-so-far)))
 929                      ((null data)
 930                       (read-string
 931                        (format "Enter %s for %s%s: "
 932                                r info-so-far default-string)
 933                        nil nil default))
 934                      (t data))))
 935
 936         (when data
 937           (setq artificial (plist-put artificial
 938                                       (intern (concat ":" (symbol-name r)))
 939                                       (if (eq r 'secret)
 940                                           (lexical-let ((data data))
 941                                             (lambda () data))
 942                                         data))))
 943
 944         ;; when r is not an empty string...
 945         (when (and (stringp data)
 946                    (< 0 (length data)))
 947           ;; append the key (the symbol name of r) and the value in r
 948           (setq add (concat add
 949                             (format "%s%s %S"
 950                                     ;; prepend a space
 951                                     (if (zerop (length add)) "" " ")
 952                                     ;; remap auth-source tokens to netrc
 953                                     (case r
 954                                      ('user "login")
 955                                      ('host "machine")
 956                                      ('secret "password")
 957                                      ('port "port") ; redundant but clearer
 958                                      (t (symbol-name r)))
 959                                     ;; the value will be printed in %S format
 960                                     data))))))
 961
 962     (with-temp-buffer
 963       (when (file-exists-p file)
 964         (insert-file-contents file))
 965       (when auth-source-gpg-encrypt-to
 966         ;; (see bug#7487) making `epa-file-encrypt-to' local to
 967         ;; this buffer lets epa-file skip the key selection query
 968         ;; (see the `local-variable-p' check in
 969         ;; `epa-file-write-region').
 970         (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 971           (make-local-variable 'epa-file-encrypt-to))
 972         (if (listp auth-source-gpg-encrypt-to)
 973             (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 974       (goto-char (point-max))
 975
 976       ;; ask AFTER we've successfully opened the file
 977       (if (y-or-n-p (format "Add to file %s: line [%s]" file add))
 978           (progn
 979             (unless (bolp)
 980               (insert "\n"))
 981             (insert add "\n")
 982             (write-region (point-min) (point-max) file nil 'silent)
 983             (auth-source-do-debug
 984              "auth-source-netrc-create: wrote 1 new line to %s"
 985              file)
 986             nil)
 987         (list artificial)))))
 988
 989 ;;; Backend specific parsing: Secrets API backend
 990
 991 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :create t))
 992 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :delete t))
 993 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1))
 994 ;;; (let ((auth-sources '(default))) (auth-source-search))
 995 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1))
 996 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1 :signon_realm "https://git.gnus.org/Git"))
 997
 998 (defun* auth-source-secrets-search (&rest
 999                                     spec
1000                                     &key backend create delete label
1001                                     type max host user port
1002                                     &allow-other-keys)
1003   "Search the Secrets API; spec is like `auth-source'.
1004
1005 The :label key specifies the item's label.  It is the only key
1006 that can specify a substring.  Any :label value besides a string
1007 will allow any label.
1008
1009 All other search keys must match exactly.  If you need substring
1010 matching, do a wider search and narrow it down yourself.
1011
1012 You'll get back all the properties of the token as a plist.
1013
1014 Here's an example that looks for the first item in the 'Login'
1015 Secrets collection:
1016
1017  \(let ((auth-sources '(\"secrets:Login\")))
1018     (auth-source-search :max 1)
1019
1020 Here's another that looks for the first item in the 'Login'
1021 Secrets collection whose label contains 'gnus':
1022
1023  \(let ((auth-sources '(\"secrets:Login\")))
1024     (auth-source-search :max 1 :label \"gnus\")
1025
1026 And this one looks for the first item in the 'Login' Secrets
1027 collection that's a Google Chrome entry for the git.gnus.org site
1028 authentication tokens:
1029
1030  \(let ((auth-sources '(\"secrets:Login\")))
1031     (auth-source-search :max 1 :signon_realm \"https://git.gnus.org/Git\"))
1032 "
1033
1034   ;; TODO
1035   (assert (not create) nil
1036           "The Secrets API auth-source backend doesn't support creation yet")
1037   ;; TODO
1038   ;; (secrets-delete-item coll elt)
1039   (assert (not delete) nil
1040           "The Secrets API auth-source backend doesn't support deletion yet")
1041
1042   (let* ((coll (oref backend source))
1043          (max (or max 5000))     ; sanity check: default to stop at 5K
1044          (ignored-keys '(:create :delete :max :backend :label))
1045          (search-keys (loop for i below (length spec) by 2
1046                             unless (memq (nth i spec) ignored-keys)
1047                             collect (nth i spec)))
1048          ;; build a search spec without the ignored keys
1049          ;; if a search key is nil or t (match anything), we skip it
1050          (search-spec (apply 'append (mapcar
1051                                       (lambda (k)
1052                                         (if (or (null (plist-get spec k))
1053                                                 (eq t (plist-get spec k)))
1054                                             nil
1055                                           (list k (plist-get spec k))))
1056                               search-keys)))
1057          ;; needed keys (always including host, login, port, and secret)
1058          (returned-keys (mm-delete-duplicates (append
1059                                                '(:host :login :port :secret)
1060                                                search-keys)))
1061          (items (loop for item in (apply 'secrets-search-items coll search-spec)
1062                       unless (and (stringp label)
1063                                   (not (string-match label item)))
1064                       collect item))
1065          ;; TODO: respect max in `secrets-search-items', not after the fact
1066          (items (butlast items (- (length items) max)))
1067          ;; convert the item name to a full plist
1068          (items (mapcar (lambda (item)
1069                           (append
1070                            ;; make an entry for the secret (password) element
1071                            (list
1072                             :secret
1073                             (lexical-let ((v (secrets-get-secret coll item)))
1074                               (lambda () v)))
1075                            ;; rewrite the entry from ((k1 v1) (k2 v2)) to plist
1076                            (apply 'append
1077                                   (mapcar (lambda (entry)
1078                                             (list (car entry) (cdr entry)))
1079                                           (secrets-get-attributes coll item)))))
1080                         items))
1081          ;; ensure each item has each key in `returned-keys'
1082          (items (mapcar (lambda (plist)
1083                           (append
1084                            (apply 'append
1085                                   (mapcar (lambda (req)
1086                                             (if (plist-get plist req)
1087                                                 nil
1088                                               (list req nil)))
1089                                           returned-keys))
1090                            plist))
1091                         items)))
1092     items))
1093
1094 (defun* auth-source-secrets-create (&rest
1095                                     spec
1096                                     &key backend type max host user port
1097                                     &allow-other-keys)
1098   ;; TODO
1099   ;; (apply 'secrets-create-item (auth-get-source entry) name passwd spec)
1100   (debug spec))
1101
1102 ;;; older API
1103
1104 ;;; (auth-source-user-or-password '("login" "password") "imap.myhost.com" t "tzz")
1105
1106 ;; deprecate the old interface
1107 (make-obsolete 'auth-source-user-or-password
1108                'auth-source-search "Emacs 24.1")
1109 (make-obsolete 'auth-source-forget-user-or-password
1110                'auth-source-forget "Emacs 24.1")
1111
1112 (defun auth-source-user-or-password
1113   (mode host port &optional username create-missing delete-existing)
1114   "Find MODE (string or list of strings) matching HOST and PORT.
1115
1116 DEPRECATED in favor of `auth-source-search'!
1117
1118 USERNAME is optional and will be used as \"login\" in a search
1119 across the Secret Service API (see secrets.el) if the resulting
1120 items don't have a username.  This means that if you search for
1121 username \"joe\" and it matches an item but the item doesn't have
1122 a :user attribute, the username \"joe\" will be returned.
1123
1124 A non nil DELETE-EXISTING means deleting any matching password
1125 entry in the respective sources.  This is useful only when
1126 CREATE-MISSING is non nil as well; the intended use case is to
1127 remove wrong password entries.
1128
1129 If no matching entry is found, and CREATE-MISSING is non nil,
1130 the password will be retrieved interactively, and it will be
1131 stored in the password database which matches best (see
1132 `auth-sources').
1133
1134 MODE can be \"login\" or \"password\"."
1135   (auth-source-do-debug
1136    "auth-source-user-or-password: DEPRECATED get %s for %s (%s) + user=%s"
1137    mode host port username)
1138
1139   (let* ((listy (listp mode))
1140          (mode (if listy mode (list mode)))
1141          (cname (if username
1142                     (format "%s %s:%s %s" mode host port username)
1143                   (format "%s %s:%s" mode host port)))
1144          (search (list :host host :port port))
1145          (search (if username (append search (list :user username)) search))
1146          (search (if create-missing
1147                      (append search (list :create t))
1148                    search))
1149          (search (if delete-existing
1150                      (append search (list :delete t))
1151                    search))
1152          ;; (found (if (not delete-existing)
1153          ;;            (gethash cname auth-source-cache)
1154          ;;          (remhash cname auth-source-cache)
1155          ;;          nil)))
1156          (found nil))
1157     (if found
1158         (progn
1159           (auth-source-do-debug
1160            "auth-source-user-or-password: DEPRECATED cached %s=%s for %s (%s) + %s"
1161            mode
1162            ;; don't show the password
1163            (if (and (member "password" mode) t)
1164                "SECRET"
1165              found)
1166            host port username)
1167           found)                        ; return the found data
1168       ;; else, if not found, search with a max of 1
1169       (let ((choice (nth 0 (apply 'auth-source-search
1170                                   (append '(:max 1) search)))))
1171         (when choice
1172           (dolist (m mode)
1173             (cond
1174              ((equal "password" m)
1175               (push (if (plist-get choice :secret)
1176                       (funcall (plist-get choice :secret))
1177                     nil) found))
1178              ((equal "login" m)
1179               (push (plist-get choice :user) found)))))
1180         (setq found (nreverse found))
1181         (setq found (if listy found (car-safe found)))))
1182
1183         found))
1184
1185 (provide 'auth-source)
1186
1187 ;;; auth-source.el ends here