cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'riece-inlines))
  28
  29 (if (featurep 'xemacs)
  30     (require 'riece-xemacs)
  31   (require 'riece-emacs))
  32
  33 (require 'riece-filter)
  34 (require 'riece-display)
  35 (require 'riece-server)
  36 (require 'riece-compat)
  37 (require 'riece-commands)
  38
  39 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  40 (defvar riece-user-list-mode-map (make-sparse-keymap))
  41
  42 (defvar riece-dialogue-mode-map
  43   (let ((keymap (make-keymap)))
  44     (suppress-keymap keymap 'nodigit)
  45     keymap))
  46
  47 (defvar riece-command-mode-map (make-keymap))
  48 (defvar riece-command-map (make-sparse-keymap))
  49
  50 (defvar riece-command-mode-syntax-table nil)
  51
  52 (put 'riece-command-mode 'mode-class 'special)
  53 (put 'riece-dialogue-mode 'mode-class 'special)
  54 (put 'riece-channel-list-mode 'mode-class 'special)
  55 (put 'riece-user-list-mode 'mode-class 'special)
  56 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  57 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  58
  59 (defvar riece-buffer-mode-alist
  60   '((riece-dialogue-buffer . riece-dialogue-mode)
  61     (riece-others-buffer . riece-others-mode)
  62     (riece-channel-list-buffer . riece-channel-list-mode)
  63     (riece-private-buffer . riece-dialogue-mode)
  64     (riece-wallops-buffer)))
  65
  66 (defvar riece-select-keys
  67   '("1" riece-command-switch-to-channel-by-number-1
  68     "2" riece-command-switch-to-channel-by-number-2
  69     "3" riece-command-switch-to-channel-by-number-3
  70     "4" riece-command-switch-to-channel-by-number-4
  71     "5" riece-command-switch-to-channel-by-number-5
  72     "6" riece-command-switch-to-channel-by-number-6
  73     "7" riece-command-switch-to-channel-by-number-7
  74     "8" riece-command-switch-to-channel-by-number-8
  75     "9" riece-command-switch-to-channel-by-number-9
  76     "0" riece-command-switch-to-channel-by-number-10
  77     "\C-c1" riece-command-switch-to-channel-by-number-11
  78     "\C-c2" riece-command-switch-to-channel-by-number-12
  79     "\C-c3" riece-command-switch-to-channel-by-number-13
  80     "\C-c4" riece-command-switch-to-channel-by-number-14
  81     "\C-c5" riece-command-switch-to-channel-by-number-15
  82     "\C-c6" riece-command-switch-to-channel-by-number-16
  83     "\C-c7" riece-command-switch-to-channel-by-number-17
  84     "\C-c8" riece-command-switch-to-channel-by-number-18
  85     "\C-c9" riece-command-switch-to-channel-by-number-19
  86     "\C-c0" riece-command-switch-to-channel-by-number-20))
  87
  88 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  89 (defmacro riece-local-set-keys (&rest plist)
  90   "Set the keys in PLIST in the current keymap."
  91   `(riece-define-keys-1 (current-local-map) ',plist))
  92
  93 (defmacro riece-define-keys (keymap &rest plist)
  94   "Assign KEYMAP keys from PLIST."
  95   `(riece-define-keys-1 ',keymap ',plist))
  96
  97 (defmacro riece-define-keys-safe (keymap &rest plist)
  98   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
  99   `(riece-define-keys-1 ',keymap ',plist t))
 100
 101 (put 'riece-define-keys 'lisp-indent-function 1)
 102 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 103 (put 'riece-local-set-keys 'lisp-indent-function 1)
 104
 105 (defun riece-define-keys-1 (keymap plist &optional safe)
 106   "Assign KEYMAP keys from PLIST.
 107 If optional argument SAFE is nil, overwrite previous definitions."
 108   (unless keymap
 109     (error "Can't set keys in a null keymap"))
 110   (cond
 111    ((symbolp keymap)
 112     (setq keymap (symbol-value keymap)))
 113    ((keymapp keymap))
 114    ((listp keymap)
 115     (set (car keymap) nil)
 116     (define-prefix-command (car keymap))
 117     (define-key (symbol-value (nth 2 keymap)) (nth 1 keymap) (car keymap))
 118     (setq keymap (symbol-value (car keymap)))))
 119   (let (key)
 120     (while plist
 121       (if (symbolp (setq key (car plist)))
 122           (setq key (symbol-value key)))
 123       (setq plist (cdr plist))
 124       (if (or (not safe)
 125               (eq (lookup-key keymap key) 'undefined))
 126           (define-key keymap key (car plist))
 127         (car plist))
 128       (setq plist (cdr plist)))))
 129
 130 (when t
 131   (riece-define-keys riece-dialogue-mode-map
 132     "\177" scroll-down
 133     [delete] scroll-down
 134     [backspace] scroll-down
 135     [return] scroll-up
 136     " " scroll-up
 137     "$" end-of-buffer
 138     "/" riece-command-raw
 139     ">" end-of-buffer
 140     "<" beginning-of-buffer
 141     "\C-ta" riece-command-toggle-away
 142     "c" riece-command-select-command-buffer
 143     "f" riece-command-finger
 144     "\C-tf" riece-command-toggle-freeze
 145     "\C-to" riece-command-toggle-own-freeze
 146     "\C-tu" riece-command-toggle-user-list-buffer-mode
 147     "\C-tc" riece-command-toggle-channel-buffer-mode
 148     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 149     "i" riece-command-invite
 150     "j" riece-command-join
 151     "\C-k" riece-command-kick
 152     "l" riece-command-list
 153     "m" riece-dialogue-enter-message
 154     "M" riece-command-change-mode
 155     "n" riece-command-change-nickname
 156     "\C-n" riece-command-names
 157     "o" other-window
 158     "O" riece-command-open-server
 159     "C" riece-command-close-server
 160     "M" riece-command-universal-server-name-argument
 161     "q" riece-command-quit
 162     "r" riece-command-configure-windows
 163     "x" riece-command-copy-region
 164     "t" riece-command-topic
 165     "w" riece-command-who)
 166
 167   (riece-define-keys riece-command-mode-map
 168     "\r" riece-command-enter-message
 169     [tab] riece-command-complete
 170     [(meta control c) >] riece-command-push
 171     [(meta control c) <] riece-command-pop)
 172
 173   (riece-define-keys (riece-command-map "\C-c" riece-command-mode-map)
 174     "\177" riece-command-scroll-down
 175     [delete] riece-command-scroll-down
 176     [backspace] riece-command-scroll-down
 177     " " riece-command-scroll-up
 178     "$" riece-command-end-of-buffer
 179     ">" riece-command-next-channel
 180     "<" riece-command-previous-channel
 181     "\C-j" riece-command-next-channel
 182     "\C-n" riece-command-names
 183     "l" riece-command-list
 184     "\C-m" riece-command-change-mode
 185     "o" riece-command-set-operators
 186     "\C-p" riece-command-part
 187     "r" riece-command-configure-windows
 188     "v" riece-command-set-voices)
 189   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 190
 191   (riece-define-keys riece-user-list-mode-map
 192     "o" riece-command-set-operators
 193     "v" riece-command-set-voices
 194     "f" riece-command-finger
 195     " " riece-command-nick-scroll-up
 196     "\177" riece-command-nick-scroll-down
 197     [delete] riece-command-nick-scroll-down
 198     [backspace] riece-command-nick-scroll-down
 199     "c" riece-command-select-command-buffer)
 200
 201   (riece-define-keys riece-channel-list-mode-map
 202     ">" riece-command-next-channel
 203     "<" riece-command-previous-channel
 204     "u" riece-command-unread-channel
 205     "o" other-window
 206     "c" riece-command-select-command-buffer)
 207
 208   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 209   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 210
 211 (defun riece-read-variables-files (&optional file)
 212   "Read variables FILEs."
 213   (or (file-directory-p riece-directory)
 214       (make-directory riece-directory))
 215   (let ((files (if file
 216                    (setq riece-variables-file file
 217                          riece-variables-files (list file))
 218                  riece-variables-files)))
 219     (while files
 220       (condition-case nil
 221           (load (expand-file-name (car files)))
 222         (file-error nil))
 223       (setq files (cdr files)))))
 224
 225 (defvar print-quoted)
 226 (defvar print-escape-multibyte)
 227 (defun riece-save-variables-files ()
 228   "Save current settings to `riece-variables-file'."
 229   (with-temp-file riece-saved-variables-file
 230     (let ((print-quoted t)
 231           (print-readably t)
 232           print-escape-multibyte
 233           print-level
 234           print-length
 235           (variables riece-saved-forms))
 236       (while variables
 237         (prin1 `(setq ,(car variables)
 238                       ',(symbol-value (car variables)))
 239                (current-buffer))
 240         (insert "\n")
 241         (setq variables (cdr variables)))))
 242   (setq riece-save-variables-are-dirty nil))
 243
 244 ;;;###autoload
 245 (defun riece (&optional confirm)
 246   "Connect to the IRC server and start chatting.
 247 If optional argument CONFIRM is non-nil, ask which IRC server to connect.
 248 If already connected, just pop up the windows."
 249   (interactive "P")
 250   (riece-read-variables-files (if noninteractive
 251                                   (car command-line-args-left)))
 252   (riece-insinuate-addons riece-addons)
 253   (run-hooks 'riece-after-load-startup-hook)
 254   (if (riece-server-opened)
 255       (riece-configure-windows)
 256     (switch-to-buffer (riece-get-buffer-create riece-command-buffer))
 257     (unless (eq major-mode 'riece-command-mode)
 258       (riece-command-mode))
 259     (if (or confirm (null riece-server))
 260         (setq riece-server (completing-read "Server: " riece-server-alist)))
 261     (if (stringp riece-server)
 262         (setq riece-server (riece-server-name-to-server riece-server)))
 263     (setq riece-server-process (riece-start-server riece-server))
 264     (riece-create-buffers)
 265     (riece-configure-windows)
 266     (let ((channel-list riece-startup-channel-list))
 267       (while channel-list
 268         (if (listp (car channel-list))
 269             (riece-command-join (car (car channel-list))
 270                                 (cadr (car channel-list)))
 271           (riece-command-join (car channel-list)))
 272         (setq channel-list (cdr channel-list))))
 273     (run-hooks 'riece-startup-hook)
 274     (message "%s" (substitute-command-keys
 275                    "Type \\[describe-mode] for help"))))
 276
 277 (defun riece-exit ()
 278   (setq riece-server nil)
 279   (if riece-save-variables-are-dirty
 280       (riece-save-variables-files))
 281   (riece-clear-system)
 282   (run-hooks 'riece-exit-hook))
 283
 284 (defun riece-command-mode ()
 285   "Major mode for Riece.  Normal edit function are available.
 286 Typing Return or Linefeed enters the current line in the dialogue.
 287 The following special commands are available:
 288 For a list of the generic commands type \\[riece-command-generic] ? RET.
 289 \\{riece-command-mode-map}"
 290   (interactive)
 291   (kill-all-local-variables)
 292
 293   (setq major-mode 'riece-command-mode
 294         mode-name "Commands"
 295         riece-away-indicator "-"
 296         riece-freeze-indicator "-"
 297         riece-own-freeze-indicator "-"
 298         mode-line-buffer-identification
 299         (riece-mode-line-buffer-identification
 300          '("Riece: "
 301            mode-line-modified
 302            riece-away-indicator
 303            "-- " riece-current-channel " " riece-real-nickname)))
 304   (riece-simplify-mode-line-format)
 305   (use-local-map riece-command-mode-map)
 306
 307   (unless riece-command-mode-syntax-table
 308     (setq riece-command-mode-syntax-table
 309           (copy-syntax-table (syntax-table)))
 310     (set-syntax-table riece-command-mode-syntax-table)
 311     (mapcar
 312      (lambda (c) (modify-syntax-entry c "w"))
 313      "^[]{}'`"))
 314
 315   (run-hooks 'riece-command-mode-hook))
 316
 317 (defun riece-dialogue-mode ()
 318   "Major mode for displaying the IRC dialogue.
 319 All normal editing commands are turned off.
 320 Instead, these commands are available:
 321 \\{riece-dialogue-mode-map}"
 322   (kill-all-local-variables)
 323
 324   (make-local-variable 'riece-freeze)
 325   (make-local-variable 'riece-freeze-indicator)
 326   (make-local-variable 'riece-own-freeze)
 327   (make-local-variable 'riece-own-freeze-indicator)
 328   (make-local-variable 'tab-stop-list)
 329
 330   (setq riece-freeze riece-default-freeze
 331         riece-freeze-indicator (if riece-freeze "F" "-")
 332         riece-own-freeze riece-default-own-freeze
 333         riece-own-freeze-indicator (if riece-own-freeze "M" "-")
 334
 335         major-mode 'riece-dialogue-mode
 336         mode-name "Dialogue"
 337         mode-line-buffer-identification
 338         (riece-mode-line-buffer-identification
 339          '("Riece: "
 340            mode-line-modified
 341            riece-away-indicator
 342            riece-freeze-indicator
 343            riece-own-freeze-indicator
 344            " " riece-channel-list-indicator " "))
 345         buffer-read-only t
 346         tab-stop-list riece-tab-stop-list)
 347   (riece-simplify-mode-line-format)
 348   (use-local-map riece-dialogue-mode-map)
 349   (buffer-disable-undo)
 350   (run-hooks 'riece-dialogue-mode-hook))
 351
 352 (define-derived-mode riece-others-mode riece-dialogue-mode
 353   "Others"
 354   "Major mode for displaying the IRC others message except current channel.
 355 All normal editing commands are turned off.
 356 Instead, these commands are available:
 357 \\{riece-others-mode-map}")
 358
 359 (define-derived-mode riece-channel-mode riece-dialogue-mode
 360   "Channel"
 361   "Major mode for displaying the IRC current channel buffer.
 362 All normal editing commands are turned off.
 363 Instead, these commands are available:
 364 \\{riece-channel-mode-map}"
 365   (setq mode-line-buffer-identification
 366         (riece-mode-line-buffer-identification
 367          '("Riece: "
 368            mode-line-modified
 369            riece-away-indicator
 370            riece-freeze-indicator
 371            riece-own-freeze-indicator
 372            " "
 373            riece-channel-indicator))))
 374
 375 (defun riece-channel-list-mode ()
 376   "Major mode for displaying channel list.
 377 All normal editing commands are turned off."
 378   (kill-all-local-variables)
 379   (setq major-mode 'riece-channel-list-mode
 380         mode-name "Channels"
 381         mode-line-buffer-identification
 382         (riece-mode-line-buffer-identification '("Riece: "))
 383         truncate-lines t
 384         buffer-read-only t)
 385   (use-local-map riece-channel-list-mode-map)
 386   (run-hooks 'riece-channel-list-mode-hook))
 387
 388 (defun riece-user-list-mode ()
 389   "Major mode for displaying members in the IRC current channel buffer.
 390 All normal editing commands are turned off.
 391 Instead, these commands are available:
 392 \\{riece-user-list-mode-map}"
 393   (kill-all-local-variables)
 394   (setq mode-line-modified "--- "
 395         major-mode 'riece-user-list-mode
 396         mode-name "Riece Channel member"
 397         mode-line-buffer-identification
 398         (riece-mode-line-buffer-identification
 399          '("Riece: " riece-channel-indicator " "))
 400         truncate-lines t
 401         buffer-read-only t)
 402   (if (boundp 'transient-mark-mode)
 403       (set (make-local-variable 'transient-mark-mode) t))
 404   (use-local-map riece-user-list-mode-map)
 405   (run-hooks 'riece-user-list-mode-hook))
 406
 407 (defun riece-create-buffers ()
 408   (let ((alist riece-buffer-mode-alist))
 409     (while alist
 410       (save-excursion
 411         (set-buffer (riece-get-buffer-create
 412                      (symbol-value (car (car alist)))))
 413         (unless (or (null (cdr (car alist)))
 414                     (eq major-mode (cdr (car alist))))
 415           (funcall (cdr (car alist))))
 416         (setq alist (cdr alist))))))
 417
 418 (defun riece-load-and-build-addon-dependencies (addons)
 419   (let ((load-path (cons riece-addon-directory load-path))
 420         dependencies)
 421     (while addons
 422       (require (car addons))            ;error will be reported here
 423       (let* ((requires
 424               (funcall (or (intern-soft (concat (symbol-name (car addons))
 425                                                 "-requires"))
 426                            #'ignore)))
 427              (pointer requires)
 428              entry)
 429         (while pointer
 430           (if (setq entry (assq (car pointer) dependencies))
 431               (setcar (cdr entry) (1+ (nth 1 entry)))
 432             (setq dependencies (cons (list (car pointer) 1 nil)
 433                                      dependencies)))
 434           (setq pointer (cdr pointer)))
 435         (if (setq entry (assq (car addons) dependencies))
 436             (setcar (nthcdr 2 entry) requires)
 437           (setq dependencies (cons (list (car addons) 0 requires)
 438                                    dependencies))))
 439       (setq addons (cdr addons)))
 440     dependencies))
 441
 442 (defun riece-insinuate-addons (addons)
 443   (let* ((dependencies (riece-load-and-build-addon-dependencies addons))
 444          (pointer dependencies)
 445          queue)
 446     (while pointer
 447       (if (zerop (nth 1 (car pointer)))
 448           (setq dependencies (delq (car pointer) dependencies)
 449                 queue (cons (car pointer) queue)))
 450       (setq pointer (cdr pointer)))
 451     (setq addons nil)
 452     (while queue
 453       (setq addons (cons (car (car queue)) addons)
 454             pointer (nth 2 (car queue)))
 455       (while pointer
 456         (let* ((entry (assq (car pointer) dependencies))
 457                (count (1- (nth 1 entry))))
 458           (if (zerop count)
 459               (progn
 460                 (setq dependencies (delq entry dependencies)
 461                       queue (nconc queue (list entry))))
 462             (setcar (cdr entry) count)))
 463         (setq pointer (cdr pointer)))
 464       (setq queue (cdr queue)))
 465     (if dependencies
 466         (error "Circular dependency found"))
 467     (while addons
 468       (require (car addons))            ;implicit dependency
 469       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 470       (setq addons (cdr addons)))))
 471
 472 (provide 'riece)
 473
 474 ;;; riece.el ends here