7ec6f4faa91611b7eec1fde45cf972f05256822f
[riece] / lisp / riece.el
1 ;;; riece.el --- IRC client for Emacsen
2 ;; Copyright (C) 1998-2003 Daiki Ueno
3
4 ;; Author: Daiki Ueno <ueno@unixuser.org>
5 ;; Created: 1998-09-28
6 ;; Keywords: IRC, riece
7
8 ;; This file is part of Riece.
9
10 ;; This program is free software; you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation; either version 2, or (at your option)
13 ;; any later version.
14
15 ;; This program is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 ;; Boston, MA 02111-1307, USA.
24
25 ;;; Code:
26
27 (require 'riece-filter)
28 (require 'riece-display)
29 (require 'riece-server)
30 (require 'riece-compat)
31 (require 'riece-commands)
32
33 (defvar riece-channel-list-mode-map (make-sparse-keymap))
34 (defvar riece-user-list-mode-map (make-sparse-keymap))
35
36 (defvar riece-dialogue-mode-map
37   (let ((keymap (make-keymap)))
38     (suppress-keymap keymap 'nodigit)
39     keymap))
40
41 (defvar riece-command-mode-map (make-keymap))
42 (defvar riece-command-map (make-sparse-keymap))
43
44 (defvar riece-command-mode-syntax-table nil)
45
46 (put 'riece-command-mode 'mode-class 'special)
47 (put 'riece-dialogue-mode 'mode-class 'special)
48 (put 'riece-channel-list-mode 'mode-class 'special)
49 (put 'riece-user-list-mode 'mode-class 'special)
50 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
51 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
52
53 (defvar riece-buffer-mode-alist
54   '((riece-command-buffer . riece-command-mode)
55     (riece-dialogue-buffer . riece-dialogue-mode)
56     (riece-others-buffer . riece-others-mode)
57     (riece-user-list-buffer . riece-user-list-mode)
58     (riece-channel-list-buffer . riece-channel-list-mode)
59     (riece-private-buffer . riece-dialogue-mode)
60     (riece-wallops-buffer)))
61     
62 (defvar riece-select-keys
63   '("1" riece-command-switch-to-channel-by-number-1
64     "2" riece-command-switch-to-channel-by-number-2
65     "3" riece-command-switch-to-channel-by-number-3
66     "4" riece-command-switch-to-channel-by-number-4
67     "5" riece-command-switch-to-channel-by-number-5
68     "6" riece-command-switch-to-channel-by-number-6
69     "7" riece-command-switch-to-channel-by-number-7
70     "8" riece-command-switch-to-channel-by-number-8
71     "9" riece-command-switch-to-channel-by-number-9
72     "0" riece-command-switch-to-channel-by-number-10
73     "\C-c1" riece-command-switch-to-channel-by-number-11
74     "\C-c2" riece-command-switch-to-channel-by-number-12
75     "\C-c3" riece-command-switch-to-channel-by-number-13
76     "\C-c4" riece-command-switch-to-channel-by-number-14
77     "\C-c5" riece-command-switch-to-channel-by-number-15
78     "\C-c6" riece-command-switch-to-channel-by-number-16
79     "\C-c7" riece-command-switch-to-channel-by-number-17
80     "\C-c8" riece-command-switch-to-channel-by-number-18
81     "\C-c9" riece-command-switch-to-channel-by-number-19
82     "\C-c0" riece-command-switch-to-channel-by-number-20))
83
84 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
85 (defmacro riece-local-set-keys (&rest plist)
86   "Set the keys in PLIST in the current keymap."
87   `(riece-define-keys-1 (current-local-map) ',plist))
88
89 (defmacro riece-define-keys (keymap &rest plist)
90   "Assign KEYMAP keys from PLIST."
91   `(riece-define-keys-1 ',keymap ',plist))
92
93 (defmacro riece-define-keys-safe (keymap &rest plist)
94   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
95   `(riece-define-keys-1 ',keymap ',plist t))
96
97 (put 'riece-define-keys 'lisp-indent-function 1)
98 (put 'riece-define-keys-safe 'lisp-indent-function 1)
99 (put 'riece-local-set-keys 'lisp-indent-function 1)
100
101 (defun riece-define-keys-1 (keymap plist &optional safe)
102   "Assign KEYMAP keys from PLIST.
103 If optional argument SAFE is nil, overwrite previous definitions."
104   (unless keymap
105     (error "Can't set keys in a null keymap"))
106   (cond
107    ((symbolp keymap)
108     (setq keymap (symbol-value keymap)))
109    ((keymapp keymap))
110    ((listp keymap)
111     (set (car keymap) nil)
112     (define-prefix-command (car keymap))
113     (define-key (symbol-value (nth 2 keymap)) (nth 1 keymap) (car keymap))
114     (setq keymap (symbol-value (car keymap)))))
115   (let (key)
116     (while plist
117       (if (symbolp (setq key (car plist)))
118           (setq key (symbol-value key)))
119       (setq plist (cdr plist))
120       (if (or (not safe)
121               (eq (lookup-key keymap key) 'undefined))
122           (define-key keymap key (car plist))
123         (car plist))
124       (setq plist (cdr plist)))))
125
126 (when t
127   (riece-define-keys riece-dialogue-mode-map
128     "\177" scroll-down
129     [delete] scroll-down
130     [backspace] scroll-down
131     [return] scroll-up
132     " " scroll-up
133     "$" end-of-buffer
134     "/" riece-command-raw
135     ">" end-of-buffer
136     "<" beginning-of-buffer
137     "\C-ta" riece-command-toggle-away
138     "c" riece-command-select-command-buffer
139     "f" riece-command-finger
140     "\C-tf" riece-command-toggle-freeze
141     "\C-to" riece-command-toggle-own-freeze
142     "\C-tu" riece-command-toggle-user-list-buffer-mode
143     "\C-tc" riece-command-toggle-channel-buffer-mode
144     "\C-tC" riece-command-toggle-channel-list-buffer-mode
145     "\C-tl" riece-command-change-layout
146     "i" riece-command-invite
147     "j" riece-command-join
148     "\C-k" riece-command-kick
149     "l" riece-command-list
150     "M" riece-command-change-mode
151     "n" riece-command-change-nickname
152     "\C-n" riece-command-names
153     "o" other-window
154     "O" riece-command-open-server
155     "C" riece-command-close-server
156     "M" riece-command-universal-server-name-argument
157     "q" riece-command-quit
158     "r" riece-command-configure-windows
159     "x" riece-command-copy-region
160     "t" riece-command-topic
161     "w" riece-command-who)
162
163   (riece-define-keys riece-command-mode-map
164     "\r" riece-command-enter-message
165     [(control return)] riece-command-enter-message-as-notice)
166
167   (riece-define-keys (riece-command-map "\C-c" riece-command-mode-map)
168     "\177" riece-command-scroll-down
169     [delete] riece-command-scroll-down
170     [backspace] riece-command-scroll-down
171     " " riece-command-scroll-up
172     "$" riece-command-end-of-buffer
173     ">" riece-command-next-channel
174     "<" riece-command-previous-channel
175     "\C-j" riece-command-next-channel
176     "\C-n" riece-command-names
177     "l" riece-command-list
178     "\C-m" riece-command-change-mode
179     "o" riece-command-set-operators
180     "\C-p" riece-command-part
181     "r" riece-command-configure-windows
182     "v" riece-command-set-speakers)
183   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
184
185   (riece-define-keys riece-user-list-mode-map
186     "o" riece-command-set-operators
187     "v" riece-command-set-voices
188     "f" riece-command-finger
189     " " riece-command-nick-scroll-up
190     "\177" riece-command-nick-scroll-down
191     [delete] riece-command-nick-scroll-down
192     [backspace] riece-command-nick-scroll-down
193     "c" riece-command-select-command-buffer)
194
195   (riece-define-keys riece-channel-list-mode-map
196     ">" riece-command-next-channel
197     "<" riece-command-previous-channel
198     "o" other-window
199     "c" riece-command-select-command-buffer)
200
201   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
202   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
203
204 (defun riece-read-variables-files (&optional file)
205   "Read variables FILEs."
206   (or (file-directory-p riece-directory)
207       (make-directory riece-directory))
208   (let ((files (if file
209                    (setq riece-variables-file file
210                          riece-variables-files (list file))
211                  riece-variables-files)))
212     (while files
213       (condition-case nil
214           (load (expand-file-name (car files)))
215         (file-error nil))
216       (setq files (cdr files)))))
217
218 (defvar print-quoted)
219 (defvar print-escape-multibyte)
220 (defun riece-save-variables-files ()
221   "Save current settings to `riece-variables-file'."
222   (with-temp-file riece-saved-variables-file
223     (let ((print-quoted t)
224           (print-readably t)
225           print-escape-multibyte
226           print-level
227           print-length
228           (variables riece-saved-forms))
229       (while variables
230         (prin1 `(setq ,(car variables)
231                       ',(symbol-value (car variables)))
232                (current-buffer))
233         (insert "\n")
234         (setq variables (cdr variables)))))
235   (setq riece-save-variables-are-dirty nil))
236
237 ;;;###autoload
238 (defun riece (&optional confirm)
239   "Connect to the IRC server and start chatting.
240 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
241   (interactive "P")
242   (riece-read-variables-files (if noninteractive
243                                   (car command-line-args-left)))
244   (riece-insinuate-addons riece-addons)
245   (run-hooks 'riece-after-load-startup-hook)
246   (if (riece-server-opened)
247       (error "Already running"))
248   (if (or confirm (null riece-server))
249       (setq riece-server (completing-read "Server: " riece-server-alist)))
250   (if (stringp riece-server)
251       (setq riece-server (riece-server-name-to-server riece-server)))
252   (riece-create-buffers)
253   (switch-to-buffer riece-command-buffer)
254   (riece-redisplay-buffers)
255   (riece-open-server riece-server "")
256   (run-hooks 'riece-startup-hook)
257   (message "%s" (substitute-command-keys "Type \\[describe-mode] for help")))
258
259 (defun riece-exit ()
260   (if riece-save-variables-are-dirty
261       (riece-save-variables-files))
262   (while riece-buffer-list
263     (if (and (get-buffer (car riece-buffer-list))
264              (buffer-live-p (car riece-buffer-list)))
265         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
266     (setq riece-buffer-list (cdr riece-buffer-list)))
267   (setq riece-server nil
268         riece-current-channels nil
269         riece-current-channel nil
270         riece-user-indicator nil
271         riece-long-channel-indicator "None"
272         riece-channel-list-indicator "No channel"
273         riece-away-indicator "-"
274         riece-operator-indicator "-"
275         riece-freeze-indicator "-")
276   (delete-other-windows)
277   (run-hooks 'riece-exit-hook))
278
279 (defun riece-command-mode ()
280   "Major mode for Riece.  Normal edit function are available.
281 Typing Return or Linefeed enters the current line in the dialogue.
282 The following special commands are available:
283 For a list of the generic commands type \\[riece-command-generic] ? RET.
284 \\{riece-command-mode-map}"
285   (interactive)
286   (kill-all-local-variables)
287
288   (setq riece-away-indicator "-"
289         riece-operator-indicator "-"
290         major-mode 'riece-command-mode
291         mode-name "Commands"
292         mode-line-buffer-identification
293         (riece-mode-line-buffer-identification
294          '("Riece: "
295            riece-away-indicator
296            riece-operator-indicator
297            riece-freeze-indicator
298            " "
299            riece-user-indicator
300            " "
301            riece-channel-indicator)))
302   (riece-simplify-mode-line-format)
303   (use-local-map riece-command-mode-map)
304
305   (unless riece-command-mode-syntax-table
306     (setq riece-command-mode-syntax-table
307           (copy-syntax-table (syntax-table)))
308     (set-syntax-table riece-command-mode-syntax-table)
309     (mapcar
310      (lambda (c) (modify-syntax-entry c "w"))
311      "^[]{}'`"))
312
313   (run-hooks 'riece-command-mode-hook))
314   
315 (defun riece-dialogue-mode ()
316   "Major mode for displaying the IRC dialogue.
317 All normal editing commands are turned off.
318 Instead, these commands are available:
319 \\{riece-dialogue-mode-map}"
320   (kill-all-local-variables)
321   (make-local-variable 'riece-freeze)
322   (make-local-variable 'tab-stop-list)
323   (setq riece-freeze riece-default-freeze
324         riece-away-indicator "-"
325         riece-operator-indicator "-"
326         major-mode 'riece-dialogue-mode
327         mode-name "Dialogue"
328         mode-line-buffer-identification
329         (riece-mode-line-buffer-identification
330          '("Riece: "
331            riece-away-indicator
332            riece-operator-indicator
333            riece-freeze-indicator
334            " "
335            riece-channel-list-indicator " "))
336         buffer-read-only t
337         tab-stop-list riece-tab-stop-list)
338   (riece-simplify-mode-line-format)
339   (use-local-map riece-dialogue-mode-map)
340   (buffer-disable-undo)
341   (run-hooks 'riece-dialogue-mode-hook))
342
343 (define-derived-mode riece-others-mode riece-dialogue-mode
344   "Others"
345   "Major mode for displaying the IRC others message except current channel.
346 All normal editing commands are turned off.
347 Instead, these commands are available:
348 \\{riece-others-mode-map}")
349
350 (define-derived-mode riece-channel-mode riece-dialogue-mode
351   "Channel"
352   "Major mode for displaying the IRC current channel buffer.
353 All normal editing commands are turned off.
354 Instead, these commands are available:
355 \\{riece-channel-mode-map}"
356   (setq mode-line-buffer-identification
357         (riece-mode-line-buffer-identification
358          '("Riece: "
359            riece-away-indicator
360            riece-operator-indicator
361            riece-freeze-indicator
362            " "
363            riece-long-channel-indicator))))
364
365 (defun riece-channel-list-mode ()
366   "Major mode for displaying channel list.
367 All normal editing commands are turned off."
368   (kill-all-local-variables)
369   (buffer-disable-undo)
370   (setq major-mode 'riece-channel-list-mode
371         mode-name "Channels"
372         mode-line-buffer-identification
373         (riece-mode-line-buffer-identification '("Riece: "))
374         truncate-lines t
375         buffer-read-only t)
376   (make-local-hook 'riece-update-buffer-functions)
377   (add-hook 'riece-update-buffer-functions
378             'riece-update-channel-list-buffer nil t)
379   (use-local-map riece-channel-list-mode-map)
380   (run-hooks 'riece-channel-list-mode-hook))
381
382 (defun riece-user-list-mode ()
383   "Major mode for displaying members in the IRC current channel buffer.
384 All normal editing commands are turned off.
385 Instead, these commands are available:
386 \\{riece-user-list-mode-map}"
387   (kill-all-local-variables)
388   (buffer-disable-undo)
389   (setq major-mode 'riece-user-list-mode
390         mode-name "User list"
391         mode-line-buffer-identification
392         (riece-mode-line-buffer-identification
393          '("Riece: " riece-long-channel-indicator " "))
394         truncate-lines t
395         buffer-read-only t)
396   (if (boundp 'transient-mark-mode)
397       (set (make-local-variable 'transient-mark-mode) t))
398   (make-local-hook 'riece-update-buffer-functions)
399   (add-hook 'riece-update-buffer-functions
400             'riece-update-user-list-buffer nil t)
401   (use-local-map riece-user-list-mode-map)
402   (run-hooks 'riece-user-list-mode-hook))
403
404 (defun riece-create-buffers ()
405   (let ((alist riece-buffer-mode-alist))
406     (while alist
407       (save-excursion
408         (set-buffer (riece-get-buffer-create
409                      (symbol-value (car (car alist)))))
410         (unless (or (null (cdr (car alist)))
411                     (eq major-mode (cdr (car alist))))
412           (funcall (cdr (car alist))))
413         (setq alist (cdr alist))))))
414
415 (defun riece-load-and-build-addon-dependencies (addons)
416   (let ((load-path (cons riece-addon-directory load-path))
417         dependencies)
418     (while addons
419       (require (car addons))            ;error will be reported here
420       (let* ((requires
421               (funcall (or (intern-soft
422                             (concat (symbol-name (car addons)) "-requires"))
423                            #'ignore)))
424              (pointer requires)
425              entry)
426         ;; Increment succs' pred count.
427         (if (setq entry (assq (car addons) dependencies))
428             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
429           (setq dependencies (cons (list (car addons) (length requires))
430                                    dependencies)))
431         ;; Merge pred's succs.
432         (while pointer
433           (if (setq entry (assq (car pointer) dependencies))
434               (setcdr (cdr entry)
435                       (cons (car addons) (nthcdr 2 entry)))
436             (setq dependencies (cons (list (car pointer) 0 (car addons))
437                                      dependencies)))
438           (setq pointer (cdr pointer))))
439       (setq addons (cdr addons)))
440     dependencies))
441
442 (defun riece-insinuate-addons (addons)
443   (let ((pointer addons)
444         dependencies queue)
445     ;; Uniquify, first.
446     (while pointer
447       (if (memq (car pointer) (cdr pointer))
448           (setcar pointer nil))
449       (setq pointer (cdr pointer)))
450     (setq dependencies (riece-load-and-build-addon-dependencies
451                         (delq nil addons))
452           pointer dependencies)
453     ;; Sort them.
454     (while pointer
455       (if (zerop (nth 1 (car pointer)))
456           (setq dependencies (delq (car pointer) dependencies)
457                 queue (cons (car pointer) queue)))
458       (setq pointer (cdr pointer)))
459     (setq addons nil)
460     (while queue
461       (setq addons (cons (car (car queue)) addons)
462             pointer (nthcdr 2 (car queue)))
463       (while pointer
464         (let* ((entry (assq (car pointer) dependencies))
465                (count (1- (nth 1 entry))))
466           (if (zerop count)
467               (progn
468                 (setq dependencies (delq entry dependencies)
469                       queue (nconc queue (list entry))))
470             (setcar (cdr entry) count)))
471         (setq pointer (cdr pointer)))
472       (setq queue (cdr queue)))
473     (if dependencies
474         (error "Circular add-on dependency found"))
475     (setq addons (nreverse addons))
476     (while addons
477       (require (car addons))            ;implicit dependency
478       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
479       (if riece-debug
480           (message "Add-on %S is loaded" (car addons)))
481       (setq addons (cdr addons)))))
482
483 (provide 'riece)
484
485 ;;; riece.el ends here