cgit.sxemacs.org Git - sxemacs/blob - lisp/menubar.el

   1 ;;; menubar.el --- Menubar support for SXEmacs
   2
   3 ;; Copyright (C) 1991-4, 1997-1998 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1995 Tinker Systems and INS Engineering Corp.
   5 ;; Copyright (C) 1995, 1996 Ben Wing.
   6
   7 ;; Maintainer: XEmacs Development Team
   8 ;; Keywords: internal, extensions, dumped
   9
  10 ;; This file is part of SXEmacs.
  11
  12 ;; SXEmacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; SXEmacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Synched up with: Not in FSF. (Completely divergent from FSF menu-bar.el)
  26
  27 ;;; Commentary:
  28
  29 ;; This file is dumped with SXEmacs (when menubar support is compiled in).
  30
  31 ;; Some stuff in FSF menu-bar.el is in menubar-items.el
  32
  33 ;;; Code:
  34
  35 (defgroup menu nil
  36   "Input from the menus."
  37   :group 'environment)
  38
  39 (defvar default-menubar nil)
  40
  41 ;; this function is considered "part of the lexicon" by many,
  42 ;; so we'll leave it here.
  43 (defun kill-this-buffer ()      ; for the menubar
  44   "Kill the current buffer."
  45   (interactive)
  46   (kill-buffer (current-buffer)))
  47
  48 (defun set-menubar-dirty-flag ()
  49   "Tell XEmacs that the menubar has to be updated.
  50 NOTE: XEmacs now recognizes when you set a different value for
  51 `current-menubar'.  You *only* need to call this function if you
  52 destructively modify a part of the menubar and don't set `current-menubar'.
  53 Note that all the functions that modify a menu call this automatically."
  54   (setq-default current-menubar (default-value 'current-menubar)))
  55
  56 ;; #### shouldn't this perhaps be `copy-tree'?
  57 (defun set-menubar (menubar)
  58   "Set the default menubar to be MENUBAR.
  59 See `current-menubar' for a description of the syntax of a menubar."
  60   (check-menu-syntax menubar t)
  61   (setq-default current-menubar (copy-sequence menubar)))
  62
  63 (defun set-buffer-menubar (menubar)
  64   "Set the buffer-local menubar to be MENUBAR.
  65 See `current-menubar' for a description of the syntax of a menubar."
  66   (check-menu-syntax menubar t)
  67   (make-local-variable 'current-menubar)
  68   (setq current-menubar (copy-sequence menubar)))
  69
  70 (defun check-menu-syntax (menu &optional menubar-p)
  71   ;; The C code does syntax checking on the value of `current-menubar',
  72   ;; but it's better to do it early, before things have gotten messed up.
  73   (if menubar-p
  74       nil
  75     (or (stringp (car menu))
  76         (signal 'error
  77                 (list "menu name (first element) must be a string" menu)))
  78     ;;(or (cdr menu) (signal 'error (list "menu is empty" menu)))
  79     (setq menu (cdr menu)))
  80   (let (menuitem item)
  81     (while (keywordp (setq item (car menu)))
  82       (or (memq item '(:config :included :filter :accelerator))
  83           (signal 'error
  84                   (list "menu keyword must be :config, :included, :accelerator or :filter"
  85                         item)))
  86       (if (or (not (cdr menu))
  87               (vectorp (nth 1 menu))
  88               (keywordp (nth 1 menu)))
  89           (signal 'error (list "strange keyword value" item (nth 1 menu))))
  90       (setq menu (nthcdr 2 menu)))
  91     (while menu
  92       (setq menuitem (car menu))
  93       (cond
  94        ((stringp menuitem)
  95         (and (string-match #r"^\(-+\|=+\):\(.*\)" menuitem)
  96              (setq item (match-string 2 menuitem))
  97              (or (member item '(;; Motif-compatible
  98                                 "singleLine"
  99                                 "doubleLine"
 100                                 "singleDashedLine"
 101                                 "doubleDashedLine"
 102                                 "noLine"
 103                                 "shadowEtchedIn"
 104                                 "shadowEtchedOut"
 105                                 "shadowEtchedInDash"
 106                                 "shadowEtchedOutDash"
 107                                 ;; non-Motif (Lucid menubar widget only)
 108                                 "shadowDoubleEtchedIn"
 109                                 "shadowDoubleEtchedOut"
 110                                 "shadowDoubleEtchedInDash"
 111                                 "shadowDoubleEtchedOutDash"
 112                                 ))
 113                  (signal 'error (list "bogus separator style in menu item" item)))
 114              ))
 115        ((null menuitem)
 116         (or menubar-p
 117             (signal 'error (list "nil is only permitted in the top level of menubars"))))
 118        ((consp menuitem)
 119         (check-menu-syntax menuitem))
 120        ((vectorp menuitem)
 121         (let ((L (length menuitem))
 122               plistp)
 123           (and (< L 2)
 124                (signal 'error
 125                        (list "button descriptors must be at least 2 long"
 126                              menuitem)))
 127           (setq plistp (or (>= L 5)
 128                            (and (> L 2) (keywordp (aref menuitem 2)))))
 129           (if plistp
 130               (let ((i 2)
 131                     selp
 132                     style
 133                     item)
 134                 (while (< i L)
 135                   (setq item (aref menuitem i))
 136                   (cond ((not (memq item '(:active :suffix :keys :style
 137                                                    :full :included :selected
 138                                                    :accelerator)))
 139                          (signal 'error
 140                                  (list (if (keywordp item)
 141                                            "unknown menu item keyword"
 142                                          "not a keyword")
 143                                        item menuitem)))
 144                         ((eq item :style)
 145                          (setq style (aref menuitem (1+ i)))
 146                          (or (memq style '(nil toggle radio button text))
 147                              (signal 'error (list "unknown style" style
 148                                                   menuitem))))
 149                         ((eq item :selected) (setq selp t))
 150                         )
 151                   (setq i (+ i (if (eq item :full) 1 2))))
 152                 (if (and selp (not (memq style '(toggle button radio))))
 153                     (signal 'error
 154                             (list
 155                              ":selected only makes sense with :style toggle, radio, or button"
 156                              menuitem)))
 157                 )))
 158         )
 159        ;; (t (signal 'error (list "unrecognized menu descriptor" menuitem))))
 160        (t (message "unrecognized menu descriptor %s" (prin1-to-string menuitem))))
 161       (setq menu (cdr menu)))))
 162
 163 \f
 164 ;;; menu manipulation functions
 165
 166 (defun find-menu-item (menubar item-path-list &optional parent)
 167   "Search MENUBAR for item given by ITEM-PATH-LIST starting from PARENT.
 168 Returns (ITEM . PARENT), where PARENT is the immediate parent of
 169  the item found.
 170 If the item does not exist, the car of the returned value is nil.
 171 If some menu in the ITEM-PATH-LIST does not exist, an error is signalled."
 172   (check-argument-type 'listp item-path-list)
 173   (unless parent
 174     (setq item-path-list (mapcar 'normalize-menu-item-name item-path-list)))
 175   (if (not (consp menubar))
 176       nil
 177     (let ((rest menubar)
 178           result)
 179       (when (stringp (car rest))
 180         (setq rest (cdr rest)))
 181       (while (keywordp (car rest))
 182         (setq rest (cddr rest)))
 183       (while rest
 184         (if (and (car rest)
 185                  (equal (car item-path-list)
 186                         (normalize-menu-item-name
 187                          (cond ((vectorp (car rest))
 188                                 (aref (car rest) 0))
 189                                ((stringp (car rest))
 190                                 (car rest))
 191                                (t
 192                                 (caar rest))))))
 193             (setq result (car rest)
 194                   rest nil)
 195           (setq rest (cdr rest))))
 196       (if (cdr item-path-list)
 197           (cond ((consp result)
 198                  (find-menu-item (cdr result) (cdr item-path-list) result))
 199                 (result
 200                  (signal 'error (list (gettext "not a submenu") result)))
 201                 (t
 202                  (signal 'error (list (gettext "no such submenu")
 203                                       (car item-path-list)))))
 204         (cons result parent)))))
 205
 206 (defun add-menu-item-1 (leaf-p menu-path new-item before in-menu)
 207   ;; This code looks like it could be cleaned up some more
 208   ;; Do we really need 6 calls to find-menu-item?
 209   (when before (setq before (normalize-menu-item-name before)))
 210   (let* ((item-name
 211           (cond ((vectorp new-item) (aref new-item 0))
 212                 ((consp   new-item) (car  new-item))
 213                 (t nil)))
 214          (menubar (or in-menu current-menubar))
 215          (menu (condition-case ()
 216                    (car (find-menu-item menubar menu-path))
 217                  (error nil)))
 218          (item-found (cond
 219                       ((null item-name)
 220                        nil)
 221                       ((not (listp menu))
 222                        (signal 'error (list (gettext "not a submenu")
 223                                             menu-path)))
 224                       (menu
 225                        (find-menu-item (cdr menu) (list item-name)))
 226                       (t
 227                        (find-menu-item menubar (list item-name)))
 228                       )))
 229     (unless menubar
 230       (error "`current-menubar' is nil: can't add menus to it."))
 231     (unless menu
 232       (let ((rest menu-path)
 233             (so-far menubar))
 234         (while rest
 235 ;;;       (setq menu (car (find-menu-item (cdr so-far) (list (car rest)))))
 236           (setq menu
 237                 (if (eq so-far menubar)
 238                     (car (find-menu-item so-far (list (car rest))))
 239                   (car (find-menu-item (cdr so-far) (list (car rest))))))
 240           (unless menu
 241             (let ((rest2 so-far))
 242               (while (and (cdr rest2) (car (cdr rest2)))
 243                 (setq rest2 (cdr rest2)))
 244               (setcdr rest2
 245                       (nconc (list (setq menu (list (car rest))))
 246                              (cdr rest2)))))
 247           (setq so-far menu)
 248           (setq rest (cdr rest)))))
 249     (if (and item-found (car item-found))
 250         ;; hack the item in place.
 251         (if menu
 252             ;; Isn't it very bad form to use nsubstitute for side effects?
 253             (nsubstitute new-item (car item-found) menu)
 254           (setq current-menubar (nsubstitute new-item
 255                                              (car item-found)
 256                                              current-menubar)))
 257       ;; OK, we have to add the whole thing...
 258       ;; if BEFORE is specified, try to add it there.
 259       (unless menu (setq menu current-menubar))
 260       (when before
 261         (setq before (car (find-menu-item menu (list before)))))
 262       (let ((rest menu)
 263             (added-before nil))
 264         (while rest
 265           (if (eq before (car (cdr rest)))
 266               (progn
 267                 (setcdr rest (cons new-item (cdr rest)))
 268                 (setq rest nil added-before t))
 269             (setq rest (cdr rest))))
 270         (when (not added-before)
 271           ;; adding before the first item on the menubar itself is harder
 272           (if (and (eq menu menubar) (eq before (car menu)))
 273               (setq menu (cons new-item menu)
 274                     current-menubar menu)
 275             ;; otherwise, add the item to the end.
 276             (nconc menu (list new-item))))))
 277     (set-menubar-dirty-flag)
 278     new-item))
 279
 280 (defun add-menu-button (menu-path menu-leaf &optional before in-menu)
 281   "Add a menu item to some menu, creating the menu first if necessary.
 282 If the named item exists already, it is changed.
 283 MENU-PATH identifies the menu under which the new menu item should be inserted.
 284  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 285  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 286 MENU-LEAF is a menubar leaf node.  See the documentation of `current-menubar'.
 287 BEFORE, if provided, is the name of a menu item before which this item should
 288  be added, if this item is not on the menu already.  If the item is already
 289  present, it will not be moved.
 290 IN-MENU, if provided, means use that instead of `current-menubar' as the
 291  menu to change."
 292   ;; Note easymenu.el uses the fact that menu-leaf can be a submenu.
 293   (add-menu-item-1 t menu-path menu-leaf before in-menu))
 294
 295 ;; I actually liked the old name better, but the interface has changed too
 296 ;; drastically to keep it. --Stig
 297 (defun add-submenu (menu-path submenu &optional before in-menu)
 298   "Add a menu to the menubar or one of its submenus.
 299 If the named menu exists already, it is changed.
 300 MENU-PATH identifies the menu under which the new menu should be inserted.
 301  It is a list of strings; for example, (\"File\") names the top-level \"File\"
 302  menu.  (\"File\" \"Foo\") names a hypothetical submenu of \"File\".
 303  If MENU-PATH is nil, then the menu will be added to the menubar itself.
 304 SUBMENU is the new menu to add.
 305  See the documentation of `current-menubar' for the syntax.
 306 BEFORE, if provided, is the name of a menu before which this menu should
 307  be added, if this menu is not on its parent already.  If the menu is already
 308  present, it will not be moved.
 309 IN-MENU, if provided, means use that instead of `current-menubar' as the
 310  menu to change."
 311   (check-menu-syntax submenu nil)
 312   (add-menu-item-1 nil menu-path submenu before in-menu))
 313 ;; purespace is no more, so this function is unnecessary
 314 ;(defun purecopy-menubar (x)
 315 ;  ;; this calls purecopy on the strings, and the contents of the vectors,
 316 ;  ;; but not on the vectors themselves, or the conses - those must be
 317 ;  ;; writable.
 318 ;  (cond ((vectorp x)
 319 ;        (let ((i (length x)))
 320 ;          (while (> i 0)
 321 ;            (aset x (1- i) (purecopy (aref x (1- i))))
 322 ;            (setq i (1- i))))
 323 ;        x)
 324 ;       ((consp x)
 325 ;        (let ((rest x))
 326 ;          (while rest
 327 ;            (setcar rest (purecopy-menubar (car rest)))
 328 ;            (setq rest (cdr rest))))
 329 ;        x)
 330 ;       (t
 331 ;        (purecopy x))))
 332
 333 (defun delete-menu-item (path &optional from-menu)
 334   "Remove the named menu item from the menu hierarchy.
 335 PATH is a list of strings which identify the position of the menu item
 336 in the menu hierarchy.  The documentation of `add-submenu' describes
 337 menu paths.
 338 FROM-MENU, if provided, means use that instead of `current-menubar'
 339 as the menu to change."
 340   (let* ((pair (condition-case nil (find-menu-item (or from-menu
 341                                                        current-menubar) path)
 342                  (error nil)))
 343          (item (car pair))
 344          (parent (or (cdr pair) current-menubar)))
 345     (if (not item)
 346         nil
 347       ;; the menubar is the only special case, because other menus begin
 348       ;; with their name.
 349       (if (eq parent current-menubar)
 350           (setq current-menubar (delq item parent))
 351         (delq item parent))
 352       (set-menubar-dirty-flag)
 353       item)))
 354
 355 (defun relabel-menu-item (path new-name)
 356   "Change the string of the specified menu item.
 357 PATH is a list of strings which identify the position of the menu item in
 358 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 359 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 360 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\".
 361 NEW-NAME is the string that the menu item will be printed as from now on."
 362   (check-type new-name string)
 363   (let* ((menubar current-menubar)
 364          (pair (find-menu-item menubar path))
 365          (item (car pair))
 366          (menu (cdr pair)))
 367     (or item
 368         (signal 'error (list (if menu (gettext "No such menu item")
 369                                (gettext "No such menu"))
 370                              path)))
 371     (if (and (consp item)
 372              (stringp (car item)))
 373         (setcar item new-name)
 374       (aset item 0 new-name))
 375     (set-menubar-dirty-flag)
 376     item))
 377
 378 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 379 ;;
 380 ;; these are all bad style.  Why in the world would we put evaluable forms
 381 ;; into the menubar if we didn't want people to use 'em?
 382 ;; x-font-menu.el is the only known offender right now and that ought to be
 383 ;; rehashed a bit.
 384 ;;
 385
 386 (defun enable-menu-item-1 (path toggle-p on-p)
 387   (let (menu item)
 388     (if (and (vectorp path) (> (length path) 2)) ; limited syntax checking...
 389         (setq item path)
 390       (let* ((menubar current-menubar)
 391              (pair (find-menu-item menubar path)))
 392         (setq item (car pair)
 393               menu (cdr pair))
 394         (or item
 395             (signal 'error (list (if menu
 396                                      "No such menu item"
 397                                    "No such menu")
 398                                  path)))
 399         (if (consp item)
 400             (error "%S is a menu, not a menu item" path))))
 401     (if (or (> (length item) 4)
 402             (and (symbolp (aref item 2))
 403                  (= ?: (aref (symbol-name (aref item 2)) 0))))
 404         ;; plist-like syntax
 405         (let ((i 2)
 406               (keyword (if toggle-p :selected :active))
 407               (ok nil))
 408           (while (< i (length item))
 409             (cond ((eq (aref item i) keyword)
 410                    (aset item (1+ i) on-p)
 411                    (setq ok t)))
 412             (setq i (+ i 2)))
 413           (cond (ok nil)
 414                 (toggle-p
 415                  (signal 'error (list "not a toggle menu item" item)))
 416                 (t
 417                  ;; Need to copy the item to extend it, sigh...
 418                  (let ((cons (memq item menu))
 419                        (new-item (vconcat item (list keyword on-p))))
 420                    (if cons
 421                        (setcar cons (setq item new-item))
 422                      (if menu
 423                          (error "couldn't find %S on its parent?" item)
 424                        (error "no %S slot to set: %S" keyword item)))))))
 425       ;; positional syntax
 426       (if toggle-p
 427           (signal 'error (list "not a toggle menu item" item))
 428         (aset item 2 on-p)))
 429     (set-menubar-dirty-flag)
 430     item))
 431
 432 (defun enable-menu-item (path)
 433   "Make the named menu item be selectable.
 434 PATH is a list of strings which identify the position of the menu item in
 435 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 436 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 437 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 438   (enable-menu-item-1 path nil t))
 439
 440 (defun disable-menu-item (path)
 441   "Make the named menu item be unselectable.
 442 PATH is a list of strings which identify the position of the menu item in
 443 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 444 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 445 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 446   (enable-menu-item-1 path nil nil))
 447
 448 (defun select-toggle-menu-item (path)
 449   "Make the named toggle- or radio-style menu item be in the `selected' state.
 450 PATH is a list of strings which identify the position of the menu item in
 451 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 452 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 453 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 454   (enable-menu-item-1 path t t))
 455
 456 (defun deselect-toggle-menu-item (path)
 457  "Make the named toggle- or radio-style menu item be in the `unselected' state.
 458 PATH is a list of strings which identify the position of the menu item in
 459 the menu hierarchy.  (\"File\" \"Save\") means the menu item called \"Save\"
 460 under the toplevel \"File\" menu.  (\"Menu\" \"Foo\" \"Item\") means the
 461 menu item called \"Item\" under the \"Foo\" submenu of \"Menu\"."
 462   (enable-menu-item-1 path t nil))
 463
 464 \f
 465
 466 ;;;;;;; popup menus
 467
 468 (defvar global-popup-menu nil
 469   "The global popup menu.  This is present in all modes.
 470 See the function `popup-menu' for a description of menu syntax.")
 471
 472 (defvar mode-popup-menu nil
 473   "The mode-specific popup menu.  Automatically buffer local.
 474 This is appended to the default items in `global-popup-menu'.
 475 See the function `popup-menu' for a description of menu syntax.")
 476 (make-variable-buffer-local 'mode-popup-menu)
 477
 478 (defvar activate-popup-menu-hook nil
 479   "Function or functions run before a mode-specific popup menu is made visible.
 480 These functions are called with no arguments, and should interrogate and
 481 modify the value of `global-popup-menu' or `mode-popup-menu' as desired.
 482 Note: this hook is only run if you use `popup-mode-menu' for activating the
 483 global and mode-specific commands; if you have your own binding for button3,
 484 this hook won't be run.")
 485
 486 (defvar last-popup-menu-event nil
 487   "The mouse event that invoked the last popup menu.
 488 NOTE: This is EXPERIMENTAL and may change at any time.")
 489
 490 (defun popup-mode-menu (&optional event)
 491   "Pop up a menu of global and mode-specific commands.
 492 The menu is computed by combining `global-popup-menu' and `mode-popup-menu'
 493 with any items derived from the `context-menu' property of the extent where the
 494 button was clicked."
 495   (interactive "_e")
 496   (setq last-popup-menu-event
 497         (or (and event (button-event-p event) event)
 498             (let* ((mouse-pos (mouse-position))
 499                    (win (car mouse-pos))
 500                    (x (cadr mouse-pos))
 501                    (y (cddr mouse-pos))
 502                    (edges (window-pixel-edges win))
 503                    (winx (first edges))
 504                    (winy (second edges))
 505                    (x (+ x winx))
 506                    (y (+ y winy)))
 507               (make-event 'button-press
 508                           `(button 3 x ,x y ,y channel ,(window-frame win)
 509                                    timestamp ,(current-event-timestamp
 510                                                (cdfw-console win)))))))
 511   (run-hooks 'activate-popup-menu-hook)
 512   (let* ((context-window (and event (event-window event)))
 513          (context-point (and event (event-point event)))
 514          (context-extents (and context-window
 515                                context-point
 516                                (extents-at context-point
 517                                            (window-buffer context-window)
 518                                            'context-menu)))
 519          (context-menu-items
 520           (apply 'append (mapcar #'(lambda (extent)
 521                                      (extent-property extent 'context-menu))
 522                                  context-extents))))
 523     (popup-menu
 524      (progn
 525             ;; Merge global-popup-menu and mode-popup-menu
 526             (and mode-popup-menu (check-menu-syntax mode-popup-menu))
 527             (let* ((mode-title (and (stringp (car mode-popup-menu))
 528                                     (car mode-popup-menu)))
 529                    (mode-items (if mode-title (cdr mode-popup-menu)
 530                                  mode-popup-menu))
 531                    (global-title (and (stringp (car global-popup-menu))
 532                                       (car global-popup-menu)))
 533                    (global-items (if global-title (cdr global-popup-menu)
 534                                    global-popup-menu))
 535                    mode-filters)
 536               ;; Strip keywords from local menu for attaching them at the top
 537               (while (and mode-items
 538                           (keywordp (car mode-items)))
 539                 ;; Push both keyword and its argument.
 540                 (push (pop mode-items) mode-filters)
 541                 (push (pop mode-items) mode-filters))
 542               (setq mode-filters (nreverse mode-filters))
 543               ;; If mode-filters contains a keyword already present in
 544               ;; `global-popup-menu', you will probably lose.
 545               (append (cond ((not popup-menu-titles) (list ""))
 546                             (mode-title (list mode-title))
 547                             (global-title (list global-title))
 548                             (t (list "")))
 549                       mode-filters
 550                       context-menu-items
 551                       (and context-menu-items mode-items '("---"))
 552                       mode-items
 553                       (and (or context-menu-items mode-items)
 554                            global-items '("---" "---"))
 555                       (and global-title (list global-title))
 556                       global-items
 557                       ))))
 558
 559     (while (popup-up-p)
 560       (dispatch-event (next-event)))
 561
 562     ))
 563
 564 (defun popup-buffer-menu (event)
 565   "Pop up a copy of the Buffers menu (from the menubar) where the mouse is clicked."
 566   (interactive "e")
 567   (let ((window (and (event-over-text-area-p event) (event-window event)))
 568         (bmenu nil))
 569     (or window
 570         (error "Pointer must be in a normal window"))
 571     (select-window window)
 572     (if current-menubar
 573         (setq bmenu (assoc "%_Buffers" current-menubar)))
 574     (if (null bmenu)
 575         (setq bmenu (assoc "%_Buffers" default-menubar)))
 576     (if (null bmenu)
 577         (error "Can't find the Buffers menu"))
 578     (popup-menu bmenu)))
 579
 580 (defun popup-menubar-menu (event)
 581   "Pop up a copy of menu that also appears in the menubar."
 582   (interactive "e")
 583   (let ((window (and (event-over-text-area-p event) (event-window event)))
 584         popup-menubar)
 585     (or window
 586         (error "Pointer must be in a normal window"))
 587     (select-window window)
 588     (and current-menubar (run-hooks 'activate-menubar-hook))
 589     ;; #### Instead of having to copy this just to safely get rid of
 590     ;; any nil what we should really do is fix up the internal menubar
 591     ;; code to just ignore nil if generating a popup menu
 592     (setq popup-menubar (delete nil (copy-sequence (or current-menubar
 593                                                        default-menubar))))
 594     (popup-menu (cons "%_Menubar Menu" popup-menubar))
 595     ))
 596
 597 (defun menu-call-at-event (form &optional event default-behavior-fallback)
 598   "Call FORM while temporarily setting point to the position in EVENT.
 599 NOTE: This is EXPERIMENTAL and may change at any time.
 600
 601 FORM is called the way forms in menu specs are: i.e. if a symbol, it's called
 602 with `call-interactively', otherwise with `eval'.  EVENT defaults to
 603 `last-popup-menu-event', making this function especially useful in popup
 604 menus.  The buffer and point are set temporarily within a `save-excursion'.
 605 If EVENT is not a mouse event, or was not over a buffer, nothing
 606 happens unless DEFAULT-BEHAVIOR-FALLBACK is non-nil, in which case the
 607 FORM is called normally."
 608   (or event (setq event last-popup-menu-event))
 609   (let ((buf (event-buffer event))
 610         (p (event-closest-point event)))
 611     (cond ((and buf p (> p 0))
 612            (save-excursion
 613              (set-buffer buf)
 614              (goto-char p)
 615              (if (symbolp form)
 616                  (call-interactively form)
 617                (eval form))))
 618           (default-behavior-fallback
 619             (if (symbolp form)
 620                 (call-interactively form)
 621               (eval form))))))
 622
 623 (global-set-key 'button3 'popup-mode-menu)
 624 ;; shift button3 and shift button2 are reserved for Hyperbole
 625 (global-set-key '(meta control button3) 'popup-buffer-menu)
 626 ;; The following command is way too dangerous with Custom.
 627 ;; (global-set-key '(meta shift button3) 'popup-menubar-menu)
 628
 629 ;; Here's a test of the cool new menu features (from Stig).
 630
 631 ;;(setq mode-popup-menu
 632 ;;      '("Test Popup Menu"
 633 ;;        :filter cdr
 634 ;;        ["this item won't appear because of the menu filter" ding t]
 635 ;;        "--:singleLine"
 636 ;;        "singleLine"
 637 ;;        "--:doubleLine"
 638 ;;        "doubleLine"
 639 ;;        "--:singleDashedLine"
 640 ;;        "singleDashedLine"
 641 ;;        "--:doubleDashedLine"
 642 ;;        "doubleDashedLine"
 643 ;;        "--:noLine"
 644 ;;        "noLine"
 645 ;;        "--:shadowEtchedIn"
 646 ;;        "shadowEtchedIn"
 647 ;;        "--:shadowEtchedOut"
 648 ;;        "shadowEtchedOut"
 649 ;;        "--:shadowDoubleEtchedIn"
 650 ;;        "shadowDoubleEtchedIn"
 651 ;;        "--:shadowDoubleEtchedOut"
 652 ;;        "shadowDoubleEtchedOut"
 653 ;;        "--:shadowEtchedInDash"
 654 ;;        "shadowEtchedInDash"
 655 ;;        "--:shadowEtchedOutDash"
 656 ;;        "shadowEtchedOutDash"
 657 ;;        "--:shadowDoubleEtchedInDash"
 658 ;;        "shadowDoubleEtchedInDash"
 659 ;;        "--:shadowDoubleEtchedOutDash"
 660 ;;        "shadowDoubleEtchedOutDash"
 661 ;;        ))
 662
 663 (defun get-popup-menu-response (menu-desc &optional event)
 664   "Pop up the given menu and wait for a response.
 665 This blocks until the response is received, and returns the misc-user
 666 event that encapsulates the response.  To execute it, you can do
 667   (funcall (event-function response) (event-object response))
 668 If no response was received, nil is returned.
 669
 670 MENU-DESC and EVENT are as in the call to `popup-menu'."
 671   ;; partially stolen from w3
 672
 673   ;; This function is way gross and assumes to much about menu
 674   ;; processing that is X specific.
 675   (let ((echo-keystrokes 0)
 676         new-event)
 677     (popup-menu menu-desc event)
 678     (catch 'popup-done
 679       (while t
 680         (setq new-event (next-command-event new-event))
 681         (cond ((misc-user-event-p new-event)
 682                (throw 'popup-done new-event))
 683               ((button-release-event-p new-event);; don't beep twice
 684                nil)
 685               ;; It shows how bogus this function is that the event
 686               ;; arg could be missing and no-one noticed ...
 687               ((event-matches-key-specifier-p new-event (quit-char))
 688                (signal 'quit nil))
 689               ;; this function has been ordered to do essentially
 690         ;; X-specifc processing after this check.
 691               ((not (popup-up-p))
 692                (setq unread-command-events (cons new-event
 693                                                  unread-command-events))
 694                (throw 'popup-done nil))
 695               ;; mswindows never gets here - who cares?
 696               (t
 697                (beep)
 698                (message "please make a choice from the menu.")))))))
 699
 700 (defun popup-menu-and-execute-in-window (menu-desc event)
 701   "Pop up the given menu and execute its response in EVENT's window.
 702 This blocks until the response is received, temporarily selects
 703 EVENT's window, and executes the command specified in the response.
 704 EVENT can also be a window.  See `popup-menu' for the semantics of
 705 MENU-DESC."
 706   (let ((response
 707          (get-popup-menu-response menu-desc
 708                                   (and (eventp event) event))))
 709     (and (misc-user-event-p response)
 710          (save-selected-window
 711            (select-window (if (windowp event) event
 712                             (event-window event)))
 713            (funcall (event-function response)
 714                     (event-object response))))))
 715
 716 ;; provide default bindings for menu accelerator map
 717 (and (boundp 'menu-accelerator-map)
 718      (keymapp menu-accelerator-map)
 719      (progn
 720        (define-key menu-accelerator-map "\e" 'menu-escape)
 721        (define-key menu-accelerator-map [left] 'menu-left)
 722        (define-key menu-accelerator-map [right] 'menu-right)
 723        (define-key menu-accelerator-map [up] 'menu-up)
 724        (define-key menu-accelerator-map [down] 'menu-down)
 725        (define-key menu-accelerator-map [return] 'menu-select)
 726        (define-key menu-accelerator-map [kp_down] 'menu-down)
 727        (define-key menu-accelerator-map [kp_up] 'menu-down)
 728        (define-key menu-accelerator-map [kp_left] 'menu-left)
 729        (define-key menu-accelerator-map [kp_right] 'menu-right)
 730        (define-key menu-accelerator-map [kp_enter] 'menu-select)
 731        (define-key menu-accelerator-map "\C-g" 'menu-quit)))
 732
 733 \f
 734 (provide 'menubar)
 735
 736 ;;; menubar.el ends here