cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'riece-inlines))
  28
  29 (if (featurep 'xemacs)
  30     (require 'riece-xemacs)
  31   (require 'riece-emacs))
  32
  33 (require 'riece-filter)
  34 (require 'riece-display)
  35 (require 'riece-server)
  36 (require 'riece-compat)
  37 (require 'riece-commands)
  38
  39 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  40 (defvar riece-user-list-mode-map (make-sparse-keymap))
  41
  42 (defvar riece-dialogue-mode-map
  43   (let ((keymap (make-keymap)))
  44     (suppress-keymap keymap 'nodigit)
  45     keymap))
  46
  47 (defvar riece-command-mode-map (make-keymap))
  48 (defvar riece-command-map (make-sparse-keymap))
  49
  50 (defvar riece-command-mode-syntax-table nil)
  51
  52 (put 'riece-command-mode 'mode-class 'special)
  53 (put 'riece-dialogue-mode 'mode-class 'special)
  54 (put 'riece-channel-list-mode 'mode-class 'special)
  55 (put 'riece-user-list-mode 'mode-class 'special)
  56 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  57 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  58
  59 (defvar riece-buffer-mode-alist
  60   '((riece-dialogue-buffer . riece-dialogue-mode)
  61     (riece-others-buffer . riece-others-mode)
  62     (riece-channel-list-buffer . riece-channel-list-mode)
  63     (riece-private-buffer . riece-dialogue-mode)
  64     (riece-wallops-buffer)))
  65
  66 (defvar riece-select-keys
  67   '("1" riece-command-switch-to-channel-by-number-1
  68     "2" riece-command-switch-to-channel-by-number-2
  69     "3" riece-command-switch-to-channel-by-number-3
  70     "4" riece-command-switch-to-channel-by-number-4
  71     "5" riece-command-switch-to-channel-by-number-5
  72     "6" riece-command-switch-to-channel-by-number-6
  73     "7" riece-command-switch-to-channel-by-number-7
  74     "8" riece-command-switch-to-channel-by-number-8
  75     "9" riece-command-switch-to-channel-by-number-9
  76     "0" riece-command-switch-to-channel-by-number-10
  77     "\C-c1" riece-command-switch-to-channel-by-number-11
  78     "\C-c2" riece-command-switch-to-channel-by-number-12
  79     "\C-c3" riece-command-switch-to-channel-by-number-13
  80     "\C-c4" riece-command-switch-to-channel-by-number-14
  81     "\C-c5" riece-command-switch-to-channel-by-number-15
  82     "\C-c6" riece-command-switch-to-channel-by-number-16
  83     "\C-c7" riece-command-switch-to-channel-by-number-17
  84     "\C-c8" riece-command-switch-to-channel-by-number-18
  85     "\C-c9" riece-command-switch-to-channel-by-number-19
  86     "\C-c0" riece-command-switch-to-channel-by-number-20))
  87
  88 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  89 (defmacro riece-local-set-keys (&rest plist)
  90   "Set the keys in PLIST in the current keymap."
  91   `(riece-define-keys-1 (current-local-map) ',plist))
  92
  93 (defmacro riece-define-keys (keymap &rest plist)
  94   "Assign KEYMAP keys from PLIST."
  95   `(riece-define-keys-1 ',keymap ',plist))
  96
  97 (defmacro riece-define-keys-safe (keymap &rest plist)
  98   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
  99   `(riece-define-keys-1 ',keymap ',plist t))
 100
 101 (put 'riece-define-keys 'lisp-indent-function 1)
 102 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 103 (put 'riece-local-set-keys 'lisp-indent-function 1)
 104
 105 (defun riece-define-keys-1 (keymap plist &optional safe)
 106   "Assign KEYMAP keys from PLIST.
 107 If optional argument SAFE is nil, overwrite previous definitions."
 108   (unless keymap
 109     (error "Can't set keys in a null keymap"))
 110   (cond
 111    ((symbolp keymap)
 112     (setq keymap (symbol-value keymap)))
 113    ((keymapp keymap))
 114    ((listp keymap)
 115     (set (car keymap) nil)
 116     (define-prefix-command (car keymap))
 117     (define-key (symbol-value (nth 2 keymap)) (nth 1 keymap) (car keymap))
 118     (setq keymap (symbol-value (car keymap)))))
 119   (let (key)
 120     (while plist
 121       (if (symbolp (setq key (car plist)))
 122           (setq key (symbol-value key)))
 123       (setq plist (cdr plist))
 124       (if (or (not safe)
 125               (eq (lookup-key keymap key) 'undefined))
 126           (define-key keymap key (car plist))
 127         (car plist))
 128       (setq plist (cdr plist)))))
 129
 130 (when t
 131   (riece-define-keys riece-dialogue-mode-map
 132     "\177" scroll-down
 133     [delete] scroll-down
 134     [backspace] scroll-down
 135     [return] scroll-up
 136     " " scroll-up
 137     "$" end-of-buffer
 138     "/" riece-command-raw
 139     ">" end-of-buffer
 140     "<" beginning-of-buffer
 141     "\C-ta" riece-command-toggle-away
 142     "c" riece-command-select-command-buffer
 143     "f" riece-command-finger
 144     "\C-tf" riece-command-toggle-freeze
 145     "\C-to" riece-command-toggle-own-freeze
 146     "\C-tu" riece-command-toggle-user-list-buffer-mode
 147     "\C-tc" riece-command-toggle-channel-buffer-mode
 148     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 149     "i" riece-command-invite
 150     "j" riece-command-join
 151     "\C-k" riece-command-kick
 152     "l" riece-command-list
 153     "m" riece-dialogue-enter-message
 154     "M" riece-command-change-mode
 155     "n" riece-command-change-nickname
 156     "\C-n" riece-command-names
 157     "o" other-window
 158     "O" riece-command-open-server
 159     "C" riece-command-close-server
 160     "M" riece-command-universal-server-name-argument
 161     "q" riece-command-quit
 162     "r" riece-command-configure-windows
 163     "x" riece-command-copy-region
 164     "t" riece-command-topic
 165     "w" riece-command-who)
 166
 167   (riece-define-keys riece-command-mode-map
 168     "\r" riece-command-enter-message
 169     [(control return)] riece-command-enter-message-as-notice)
 170
 171   (riece-define-keys (riece-command-map "\C-c" riece-command-mode-map)
 172     "\177" riece-command-scroll-down
 173     [delete] riece-command-scroll-down
 174     [backspace] riece-command-scroll-down
 175     " " riece-command-scroll-up
 176     "$" riece-command-end-of-buffer
 177     ">" riece-command-next-channel
 178     "<" riece-command-previous-channel
 179     "\C-j" riece-command-next-channel
 180     "\C-n" riece-command-names
 181     "l" riece-command-list
 182     "\C-m" riece-command-change-mode
 183     "o" riece-command-set-operators
 184     "\C-p" riece-command-part
 185     "r" riece-command-configure-windows
 186     "v" riece-command-set-speakers)
 187   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 188
 189   (riece-define-keys riece-user-list-mode-map
 190     "o" riece-command-set-operators
 191     "v" riece-command-set-voices
 192     "f" riece-command-finger
 193     " " riece-command-nick-scroll-up
 194     "\177" riece-command-nick-scroll-down
 195     [delete] riece-command-nick-scroll-down
 196     [backspace] riece-command-nick-scroll-down
 197     "c" riece-command-select-command-buffer)
 198
 199   (riece-define-keys riece-channel-list-mode-map
 200     ">" riece-command-next-channel
 201     "<" riece-command-previous-channel
 202     "u" riece-command-unread-channel
 203     "o" other-window
 204     "c" riece-command-select-command-buffer)
 205
 206   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 207   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 208
 209 (defun riece-read-variables-files (&optional file)
 210   "Read variables FILEs."
 211   (or (file-directory-p riece-directory)
 212       (make-directory riece-directory))
 213   (let ((files (if file
 214                    (setq riece-variables-file file
 215                          riece-variables-files (list file))
 216                  riece-variables-files)))
 217     (while files
 218       (condition-case nil
 219           (load (expand-file-name (car files)))
 220         (file-error nil))
 221       (setq files (cdr files)))))
 222
 223 (defvar print-quoted)
 224 (defvar print-escape-multibyte)
 225 (defun riece-save-variables-files ()
 226   "Save current settings to `riece-variables-file'."
 227   (with-temp-file riece-saved-variables-file
 228     (let ((print-quoted t)
 229           (print-readably t)
 230           print-escape-multibyte
 231           print-level
 232           print-length
 233           (variables riece-saved-forms))
 234       (while variables
 235         (prin1 `(setq ,(car variables)
 236                       ',(symbol-value (car variables)))
 237                (current-buffer))
 238         (insert "\n")
 239         (setq variables (cdr variables)))))
 240   (setq riece-save-variables-are-dirty nil))
 241
 242 ;;;###autoload
 243 (defun riece (&optional confirm)
 244   "Connect to the IRC server and start chatting.
 245 If optional argument CONFIRM is non-nil, ask which IRC server to connect.
 246 If already connected, just pop up the windows."
 247   (interactive "P")
 248   (riece-read-variables-files (if noninteractive
 249                                   (car command-line-args-left)))
 250   (riece-insinuate-addons riece-addons)
 251   (run-hooks 'riece-after-load-startup-hook)
 252   (if (riece-server-opened)
 253       (riece-configure-windows)
 254     (switch-to-buffer (riece-get-buffer-create riece-command-buffer))
 255     (unless (eq major-mode 'riece-command-mode)
 256       (riece-command-mode))
 257     (if (or confirm (null riece-server))
 258         (setq riece-server (completing-read "Server: " riece-server-alist)))
 259     (if (stringp riece-server)
 260         (setq riece-server (riece-server-name-to-server riece-server)))
 261     (riece-open-server riece-server)
 262     (riece-create-buffers)
 263     (riece-configure-windows)
 264     (let ((channel-list riece-startup-channel-list))
 265       (while channel-list
 266         (if (listp (car channel-list))
 267             (riece-command-join (car (car channel-list))
 268                                 (cadr (car channel-list)))
 269           (riece-command-join (car channel-list)))
 270         (setq channel-list (cdr channel-list))))
 271     (run-hooks 'riece-startup-hook)
 272     (message "%s" (substitute-command-keys
 273                    "Type \\[describe-mode] for help"))))
 274
 275 (defun riece-exit ()
 276   (setq riece-server nil)
 277   (if riece-save-variables-are-dirty
 278       (riece-save-variables-files))
 279   (riece-clear-system)
 280   (run-hooks 'riece-exit-hook))
 281
 282 (defun riece-command-mode ()
 283   "Major mode for Riece.  Normal edit function are available.
 284 Typing Return or Linefeed enters the current line in the dialogue.
 285 The following special commands are available:
 286 For a list of the generic commands type \\[riece-command-generic] ? RET.
 287 \\{riece-command-mode-map}"
 288   (interactive)
 289   (kill-all-local-variables)
 290
 291   (setq riece-away-indicator "-"
 292         riece-operator-indicator "-"
 293         major-mode 'riece-command-mode
 294         mode-name "Commands"
 295         mode-line-buffer-identification
 296         (riece-mode-line-buffer-identification
 297          '("Riece: "
 298            mode-line-modified
 299            riece-away-indicator
 300            riece-operator-indicator
 301            "-- " riece-current-channel " " riece-real-nickname)))
 302   (riece-simplify-mode-line-format)
 303   (use-local-map riece-command-mode-map)
 304
 305   (unless riece-command-mode-syntax-table
 306     (setq riece-command-mode-syntax-table
 307           (copy-syntax-table (syntax-table)))
 308     (set-syntax-table riece-command-mode-syntax-table)
 309     (mapcar
 310      (lambda (c) (modify-syntax-entry c "w"))
 311      "^[]{}'`"))
 312
 313   (run-hooks 'riece-command-mode-hook))
 314
 315 (defun riece-dialogue-mode ()
 316   "Major mode for displaying the IRC dialogue.
 317 All normal editing commands are turned off.
 318 Instead, these commands are available:
 319 \\{riece-dialogue-mode-map}"
 320   (kill-all-local-variables)
 321
 322   (make-local-variable 'riece-freeze)
 323   (make-local-variable 'tab-stop-list)
 324
 325   (setq riece-freeze riece-default-freeze
 326         riece-away-indicator "-"
 327         riece-operator-indicator "-"
 328         major-mode 'riece-dialogue-mode
 329         mode-name "Dialogue"
 330         mode-line-buffer-identification
 331         (riece-mode-line-buffer-identification
 332          '("Riece: "
 333            mode-line-modified
 334            riece-away-indicator
 335            riece-operator-indicator
 336            riece-freeze-indicator
 337            riece-own-freeze-indicator
 338            " " riece-channel-list-indicator " "))
 339         buffer-read-only t
 340         tab-stop-list riece-tab-stop-list)
 341   (riece-update-status-indicators)
 342   (riece-simplify-mode-line-format)
 343   (use-local-map riece-dialogue-mode-map)
 344   (buffer-disable-undo)
 345   (run-hooks 'riece-dialogue-mode-hook))
 346
 347 (define-derived-mode riece-others-mode riece-dialogue-mode
 348   "Others"
 349   "Major mode for displaying the IRC others message except current channel.
 350 All normal editing commands are turned off.
 351 Instead, these commands are available:
 352 \\{riece-others-mode-map}")
 353
 354 (define-derived-mode riece-channel-mode riece-dialogue-mode
 355   "Channel"
 356   "Major mode for displaying the IRC current channel buffer.
 357 All normal editing commands are turned off.
 358 Instead, these commands are available:
 359 \\{riece-channel-mode-map}"
 360   (setq mode-line-buffer-identification
 361         (riece-mode-line-buffer-identification
 362          '("Riece: "
 363            mode-line-modified
 364            riece-away-indicator
 365            riece-operator-indicator
 366            riece-freeze-indicator
 367            riece-own-freeze-indicator
 368            " "
 369            riece-channel-indicator))))
 370
 371 (defun riece-channel-list-mode ()
 372   "Major mode for displaying channel list.
 373 All normal editing commands are turned off."
 374   (kill-all-local-variables)
 375   (setq major-mode 'riece-channel-list-mode
 376         mode-name "Channels"
 377         mode-line-buffer-identification
 378         (riece-mode-line-buffer-identification '("Riece: "))
 379         truncate-lines t
 380         buffer-read-only t)
 381   (use-local-map riece-channel-list-mode-map)
 382   (run-hooks 'riece-channel-list-mode-hook))
 383
 384 (defun riece-user-list-mode ()
 385   "Major mode for displaying members in the IRC current channel buffer.
 386 All normal editing commands are turned off.
 387 Instead, these commands are available:
 388 \\{riece-user-list-mode-map}"
 389   (kill-all-local-variables)
 390   (setq mode-line-modified "--- "
 391         major-mode 'riece-user-list-mode
 392         mode-name "Riece Channel member"
 393         mode-line-buffer-identification
 394         (riece-mode-line-buffer-identification
 395          '("Riece: " riece-channel-indicator " "))
 396         truncate-lines t
 397         buffer-read-only t)
 398   (if (boundp 'transient-mark-mode)
 399       (set (make-local-variable 'transient-mark-mode) t))
 400   (use-local-map riece-user-list-mode-map)
 401   (run-hooks 'riece-user-list-mode-hook))
 402
 403 (defun riece-create-buffers ()
 404   (let ((alist riece-buffer-mode-alist))
 405     (while alist
 406       (save-excursion
 407         (set-buffer (riece-get-buffer-create
 408                      (symbol-value (car (car alist)))))
 409         (unless (or (null (cdr (car alist)))
 410                     (eq major-mode (cdr (car alist))))
 411           (funcall (cdr (car alist))))
 412         (setq alist (cdr alist))))))
 413
 414 (defun riece-load-and-build-addon-dependencies (addons)
 415   (let ((load-path (cons riece-addon-directory load-path))
 416         dependencies
 417         pointer)
 418     (while addons
 419       (require (car addons))            ;error will be reported here
 420       (let* ((requires
 421               (funcall (or (intern-soft
 422                             (concat (symbol-name (car addons)) "-requires"))
 423                            #'ignore)))
 424              (pointer requires)
 425              entry)
 426         ;; Increment succs' pred count.
 427         (if (setq entry (assq (car addons) dependencies))
 428             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 429           (setq dependencies (cons (list (car addons) (length requires))
 430                                    dependencies)))
 431         ;; Merge pred's succs.
 432         (while pointer
 433           (if (setq entry (assq (car pointer) dependencies))
 434               (setcdr (cdr entry)
 435                       (cons (car addons) (nthcdr 2 entry)))
 436             (setq dependencies (cons (list (car pointer) 0 (car addons))
 437                                      dependencies)))
 438           (setq pointer (cdr pointer))))
 439       (setq addons (cdr addons)))
 440     dependencies))
 441
 442 (defun riece-insinuate-addons (addons)
 443   (let ((pointer addons)
 444         dependencies queue)
 445     ;; Uniquify, first.
 446     (while pointer
 447       (if (memq (car pointer) (cdr pointer))
 448           (setcar pointer nil))
 449       (setq pointer (cdr pointer)))
 450     (setq dependencies (riece-load-and-build-addon-dependencies
 451                         (delq nil addons))
 452           pointer dependencies)
 453     ;; Sort them.
 454     (while pointer
 455       (if (zerop (nth 1 (car pointer)))
 456           (setq dependencies (delq (car pointer) dependencies)
 457                 queue (cons (car pointer) queue)))
 458       (setq pointer (cdr pointer)))
 459     (setq addons nil)
 460     (while queue
 461       (setq addons (cons (car (car queue)) addons)
 462             pointer (nthcdr 2 (car queue)))
 463       (while pointer
 464         (let* ((entry (assq (car pointer) dependencies))
 465                (count (1- (nth 1 entry))))
 466           (if (zerop count)
 467               (progn
 468                 (setq dependencies (delq entry dependencies)
 469                       queue (nconc queue (list entry))))
 470             (setcar (cdr entry) count)))
 471         (setq pointer (cdr pointer)))
 472       (setq queue (cdr queue)))
 473     (if dependencies
 474         (error "Circular add-on dependency found"))
 475     (while addons
 476       (require (car addons))            ;implicit dependency
 477       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 478       (setq addons (cdr addons)))))
 479
 480 (provide 'riece)
 481
 482 ;;; riece.el ends here