cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-display)
  28 (require 'riece-server)
  29 (require 'riece-compat)
  30 (require 'riece-commands)
  31 (require 'riece-addon)
  32 (require 'riece-signal)
  33
  34 (autoload 'derived-mode-class "derived")
  35
  36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  37 (defvar riece-user-list-mode-map (make-sparse-keymap))
  38
  39 (defvar riece-dialogue-mode-map
  40   (let ((keymap (make-keymap)))
  41     (suppress-keymap keymap 'nodigit)
  42     keymap))
  43
  44 (defvar riece-command-mode-map (make-keymap))
  45 (defvar riece-command-map (make-sparse-keymap))
  46
  47 (defvar riece-command-mode-syntax-table nil)
  48
  49 (put 'riece-command-mode 'mode-class 'special)
  50 (put 'riece-dialogue-mode 'mode-class 'special)
  51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  52 (put 'riece-channel-list-mode 'mode-class 'special)
  53 (put 'riece-user-list-mode 'mode-class 'special)
  54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  55
  56 (defvar riece-buffer-alist
  57   '((riece-command-buffer "*Command*" riece-command-mode)
  58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  59     (riece-others-buffer "*Others*" riece-others-mode)
  60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  61     (riece-user-list-buffer " *Users*" riece-user-list-mode)
  62     (riece-temp-buffer " *Temp*")
  63     (riece-debug-buffer "*Debug*")))
  64
  65 (defvar riece-select-keys
  66   `("#" riece-command-switch-to-channel-by-number
  67     "1" riece-command-switch-to-channel-by-number-1
  68     "2" riece-command-switch-to-channel-by-number-2
  69     "3" riece-command-switch-to-channel-by-number-3
  70     "4" riece-command-switch-to-channel-by-number-4
  71     "5" riece-command-switch-to-channel-by-number-5
  72     "6" riece-command-switch-to-channel-by-number-6
  73     "7" riece-command-switch-to-channel-by-number-7
  74     "8" riece-command-switch-to-channel-by-number-8
  75     "9" riece-command-switch-to-channel-by-number-9
  76     "0" riece-command-switch-to-channel-by-number-10
  77     ,(concat riece-command-prefix "1")
  78     riece-command-switch-to-channel-by-number-11
  79     ,(concat riece-command-prefix "2")
  80     riece-command-switch-to-channel-by-number-12
  81     ,(concat riece-command-prefix "3")
  82     riece-command-switch-to-channel-by-number-13
  83     ,(concat riece-command-prefix "4")
  84     riece-command-switch-to-channel-by-number-14
  85     ,(concat riece-command-prefix "5")
  86     riece-command-switch-to-channel-by-number-15
  87     ,(concat riece-command-prefix "6")
  88     riece-command-switch-to-channel-by-number-16
  89     ,(concat riece-command-prefix "7")
  90     riece-command-switch-to-channel-by-number-17
  91     ,(concat riece-command-prefix "8")
  92     riece-command-switch-to-channel-by-number-18
  93     ,(concat riece-command-prefix "9")
  94     riece-command-switch-to-channel-by-number-19
  95     ,(concat riece-command-prefix "0")
  96     riece-command-switch-to-channel-by-number-20))
  97
  98 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  99 (defmacro riece-local-set-keys (&rest plist)
 100   "Set the keys in PLIST in the current keymap."
 101   `(riece-define-keys-1 (current-local-map) ',plist))
 102
 103 (defmacro riece-define-keys (keymap &rest plist)
 104   "Assign KEYMAP keys from PLIST."
 105   `(riece-define-keys-1 ',keymap ',plist))
 106
 107 (defmacro riece-define-keys-safe (keymap &rest plist)
 108   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 109   `(riece-define-keys-1 ',keymap ',plist t))
 110
 111 (put 'riece-define-keys 'lisp-indent-function 1)
 112 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 113 (put 'riece-local-set-keys 'lisp-indent-function 1)
 114
 115 (defun riece-define-keys-1 (keymap plist &optional safe)
 116   "Assign KEYMAP keys from PLIST.
 117 If optional argument SAFE is nil, overwrite previous definitions."
 118   (unless keymap
 119     (error "Can't set keys in a null keymap"))
 120   (cond
 121    ((symbolp keymap)
 122     (setq keymap (symbol-value keymap)))
 123    ((keymapp keymap))
 124    ((listp keymap)
 125     (set (car keymap) nil)
 126     (define-prefix-command (car keymap))
 127     (define-key (symbol-value (nth 2 keymap))
 128       (if (symbolp (nth 1 keymap))
 129           (symbol-value (nth 1 keymap))
 130         (nth 1 keymap))
 131       (car keymap))
 132     (setq keymap (symbol-value (car keymap)))))
 133   (let (key)
 134     (while plist
 135       (if (symbolp (setq key (car plist)))
 136           (setq key (symbol-value key)))
 137       (setq plist (cdr plist))
 138       (if (or (not safe)
 139               (eq (lookup-key keymap key) 'undefined))
 140           (define-key keymap key (car plist))
 141         (car plist))
 142       (setq plist (cdr plist)))))
 143
 144 (when t
 145   (riece-define-keys riece-dialogue-mode-map
 146     "\177" scroll-down
 147     [delete] scroll-down
 148     [backspace] scroll-down
 149     [return] scroll-up
 150     " " scroll-up
 151     [home] beginning-of-buffer
 152     "$" end-of-buffer
 153     [end] end-of-buffer
 154     "/" riece-command-raw
 155     ">" end-of-buffer
 156     "<" beginning-of-buffer
 157     "^" riece-command-list-addons
 158     "\C-ta" riece-command-toggle-away
 159     "c" riece-command-select-command-buffer
 160     "f" riece-command-finger
 161     "\C-tf" riece-command-toggle-freeze
 162     "\C-to" riece-command-toggle-own-freeze
 163     "\C-tO" riece-command-toggle-others-buffer-mode
 164     "\C-tu" riece-command-toggle-user-list-buffer-mode
 165     "\C-tc" riece-command-toggle-channel-buffer-mode
 166     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 167     "\C-tl" riece-command-change-layout
 168     "i" riece-command-invite
 169     "j" riece-command-join
 170     "\C-k" riece-command-kick
 171     "l" riece-command-list
 172     "M" riece-command-change-mode
 173     "n" riece-command-change-nickname
 174     "N" riece-command-names
 175     "o" other-window
 176     "O" riece-command-open-server
 177     "C" riece-command-close-server
 178     "M" riece-command-universal-server-name-argument
 179     "p" riece-command-enter-message-to-user
 180     "q" riece-command-quit
 181     "r" riece-command-configure-windows
 182     "s" riece-command-save-variables
 183     "x" riece-command-copy-region
 184     "t" riece-command-topic
 185     "w" riece-command-who
 186     "z" riece-command-suspend-resume)
 187
 188   (riece-define-keys riece-command-mode-map
 189     "\r" riece-command-enter-message
 190     [(control return)] riece-command-enter-message-as-notice
 191     [tab] riece-command-complete-user)
 192
 193   (riece-define-keys (riece-command-map riece-command-prefix
 194                                         riece-command-mode-map)
 195     "\177" riece-command-scroll-down
 196     [delete] riece-command-scroll-down
 197     [backspace] riece-command-scroll-down
 198     " " riece-command-scroll-up
 199     [home] riece-command-beginning-of-buffer
 200     "$" riece-command-end-of-buffer
 201     [end] riece-command-end-of-buffer
 202     ">" riece-command-next-channel
 203     "<" riece-command-previous-channel
 204     "\C-j" riece-command-next-channel
 205     "\C-n" riece-command-names
 206     "l" riece-command-list
 207     "\C-m" riece-command-change-mode
 208     "o" riece-command-set-operators
 209     "\C-p" riece-command-part
 210     "r" riece-command-configure-windows
 211     "v" riece-command-set-speakers
 212     "V" riece-version)
 213   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 214
 215   (riece-define-keys riece-user-list-mode-map
 216     "o" riece-command-set-operators
 217     "v" riece-command-set-voices
 218     "f" riece-command-finger
 219     " " riece-command-user-list-scroll-up
 220     "\177" riece-command-user-list-scroll-down
 221     [delete] riece-command-user-list-scroll-down
 222     [backspace] riece-command-user-list-scroll-down
 223     "c" riece-command-select-command-buffer)
 224
 225   (riece-define-keys riece-channel-list-mode-map
 226     ">" riece-command-next-channel
 227     "<" riece-command-previous-channel
 228     "o" other-window
 229     "c" riece-command-select-command-buffer)
 230
 231   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 232   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 233
 234 (defun riece-read-variables-files (&optional file)
 235   "Read variables FILEs."
 236   (or (file-directory-p riece-directory)
 237       (make-directory riece-directory))
 238   (let ((files (if file
 239                    (setq riece-variables-file file
 240                          riece-variables-files (list file))
 241                  riece-variables-files)))
 242     (while files
 243       (condition-case nil
 244           (load (expand-file-name (car files)))
 245         (file-error nil))
 246       (setq files (cdr files)))))
 247
 248 (defvar print-quoted)
 249 (defvar print-escape-multibyte)
 250 (defun riece-save-variables-files ()
 251   "Save current settings to `riece-saved-variables-file'."
 252   (with-temp-file riece-saved-variables-file
 253     (insert ";;; This file is generated automatically by " riece-version ".\n"
 254             ";;; Do not edit this file!\n\n")
 255     (let ((print-quoted t)
 256           (print-readably t)
 257           print-escape-multibyte
 258           print-level
 259           print-length
 260           (variables riece-saved-forms))
 261       (while variables
 262         (prin1 `(setq ,(car variables)
 263                       ',(symbol-value (car variables)))
 264                (current-buffer))
 265         (insert "\n")
 266         (setq variables (cdr variables)))))
 267   (setq riece-save-variables-are-dirty nil))
 268
 269 ;;;###autoload
 270 (defun riece (&optional confirm)
 271   "Connect to the IRC server and start chatting.
 272 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 273   (interactive "P")
 274   (riece-read-variables-files (if noninteractive
 275                                   (car command-line-args-left)))
 276   (run-hooks 'riece-after-load-startup-hook)
 277   (if (riece-server-opened)
 278       (riece-command-configure-windows)
 279     (modify-frame-parameters (selected-frame)
 280                              (list (cons 'riece-window-configuration
 281                                          (current-window-configuration))))
 282     (setq riece-addon-dependencies (riece-resolve-addons
 283                                     (copy-sequence riece-addons)))
 284     (let ((pointer riece-addon-dependencies))
 285       (while pointer
 286         (riece-insinuate-addon (car (car pointer)) riece-debug)
 287         (setq pointer (cdr pointer))))
 288     (if (or confirm (null riece-server))
 289         (setq riece-server (completing-read (riece-mcat "Server: ")
 290                                             riece-server-alist)))
 291     (if (stringp riece-server)
 292         (setq riece-server (riece-server-name-to-server riece-server)))
 293     (riece-create-buffers)
 294     (switch-to-buffer riece-command-buffer)
 295     (riece-display-connect-signals)
 296     (riece-redisplay-buffers)
 297     (riece-open-server riece-server "")
 298     ;; If no server process is available, exit.
 299     (if (null riece-server-process-alist)
 300         (riece-exit)
 301       (let ((server-list riece-startup-server-list))
 302         (while server-list
 303           (riece-command-open-server (car server-list))
 304           (setq server-list (cdr server-list))))
 305       (let ((channel-list riece-startup-channel-list)
 306             server)
 307         (while channel-list
 308           (setq server (riece-identity-server
 309                         (riece-parse-identity (car channel-list))))
 310           (unless (riece-server-opened server)
 311             (riece-command-open-server server))
 312           (setq channel-list (cdr channel-list))))
 313       (let ((pointer riece-addon-dependencies))
 314         (while pointer
 315           (unless (get (car (car pointer)) 'riece-addon-default-disabled)
 316             (riece-enable-addon (car (car pointer)) riece-debug))
 317           (setq pointer (cdr pointer))))
 318       (run-hooks 'riece-startup-hook)
 319       (message "%s" (substitute-command-keys
 320                      (riece-mcat "Type \\[describe-mode] for help"))))))
 321
 322 (defun riece-exit ()
 323   (if riece-save-variables-are-dirty
 324       (riece-save-variables-files))
 325   (while riece-buffer-list
 326     (if (and (get-buffer (car riece-buffer-list))
 327              (buffer-live-p (car riece-buffer-list)))
 328         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 329     (setq riece-buffer-list (cdr riece-buffer-list)))
 330   (riece-clear-signal-slots)
 331   (setq riece-server nil
 332         riece-current-channels nil
 333         riece-current-channel nil
 334         riece-channel-buffer nil
 335         riece-channel-buffer-alist nil
 336         riece-user-indicator nil
 337         riece-long-channel-indicator (riece-mcat "None")
 338         riece-channel-list-indicator (riece-mcat "No channel")
 339         riece-away-indicator "-"
 340         riece-operator-indicator "-"
 341         riece-channel-status-indicator "-"
 342         riece-freeze-indicator "-")
 343   (modify-frame-parameters (selected-frame)
 344                            (list (list 'riece-window-configuration)))
 345   (delete-other-windows)
 346   (run-hooks 'riece-exit-hook))
 347
 348 (defun riece-command-mode ()
 349   "Major mode for Riece.  Normal edit function are available.
 350 Typing Return or Linefeed enters the current line in the dialogue.
 351 The following special commands are available:
 352 For a list of the generic commands type \\[riece-command-generic] ? RET.
 353 \\{riece-command-mode-map}"
 354   (interactive)
 355   (kill-all-local-variables)
 356
 357   ;; Make `truncate-partial-width-windows' buffer local and set it to
 358   ;; nil.  This causes `truncate-lines' to directly control line
 359   ;; truncation.
 360   (make-local-variable 'truncate-partial-width-windows)
 361   (setq truncate-partial-width-windows nil)
 362
 363   (make-local-variable 'riece-mode-line-buffer-identification)
 364   (setq riece-away-indicator "-"
 365         riece-operator-indicator "-"
 366         riece-channel-status-indicator "-"
 367         major-mode 'riece-command-mode
 368         mode-name "Command"
 369         riece-mode-line-buffer-identification
 370         '("Riece: "
 371           riece-away-indicator
 372           riece-operator-indicator
 373           riece-channel-status-indicator
 374           " "
 375           riece-user-indicator
 376           " "
 377           riece-channel-indicator)
 378         mode-line-buffer-identification
 379         (riece-mode-line-buffer-identification
 380          riece-mode-line-buffer-identification)
 381         truncate-lines nil)
 382   (riece-simplify-mode-line-format)
 383   (use-local-map riece-command-mode-map)
 384
 385   (unless riece-command-mode-syntax-table
 386     (setq riece-command-mode-syntax-table
 387           (copy-syntax-table (syntax-table)))
 388     (set-syntax-table riece-command-mode-syntax-table)
 389     (mapcar
 390      (lambda (c) (modify-syntax-entry c "w"))
 391      "^[]{}'`"))
 392
 393   (run-hooks 'riece-command-mode-hook))
 394
 395 (defun riece-dialogue-mode ()
 396   "Major mode for displaying the IRC dialogue.
 397 All normal editing commands are turned off.
 398 Instead, these commands are available:
 399 \\{riece-dialogue-mode-map}"
 400   (kill-all-local-variables)
 401   (make-local-variable 'riece-freeze)
 402   (make-local-variable 'riece-freeze-indicator)
 403
 404   ;; Make `truncate-partial-width-windows' buffer local and set it to
 405   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 406   (make-local-variable 'truncate-partial-width-windows)
 407   (setq truncate-partial-width-windows nil)
 408
 409   (make-local-variable 'riece-mode-line-buffer-identification)
 410   (setq riece-freeze riece-default-freeze
 411         riece-away-indicator "-"
 412         riece-operator-indicator "-"
 413         riece-channel-status-indicator "-"
 414         major-mode 'riece-dialogue-mode
 415         mode-name "Dialogue"
 416         riece-mode-line-buffer-identification
 417         '("Riece: "
 418           riece-away-indicator
 419           riece-operator-indicator
 420           riece-freeze-indicator
 421           riece-channel-status-indicator
 422           " "
 423           riece-channel-list-indicator " ")
 424         mode-line-buffer-identification
 425         (riece-mode-line-buffer-identification
 426          riece-mode-line-buffer-identification)
 427         truncate-lines nil
 428         buffer-read-only t)
 429   (riece-simplify-mode-line-format)
 430   (use-local-map riece-dialogue-mode-map)
 431   (buffer-disable-undo)
 432   (run-hooks 'riece-dialogue-mode-hook))
 433
 434 (define-derived-mode riece-others-mode riece-dialogue-mode
 435   "Others"
 436   "Major mode for displaying the IRC others message except current channel.
 437 All normal editing commands are turned off.
 438 Instead, these commands are available:
 439 \\{riece-others-mode-map}")
 440
 441 (define-derived-mode riece-channel-mode riece-dialogue-mode
 442   "Channel"
 443   "Major mode for displaying the IRC current channel buffer.
 444 All normal editing commands are turned off.
 445 Instead, these commands are available:
 446 \\{riece-channel-mode-map}"
 447   (make-local-variable 'riece-channel-buffer-window-point)
 448   (make-local-variable 'riece-mode-line-buffer-identification)
 449   (setq riece-mode-line-buffer-identification
 450         '("Riece: "
 451           riece-away-indicator
 452           riece-operator-indicator
 453           riece-freeze-indicator
 454           riece-channel-status-indicator
 455           " "
 456           riece-long-channel-indicator)
 457         mode-line-buffer-identification
 458         (riece-mode-line-buffer-identification
 459          riece-mode-line-buffer-identification)))
 460
 461 (defun riece-channel-list-mode ()
 462   "Major mode for displaying channel list.
 463 All normal editing commands are turned off."
 464   (kill-all-local-variables)
 465   (buffer-disable-undo)
 466
 467   ;; Make `truncate-partial-width-windows' buffer local and set it to
 468   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 469   (make-local-variable 'truncate-partial-width-windows)
 470   (setq truncate-partial-width-windows nil)
 471
 472   (make-local-variable 'riece-mode-line-buffer-identification)
 473   (setq major-mode 'riece-channel-list-mode
 474         mode-name "Channels"
 475         riece-mode-line-buffer-identification '("Riece: ")
 476         mode-line-buffer-identification
 477         (riece-mode-line-buffer-identification
 478          riece-mode-line-buffer-identification)
 479         truncate-lines t
 480         buffer-read-only t)
 481   (make-local-hook 'riece-update-buffer-functions)
 482   (add-hook 'riece-update-buffer-functions
 483             'riece-update-channel-list-buffer nil t)
 484   (use-local-map riece-channel-list-mode-map)
 485   (run-hooks 'riece-channel-list-mode-hook))
 486
 487 (defun riece-user-list-mode ()
 488   "Major mode for displaying members in the IRC current channel buffer.
 489 All normal editing commands are turned off.
 490 Instead, these commands are available:
 491 \\{riece-user-list-mode-map}"
 492   (kill-all-local-variables)
 493   (buffer-disable-undo)
 494
 495   ;; Make `truncate-partial-width-windows' buffer local and set it to
 496   ;; nil.  This causes `truncate-lines' to directly control line truncation.
 497   (make-local-variable 'truncate-partial-width-windows)
 498   (setq truncate-partial-width-windows nil)
 499
 500   (make-local-variable 'riece-mode-line-buffer-identification)
 501   (setq major-mode 'riece-user-list-mode
 502         mode-name "Users"
 503         riece-mode-line-buffer-identification
 504         '("Riece: " riece-long-channel-indicator " ")
 505         mode-line-buffer-identification
 506         (riece-mode-line-buffer-identification
 507          riece-mode-line-buffer-identification)
 508         truncate-lines t
 509         buffer-read-only t)
 510   (if (boundp 'transient-mark-mode)
 511       (set (make-local-variable 'transient-mark-mode) t))
 512   (make-local-hook 'riece-update-buffer-functions)
 513   (add-hook 'riece-update-buffer-functions
 514             'riece-update-user-list-buffer nil t)
 515   (use-local-map riece-user-list-mode-map)
 516   (run-hooks 'riece-user-list-mode-hook))
 517
 518 (defun riece-create-buffers ()
 519   (let ((alist riece-buffer-alist))
 520     (while alist
 521       (save-excursion
 522         (set-buffer (apply #'riece-get-buffer-create
 523                            (cdr (car alist))))
 524         (set (car (car alist)) (current-buffer))
 525         (unless (or (null (nth 2 (car alist)))
 526                     (eq major-mode (nth 2 (car alist))))
 527           (funcall (nth 2 (car alist))))
 528         (setq alist (cdr alist))))))
 529
 530 (defvar reporter-prompt-for-summary-p)
 531 (defun riece-submit-bug-report (&optional recent-messages recent-keys)
 532   "Submit via mail a bug report on Riece."
 533   ;; This strange form ensures that (recent-keys) is the value before
 534   ;; the bug subject string is read.
 535   (interactive (list (riece-recent-messages 20) (recent-keys)))
 536   (message "Querying server version...")
 537   (let ((pointer riece-server-process-alist)
 538         nickname)
 539     (while pointer
 540       (when (riece-server-process-opened (cdr (car pointer)))
 541         (process-send-string (cdr (car pointer)) "VERSION\r\n")
 542         (if (setq nickname
 543                   (with-current-buffer (process-buffer (cdr (car pointer)))
 544                     riece-real-nickname))
 545             (process-send-string
 546              (cdr (car pointer))
 547              (format "PRIVMSG %s :\1VERSION\1\r\n" nickname))))
 548       (setq pointer (cdr pointer))))
 549   (sit-for 3)
 550   (message "Querying server version...done")
 551   (require 'reporter)
 552   (let ((reporter-prompt-for-summary-p t))
 553     (unless riece-debug
 554       (error "Please turn on riece-debug and restart Riece."))
 555     (reporter-submit-bug-report
 556      "liece@unixuser.org"
 557      (riece-version)
 558      '(riece-debug)
 559      nil
 560      nil
 561      "This bug report will be sent to the Riece Development Team,
 562 not to your local site managers!!
 563
 564 Please write in Japanese or English, because the Riece maintainers do
 565 not have translators to read other languages for them.
 566
 567 Please describe as succinctly as possible:
 568 \t- What happened.
 569 \t- What you thought should have happened.
 570 \t- Precisely what you were doing at the time.
 571
 572 Also include a reliable recipe for triggering the bug, as well as
 573 any lisp back-traces that you may have.
 574 \(setq stack-trace-on-error t\), or \(setq debug-on-error t\) if you
 575 are familiar with the debugger, to get a lisp back-trace.")
 576     (delete-other-windows)
 577     (save-excursion
 578       (goto-char (point-max))
 579       (insert
 580        "\nAdd-on state:\n"
 581        "------------\n"
 582        (save-window-excursion
 583          (save-excursion
 584            (riece-command-list-addons)
 585            (search-forward "\n\n")
 586            (buffer-substring (point-min) (point)))))
 587       (insert "Recent messages from servers:\n"
 588               "--------------------------")
 589       (let ((pointer riece-server-process-alist))
 590         (while pointer
 591           (insert "\n- \"" (car (car pointer)) "\", \n"
 592                   (format "%S" (if (equal (car (car pointer)) "")
 593                                    riece-server
 594                                  (cdr (assoc (car (car pointer))
 595                                              riece-server-alist))))
 596                   "\n"
 597                   (if (riece-server-process-opened (cdr (car pointer)))
 598                       (save-excursion
 599                         (set-buffer (process-buffer (cdr (car pointer))))
 600                         (goto-char (point-max))
 601                         (beginning-of-line -60)
 602                         (buffer-substring (point) (point-max)))
 603                     "(closed server)"))
 604           (setq pointer (cdr pointer))))
 605       (insert "\n\nRecent debug messages:\n"
 606               "-----------------------------------\n"
 607               (with-current-buffer riece-debug-buffer
 608                 (buffer-string)))
 609       ;; Insert recent keystrokes.
 610       (insert "\n\nRecent keystrokes:\n"
 611               "-----------------\n\n")
 612       (let ((before-keys (point)))
 613         (insert (key-description recent-keys))
 614         (save-restriction
 615           (narrow-to-region before-keys (point))
 616           (goto-char before-keys)
 617           (while (progn (move-to-column 50) (not (eobp)))
 618             (search-forward " " nil t)
 619             (insert "\n"))))
 620       ;; Insert recent minibuffer messages.
 621       (insert "\n\nRecent messages (most recent first):\n"
 622               "-----------------------------------\n"
 623               recent-messages))))
 624
 625 (provide 'riece)
 626
 627 ;;; riece.el ends here