cgit.sxemacs.org Git - riece/blob - lisp/riece-server.el

   1 ;;; riece-server.el --- functions to open and close servers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-options)
  28 (require 'riece-globals)                ;for server local variables.
  29 (require 'riece-coding)                 ;riece-default-coding-system
  30 (require 'riece-identity)
  31 (require 'riece-compat)
  32
  33 (eval-and-compile
  34   (defvar riece-server-keyword-map
  35     '((:host)
  36       (:service 6667)
  37       (:nickname riece-nickname)
  38       (:username riece-username)
  39       (:password)
  40       (:function riece-default-open-connection-function)
  41       (:coding riece-default-coding-system))
  42     "Mapping from keywords to default values.
  43 All keywords that can be used must be listed here."))
  44
  45 (defmacro riece-server-keyword-bind (plist &rest body)
  46   "Return a `let' form that binds all variables in PLIST.
  47 After this is done, BODY will be executed in the scope
  48 of the `let' form.
  49
  50 The variables bound and their default values are described by
  51 the `riece-server-keyword-map' variable."
  52   `(let ,(mapcar
  53           (lambda (keyword)
  54             (list (intern (substring (symbol-name (car keyword)) 1))
  55                   (if (cadr keyword)
  56                       `(or (plist-get ,plist ',(car keyword))
  57                            ,(cadr keyword))
  58                     `(plist-get ,plist ',(car keyword)))))
  59           riece-server-keyword-map)
  60      ,@body))
  61
  62 (put 'riece-server-keyword-bind 'lisp-indent-function 1)
  63 (put 'riece-server-keyword-bind 'edebug-form-spec '(form body))
  64
  65 (defun riece-server-parse-string (string)
  66   "Convert a STRING set as `riece-server' and return a property list."
  67   (when (or (string-match "^\\[\\([^]]+\\)\\]:?\\([0-9]*\\)" string)
  68             (string-match "^\\([^:]+\\):?\\([0-9]*\\)" string))
  69     (let ((host (match-string 1 string))
  70           (service (match-string 2 string))
  71           (password (substring string (match-end 0)))
  72           plist)
  73       (setq plist (cons `(:host ,host) plist))
  74       (unless (equal service "")
  75         (setq plist (cons `(:service ,(string-to-int service)) plist)))
  76       (unless (equal password "")
  77         (setq plist (cons `(:password ,(substring password 1)) plist)))
  78       (apply #'nconc plist))))
  79
  80 (defun riece-server-name-to-server (server-name)
  81   (let ((entry (assoc server-name riece-server-alist)))
  82     (if entry
  83         (unless (listp (cdr entry))
  84           (setcdr entry (riece-server-parse-string (cdr entry))))
  85       (setq entry (cons server-name (riece-server-parse-string server-name))
  86             riece-server-alist (cons entry riece-server-alist)
  87             riece-save-variables-are-dirty t))
  88     (cdr entry)))
  89
  90 (defun riece-server-process-name (server-name)
  91   (if (equal server-name "")
  92       "IRC"
  93     (format "IRC<%s>" server-name)))
  94
  95 (defun riece-server-process (server-name)
  96   (cdr (assoc server-name riece-server-process-alist)))
  97
  98 (defmacro riece-with-server-buffer (server-name &rest body)
  99   `(let ((process (riece-server-process ,server-name)))
 100      (if process
 101          (with-current-buffer (process-buffer process)
 102            ,@body)
 103        (error "Server closed"))))
 104
 105 (put 'riece-with-server-buffer 'lisp-indent-function 1)
 106 (put 'riece-with-server-buffer 'edebug-form-spec '(form body))
 107
 108 ;; stolen (and renamed) from time-date.el.
 109 (defun riece-seconds-to-time (seconds)
 110   "Convert SECONDS (a floating point number) to a time value."
 111   (list (floor seconds 65536)
 112         (floor (mod seconds 65536))
 113         (floor (* (- seconds (ffloor seconds)) 1000000))))
 114
 115 ;; stolen (and renamed) from time-date.el.
 116 (defun riece-time-less-p (t1 t2)
 117   "Say whether time value T1 is less than time value T2."
 118   (or (< (car t1) (car t2))
 119       (and (= (car t1) (car t2))
 120            (< (nth 1 t1) (nth 1 t2)))))
 121
 122 ;; stolen (and renamed) from time-date.el.
 123 (defun riece-time-since (time)
 124   "Return the time elapsed since TIME."
 125   (let* ((current (current-time))
 126          (rest (when (< (nth 1 current) (nth 1 time))
 127                  (expt 2 16))))
 128     (list (- (+ (car current) (if rest -1 0)) (car time))
 129           (- (+ (or rest 0) (nth 1 current)) (nth 1 time)))))
 130
 131 (defun riece-flush-send-queue (process)
 132   (with-current-buffer (process-buffer process)
 133     (let ((length 0)
 134           string)
 135       (if (riece-time-less-p (riece-seconds-to-time riece-send-delay)
 136                              (riece-time-since riece-last-send-time))
 137           (setq riece-send-size 0))
 138       (while (and riece-send-queue
 139                   (<= riece-send-size riece-max-send-size))
 140         (setq string (riece-encode-coding-string (car riece-send-queue))
 141               length (length string))
 142         (if (> length riece-max-send-size)
 143             (message "Long message (%d > %d)" length riece-max-send-size)
 144           (setq riece-send-size (+ riece-send-size length))
 145           (when (<= riece-send-size riece-max-send-size)
 146             (process-send-string process string)
 147             (setq riece-last-send-time (current-time))))
 148         (setq riece-send-queue (cdr riece-send-queue)))
 149       (if riece-send-queue
 150           (riece-run-at-time riece-send-delay nil
 151                              #'riece-flush-send-queue process)))))
 152
 153 (defun riece-process-send-string (process string)
 154   (with-current-buffer (process-buffer process)
 155     (setq riece-send-queue (nconc riece-send-queue (list string))))
 156   (riece-flush-send-queue process))
 157
 158 (defun riece-current-server-name ()
 159   (or riece-overriding-server-name
 160                                         ;already in the server buffer
 161       (if (local-variable-p 'riece-server-name (current-buffer))
 162           riece-server-name
 163         (if riece-current-channel
 164             (riece-identity-server riece-current-channel)
 165           (if (riece-server-opened "")
 166               "")))))
 167
 168 (defun riece-send-string (string)
 169   (let* ((server-name (riece-current-server-name))
 170          (process (riece-server-process server-name)))
 171     (unless process
 172       (error "%s" (substitute-command-keys
 173                    "Type \\[riece-command-open-server] to open server.")))
 174     (riece-process-send-string process string)))
 175
 176 (defun riece-open-server (server server-name)
 177   (let ((protocol (or (plist-get server :protocol)
 178                       riece-protocol))
 179         function
 180         process)
 181     (condition-case nil
 182         (require (intern (concat "riece-" (symbol-name protocol))))
 183       (error))
 184     (setq function (intern-soft (concat "riece-"
 185                                         (symbol-name protocol)
 186                                         "-open-server")))
 187     (unless function
 188       (error "\"%S\" is not supported" protocol))
 189     (condition-case nil
 190         (setq process (funcall function server server-name))
 191       (error))
 192     (when process
 193       (with-current-buffer (process-buffer process)
 194         (make-local-variable 'riece-protocol)
 195         (setq riece-protocol protocol))
 196       (setq riece-server-process-alist
 197             (cons (cons server-name process)
 198                   riece-server-process-alist)))))
 199
 200 (defun riece-quit-server-process (process &optional message)
 201   (let ((function (intern-soft
 202                    (concat "riece-"
 203                            (with-current-buffer (process-buffer process)
 204                              (symbol-name riece-protocol))
 205                            "-quit-server-process"))))
 206     (if function
 207         (funcall function process message))))
 208
 209 (defun riece-reset-process-buffer (process)
 210   (save-excursion
 211     (set-buffer (process-buffer process))
 212     (if (fboundp 'set-buffer-multibyte)
 213         (set-buffer-multibyte nil))
 214     (kill-all-local-variables)
 215     (make-local-variable 'riece-real-nickname)
 216     (make-local-variable 'riece-last-nickname)
 217     (make-local-variable 'riece-nick-accepted)
 218     (make-local-variable 'riece-real-server-name)
 219     (make-local-variable 'riece-real-userhost)
 220     (make-local-variable 'riece-user-at-host)
 221     (make-local-variable 'riece-user-at-host-type)
 222     (make-local-variable 'riece-supported-user-modes)
 223     (make-local-variable 'riece-supported-channel-modes)
 224     (make-local-variable 'riece-channel-filter)
 225     (make-local-variable 'riece-server-name)
 226     (make-local-variable 'riece-read-point)
 227     (setq riece-read-point (point-min))
 228     (make-local-variable 'riece-send-queue)
 229     (make-local-variable 'riece-send-size)
 230     (setq riece-send-size 0)
 231     (make-local-variable 'riece-last-send-time)
 232     (setq riece-last-send-time '(0 0 0))
 233     (make-local-variable 'riece-obarray)
 234     (setq riece-obarray (make-vector riece-obarray-size 0))
 235     (make-local-variable 'riece-coding-system)
 236     (buffer-disable-undo)
 237     (erase-buffer)))
 238
 239 (defun riece-close-server-process (process)
 240   (kill-buffer (process-buffer process))
 241   (setq riece-server-process-alist
 242         (delq (rassq process riece-server-process-alist)
 243               riece-server-process-alist)))
 244
 245 (defun riece-server-process-opened (process)
 246   (not (null (memq (process-status process) '(open run)))))
 247
 248 (defun riece-server-opened (&optional server-name)
 249   (if server-name
 250       (let ((process (riece-server-process server-name)))
 251         (and process
 252              (riece-server-process-opened process)))
 253     (let ((alist riece-server-process-alist))
 254       (catch 'found
 255         (while alist
 256           (if (riece-server-process-opened (cdr (car alist)))
 257               (throw 'found t))
 258           (setq alist (cdr alist)))))))
 259
 260 (provide 'riece-server)
 261
 262 ;;; riece-server.el ends here