cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-filter)
  28 (require 'riece-display)
  29 (require 'riece-server)
  30 (require 'riece-compat)
  31 (require 'riece-commands)
  32
  33 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  34 (defvar riece-user-list-mode-map (make-sparse-keymap))
  35
  36 (defvar riece-dialogue-mode-map
  37   (let ((keymap (make-keymap)))
  38     (suppress-keymap keymap 'nodigit)
  39     keymap))
  40
  41 (defvar riece-command-mode-map (make-keymap))
  42 (defvar riece-command-map (make-sparse-keymap))
  43
  44 (defvar riece-command-mode-syntax-table nil)
  45
  46 (put 'riece-command-mode 'mode-class 'special)
  47 (put 'riece-dialogue-mode 'mode-class 'special)
  48 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  49 (put 'riece-channel-list-mode 'mode-class 'special)
  50 (put 'riece-user-list-mode 'mode-class 'special)
  51 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  52
  53 (defvar riece-buffer-alist
  54   '((riece-command-buffer "*Commands*" riece-command-mode)
  55     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  56     (riece-others-buffer "*Others*" riece-others-mode)
  57     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  58     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
  59
  60 (defvar riece-select-keys
  61   `("1" riece-command-switch-to-channel-by-number-1
  62     "2" riece-command-switch-to-channel-by-number-2
  63     "3" riece-command-switch-to-channel-by-number-3
  64     "4" riece-command-switch-to-channel-by-number-4
  65     "5" riece-command-switch-to-channel-by-number-5
  66     "6" riece-command-switch-to-channel-by-number-6
  67     "7" riece-command-switch-to-channel-by-number-7
  68     "8" riece-command-switch-to-channel-by-number-8
  69     "9" riece-command-switch-to-channel-by-number-9
  70     "0" riece-command-switch-to-channel-by-number-10
  71     ,(concat riece-command-prefix "1")
  72     riece-command-switch-to-channel-by-number-11
  73     ,(concat riece-command-prefix "2")
  74     riece-command-switch-to-channel-by-number-12
  75     ,(concat riece-command-prefix "3")
  76     riece-command-switch-to-channel-by-number-13
  77     ,(concat riece-command-prefix "4")
  78     riece-command-switch-to-channel-by-number-14
  79     ,(concat riece-command-prefix "5")
  80     riece-command-switch-to-channel-by-number-15
  81     ,(concat riece-command-prefix "6")
  82     riece-command-switch-to-channel-by-number-16
  83     ,(concat riece-command-prefix "7")
  84     riece-command-switch-to-channel-by-number-17
  85     ,(concat riece-command-prefix "8")
  86     riece-command-switch-to-channel-by-number-18
  87     ,(concat riece-command-prefix "9")
  88     riece-command-switch-to-channel-by-number-19
  89     ,(concat riece-command-prefix "0")
  90     riece-command-switch-to-channel-by-number-20))
  91
  92 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  93 (defmacro riece-local-set-keys (&rest plist)
  94   "Set the keys in PLIST in the current keymap."
  95   `(riece-define-keys-1 (current-local-map) ',plist))
  96
  97 (defmacro riece-define-keys (keymap &rest plist)
  98   "Assign KEYMAP keys from PLIST."
  99   `(riece-define-keys-1 ',keymap ',plist))
 100
 101 (defmacro riece-define-keys-safe (keymap &rest plist)
 102   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 103   `(riece-define-keys-1 ',keymap ',plist t))
 104
 105 (put 'riece-define-keys 'lisp-indent-function 1)
 106 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 107 (put 'riece-local-set-keys 'lisp-indent-function 1)
 108
 109 (defun riece-define-keys-1 (keymap plist &optional safe)
 110   "Assign KEYMAP keys from PLIST.
 111 If optional argument SAFE is nil, overwrite previous definitions."
 112   (unless keymap
 113     (error "Can't set keys in a null keymap"))
 114   (cond
 115    ((symbolp keymap)
 116     (setq keymap (symbol-value keymap)))
 117    ((keymapp keymap))
 118    ((listp keymap)
 119     (set (car keymap) nil)
 120     (define-prefix-command (car keymap))
 121     (define-key (symbol-value (nth 2 keymap))
 122       (if (symbolp (nth 1 keymap))
 123           (symbol-value (nth 1 keymap))
 124         (nth 1 keymap))
 125       (car keymap))
 126     (setq keymap (symbol-value (car keymap)))))
 127   (let (key)
 128     (while plist
 129       (if (symbolp (setq key (car plist)))
 130           (setq key (symbol-value key)))
 131       (setq plist (cdr plist))
 132       (if (or (not safe)
 133               (eq (lookup-key keymap key) 'undefined))
 134           (define-key keymap key (car plist))
 135         (car plist))
 136       (setq plist (cdr plist)))))
 137
 138 (when t
 139   (riece-define-keys riece-dialogue-mode-map
 140     "\177" scroll-down
 141     [delete] scroll-down
 142     [backspace] scroll-down
 143     [return] scroll-up
 144     " " scroll-up
 145     "$" end-of-buffer
 146     "/" riece-command-raw
 147     ">" end-of-buffer
 148     "<" beginning-of-buffer
 149     "\C-ta" riece-command-toggle-away
 150     "c" riece-command-select-command-buffer
 151     "f" riece-command-finger
 152     "\C-tf" riece-command-toggle-freeze
 153     "\C-to" riece-command-toggle-own-freeze
 154     "\C-tu" riece-command-toggle-user-list-buffer-mode
 155     "\C-tc" riece-command-toggle-channel-buffer-mode
 156     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 157     "\C-tl" riece-command-change-layout
 158     "i" riece-command-invite
 159     "j" riece-command-join
 160     "\C-k" riece-command-kick
 161     "l" riece-command-list
 162     "M" riece-command-change-mode
 163     "n" riece-command-change-nickname
 164     "N" riece-command-names
 165     "o" other-window
 166     "O" riece-command-open-server
 167     "C" riece-command-close-server
 168     "M" riece-command-universal-server-name-argument
 169     "p" riece-command-enter-message-to-user
 170     "q" riece-command-quit
 171     "r" riece-command-configure-windows
 172     "x" riece-command-copy-region
 173     "t" riece-command-topic
 174     "w" riece-command-who)
 175
 176   (riece-define-keys riece-command-mode-map
 177     "\r" riece-command-enter-message
 178     [(control return)] riece-command-enter-message-as-notice)
 179
 180   (riece-define-keys (riece-command-map riece-command-prefix
 181                                         riece-command-mode-map)
 182     "\177" riece-command-scroll-down
 183     [delete] riece-command-scroll-down
 184     [backspace] riece-command-scroll-down
 185     " " riece-command-scroll-up
 186     "$" riece-command-end-of-buffer
 187     ">" riece-command-next-channel
 188     "<" riece-command-previous-channel
 189     "\C-j" riece-command-next-channel
 190     "\C-n" riece-command-names
 191     "l" riece-command-list
 192     "\C-m" riece-command-change-mode
 193     "o" riece-command-set-operators
 194     "\C-p" riece-command-part
 195     "r" riece-command-configure-windows
 196     "v" riece-command-set-speakers
 197     "V" riece-version)
 198   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 199
 200   (riece-define-keys riece-user-list-mode-map
 201     "o" riece-command-set-operators
 202     "v" riece-command-set-voices
 203     "f" riece-command-finger
 204     " " riece-command-nick-scroll-up
 205     "\177" riece-command-nick-scroll-down
 206     [delete] riece-command-nick-scroll-down
 207     [backspace] riece-command-nick-scroll-down
 208     "c" riece-command-select-command-buffer)
 209
 210   (riece-define-keys riece-channel-list-mode-map
 211     ">" riece-command-next-channel
 212     "<" riece-command-previous-channel
 213     "o" other-window
 214     "c" riece-command-select-command-buffer)
 215
 216   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 217   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 218
 219 (defun riece-read-variables-files (&optional file)
 220   "Read variables FILEs."
 221   (or (file-directory-p riece-directory)
 222       (make-directory riece-directory))
 223   (let ((files (if file
 224                    (setq riece-variables-file file
 225                          riece-variables-files (list file))
 226                  riece-variables-files)))
 227     (while files
 228       (condition-case nil
 229           (load (expand-file-name (car files)))
 230         (file-error nil))
 231       (setq files (cdr files)))))
 232
 233 (defvar print-quoted)
 234 (defvar print-escape-multibyte)
 235 (defun riece-save-variables-files ()
 236   "Save current settings to `riece-variables-file'."
 237   (with-temp-file riece-saved-variables-file
 238     (let ((print-quoted t)
 239           (print-readably t)
 240           print-escape-multibyte
 241           print-level
 242           print-length
 243           (variables riece-saved-forms))
 244       (while variables
 245         (prin1 `(setq ,(car variables)
 246                       ',(symbol-value (car variables)))
 247                (current-buffer))
 248         (insert "\n")
 249         (setq variables (cdr variables)))))
 250   (setq riece-save-variables-are-dirty nil))
 251
 252 ;;;###autoload
 253 (defun riece (&optional confirm)
 254   "Connect to the IRC server and start chatting.
 255 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 256   (interactive "P")
 257   (riece-read-variables-files (if noninteractive
 258                                   (car command-line-args-left)))
 259   (riece-insinuate-addons riece-addons)
 260   (run-hooks 'riece-after-load-startup-hook)
 261   (if (riece-server-opened)
 262       (riece-command-configure-windows)
 263     (if (or confirm (null riece-server))
 264         (setq riece-server (completing-read "Server: " riece-server-alist)))
 265     (if (stringp riece-server)
 266         (setq riece-server (riece-server-name-to-server riece-server)))
 267     (riece-create-buffers)
 268     (switch-to-buffer riece-command-buffer)
 269     (riece-redisplay-buffers)
 270     (riece-open-server riece-server "")
 271     (run-hooks 'riece-startup-hook)
 272     (message "%s" (substitute-command-keys
 273                    "Type \\[describe-mode] for help"))))
 274
 275 (defun riece-exit ()
 276   (if riece-save-variables-are-dirty
 277       (riece-save-variables-files))
 278   (while riece-buffer-list
 279     (if (and (get-buffer (car riece-buffer-list))
 280              (buffer-live-p (car riece-buffer-list)))
 281         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 282     (setq riece-buffer-list (cdr riece-buffer-list)))
 283   (setq riece-server nil
 284         riece-current-channels nil
 285         riece-current-channel nil
 286         riece-channel-buffer-alist nil
 287         riece-user-indicator nil
 288         riece-long-channel-indicator "None"
 289         riece-channel-list-indicator "No channel"
 290         riece-away-indicator "-"
 291         riece-operator-indicator "-"
 292         riece-freeze-indicator "-")
 293   (delete-other-windows)
 294   (run-hooks 'riece-exit-hook))
 295
 296 (defun riece-command-mode ()
 297   "Major mode for Riece.  Normal edit function are available.
 298 Typing Return or Linefeed enters the current line in the dialogue.
 299 The following special commands are available:
 300 For a list of the generic commands type \\[riece-command-generic] ? RET.
 301 \\{riece-command-mode-map}"
 302   (interactive)
 303   (kill-all-local-variables)
 304
 305   (setq riece-away-indicator "-"
 306         riece-operator-indicator "-"
 307         major-mode 'riece-command-mode
 308         mode-name "Commands"
 309         mode-line-buffer-identification
 310         (riece-mode-line-buffer-identification
 311          '("Riece: "
 312            riece-away-indicator
 313            riece-operator-indicator
 314            riece-freeze-indicator
 315            " "
 316            riece-user-indicator
 317            " "
 318            riece-channel-indicator)))
 319   (riece-simplify-mode-line-format)
 320   (use-local-map riece-command-mode-map)
 321
 322   (unless riece-command-mode-syntax-table
 323     (setq riece-command-mode-syntax-table
 324           (copy-syntax-table (syntax-table)))
 325     (set-syntax-table riece-command-mode-syntax-table)
 326     (mapcar
 327      (lambda (c) (modify-syntax-entry c "w"))
 328      "^[]{}'`"))
 329
 330   (run-hooks 'riece-command-mode-hook))
 331
 332 (defun riece-dialogue-mode ()
 333   "Major mode for displaying the IRC dialogue.
 334 All normal editing commands are turned off.
 335 Instead, these commands are available:
 336 \\{riece-dialogue-mode-map}"
 337   (kill-all-local-variables)
 338   (make-local-variable 'riece-freeze)
 339   (setq riece-freeze riece-default-freeze
 340         riece-away-indicator "-"
 341         riece-operator-indicator "-"
 342         major-mode 'riece-dialogue-mode
 343         mode-name "Dialogue"
 344         mode-line-buffer-identification
 345         (riece-mode-line-buffer-identification
 346          '("Riece: "
 347            riece-away-indicator
 348            riece-operator-indicator
 349            riece-freeze-indicator
 350            " "
 351            riece-channel-list-indicator " "))
 352         buffer-read-only t)
 353   (riece-simplify-mode-line-format)
 354   (use-local-map riece-dialogue-mode-map)
 355   (buffer-disable-undo)
 356   (run-hooks 'riece-dialogue-mode-hook))
 357
 358 (define-derived-mode riece-others-mode riece-dialogue-mode
 359   "Others"
 360   "Major mode for displaying the IRC others message except current channel.
 361 All normal editing commands are turned off.
 362 Instead, these commands are available:
 363 \\{riece-others-mode-map}")
 364
 365 (define-derived-mode riece-channel-mode riece-dialogue-mode
 366   "Channel"
 367   "Major mode for displaying the IRC current channel buffer.
 368 All normal editing commands are turned off.
 369 Instead, these commands are available:
 370 \\{riece-channel-mode-map}"
 371   (setq mode-line-buffer-identification
 372         (riece-mode-line-buffer-identification
 373          '("Riece: "
 374            riece-away-indicator
 375            riece-operator-indicator
 376            riece-freeze-indicator
 377            " "
 378            riece-long-channel-indicator))))
 379
 380 (defun riece-channel-list-mode ()
 381   "Major mode for displaying channel list.
 382 All normal editing commands are turned off."
 383   (kill-all-local-variables)
 384   (buffer-disable-undo)
 385   (setq major-mode 'riece-channel-list-mode
 386         mode-name "Channels"
 387         mode-line-buffer-identification
 388         (riece-mode-line-buffer-identification '("Riece: "))
 389         truncate-lines t
 390         buffer-read-only t)
 391   (make-local-hook 'riece-update-buffer-functions)
 392   (add-hook 'riece-update-buffer-functions
 393             'riece-update-channel-list-buffer nil t)
 394   (use-local-map riece-channel-list-mode-map)
 395   (run-hooks 'riece-channel-list-mode-hook))
 396
 397 (defun riece-user-list-mode ()
 398   "Major mode for displaying members in the IRC current channel buffer.
 399 All normal editing commands are turned off.
 400 Instead, these commands are available:
 401 \\{riece-user-list-mode-map}"
 402   (kill-all-local-variables)
 403   (buffer-disable-undo)
 404   (setq major-mode 'riece-user-list-mode
 405         mode-name "Users"
 406         mode-line-buffer-identification
 407         (riece-mode-line-buffer-identification
 408          '("Riece: " riece-long-channel-indicator " "))
 409         truncate-lines t
 410         buffer-read-only t)
 411   (if (boundp 'transient-mark-mode)
 412       (set (make-local-variable 'transient-mark-mode) t))
 413   (make-local-hook 'riece-update-buffer-functions)
 414   (add-hook 'riece-update-buffer-functions
 415             'riece-update-user-list-buffer nil t)
 416   (use-local-map riece-user-list-mode-map)
 417   (run-hooks 'riece-user-list-mode-hook))
 418
 419 (defun riece-create-buffers ()
 420   (let ((alist riece-buffer-alist))
 421     (while alist
 422       (save-excursion
 423         (set-buffer (apply #'riece-get-buffer-create
 424                            (cdr (car alist))))
 425         (set (car (car alist)) (current-buffer))
 426         (unless (or (null (nth 2 (car alist)))
 427                     (eq major-mode (nth 2 (car alist))))
 428           (funcall (nth 2 (car alist))))
 429         (setq alist (cdr alist))))))
 430
 431 (defun riece-load-and-build-addon-dependencies (addons)
 432   (let ((load-path (cons riece-addon-directory load-path))
 433         dependencies)
 434     (while addons
 435       (require (car addons))            ;error will be reported here
 436       (let* ((requires
 437               (funcall (or (intern-soft
 438                             (concat (symbol-name (car addons)) "-requires"))
 439                            #'ignore)))
 440              (pointer requires)
 441              entry)
 442         ;; Increment succs' pred count.
 443         (if (setq entry (assq (car addons) dependencies))
 444             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 445           (setq dependencies (cons (list (car addons) (length requires))
 446                                    dependencies)))
 447         ;; Merge pred's succs.
 448         (while pointer
 449           (if (setq entry (assq (car pointer) dependencies))
 450               (setcdr (cdr entry)
 451                       (cons (car addons) (nthcdr 2 entry)))
 452             (setq dependencies (cons (list (car pointer) 0 (car addons))
 453                                      dependencies)))
 454           (setq pointer (cdr pointer))))
 455       (setq addons (cdr addons)))
 456     dependencies))
 457
 458 (defun riece-insinuate-addons (addons)
 459   (let ((pointer addons)
 460         dependencies queue)
 461     ;; Uniquify, first.
 462     (while pointer
 463       (if (memq (car pointer) (cdr pointer))
 464           (setcar pointer nil))
 465       (setq pointer (cdr pointer)))
 466     (setq dependencies (riece-load-and-build-addon-dependencies
 467                         (delq nil addons))
 468           pointer dependencies)
 469     ;; Sort them.
 470     (while pointer
 471       (if (zerop (nth 1 (car pointer)))
 472           (setq dependencies (delq (car pointer) dependencies)
 473                 queue (cons (car pointer) queue)))
 474       (setq pointer (cdr pointer)))
 475     (setq addons nil)
 476     (while queue
 477       (setq addons (cons (car (car queue)) addons)
 478             pointer (nthcdr 2 (car queue)))
 479       (while pointer
 480         (let* ((entry (assq (car pointer) dependencies))
 481                (count (1- (nth 1 entry))))
 482           (if (zerop count)
 483               (progn
 484                 (setq dependencies (delq entry dependencies)
 485                       queue (nconc queue (list entry))))
 486             (setcar (cdr entry) count)))
 487         (setq pointer (cdr pointer)))
 488       (setq queue (cdr queue)))
 489     (if dependencies
 490         (error "Circular add-on dependency found"))
 491     (setq addons (nreverse addons))
 492     (while addons
 493       (require (car addons))            ;implicit dependency
 494       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 495       (if riece-debug
 496           (message "Add-on %S is loaded" (car addons)))
 497       (setq addons (cdr addons)))))
 498
 499 (provide 'riece)
 500
 501 ;;; riece.el ends here