cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-filter)
  28 (require 'riece-display)
  29 (require 'riece-server)
  30 (require 'riece-compat)
  31 (require 'riece-commands)
  32
  33 (autoload 'derived-mode-class "derived")
  34
  35 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  36 (defvar riece-user-list-mode-map (make-sparse-keymap))
  37
  38 (defvar riece-dialogue-mode-map
  39   (let ((keymap (make-keymap)))
  40     (suppress-keymap keymap 'nodigit)
  41     keymap))
  42
  43 (defvar riece-command-mode-map (make-keymap))
  44 (defvar riece-command-map (make-sparse-keymap))
  45
  46 (defvar riece-command-mode-syntax-table nil)
  47
  48 (put 'riece-command-mode 'mode-class 'special)
  49 (put 'riece-dialogue-mode 'mode-class 'special)
  50 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  51 (put 'riece-channel-list-mode 'mode-class 'special)
  52 (put 'riece-user-list-mode 'mode-class 'special)
  53 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  54
  55 (defvar riece-buffer-alist
  56   '((riece-command-buffer "*Commands*" riece-command-mode)
  57     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  58     (riece-others-buffer "*Others*" riece-others-mode)
  59     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  60     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
  61
  62 (defvar riece-shrink-buffer-idle-timer nil
  63   "Timer object to periodically shrink channel buffers.")
  64
  65 (defvar riece-select-keys
  66   `("1" riece-command-switch-to-channel-by-number-1
  67     "2" riece-command-switch-to-channel-by-number-2
  68     "3" riece-command-switch-to-channel-by-number-3
  69     "4" riece-command-switch-to-channel-by-number-4
  70     "5" riece-command-switch-to-channel-by-number-5
  71     "6" riece-command-switch-to-channel-by-number-6
  72     "7" riece-command-switch-to-channel-by-number-7
  73     "8" riece-command-switch-to-channel-by-number-8
  74     "9" riece-command-switch-to-channel-by-number-9
  75     "0" riece-command-switch-to-channel-by-number-10
  76     ,(concat riece-command-prefix "1")
  77     riece-command-switch-to-channel-by-number-11
  78     ,(concat riece-command-prefix "2")
  79     riece-command-switch-to-channel-by-number-12
  80     ,(concat riece-command-prefix "3")
  81     riece-command-switch-to-channel-by-number-13
  82     ,(concat riece-command-prefix "4")
  83     riece-command-switch-to-channel-by-number-14
  84     ,(concat riece-command-prefix "5")
  85     riece-command-switch-to-channel-by-number-15
  86     ,(concat riece-command-prefix "6")
  87     riece-command-switch-to-channel-by-number-16
  88     ,(concat riece-command-prefix "7")
  89     riece-command-switch-to-channel-by-number-17
  90     ,(concat riece-command-prefix "8")
  91     riece-command-switch-to-channel-by-number-18
  92     ,(concat riece-command-prefix "9")
  93     riece-command-switch-to-channel-by-number-19
  94     ,(concat riece-command-prefix "0")
  95     riece-command-switch-to-channel-by-number-20))
  96
  97 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  98 (defmacro riece-local-set-keys (&rest plist)
  99   "Set the keys in PLIST in the current keymap."
 100   `(riece-define-keys-1 (current-local-map) ',plist))
 101
 102 (defmacro riece-define-keys (keymap &rest plist)
 103   "Assign KEYMAP keys from PLIST."
 104   `(riece-define-keys-1 ',keymap ',plist))
 105
 106 (defmacro riece-define-keys-safe (keymap &rest plist)
 107   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 108   `(riece-define-keys-1 ',keymap ',plist t))
 109
 110 (put 'riece-define-keys 'lisp-indent-function 1)
 111 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 112 (put 'riece-local-set-keys 'lisp-indent-function 1)
 113
 114 (defun riece-define-keys-1 (keymap plist &optional safe)
 115   "Assign KEYMAP keys from PLIST.
 116 If optional argument SAFE is nil, overwrite previous definitions."
 117   (unless keymap
 118     (error "Can't set keys in a null keymap"))
 119   (cond
 120    ((symbolp keymap)
 121     (setq keymap (symbol-value keymap)))
 122    ((keymapp keymap))
 123    ((listp keymap)
 124     (set (car keymap) nil)
 125     (define-prefix-command (car keymap))
 126     (define-key (symbol-value (nth 2 keymap))
 127       (if (symbolp (nth 1 keymap))
 128           (symbol-value (nth 1 keymap))
 129         (nth 1 keymap))
 130       (car keymap))
 131     (setq keymap (symbol-value (car keymap)))))
 132   (let (key)
 133     (while plist
 134       (if (symbolp (setq key (car plist)))
 135           (setq key (symbol-value key)))
 136       (setq plist (cdr plist))
 137       (if (or (not safe)
 138               (eq (lookup-key keymap key) 'undefined))
 139           (define-key keymap key (car plist))
 140         (car plist))
 141       (setq plist (cdr plist)))))
 142
 143 (when t
 144   (riece-define-keys riece-dialogue-mode-map
 145     "\177" scroll-down
 146     [delete] scroll-down
 147     [backspace] scroll-down
 148     [return] scroll-up
 149     " " scroll-up
 150     "$" end-of-buffer
 151     "/" riece-command-raw
 152     ">" end-of-buffer
 153     "<" beginning-of-buffer
 154     "\C-ta" riece-command-toggle-away
 155     "c" riece-command-select-command-buffer
 156     "f" riece-command-finger
 157     "\C-tf" riece-command-toggle-freeze
 158     "\C-to" riece-command-toggle-own-freeze
 159     "\C-tu" riece-command-toggle-user-list-buffer-mode
 160     "\C-tc" riece-command-toggle-channel-buffer-mode
 161     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 162     "\C-tl" riece-command-change-layout
 163     "i" riece-command-invite
 164     "j" riece-command-join
 165     "\C-k" riece-command-kick
 166     "l" riece-command-list
 167     "M" riece-command-change-mode
 168     "n" riece-command-change-nickname
 169     "N" riece-command-names
 170     "o" other-window
 171     "O" riece-command-open-server
 172     "C" riece-command-close-server
 173     "M" riece-command-universal-server-name-argument
 174     "p" riece-command-enter-message-to-user
 175     "q" riece-command-quit
 176     "r" riece-command-configure-windows
 177     "x" riece-command-copy-region
 178     "t" riece-command-topic
 179     "w" riece-command-who)
 180
 181   (riece-define-keys riece-command-mode-map
 182     "\r" riece-command-enter-message
 183     [(control return)] riece-command-enter-message-as-notice)
 184
 185   (riece-define-keys (riece-command-map riece-command-prefix
 186                                         riece-command-mode-map)
 187     "\177" riece-command-scroll-down
 188     [delete] riece-command-scroll-down
 189     [backspace] riece-command-scroll-down
 190     " " riece-command-scroll-up
 191     "$" riece-command-end-of-buffer
 192     ">" riece-command-next-channel
 193     "<" riece-command-previous-channel
 194     "\C-j" riece-command-next-channel
 195     "\C-n" riece-command-names
 196     "l" riece-command-list
 197     "\C-m" riece-command-change-mode
 198     "o" riece-command-set-operators
 199     "\C-p" riece-command-part
 200     "r" riece-command-configure-windows
 201     "v" riece-command-set-speakers
 202     "V" riece-version)
 203   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 204
 205   (riece-define-keys riece-user-list-mode-map
 206     "o" riece-command-set-operators
 207     "v" riece-command-set-voices
 208     "f" riece-command-finger
 209     " " riece-command-user-list-scroll-up
 210     "\177" riece-command-user-list-scroll-down
 211     [delete] riece-command-user-list-scroll-down
 212     [backspace] riece-command-user-list-scroll-down
 213     "c" riece-command-select-command-buffer)
 214
 215   (riece-define-keys riece-channel-list-mode-map
 216     ">" riece-command-next-channel
 217     "<" riece-command-previous-channel
 218     "o" other-window
 219     "c" riece-command-select-command-buffer)
 220
 221   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 222   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 223
 224 (defun riece-read-variables-files (&optional file)
 225   "Read variables FILEs."
 226   (or (file-directory-p riece-directory)
 227       (make-directory riece-directory))
 228   (let ((files (if file
 229                    (setq riece-variables-file file
 230                          riece-variables-files (list file))
 231                  riece-variables-files)))
 232     (while files
 233       (condition-case nil
 234           (load (expand-file-name (car files)))
 235         (file-error nil))
 236       (setq files (cdr files)))))
 237
 238 (defvar print-quoted)
 239 (defvar print-escape-multibyte)
 240 (defun riece-save-variables-files ()
 241   "Save current settings to `riece-variables-file'."
 242   (with-temp-file riece-saved-variables-file
 243     (let ((print-quoted t)
 244           (print-readably t)
 245           print-escape-multibyte
 246           print-level
 247           print-length
 248           (variables riece-saved-forms))
 249       (while variables
 250         (prin1 `(setq ,(car variables)
 251                       ',(symbol-value (car variables)))
 252                (current-buffer))
 253         (insert "\n")
 254         (setq variables (cdr variables)))))
 255   (setq riece-save-variables-are-dirty nil))
 256
 257 ;;;###autoload
 258 (defun riece (&optional confirm)
 259   "Connect to the IRC server and start chatting.
 260 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 261   (interactive "P")
 262   (riece-read-variables-files (if noninteractive
 263                                   (car command-line-args-left)))
 264   (riece-insinuate-addons riece-addons)
 265   (run-hooks 'riece-after-load-startup-hook)
 266   (if (riece-server-opened)
 267       (riece-command-configure-windows)
 268     (if (or confirm (null riece-server))
 269         (setq riece-server (completing-read "Server: " riece-server-alist)))
 270     (if (stringp riece-server)
 271         (setq riece-server (riece-server-name-to-server riece-server)))
 272     (riece-create-buffers)
 273     (if riece-max-buffer-size
 274         (setq riece-shrink-buffer-idle-timer
 275               (riece-run-with-idle-timer
 276                riece-shrink-buffer-idle-time-delay t
 277                (lambda ()
 278                  (let ((buffers riece-buffer-list))
 279                    (while buffers
 280                      (if (eq (derived-mode-class
 281                               (with-current-buffer (car buffers)
 282                                 major-mode))
 283                              'riece-dialogue-mode)
 284                          (riece-shrink-buffer (car buffers)))
 285                      (setq buffers (cdr buffers))))))))
 286     (switch-to-buffer riece-command-buffer)
 287     (riece-redisplay-buffers)
 288     (riece-open-server riece-server "")
 289     (run-hooks 'riece-startup-hook)
 290     (message "%s" (substitute-command-keys
 291                    "Type \\[describe-mode] for help"))))
 292
 293 (defun riece-shrink-buffer (buffer)
 294   (save-excursion
 295     (set-buffer buffer)
 296     (goto-char (point-min))
 297     (while (> (buffer-size) riece-max-buffer-size)
 298       (let* ((inhibit-read-only t)
 299              buffer-read-only
 300              (start (point))
 301              (end (progn (beginning-of-line 2) (point)))
 302              (overlays (riece-overlays-in start end)))
 303         (while overlays
 304           (riece-delete-overlay (car overlays))
 305           (setq overlays (cdr overlays)))
 306         (delete-region start end)))))
 307
 308 (defun riece-exit ()
 309   (if riece-save-variables-are-dirty
 310       (riece-save-variables-files))
 311   (while riece-buffer-list
 312     (if (and (get-buffer (car riece-buffer-list))
 313              (buffer-live-p (car riece-buffer-list)))
 314         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 315     (setq riece-buffer-list (cdr riece-buffer-list)))
 316   (if riece-shrink-buffer-idle-timer
 317       (riece-cancel-timer riece-shrink-buffer-idle-timer))
 318   (setq riece-server nil
 319         riece-current-channels nil
 320         riece-current-channel nil
 321         riece-channel-buffer-alist nil
 322         riece-user-indicator nil
 323         riece-long-channel-indicator "None"
 324         riece-channel-list-indicator "No channel"
 325         riece-away-indicator "-"
 326         riece-operator-indicator "-"
 327         riece-freeze-indicator "-")
 328   (delete-other-windows)
 329   (run-hooks 'riece-exit-hook))
 330
 331 (defun riece-command-mode ()
 332   "Major mode for Riece.  Normal edit function are available.
 333 Typing Return or Linefeed enters the current line in the dialogue.
 334 The following special commands are available:
 335 For a list of the generic commands type \\[riece-command-generic] ? RET.
 336 \\{riece-command-mode-map}"
 337   (interactive)
 338   (kill-all-local-variables)
 339
 340   (setq riece-away-indicator "-"
 341         riece-operator-indicator "-"
 342         major-mode 'riece-command-mode
 343         mode-name "Commands"
 344         mode-line-buffer-identification
 345         (riece-mode-line-buffer-identification
 346          '("Riece: "
 347            riece-away-indicator
 348            riece-operator-indicator
 349            riece-freeze-indicator
 350            " "
 351            riece-user-indicator
 352            " "
 353            riece-channel-indicator)))
 354   (riece-simplify-mode-line-format)
 355   (use-local-map riece-command-mode-map)
 356
 357   (unless riece-command-mode-syntax-table
 358     (setq riece-command-mode-syntax-table
 359           (copy-syntax-table (syntax-table)))
 360     (set-syntax-table riece-command-mode-syntax-table)
 361     (mapcar
 362      (lambda (c) (modify-syntax-entry c "w"))
 363      "^[]{}'`"))
 364
 365   (run-hooks 'riece-command-mode-hook))
 366
 367 (defun riece-dialogue-mode ()
 368   "Major mode for displaying the IRC dialogue.
 369 All normal editing commands are turned off.
 370 Instead, these commands are available:
 371 \\{riece-dialogue-mode-map}"
 372   (kill-all-local-variables)
 373   (make-local-variable 'riece-freeze)
 374   (setq riece-freeze riece-default-freeze
 375         riece-away-indicator "-"
 376         riece-operator-indicator "-"
 377         major-mode 'riece-dialogue-mode
 378         mode-name "Dialogue"
 379         mode-line-buffer-identification
 380         (riece-mode-line-buffer-identification
 381          '("Riece: "
 382            riece-away-indicator
 383            riece-operator-indicator
 384            riece-freeze-indicator
 385            " "
 386            riece-channel-list-indicator " "))
 387         buffer-read-only t)
 388   (riece-simplify-mode-line-format)
 389   (use-local-map riece-dialogue-mode-map)
 390   (buffer-disable-undo)
 391   (run-hooks 'riece-dialogue-mode-hook))
 392
 393 (define-derived-mode riece-others-mode riece-dialogue-mode
 394   "Others"
 395   "Major mode for displaying the IRC others message except current channel.
 396 All normal editing commands are turned off.
 397 Instead, these commands are available:
 398 \\{riece-others-mode-map}")
 399
 400 (define-derived-mode riece-channel-mode riece-dialogue-mode
 401   "Channel"
 402   "Major mode for displaying the IRC current channel buffer.
 403 All normal editing commands are turned off.
 404 Instead, these commands are available:
 405 \\{riece-channel-mode-map}"
 406   (setq mode-line-buffer-identification
 407         (riece-mode-line-buffer-identification
 408          '("Riece: "
 409            riece-away-indicator
 410            riece-operator-indicator
 411            riece-freeze-indicator
 412            " "
 413            riece-long-channel-indicator))))
 414
 415 (defun riece-channel-list-mode ()
 416   "Major mode for displaying channel list.
 417 All normal editing commands are turned off."
 418   (kill-all-local-variables)
 419   (buffer-disable-undo)
 420   (setq major-mode 'riece-channel-list-mode
 421         mode-name "Channels"
 422         mode-line-buffer-identification
 423         (riece-mode-line-buffer-identification '("Riece: "))
 424         truncate-lines t
 425         buffer-read-only t)
 426   (make-local-hook 'riece-update-buffer-functions)
 427   (add-hook 'riece-update-buffer-functions
 428             'riece-update-channel-list-buffer nil t)
 429   (use-local-map riece-channel-list-mode-map)
 430   (run-hooks 'riece-channel-list-mode-hook))
 431
 432 (defun riece-user-list-mode ()
 433   "Major mode for displaying members in the IRC current channel buffer.
 434 All normal editing commands are turned off.
 435 Instead, these commands are available:
 436 \\{riece-user-list-mode-map}"
 437   (kill-all-local-variables)
 438   (buffer-disable-undo)
 439   (setq major-mode 'riece-user-list-mode
 440         mode-name "Users"
 441         mode-line-buffer-identification
 442         (riece-mode-line-buffer-identification
 443          '("Riece: " riece-long-channel-indicator " "))
 444         truncate-lines t
 445         buffer-read-only t)
 446   (if (boundp 'transient-mark-mode)
 447       (set (make-local-variable 'transient-mark-mode) t))
 448   (make-local-hook 'riece-update-buffer-functions)
 449   (add-hook 'riece-update-buffer-functions
 450             'riece-update-user-list-buffer nil t)
 451   (use-local-map riece-user-list-mode-map)
 452   (run-hooks 'riece-user-list-mode-hook))
 453
 454 (defun riece-create-buffers ()
 455   (let ((alist riece-buffer-alist))
 456     (while alist
 457       (save-excursion
 458         (set-buffer (apply #'riece-get-buffer-create
 459                            (cdr (car alist))))
 460         (set (car (car alist)) (current-buffer))
 461         (unless (or (null (nth 2 (car alist)))
 462                     (eq major-mode (nth 2 (car alist))))
 463           (funcall (nth 2 (car alist))))
 464         (setq alist (cdr alist))))))
 465
 466 (defun riece-load-and-build-addon-dependencies (addons)
 467   (let ((load-path (cons riece-addon-directory load-path))
 468         dependencies)
 469     (while addons
 470       (require (car addons))            ;error will be reported here
 471       (let* ((requires
 472               (funcall (or (intern-soft
 473                             (concat (symbol-name (car addons)) "-requires"))
 474                            #'ignore)))
 475              (pointer requires)
 476              entry)
 477         ;; Increment succs' pred count.
 478         (if (setq entry (assq (car addons) dependencies))
 479             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 480           (setq dependencies (cons (list (car addons) (length requires))
 481                                    dependencies)))
 482         ;; Merge pred's succs.
 483         (while pointer
 484           (if (setq entry (assq (car pointer) dependencies))
 485               (setcdr (cdr entry)
 486                       (cons (car addons) (nthcdr 2 entry)))
 487             (setq dependencies (cons (list (car pointer) 0 (car addons))
 488                                      dependencies)))
 489           (setq pointer (cdr pointer))))
 490       (setq addons (cdr addons)))
 491     dependencies))
 492
 493 (defun riece-insinuate-addons (addons)
 494   (let ((pointer addons)
 495         dependencies queue)
 496     ;; Uniquify, first.
 497     (while pointer
 498       (if (memq (car pointer) (cdr pointer))
 499           (setcar pointer nil))
 500       (setq pointer (cdr pointer)))
 501     (setq dependencies (riece-load-and-build-addon-dependencies
 502                         (delq nil addons))
 503           pointer dependencies)
 504     ;; Sort them.
 505     (while pointer
 506       (if (zerop (nth 1 (car pointer)))
 507           (setq dependencies (delq (car pointer) dependencies)
 508                 queue (cons (car pointer) queue)))
 509       (setq pointer (cdr pointer)))
 510     (setq addons nil)
 511     (while queue
 512       (setq addons (cons (car (car queue)) addons)
 513             pointer (nthcdr 2 (car queue)))
 514       (while pointer
 515         (let* ((entry (assq (car pointer) dependencies))
 516                (count (1- (nth 1 entry))))
 517           (if (zerop count)
 518               (progn
 519                 (setq dependencies (delq entry dependencies)
 520                       queue (nconc queue (list entry))))
 521             (setcar (cdr entry) count)))
 522         (setq pointer (cdr pointer)))
 523       (setq queue (cdr queue)))
 524     (if dependencies
 525         (error "Circular add-on dependency found"))
 526     (setq addons (nreverse addons))
 527     (while addons
 528       (require (car addons))            ;implicit dependency
 529       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 530       (if riece-debug
 531           (message "Add-on %S is loaded" (car addons)))
 532       (setq addons (cdr addons)))))
 533
 534 (provide 'riece)
 535
 536 ;;; riece.el ends here