cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'riece-inlines))
  28
  29 (if (featurep 'xemacs)
  30     (require 'riece-xemacs)
  31   (require 'riece-emacs))
  32
  33 (require 'riece-filter)
  34 (require 'riece-highlight)
  35 (require 'riece-display)
  36 (require 'riece-server)
  37 (require 'riece-compat)
  38 (require 'riece-commands)
  39
  40 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  41 (defvar riece-user-list-mode-map (make-sparse-keymap))
  42
  43 (defvar riece-dialogue-mode-map
  44   (let ((keymap (make-keymap)))
  45     (suppress-keymap keymap 'nodigit)
  46     keymap))
  47
  48 (defvar riece-command-mode-map (make-keymap))
  49 (defvar riece-command-map (make-sparse-keymap))
  50
  51 (defvar riece-command-mode-syntax-table nil)
  52
  53 (put 'riece-command-mode 'mode-class 'special)
  54 (put 'riece-dialogue-mode 'mode-class 'special)
  55 (put 'riece-channel-list-mode 'mode-class 'special)
  56 (put 'riece-user-list-mode 'mode-class 'special)
  57 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  58 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  59
  60 (defvar riece-buffer-mode-alist
  61   '((riece-dialogue-buffer . riece-dialogue-mode)
  62     (riece-others-buffer . riece-others-mode)
  63     (riece-channel-list-buffer . riece-channel-list-mode)
  64     (riece-private-buffer . riece-dialogue-mode)
  65     (riece-wallops-buffer)))
  66
  67 (defvar riece-select-keys
  68   '("1" riece-command-switch-to-channel-by-number-1
  69     "2" riece-command-switch-to-channel-by-number-2
  70     "3" riece-command-switch-to-channel-by-number-3
  71     "4" riece-command-switch-to-channel-by-number-4
  72     "5" riece-command-switch-to-channel-by-number-5
  73     "6" riece-command-switch-to-channel-by-number-6
  74     "7" riece-command-switch-to-channel-by-number-7
  75     "8" riece-command-switch-to-channel-by-number-8
  76     "9" riece-command-switch-to-channel-by-number-9
  77     "0" riece-command-switch-to-channel-by-number-10
  78     "\C-c1" riece-command-switch-to-channel-by-number-11
  79     "\C-c2" riece-command-switch-to-channel-by-number-12
  80     "\C-c3" riece-command-switch-to-channel-by-number-13
  81     "\C-c4" riece-command-switch-to-channel-by-number-14
  82     "\C-c5" riece-command-switch-to-channel-by-number-15
  83     "\C-c6" riece-command-switch-to-channel-by-number-16
  84     "\C-c7" riece-command-switch-to-channel-by-number-17
  85     "\C-c8" riece-command-switch-to-channel-by-number-18
  86     "\C-c9" riece-command-switch-to-channel-by-number-19
  87     "\C-c0" riece-command-switch-to-channel-by-number-20))
  88
  89 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  90 (defmacro riece-local-set-keys (&rest plist)
  91   "Set the keys in PLIST in the current keymap."
  92   `(riece-define-keys-1 (current-local-map) ',plist))
  93
  94 (defmacro riece-define-keys (keymap &rest plist)
  95   "Assign KEYMAP keys from PLIST."
  96   `(riece-define-keys-1 ',keymap ',plist))
  97
  98 (defmacro riece-define-keys-safe (keymap &rest plist)
  99   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 100   `(riece-define-keys-1 ',keymap ',plist t))
 101
 102 (put 'riece-define-keys 'lisp-indent-function 1)
 103 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 104 (put 'riece-local-set-keys 'lisp-indent-function 1)
 105
 106 (defun riece-define-keys-1 (keymap plist &optional safe)
 107   "Assign KEYMAP keys from PLIST.
 108 If optional argument SAFE is nil, overwrite previous definitions."
 109   (unless keymap
 110     (error "Can't set keys in a null keymap"))
 111   (cond
 112    ((symbolp keymap)
 113     (setq keymap (symbol-value keymap)))
 114    ((keymapp keymap))
 115    ((listp keymap)
 116     (set (car keymap) nil)
 117     (define-prefix-command (car keymap))
 118     (define-key (symbol-value (nth 2 keymap)) (nth 1 keymap) (car keymap))
 119     (setq keymap (symbol-value (car keymap)))))
 120   (let (key)
 121     (while plist
 122       (when (symbolp (setq key (pop plist)))
 123         (setq key (symbol-value key)))
 124       (if (or (not safe)
 125               (eq (lookup-key keymap key) 'undefined))
 126           (define-key keymap key (pop plist))
 127         (pop plist)))))
 128
 129 (when t
 130   (riece-define-keys riece-dialogue-mode-map
 131     "\177" scroll-down
 132     [delete] scroll-down
 133     [backspace] scroll-down
 134     [return] scroll-up
 135     " " scroll-up
 136     "$" end-of-buffer
 137     "/" riece-command-raw
 138     ">" end-of-buffer
 139     "<" beginning-of-buffer
 140     "\C-ta" riece-command-toggle-away
 141     "c" riece-command-select-command-buffer
 142     "f" riece-command-finger
 143     "\C-tf" riece-command-toggle-freeze
 144     "\C-to" riece-command-toggle-own-freeze
 145     "\C-tu" riece-command-toggle-user-list-buffer-mode
 146     "\C-tc" riece-command-toggle-channel-buffer-mode
 147     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 148     "i" riece-command-invite
 149     "j" riece-command-join
 150     "\C-k" riece-command-kick
 151     "l" riece-command-list
 152     "m" riece-dialogue-enter-message
 153     "M" riece-command-change-mode
 154     "n" riece-command-change-nickname
 155     "\C-n" riece-command-names
 156     "o" other-window
 157     "O" riece-command-open-server
 158     "C" riece-command-close-server
 159     "M" riece-command-universal-server-name-argument
 160     "q" riece-command-quit
 161     "r" riece-command-configure-windows
 162     "x" riece-command-copy-region
 163     "t" riece-command-topic
 164     "w" riece-command-who)
 165
 166   (riece-define-keys riece-command-mode-map
 167     "\r" riece-command-enter-message
 168     [tab] riece-command-complete
 169     [(meta control c) >] riece-command-push
 170     [(meta control c) <] riece-command-pop)
 171
 172   (riece-define-keys (riece-command-map "\C-c" riece-command-mode-map)
 173     "\177" riece-command-scroll-down
 174     [delete] riece-command-scroll-down
 175     [backspace] riece-command-scroll-down
 176     " " riece-command-scroll-up
 177     "$" riece-command-end-of-buffer
 178     ">" riece-command-next-channel
 179     "<" riece-command-previous-channel
 180     "\C-j" riece-command-next-channel
 181     "\C-n" riece-command-names
 182     "l" riece-command-list
 183     "\C-m" riece-command-change-mode
 184     "o" riece-command-set-operators
 185     "\C-p" riece-command-part
 186     "r" riece-command-configure-windows
 187     "v" riece-command-set-voices)
 188   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 189
 190   (riece-define-keys riece-user-list-mode-map
 191     "o" riece-command-set-operators
 192     "v" riece-command-set-voices
 193     "f" riece-command-finger
 194     " " riece-command-nick-scroll-up
 195     "\177" riece-command-nick-scroll-down
 196     [delete] riece-command-nick-scroll-down
 197     [backspace] riece-command-nick-scroll-down
 198     "c" riece-command-select-command-buffer)
 199
 200   (riece-define-keys riece-channel-list-mode-map
 201     ">" riece-command-next-channel
 202     "<" riece-command-previous-channel
 203     "u" riece-command-unread-channel
 204     "o" other-window
 205     "c" riece-command-select-command-buffer)
 206
 207   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 208   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 209
 210 (defun riece-read-variables-files (&optional file)
 211   "Read variables FILEs."
 212   (or (file-directory-p riece-directory)
 213       (make-directory riece-directory))
 214   (let ((files (if file
 215                    (setq riece-variables-file file
 216                          riece-variables-files (list file))
 217                  riece-variables-files)))
 218     (while files
 219       (condition-case nil
 220           (load (expand-file-name (car files)))
 221         (file-error nil))
 222       (setq files (cdr files)))))
 223
 224 (defvar print-quoted)
 225 (defvar print-escape-multibyte)
 226 (defun riece-save-variables-files ()
 227   "Save current settings to `riece-variables-file'."
 228   (with-temp-file riece-saved-variables-file
 229     (let ((print-quoted t)
 230           (print-readably t)
 231           print-escape-multibyte
 232           print-level
 233           print-length
 234           (variables riece-saved-forms))
 235       (while variables
 236         (prin1 `(setq ,(car variables)
 237                       ',(symbol-value (car variables)))
 238                (current-buffer))
 239         (insert "\n")
 240         (setq variables (cdr variables)))))
 241   (setq riece-save-variables-are-dirty nil))
 242
 243 ;;;###autoload
 244 (defun riece (&optional confirm)
 245   "Connect to the IRC server and start chatting.
 246 If optional argument CONFIRM is non-nil, ask which IRC server to connect.
 247 If already connected, just pop up the windows."
 248   (interactive "P")
 249   (riece-read-variables-files (if noninteractive
 250                                   (car command-line-args-left)))
 251   (riece-insinuate-addons riece-addons)
 252   (run-hooks 'riece-after-load-startup-hook)
 253   (if (riece-server-opened)
 254       (riece-configure-windows)
 255     (switch-to-buffer (riece-get-buffer-create riece-command-buffer))
 256     (unless (eq major-mode 'riece-command-mode)
 257       (riece-command-mode))
 258     (if (or confirm (null riece-server))
 259         (setq riece-server (completing-read "Server: " riece-server-alist)))
 260     (if (stringp riece-server)
 261         (setq riece-server (riece-server-name-to-server riece-server)))
 262     (setq riece-server-process (riece-start-server riece-server))
 263     (riece-create-buffers)
 264     (riece-configure-windows)
 265     (let ((channel-list riece-startup-channel-list))
 266       (while channel-list
 267         (if (listp (car channel-list))
 268             (riece-command-join (car (car channel-list))
 269                                 (cadr (car channel-list)))
 270           (riece-command-join (car channel-list)))
 271         (setq channel-list (cdr channel-list))))
 272     (run-hooks 'riece-startup-hook)
 273     (message "%s" (substitute-command-keys
 274                    "Type \\[describe-mode] for help"))))
 275
 276 (defun riece-exit ()
 277   (setq riece-server nil)
 278   (if riece-save-variables-are-dirty
 279       (riece-save-variables-files))
 280   (riece-clear-system)
 281   (run-hooks 'riece-exit-hook))
 282
 283 (defun riece-command-mode ()
 284   "Major mode for Riece.  Normal edit function are available.
 285 Typing Return or Linefeed enters the current line in the dialogue.
 286 The following special commands are available:
 287 For a list of the generic commands type \\[riece-command-generic] ? RET.
 288 \\{riece-command-mode-map}"
 289   (interactive)
 290   (kill-all-local-variables)
 291
 292   (setq major-mode 'riece-command-mode
 293         mode-name "Commands"
 294         riece-away-indicator "-"
 295         riece-freeze-indicator "-"
 296         riece-own-freeze-indicator "-"
 297         mode-line-buffer-identification
 298         (riece-mode-line-buffer-identification
 299          '("Riece: "
 300            mode-line-modified
 301            riece-away-indicator
 302            "-- " riece-current-channel " " riece-real-nickname)))
 303   (riece-simplify-mode-line-format)
 304   (use-local-map riece-command-mode-map)
 305
 306   (unless riece-command-mode-syntax-table
 307     (setq riece-command-mode-syntax-table
 308           (copy-syntax-table (syntax-table)))
 309     (set-syntax-table riece-command-mode-syntax-table)
 310     (mapcar
 311      (lambda (c) (modify-syntax-entry c "w"))
 312      "^[]{}'`"))
 313
 314   (run-hooks 'riece-command-mode-hook))
 315
 316 (defun riece-dialogue-mode ()
 317   "Major mode for displaying the IRC dialogue.
 318 All normal editing commands are turned off.
 319 Instead, these commands are available:
 320 \\{riece-dialogue-mode-map}"
 321   (kill-all-local-variables)
 322
 323   (make-local-variable 'riece-freeze)
 324   (make-local-variable 'riece-freeze-indicator)
 325   (make-local-variable 'riece-own-freeze)
 326   (make-local-variable 'riece-own-freeze-indicator)
 327   (make-local-variable 'tab-stop-list)
 328
 329   (setq riece-freeze riece-default-freeze
 330         riece-freeze-indicator (if riece-freeze "F" "-")
 331         riece-own-freeze riece-default-own-freeze
 332         riece-own-freeze-indicator (if riece-own-freeze "M" "-")
 333
 334         major-mode 'riece-dialogue-mode
 335         mode-name "Dialogue"
 336         mode-line-buffer-identification
 337         (riece-mode-line-buffer-identification
 338          '("Riece: "
 339            mode-line-modified
 340            riece-away-indicator
 341            riece-freeze-indicator
 342            riece-own-freeze-indicator
 343            " " riece-channel-list-indicator " "))
 344         buffer-read-only t
 345         tab-stop-list riece-tab-stop-list)
 346   (riece-simplify-mode-line-format)
 347   (use-local-map riece-dialogue-mode-map)
 348   (buffer-disable-undo)
 349   (run-hooks 'riece-dialogue-mode-hook))
 350
 351 (define-derived-mode riece-others-mode riece-dialogue-mode
 352   "Others"
 353   "Major mode for displaying the IRC others message except current channel.
 354 All normal editing commands are turned off.
 355 Instead, these commands are available:
 356 \\{riece-others-mode-map}")
 357
 358 (define-derived-mode riece-channel-mode riece-dialogue-mode
 359   "Channel"
 360   "Major mode for displaying the IRC current channel buffer.
 361 All normal editing commands are turned off.
 362 Instead, these commands are available:
 363 \\{riece-channel-mode-map}"
 364   (setq mode-line-buffer-identification
 365         (riece-mode-line-buffer-identification
 366          '("Riece: "
 367            mode-line-modified
 368            riece-away-indicator
 369            riece-freeze-indicator
 370            riece-own-freeze-indicator
 371            " "
 372            riece-channel-indicator))))
 373
 374 (defun riece-channel-list-mode ()
 375   "Major mode for displaying channel list.
 376 All normal editing commands are turned off."
 377   (kill-all-local-variables)
 378   (setq major-mode 'riece-channel-list-mode
 379         mode-name "Channels"
 380         mode-line-buffer-identification
 381         (riece-mode-line-buffer-identification '("Riece: "))
 382         truncate-lines t
 383         buffer-read-only t)
 384   (use-local-map riece-channel-list-mode-map)
 385   (run-hooks 'riece-channel-list-mode-hook))
 386
 387 (defun riece-user-list-mode ()
 388   "Major mode for displaying members in the IRC current channel buffer.
 389 All normal editing commands are turned off.
 390 Instead, these commands are available:
 391 \\{riece-user-list-mode-map}"
 392   (kill-all-local-variables)
 393   (setq mode-line-modified "--- "
 394         major-mode 'riece-user-list-mode
 395         mode-name "Riece Channel member"
 396         mode-line-buffer-identification
 397         (riece-mode-line-buffer-identification
 398          '("Riece: " riece-channel-indicator " "))
 399         truncate-lines t
 400         buffer-read-only t)
 401   (if (boundp 'transient-mark-mode)
 402       (set (make-local-variable 'transient-mark-mode) t))
 403   (use-local-map riece-user-list-mode-map)
 404   (run-hooks 'riece-user-list-mode-hook))
 405
 406 (defun riece-create-buffers ()
 407   (let ((alist riece-buffer-mode-alist))
 408     (while alist
 409       (save-excursion
 410         (set-buffer (riece-get-buffer-create
 411                      (symbol-value (car (car alist)))))
 412         (unless (or (null (cdr (car alist)))
 413                     (eq major-mode (cdr (car alist))))
 414           (funcall (cdr (car alist))))
 415         (setq alist (cdr alist))))))
 416
 417 (defun riece-load-and-build-addon-dependencies (addons)
 418   (let ((load-path (cons riece-addon-directory load-path))
 419         dependencies)
 420     (while addons
 421       (require (car addons))            ;error will be reported here
 422       (let* ((requires
 423               (funcall (or (intern-soft (concat (symbol-name (car addons))
 424                                                 "-requires"))
 425                            #'ignore)))
 426              (pointer requires)
 427              entry)
 428         (while pointer
 429           (if (setq entry (assq (car pointer) dependencies))
 430               (setcar (cdr entry) (1+ (nth 1 entry)))
 431             (push (list (car pointer) 1 nil) dependencies))
 432           (setq pointer (cdr pointer)))
 433         (if (setq entry (assq (car addons) dependencies))
 434             (setcar (nthcdr 2 entry) requires)
 435           (push (list (car addons) 0 requires) dependencies)))
 436       (setq addons (cdr addons)))
 437     dependencies))
 438
 439 (defun riece-insinuate-addons (addons)
 440   (let* ((dependencies (riece-load-and-build-addon-dependencies addons))
 441          (pointer dependencies)
 442          queue)
 443     (while pointer
 444       (when (zerop (nth 1 (car pointer)))
 445         (setq dependencies (delq (car pointer) dependencies))
 446         (push (car pointer) queue))
 447       (setq pointer (cdr pointer)))
 448     (setq addons nil)
 449     (while queue
 450       (push (car (car queue)) addons)
 451       (setq pointer (nth 2 (car queue)))
 452       (while pointer
 453         (let* ((entry (assq (car pointer) dependencies))
 454                (count (1- (nth 1 entry))))
 455           (if (zerop count)
 456               (progn
 457                 (setq dependencies (delq entry dependencies)
 458                       queue (nconc queue (list entry))))
 459             (setcar (cdr entry) count)))
 460         (setq pointer (cdr pointer)))
 461       (setq queue (cdr queue)))
 462     (if dependencies
 463         (error "Circular dependency found"))
 464     (while addons
 465       (require (car addons))            ;implicit dependency
 466       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 467       (setq addons (cdr addons)))))
 468
 469 (provide 'riece)
 470
 471 ;;; riece.el ends here