cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-filter)
  28 (require 'riece-display)
  29 (require 'riece-server)
  30 (require 'riece-compat)
  31 (require 'riece-commands)
  32 (require 'riece-addon)
  33
  34 (autoload 'derived-mode-class "derived")
  35
  36 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  37 (defvar riece-user-list-mode-map (make-sparse-keymap))
  38
  39 (defvar riece-dialogue-mode-map
  40   (let ((keymap (make-keymap)))
  41     (suppress-keymap keymap 'nodigit)
  42     keymap))
  43
  44 (defvar riece-command-mode-map (make-keymap))
  45 (defvar riece-command-map (make-sparse-keymap))
  46
  47 (defvar riece-command-mode-syntax-table nil)
  48
  49 (put 'riece-command-mode 'mode-class 'special)
  50 (put 'riece-dialogue-mode 'mode-class 'special)
  51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  52 (put 'riece-channel-list-mode 'mode-class 'special)
  53 (put 'riece-user-list-mode 'mode-class 'special)
  54 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  55
  56 (defvar riece-buffer-alist
  57   '((riece-command-buffer "*Command*" riece-command-mode)
  58     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  59     (riece-others-buffer "*Others*" riece-others-mode)
  60     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  61     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
  62
  63 (defvar riece-shrink-buffer-idle-timer nil
  64   "Timer object to periodically shrink channel buffers.")
  65
  66 (defvar riece-addons-insinuated nil
  67   "Non nil if add-ons are already insinuated.")
  68
  69 (defvar riece-select-keys
  70   `("1" riece-command-switch-to-channel-by-number-1
  71     "2" riece-command-switch-to-channel-by-number-2
  72     "3" riece-command-switch-to-channel-by-number-3
  73     "4" riece-command-switch-to-channel-by-number-4
  74     "5" riece-command-switch-to-channel-by-number-5
  75     "6" riece-command-switch-to-channel-by-number-6
  76     "7" riece-command-switch-to-channel-by-number-7
  77     "8" riece-command-switch-to-channel-by-number-8
  78     "9" riece-command-switch-to-channel-by-number-9
  79     "0" riece-command-switch-to-channel-by-number-10
  80     ,(concat riece-command-prefix "1")
  81     riece-command-switch-to-channel-by-number-11
  82     ,(concat riece-command-prefix "2")
  83     riece-command-switch-to-channel-by-number-12
  84     ,(concat riece-command-prefix "3")
  85     riece-command-switch-to-channel-by-number-13
  86     ,(concat riece-command-prefix "4")
  87     riece-command-switch-to-channel-by-number-14
  88     ,(concat riece-command-prefix "5")
  89     riece-command-switch-to-channel-by-number-15
  90     ,(concat riece-command-prefix "6")
  91     riece-command-switch-to-channel-by-number-16
  92     ,(concat riece-command-prefix "7")
  93     riece-command-switch-to-channel-by-number-17
  94     ,(concat riece-command-prefix "8")
  95     riece-command-switch-to-channel-by-number-18
  96     ,(concat riece-command-prefix "9")
  97     riece-command-switch-to-channel-by-number-19
  98     ,(concat riece-command-prefix "0")
  99     riece-command-switch-to-channel-by-number-20))
 100
 101 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
 102 (defmacro riece-local-set-keys (&rest plist)
 103   "Set the keys in PLIST in the current keymap."
 104   `(riece-define-keys-1 (current-local-map) ',plist))
 105
 106 (defmacro riece-define-keys (keymap &rest plist)
 107   "Assign KEYMAP keys from PLIST."
 108   `(riece-define-keys-1 ',keymap ',plist))
 109
 110 (defmacro riece-define-keys-safe (keymap &rest plist)
 111   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 112   `(riece-define-keys-1 ',keymap ',plist t))
 113
 114 (put 'riece-define-keys 'lisp-indent-function 1)
 115 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 116 (put 'riece-local-set-keys 'lisp-indent-function 1)
 117
 118 (defun riece-define-keys-1 (keymap plist &optional safe)
 119   "Assign KEYMAP keys from PLIST.
 120 If optional argument SAFE is nil, overwrite previous definitions."
 121   (unless keymap
 122     (error "Can't set keys in a null keymap"))
 123   (cond
 124    ((symbolp keymap)
 125     (setq keymap (symbol-value keymap)))
 126    ((keymapp keymap))
 127    ((listp keymap)
 128     (set (car keymap) nil)
 129     (define-prefix-command (car keymap))
 130     (define-key (symbol-value (nth 2 keymap))
 131       (if (symbolp (nth 1 keymap))
 132           (symbol-value (nth 1 keymap))
 133         (nth 1 keymap))
 134       (car keymap))
 135     (setq keymap (symbol-value (car keymap)))))
 136   (let (key)
 137     (while plist
 138       (if (symbolp (setq key (car plist)))
 139           (setq key (symbol-value key)))
 140       (setq plist (cdr plist))
 141       (if (or (not safe)
 142               (eq (lookup-key keymap key) 'undefined))
 143           (define-key keymap key (car plist))
 144         (car plist))
 145       (setq plist (cdr plist)))))
 146
 147 (when t
 148   (riece-define-keys riece-dialogue-mode-map
 149     "\177" scroll-down
 150     [delete] scroll-down
 151     [backspace] scroll-down
 152     [return] scroll-up
 153     " " scroll-up
 154     "$" end-of-buffer
 155     "/" riece-command-raw
 156     ">" end-of-buffer
 157     "<" beginning-of-buffer
 158     "^" riece-command-list-addons
 159     "\C-ta" riece-command-toggle-away
 160     "c" riece-command-select-command-buffer
 161     "f" riece-command-finger
 162     "\C-tf" riece-command-toggle-freeze
 163     "\C-to" riece-command-toggle-own-freeze
 164     "\C-tu" riece-command-toggle-user-list-buffer-mode
 165     "\C-tc" riece-command-toggle-channel-buffer-mode
 166     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 167     "\C-tl" riece-command-change-layout
 168     "i" riece-command-invite
 169     "j" riece-command-join
 170     "\C-k" riece-command-kick
 171     "l" riece-command-list
 172     "M" riece-command-change-mode
 173     "n" riece-command-change-nickname
 174     "N" riece-command-names
 175     "o" other-window
 176     "O" riece-command-open-server
 177     "C" riece-command-close-server
 178     "M" riece-command-universal-server-name-argument
 179     "p" riece-command-enter-message-to-user
 180     "q" riece-command-quit
 181     "r" riece-command-configure-windows
 182     "x" riece-command-copy-region
 183     "t" riece-command-topic
 184     "w" riece-command-who)
 185
 186   (riece-define-keys riece-command-mode-map
 187     "\r" riece-command-enter-message
 188     [(control return)] riece-command-enter-message-as-notice
 189     [tab] riece-command-complete-user)
 190
 191   (riece-define-keys (riece-command-map riece-command-prefix
 192                                         riece-command-mode-map)
 193     "\177" riece-command-scroll-down
 194     [delete] riece-command-scroll-down
 195     [backspace] riece-command-scroll-down
 196     " " riece-command-scroll-up
 197     "$" riece-command-end-of-buffer
 198     ">" riece-command-next-channel
 199     "<" riece-command-previous-channel
 200     "\C-j" riece-command-next-channel
 201     "\C-n" riece-command-names
 202     "l" riece-command-list
 203     "\C-m" riece-command-change-mode
 204     "o" riece-command-set-operators
 205     "\C-p" riece-command-part
 206     "r" riece-command-configure-windows
 207     "v" riece-command-set-speakers
 208     "V" riece-version)
 209   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 210
 211   (riece-define-keys riece-user-list-mode-map
 212     "o" riece-command-set-operators
 213     "v" riece-command-set-voices
 214     "f" riece-command-finger
 215     " " riece-command-user-list-scroll-up
 216     "\177" riece-command-user-list-scroll-down
 217     [delete] riece-command-user-list-scroll-down
 218     [backspace] riece-command-user-list-scroll-down
 219     "c" riece-command-select-command-buffer)
 220
 221   (riece-define-keys riece-channel-list-mode-map
 222     ">" riece-command-next-channel
 223     "<" riece-command-previous-channel
 224     "o" other-window
 225     "c" riece-command-select-command-buffer)
 226
 227   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 228   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 229
 230 (defun riece-read-variables-files (&optional file)
 231   "Read variables FILEs."
 232   (or (file-directory-p riece-directory)
 233       (make-directory riece-directory))
 234   (let ((files (if file
 235                    (setq riece-variables-file file
 236                          riece-variables-files (list file))
 237                  riece-variables-files)))
 238     (while files
 239       (condition-case nil
 240           (load (expand-file-name (car files)))
 241         (file-error nil))
 242       (setq files (cdr files)))))
 243
 244 (defvar print-quoted)
 245 (defvar print-escape-multibyte)
 246 (defun riece-save-variables-files ()
 247   "Save current settings to `riece-variables-file'."
 248   (with-temp-file riece-saved-variables-file
 249     (let ((print-quoted t)
 250           (print-readably t)
 251           print-escape-multibyte
 252           print-level
 253           print-length
 254           (variables riece-saved-forms))
 255       (while variables
 256         (prin1 `(setq ,(car variables)
 257                       ',(symbol-value (car variables)))
 258                (current-buffer))
 259         (insert "\n")
 260         (setq variables (cdr variables)))))
 261   (setq riece-save-variables-are-dirty nil))
 262
 263 ;;;###autoload
 264 (defun riece (&optional confirm)
 265   "Connect to the IRC server and start chatting.
 266 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 267   (interactive "P")
 268   (riece-read-variables-files (if noninteractive
 269                                   (car command-line-args-left)))
 270   (run-hooks 'riece-after-load-startup-hook)
 271   (if (riece-server-opened)
 272       (riece-command-configure-windows)
 273     (unless riece-addons-insinuated
 274       (setq riece-addons (riece-resolve-addons riece-addons))
 275       (let ((pointer riece-addons))
 276         (while pointer
 277           (riece-insinuate-addon (car pointer) riece-debug)
 278           (riece-enable-addon (car pointer) riece-debug)
 279           (setq pointer (cdr pointer))))
 280       (setq riece-addons-insinuated t))
 281     (if (or confirm (null riece-server))
 282         (setq riece-server (completing-read "Server: " riece-server-alist)))
 283     (if (stringp riece-server)
 284         (setq riece-server (riece-server-name-to-server riece-server)))
 285     (riece-create-buffers)
 286     (if riece-max-buffer-size
 287         (setq riece-shrink-buffer-idle-timer
 288               (riece-run-with-idle-timer
 289                riece-shrink-buffer-idle-time-delay t
 290                (lambda ()
 291                  (let ((buffers riece-buffer-list))
 292                    (while buffers
 293                      (if (eq (derived-mode-class
 294                               (with-current-buffer (car buffers)
 295                                 major-mode))
 296                              'riece-dialogue-mode)
 297                          (riece-shrink-buffer (car buffers)))
 298                      (setq buffers (cdr buffers))))))))
 299     (switch-to-buffer riece-command-buffer)
 300     (riece-display-connect-signals)
 301     (riece-redisplay-buffers)
 302     (riece-open-server riece-server "")
 303     (let ((server-list riece-startup-server-list))
 304       (while server-list
 305         (riece-command-open-server (car server-list))
 306         (setq server-list (cdr server-list))))
 307     (run-hooks 'riece-startup-hook)
 308     (message "%s" (substitute-command-keys
 309                    "Type \\[describe-mode] for help"))))
 310
 311 (defun riece-shrink-buffer (buffer)
 312   (save-excursion
 313     (set-buffer buffer)
 314     (goto-char (point-min))
 315     (while (> (buffer-size) riece-max-buffer-size)
 316       (let* ((inhibit-read-only t)
 317              buffer-read-only
 318              (start (point))
 319              (end (progn (beginning-of-line 2) (point)))
 320              (overlays (riece-overlays-in start end)))
 321         (while overlays
 322           (riece-delete-overlay (car overlays))
 323           (setq overlays (cdr overlays)))
 324         (delete-region start end)))))
 325
 326 (defun riece-exit ()
 327   (if riece-save-variables-are-dirty
 328       (riece-save-variables-files))
 329   (while riece-buffer-list
 330     (if (and (get-buffer (car riece-buffer-list))
 331              (buffer-live-p (car riece-buffer-list)))
 332         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 333     (setq riece-buffer-list (cdr riece-buffer-list)))
 334   (if riece-shrink-buffer-idle-timer
 335       (riece-cancel-timer riece-shrink-buffer-idle-timer))
 336   (setq riece-server nil
 337         riece-current-channels nil
 338         riece-current-channel nil
 339         riece-channel-buffer nil
 340         riece-channel-buffer-alist nil
 341         riece-user-indicator nil
 342         riece-long-channel-indicator "None"
 343         riece-channel-list-indicator "No channel"
 344         riece-away-indicator "-"
 345         riece-operator-indicator "-"
 346         riece-freeze-indicator "-")
 347   (delete-other-windows)
 348   (run-hooks 'riece-exit-hook))
 349
 350 (defun riece-command-mode ()
 351   "Major mode for Riece.  Normal edit function are available.
 352 Typing Return or Linefeed enters the current line in the dialogue.
 353 The following special commands are available:
 354 For a list of the generic commands type \\[riece-command-generic] ? RET.
 355 \\{riece-command-mode-map}"
 356   (interactive)
 357   (kill-all-local-variables)
 358
 359   (setq riece-away-indicator "-"
 360         riece-operator-indicator "-"
 361         major-mode 'riece-command-mode
 362         mode-name "Command"
 363         mode-line-buffer-identification
 364         (riece-mode-line-buffer-identification
 365          '("Riece: "
 366            riece-away-indicator
 367            riece-operator-indicator
 368            " "
 369            riece-user-indicator
 370            " "
 371            riece-channel-indicator)))
 372   (riece-simplify-mode-line-format)
 373   (use-local-map riece-command-mode-map)
 374
 375   (unless riece-command-mode-syntax-table
 376     (setq riece-command-mode-syntax-table
 377           (copy-syntax-table (syntax-table)))
 378     (set-syntax-table riece-command-mode-syntax-table)
 379     (mapcar
 380      (lambda (c) (modify-syntax-entry c "w"))
 381      "^[]{}'`"))
 382
 383   (run-hooks 'riece-command-mode-hook))
 384
 385 (defun riece-dialogue-mode ()
 386   "Major mode for displaying the IRC dialogue.
 387 All normal editing commands are turned off.
 388 Instead, these commands are available:
 389 \\{riece-dialogue-mode-map}"
 390   (kill-all-local-variables)
 391   (make-local-variable 'riece-freeze)
 392   (make-local-variable 'riece-freeze-indicator)
 393   (setq riece-freeze riece-default-freeze
 394         riece-away-indicator "-"
 395         riece-operator-indicator "-"
 396         major-mode 'riece-dialogue-mode
 397         mode-name "Dialogue"
 398         mode-line-buffer-identification
 399         (riece-mode-line-buffer-identification
 400          '("Riece: "
 401            riece-away-indicator
 402            riece-operator-indicator
 403            riece-freeze-indicator
 404            " "
 405            riece-channel-list-indicator " "))
 406         buffer-read-only t)
 407   (riece-simplify-mode-line-format)
 408   (use-local-map riece-dialogue-mode-map)
 409   (buffer-disable-undo)
 410   (run-hooks 'riece-dialogue-mode-hook))
 411
 412 (define-derived-mode riece-others-mode riece-dialogue-mode
 413   "Others"
 414   "Major mode for displaying the IRC others message except current channel.
 415 All normal editing commands are turned off.
 416 Instead, these commands are available:
 417 \\{riece-others-mode-map}")
 418
 419 (define-derived-mode riece-channel-mode riece-dialogue-mode
 420   "Channel"
 421   "Major mode for displaying the IRC current channel buffer.
 422 All normal editing commands are turned off.
 423 Instead, these commands are available:
 424 \\{riece-channel-mode-map}"
 425   (setq mode-line-buffer-identification
 426         (riece-mode-line-buffer-identification
 427          '("Riece: "
 428            riece-away-indicator
 429            riece-operator-indicator
 430            riece-freeze-indicator
 431            " "
 432            riece-long-channel-indicator))))
 433
 434 (defun riece-channel-list-mode ()
 435   "Major mode for displaying channel list.
 436 All normal editing commands are turned off."
 437   (kill-all-local-variables)
 438   (buffer-disable-undo)
 439   (setq major-mode 'riece-channel-list-mode
 440         mode-name "Channels"
 441         mode-line-buffer-identification
 442         (riece-mode-line-buffer-identification '("Riece: "))
 443         truncate-lines t
 444         buffer-read-only t)
 445   (make-local-hook 'riece-update-buffer-functions)
 446   (add-hook 'riece-update-buffer-functions
 447             'riece-update-channel-list-buffer nil t)
 448   (use-local-map riece-channel-list-mode-map)
 449   (run-hooks 'riece-channel-list-mode-hook))
 450
 451 (defun riece-user-list-mode ()
 452   "Major mode for displaying members in the IRC current channel buffer.
 453 All normal editing commands are turned off.
 454 Instead, these commands are available:
 455 \\{riece-user-list-mode-map}"
 456   (kill-all-local-variables)
 457   (buffer-disable-undo)
 458   (setq major-mode 'riece-user-list-mode
 459         mode-name "Users"
 460         mode-line-buffer-identification
 461         (riece-mode-line-buffer-identification
 462          '("Riece: " riece-long-channel-indicator " "))
 463         truncate-lines t
 464         buffer-read-only t)
 465   (if (boundp 'transient-mark-mode)
 466       (set (make-local-variable 'transient-mark-mode) t))
 467   (make-local-hook 'riece-update-buffer-functions)
 468   (add-hook 'riece-update-buffer-functions
 469             'riece-update-user-list-buffer nil t)
 470   (use-local-map riece-user-list-mode-map)
 471   (run-hooks 'riece-user-list-mode-hook))
 472
 473 (defun riece-create-buffers ()
 474   (let ((alist riece-buffer-alist))
 475     (while alist
 476       (save-excursion
 477         (set-buffer (apply #'riece-get-buffer-create
 478                            (cdr (car alist))))
 479         (set (car (car alist)) (current-buffer))
 480         (unless (or (null (nth 2 (car alist)))
 481                     (eq major-mode (nth 2 (car alist))))
 482           (funcall (nth 2 (car alist))))
 483         (setq alist (cdr alist))))))
 484
 485 (provide 'riece)
 486
 487 ;;; riece.el ends here