cgit.sxemacs.org Git - riece/blob - lisp/riece.el

   1 ;;; riece.el --- IRC client for Emacsen
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-filter)
  28 (require 'riece-display)
  29 (require 'riece-server)
  30 (require 'riece-compat)
  31 (require 'riece-commands)
  32
  33 (defvar riece-channel-list-mode-map (make-sparse-keymap))
  34 (defvar riece-user-list-mode-map (make-sparse-keymap))
  35
  36 (defvar riece-dialogue-mode-map
  37   (let ((keymap (make-keymap)))
  38     (suppress-keymap keymap 'nodigit)
  39     keymap))
  40
  41 (defvar riece-command-mode-map (make-keymap))
  42 (defvar riece-command-map (make-sparse-keymap))
  43
  44 (defvar riece-command-mode-syntax-table nil)
  45
  46 (put 'riece-command-mode 'mode-class 'special)
  47 (put 'riece-dialogue-mode 'mode-class 'special)
  48 (put 'riece-others-mode 'derived-mode-parent 'riece-dialogue-mode)
  49 (put 'riece-channel-list-mode 'mode-class 'special)
  50 (put 'riece-user-list-mode 'mode-class 'special)
  51 (put 'riece-channel-mode 'derived-mode-parent 'riece-dialogue-mode)
  52
  53 (defvar riece-buffer-alist
  54   '((riece-command-buffer "*Commands*" riece-command-mode)
  55     (riece-dialogue-buffer "*Dialogue*" riece-dialogue-mode)
  56     (riece-others-buffer "*Others*" riece-others-mode)
  57     (riece-channel-list-buffer "*Channels*" riece-channel-list-mode)
  58     (riece-user-list-buffer " *Users*" riece-user-list-mode)))
  59
  60 (defvar riece-select-keys
  61   `("1" riece-command-switch-to-channel-by-number-1
  62     "2" riece-command-switch-to-channel-by-number-2
  63     "3" riece-command-switch-to-channel-by-number-3
  64     "4" riece-command-switch-to-channel-by-number-4
  65     "5" riece-command-switch-to-channel-by-number-5
  66     "6" riece-command-switch-to-channel-by-number-6
  67     "7" riece-command-switch-to-channel-by-number-7
  68     "8" riece-command-switch-to-channel-by-number-8
  69     "9" riece-command-switch-to-channel-by-number-9
  70     "0" riece-command-switch-to-channel-by-number-10
  71     ,(concat riece-command-prefix "1")
  72     riece-command-switch-to-channel-by-number-11
  73     ,(concat riece-command-prefix "2")
  74     riece-command-switch-to-channel-by-number-12
  75     ,(concat riece-command-prefix "3")
  76     riece-command-switch-to-channel-by-number-13
  77     ,(concat riece-command-prefix "4")
  78     riece-command-switch-to-channel-by-number-14
  79     ,(concat riece-command-prefix "5")
  80     riece-command-switch-to-channel-by-number-15
  81     ,(concat riece-command-prefix "6")
  82     riece-command-switch-to-channel-by-number-16
  83     ,(concat riece-command-prefix "7")
  84     riece-command-switch-to-channel-by-number-17
  85     ,(concat riece-command-prefix "8")
  86     riece-command-switch-to-channel-by-number-18
  87     ,(concat riece-command-prefix "9")
  88     riece-command-switch-to-channel-by-number-19
  89     ,(concat riece-command-prefix "0")
  90     riece-command-switch-to-channel-by-number-20))
  91
  92 ;;; Keymap macros. -- borrowed from `gnus-util.el'.
  93 (defmacro riece-local-set-keys (&rest plist)
  94   "Set the keys in PLIST in the current keymap."
  95   `(riece-define-keys-1 (current-local-map) ',plist))
  96
  97 (defmacro riece-define-keys (keymap &rest plist)
  98   "Assign KEYMAP keys from PLIST."
  99   `(riece-define-keys-1 ',keymap ',plist))
 100
 101 (defmacro riece-define-keys-safe (keymap &rest plist)
 102   "Assign KEYMAP keys from PLIST without overwriting previous definitions."
 103   `(riece-define-keys-1 ',keymap ',plist t))
 104
 105 (put 'riece-define-keys 'lisp-indent-function 1)
 106 (put 'riece-define-keys-safe 'lisp-indent-function 1)
 107 (put 'riece-local-set-keys 'lisp-indent-function 1)
 108
 109 (defun riece-define-keys-1 (keymap plist &optional safe)
 110   "Assign KEYMAP keys from PLIST.
 111 If optional argument SAFE is nil, overwrite previous definitions."
 112   (unless keymap
 113     (error "Can't set keys in a null keymap"))
 114   (cond
 115    ((symbolp keymap)
 116     (setq keymap (symbol-value keymap)))
 117    ((keymapp keymap))
 118    ((listp keymap)
 119     (set (car keymap) nil)
 120     (define-prefix-command (car keymap))
 121     (define-key (symbol-value (nth 2 keymap))
 122       (if (symbolp (nth 1 keymap))
 123           (symbol-value (nth 1 keymap))
 124         (nth 1 keymap))
 125       (car keymap))
 126     (setq keymap (symbol-value (car keymap)))))
 127   (let (key)
 128     (while plist
 129       (if (symbolp (setq key (car plist)))
 130           (setq key (symbol-value key)))
 131       (setq plist (cdr plist))
 132       (if (or (not safe)
 133               (eq (lookup-key keymap key) 'undefined))
 134           (define-key keymap key (car plist))
 135         (car plist))
 136       (setq plist (cdr plist)))))
 137
 138 (when t
 139   (riece-define-keys riece-dialogue-mode-map
 140     "\177" scroll-down
 141     [delete] scroll-down
 142     [backspace] scroll-down
 143     [return] scroll-up
 144     " " scroll-up
 145     "$" end-of-buffer
 146     "/" riece-command-raw
 147     ">" end-of-buffer
 148     "<" beginning-of-buffer
 149     "\C-ta" riece-command-toggle-away
 150     "c" riece-command-select-command-buffer
 151     "f" riece-command-finger
 152     "\C-tf" riece-command-toggle-freeze
 153     "\C-to" riece-command-toggle-own-freeze
 154     "\C-tu" riece-command-toggle-user-list-buffer-mode
 155     "\C-tc" riece-command-toggle-channel-buffer-mode
 156     "\C-tC" riece-command-toggle-channel-list-buffer-mode
 157     "\C-tl" riece-command-change-layout
 158     "i" riece-command-invite
 159     "j" riece-command-join
 160     "\C-k" riece-command-kick
 161     "l" riece-command-list
 162     "M" riece-command-change-mode
 163     "n" riece-command-change-nickname
 164     "N" riece-command-names
 165     "o" other-window
 166     "O" riece-command-open-server
 167     "C" riece-command-close-server
 168     "M" riece-command-universal-server-name-argument
 169     "p" riece-command-enter-message-to-user
 170     "q" riece-command-quit
 171     "r" riece-command-configure-windows
 172     "x" riece-command-copy-region
 173     "t" riece-command-topic
 174     "w" riece-command-who)
 175
 176   (riece-define-keys riece-command-mode-map
 177     "\r" riece-command-enter-message
 178     [(control return)] riece-command-enter-message-as-notice)
 179
 180   (riece-define-keys (riece-command-map riece-command-prefix
 181                                         riece-command-mode-map)
 182     "\177" riece-command-scroll-down
 183     [delete] riece-command-scroll-down
 184     [backspace] riece-command-scroll-down
 185     " " riece-command-scroll-up
 186     "$" riece-command-end-of-buffer
 187     ">" riece-command-next-channel
 188     "<" riece-command-previous-channel
 189     "\C-j" riece-command-next-channel
 190     "\C-n" riece-command-names
 191     "l" riece-command-list
 192     "\C-m" riece-command-change-mode
 193     "o" riece-command-set-operators
 194     "\C-p" riece-command-part
 195     "r" riece-command-configure-windows
 196     "v" riece-command-set-speakers
 197     "V" riece-version)
 198   (set-keymap-parent riece-command-map riece-dialogue-mode-map)
 199
 200   (riece-define-keys riece-user-list-mode-map
 201     "o" riece-command-set-operators
 202     "v" riece-command-set-voices
 203     "f" riece-command-finger
 204     " " riece-command-nick-scroll-up
 205     "\177" riece-command-nick-scroll-down
 206     [delete] riece-command-nick-scroll-down
 207     [backspace] riece-command-nick-scroll-down
 208     "c" riece-command-select-command-buffer)
 209
 210   (riece-define-keys riece-channel-list-mode-map
 211     ">" riece-command-next-channel
 212     "<" riece-command-previous-channel
 213     "o" other-window
 214     "c" riece-command-select-command-buffer)
 215
 216   (riece-define-keys-1 riece-dialogue-mode-map riece-select-keys)
 217   (riece-define-keys-1 riece-channel-list-mode-map riece-select-keys))
 218
 219 (defun riece-read-variables-files (&optional file)
 220   "Read variables FILEs."
 221   (or (file-directory-p riece-directory)
 222       (make-directory riece-directory))
 223   (let ((files (if file
 224                    (setq riece-variables-file file
 225                          riece-variables-files (list file))
 226                  riece-variables-files)))
 227     (while files
 228       (condition-case nil
 229           (load (expand-file-name (car files)))
 230         (file-error nil))
 231       (setq files (cdr files)))))
 232
 233 (defvar print-quoted)
 234 (defvar print-escape-multibyte)
 235 (defun riece-save-variables-files ()
 236   "Save current settings to `riece-variables-file'."
 237   (with-temp-file riece-saved-variables-file
 238     (let ((print-quoted t)
 239           (print-readably t)
 240           print-escape-multibyte
 241           print-level
 242           print-length
 243           (variables riece-saved-forms))
 244       (while variables
 245         (prin1 `(setq ,(car variables)
 246                       ',(symbol-value (car variables)))
 247                (current-buffer))
 248         (insert "\n")
 249         (setq variables (cdr variables)))))
 250   (setq riece-save-variables-are-dirty nil))
 251
 252 ;;;###autoload
 253 (defun riece (&optional confirm)
 254   "Connect to the IRC server and start chatting.
 255 If optional argument CONFIRM is non-nil, ask which IRC server to connect."
 256   (interactive "P")
 257   (riece-read-variables-files (if noninteractive
 258                                   (car command-line-args-left)))
 259   (riece-insinuate-addons riece-addons)
 260   (run-hooks 'riece-after-load-startup-hook)
 261   (if (riece-server-opened)
 262       (error "Already running"))
 263   (if (or confirm (null riece-server))
 264       (setq riece-server (completing-read "Server: " riece-server-alist)))
 265   (if (stringp riece-server)
 266       (setq riece-server (riece-server-name-to-server riece-server)))
 267   (riece-create-buffers)
 268   (switch-to-buffer riece-command-buffer)
 269   (riece-redisplay-buffers)
 270   (riece-open-server riece-server "")
 271   (run-hooks 'riece-startup-hook)
 272   (message "%s" (substitute-command-keys "Type \\[describe-mode] for help")))
 273
 274 (defun riece-exit ()
 275   (if riece-save-variables-are-dirty
 276       (riece-save-variables-files))
 277   (while riece-buffer-list
 278     (if (and (get-buffer (car riece-buffer-list))
 279              (buffer-live-p (car riece-buffer-list)))
 280         (funcall riece-buffer-dispose-function (car riece-buffer-list)))
 281     (setq riece-buffer-list (cdr riece-buffer-list)))
 282   (setq riece-server nil
 283         riece-current-channels nil
 284         riece-current-channel nil
 285         riece-channel-buffer-alist nil
 286         riece-user-indicator nil
 287         riece-long-channel-indicator "None"
 288         riece-channel-list-indicator "No channel"
 289         riece-away-indicator "-"
 290         riece-operator-indicator "-"
 291         riece-freeze-indicator "-")
 292   (delete-other-windows)
 293   (run-hooks 'riece-exit-hook))
 294
 295 (defun riece-command-mode ()
 296   "Major mode for Riece.  Normal edit function are available.
 297 Typing Return or Linefeed enters the current line in the dialogue.
 298 The following special commands are available:
 299 For a list of the generic commands type \\[riece-command-generic] ? RET.
 300 \\{riece-command-mode-map}"
 301   (interactive)
 302   (kill-all-local-variables)
 303
 304   (setq riece-away-indicator "-"
 305         riece-operator-indicator "-"
 306         major-mode 'riece-command-mode
 307         mode-name "Commands"
 308         mode-line-buffer-identification
 309         (riece-mode-line-buffer-identification
 310          '("Riece: "
 311            riece-away-indicator
 312            riece-operator-indicator
 313            riece-freeze-indicator
 314            " "
 315            riece-user-indicator
 316            " "
 317            riece-channel-indicator)))
 318   (riece-simplify-mode-line-format)
 319   (use-local-map riece-command-mode-map)
 320
 321   (unless riece-command-mode-syntax-table
 322     (setq riece-command-mode-syntax-table
 323           (copy-syntax-table (syntax-table)))
 324     (set-syntax-table riece-command-mode-syntax-table)
 325     (mapcar
 326      (lambda (c) (modify-syntax-entry c "w"))
 327      "^[]{}'`"))
 328
 329   (run-hooks 'riece-command-mode-hook))
 330
 331 (defun riece-dialogue-mode ()
 332   "Major mode for displaying the IRC dialogue.
 333 All normal editing commands are turned off.
 334 Instead, these commands are available:
 335 \\{riece-dialogue-mode-map}"
 336   (kill-all-local-variables)
 337   (make-local-variable 'riece-freeze)
 338   (setq riece-freeze riece-default-freeze
 339         riece-away-indicator "-"
 340         riece-operator-indicator "-"
 341         major-mode 'riece-dialogue-mode
 342         mode-name "Dialogue"
 343         mode-line-buffer-identification
 344         (riece-mode-line-buffer-identification
 345          '("Riece: "
 346            riece-away-indicator
 347            riece-operator-indicator
 348            riece-freeze-indicator
 349            " "
 350            riece-channel-list-indicator " "))
 351         buffer-read-only t)
 352   (riece-simplify-mode-line-format)
 353   (use-local-map riece-dialogue-mode-map)
 354   (buffer-disable-undo)
 355   (run-hooks 'riece-dialogue-mode-hook))
 356
 357 (define-derived-mode riece-others-mode riece-dialogue-mode
 358   "Others"
 359   "Major mode for displaying the IRC others message except current channel.
 360 All normal editing commands are turned off.
 361 Instead, these commands are available:
 362 \\{riece-others-mode-map}")
 363
 364 (define-derived-mode riece-channel-mode riece-dialogue-mode
 365   "Channel"
 366   "Major mode for displaying the IRC current channel buffer.
 367 All normal editing commands are turned off.
 368 Instead, these commands are available:
 369 \\{riece-channel-mode-map}"
 370   (setq mode-line-buffer-identification
 371         (riece-mode-line-buffer-identification
 372          '("Riece: "
 373            riece-away-indicator
 374            riece-operator-indicator
 375            riece-freeze-indicator
 376            " "
 377            riece-long-channel-indicator))))
 378
 379 (defun riece-channel-list-mode ()
 380   "Major mode for displaying channel list.
 381 All normal editing commands are turned off."
 382   (kill-all-local-variables)
 383   (buffer-disable-undo)
 384   (setq major-mode 'riece-channel-list-mode
 385         mode-name "Channels"
 386         mode-line-buffer-identification
 387         (riece-mode-line-buffer-identification '("Riece: "))
 388         truncate-lines t
 389         buffer-read-only t)
 390   (make-local-hook 'riece-update-buffer-functions)
 391   (add-hook 'riece-update-buffer-functions
 392             'riece-update-channel-list-buffer nil t)
 393   (use-local-map riece-channel-list-mode-map)
 394   (run-hooks 'riece-channel-list-mode-hook))
 395
 396 (defun riece-user-list-mode ()
 397   "Major mode for displaying members in the IRC current channel buffer.
 398 All normal editing commands are turned off.
 399 Instead, these commands are available:
 400 \\{riece-user-list-mode-map}"
 401   (kill-all-local-variables)
 402   (buffer-disable-undo)
 403   (setq major-mode 'riece-user-list-mode
 404         mode-name "User list"
 405         mode-line-buffer-identification
 406         (riece-mode-line-buffer-identification
 407          '("Riece: " riece-long-channel-indicator " "))
 408         truncate-lines t
 409         buffer-read-only t)
 410   (if (boundp 'transient-mark-mode)
 411       (set (make-local-variable 'transient-mark-mode) t))
 412   (make-local-hook 'riece-update-buffer-functions)
 413   (add-hook 'riece-update-buffer-functions
 414             'riece-update-user-list-buffer nil t)
 415   (use-local-map riece-user-list-mode-map)
 416   (run-hooks 'riece-user-list-mode-hook))
 417
 418 (defun riece-create-buffers ()
 419   (let ((alist riece-buffer-alist))
 420     (while alist
 421       (save-excursion
 422         (set-buffer (apply #'riece-get-buffer-create
 423                            (cdr (car alist))))
 424         (set (car (car alist)) (current-buffer))
 425         (unless (or (null (nth 2 (car alist)))
 426                     (eq major-mode (nth 2 (car alist))))
 427           (funcall (nth 2 (car alist))))
 428         (setq alist (cdr alist))))))
 429
 430 (defun riece-load-and-build-addon-dependencies (addons)
 431   (let ((load-path (cons riece-addon-directory load-path))
 432         dependencies)
 433     (while addons
 434       (require (car addons))            ;error will be reported here
 435       (let* ((requires
 436               (funcall (or (intern-soft
 437                             (concat (symbol-name (car addons)) "-requires"))
 438                            #'ignore)))
 439              (pointer requires)
 440              entry)
 441         ;; Increment succs' pred count.
 442         (if (setq entry (assq (car addons) dependencies))
 443             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 444           (setq dependencies (cons (list (car addons) (length requires))
 445                                    dependencies)))
 446         ;; Merge pred's succs.
 447         (while pointer
 448           (if (setq entry (assq (car pointer) dependencies))
 449               (setcdr (cdr entry)
 450                       (cons (car addons) (nthcdr 2 entry)))
 451             (setq dependencies (cons (list (car pointer) 0 (car addons))
 452                                      dependencies)))
 453           (setq pointer (cdr pointer))))
 454       (setq addons (cdr addons)))
 455     dependencies))
 456
 457 (defun riece-insinuate-addons (addons)
 458   (let ((pointer addons)
 459         dependencies queue)
 460     ;; Uniquify, first.
 461     (while pointer
 462       (if (memq (car pointer) (cdr pointer))
 463           (setcar pointer nil))
 464       (setq pointer (cdr pointer)))
 465     (setq dependencies (riece-load-and-build-addon-dependencies
 466                         (delq nil addons))
 467           pointer dependencies)
 468     ;; Sort them.
 469     (while pointer
 470       (if (zerop (nth 1 (car pointer)))
 471           (setq dependencies (delq (car pointer) dependencies)
 472                 queue (cons (car pointer) queue)))
 473       (setq pointer (cdr pointer)))
 474     (setq addons nil)
 475     (while queue
 476       (setq addons (cons (car (car queue)) addons)
 477             pointer (nthcdr 2 (car queue)))
 478       (while pointer
 479         (let* ((entry (assq (car pointer) dependencies))
 480                (count (1- (nth 1 entry))))
 481           (if (zerop count)
 482               (progn
 483                 (setq dependencies (delq entry dependencies)
 484                       queue (nconc queue (list entry))))
 485             (setcar (cdr entry) count)))
 486         (setq pointer (cdr pointer)))
 487       (setq queue (cdr queue)))
 488     (if dependencies
 489         (error "Circular add-on dependency found"))
 490     (setq addons (nreverse addons))
 491     (while addons
 492       (require (car addons))            ;implicit dependency
 493       (funcall (intern (concat (symbol-name (car addons)) "-insinuate")))
 494       (if riece-debug
 495           (message "Add-on %S is loaded" (car addons)))
 496       (setq addons (cdr addons)))))
 497
 498 (provide 'riece)
 499
 500 ;;; riece.el ends here