cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- ruby implementation of DCC add-on
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-globals)
  27 (require 'riece-misc)
  28 (require 'riece-channel)
  29 (require 'riece-identity)
  30 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  31
  32 (defgroup riece-rdcc nil
  33   "DCC implementation using ruby"
  34   :prefix "riece-"
  35   :group 'riece)
  36
  37 (defcustom riece-rdcc-server-address nil
  38   "Local address of the DCC server.
  39 Only used for sending files."
  40   :type 'string
  41   :group 'riece-rdcc)
  42
  43 (defcustom riece-rdcc-ruby-command "ruby"
  44   "Command name for Ruby interpreter."
  45   :type 'string
  46   :group 'riece-rdcc)
  47
  48 (defcustom riece-rdcc-send-program
  49   '("\
  50 address = " address "
  51 unless address
  52   sock = UDPSocket.new
  53   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  54   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  55 end
  56 server = TCPServer.new(address, 0)
  57 puts(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  58 session = server.accept
  59 if session
  60   total = 0
  61   File.open(" file ") {|file|
  62     while (bytes = file.read(4096))
  63       total += bytes.length
  64       puts(\"#{total}\")
  65       session.write(bytes)
  66     end
  67   }
  68   session.close
  69 end
  70 ")
  71   "Ruby program to send file with DCC."
  72   :type 'list
  73   :group 'riece-rdcc)
  74
  75 (defcustom riece-rdcc-decode-address-program
  76   '("\
  77 puts(\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  78     address " >> 8 & 0xFF}.#{" address " & 0xFF}\")")
  79   "Ruby program to numeric IP address."
  80   :type 'list
  81   :group 'riece-rdcc)
  82
  83 (defvar riece-rdcc-requests nil)
  84
  85 (defvar riece-rdcc-request-user nil)
  86 (defvar riece-rdcc-request-file nil)
  87 (defvar riece-rdcc-request-size nil)
  88
  89 (defvar jka-compr-compression-info-list)
  90 (defvar jam-zcat-filename-list)
  91 (defun riece-rdcc-substitute-variables (program variable value)
  92   (setq program (copy-sequence program))
  93   (let ((pointer program))
  94     (while pointer
  95       (setq pointer (memq variable program))
  96       (if pointer
  97           (setcar pointer value)))
  98     program))
  99
 100 (defun riece-rdcc-server-filter (process input)
 101   (save-excursion
 102     (set-buffer (process-buffer process))
 103     (goto-char (point-max))
 104     (insert input)
 105     (goto-char (point-min))
 106     (while (and (not (eobp))
 107                 (looking-at "\\([0-9]+\\)\n"))
 108       (message "Sending %s...(%s/%d)"
 109                riece-rdcc-request-file
 110                (match-string 1) riece-rdcc-request-size)
 111       (forward-line))
 112     (unless (eobp)
 113       (delete-region (point-min) (point)))))
 114
 115 (defun riece-rdcc-server-sentinel (process status)
 116   (with-current-buffer (process-buffer process)
 117     (message "Sending %s...done" riece-rdcc-request-file))
 118   (kill-buffer (process-buffer process))
 119   (delete-process process))
 120
 121 (defun riece-command-dcc-send (user file)
 122   (interactive
 123    (let ((completion-ignore-case t))
 124      (list (completing-read
 125             "User: "
 126             (mapcar #'list (riece-get-users-on-server)))
 127            (expand-file-name (read-file-name "File: ")))))
 128   (let ((process
 129          (start-process "DCC" (generate-new-buffer " *DCC*")
 130                         "ruby" "-rsocket")))
 131     (process-send-string process
 132                          (apply #'concat
 133                                 (riece-rdcc-substitute-variables
 134                                  (riece-rdcc-substitute-variables
 135                                   riece-rdcc-send-program
 136                                   'address
 137                                   (if riece-rdcc-server-address
 138                                       (concat "'" riece-rdcc-server-address
 139                                               "'")
 140                                     "nil"))
 141                                  'file
 142                                  (concat "'" file "'"))))
 143     (process-send-eof process)
 144     (save-excursion
 145       (set-buffer (process-buffer process))
 146       (while (and (eq (process-status process) 'run)
 147                   (progn
 148                     (goto-char (point-min))
 149                     (not (looking-at "\\([0-9]+\\) \\([0-9]+\\)"))))
 150         (accept-process-output))
 151       (if (eq (process-status process) 'run)
 152           (let ((address (match-string 1))
 153                 (port (match-string 2)))
 154             (erase-buffer)
 155             (make-local-variable 'riece-rdcc-request-size)
 156             (setq riece-rdcc-request-file file
 157                   riece-rdcc-request-size (nth 7 (file-attributes file)))
 158             (set-buffer-modified-p nil)
 159             (set-process-filter process #'riece-rdcc-server-filter)
 160             (set-process-sentinel process #'riece-rdcc-server-sentinel)
 161             (riece-send-string
 162              (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 163                      user (file-name-nondirectory file)
 164                      address port
 165                      riece-rdcc-request-size)))))))
 166
 167 (defun riece-rdcc-filter (process input)
 168   (save-excursion
 169     (set-buffer (process-buffer process))
 170     (goto-char (point-max))
 171     (insert input)
 172     (message "Receiving %s from %s...(%d/%d)"
 173              (file-name-nondirectory riece-rdcc-request-file)
 174              riece-rdcc-request-user
 175              (1- (point))
 176              riece-rdcc-request-size)))
 177
 178 (defun riece-rdcc-sentinel (process status)
 179   (save-excursion
 180     (set-buffer (process-buffer process))
 181     (unless (= (buffer-size) riece-rdcc-request-size)
 182       (error "Premature end of file"))
 183     (message "Receiving %s from %s...done"
 184              (file-name-nondirectory riece-rdcc-request-file)
 185              riece-rdcc-request-user)
 186     (let ((coding-system-for-write 'binary)
 187           jka-compr-compression-info-list jam-zcat-filename-list)
 188       (write-region (point-min) (point-max) riece-rdcc-request-file)))
 189   (kill-buffer (process-buffer process))
 190   (delete-process process))
 191
 192 (defun riece-rdcc-decode-address (address)
 193   (with-temp-buffer
 194     (call-process riece-rdcc-ruby-command nil t nil "-e"
 195                   (apply #'concat
 196                          (riece-rdcc-substitute-variables
 197                           riece-rdcc-decode-address-program
 198                           'address
 199                           address)))
 200     (buffer-substring (point-min) (1- (point-max)))))
 201
 202 (defun riece-command-dcc-receive (request file)
 203   (interactive
 204    (progn
 205      (unless riece-rdcc-requests
 206        (error "No request"))
 207      (let* ((request
 208              (if (= (length riece-rdcc-requests) 1)
 209                  (car riece-rdcc-requests)
 210                (with-output-to-temp-buffer "*Help*"
 211                  (let ((requests riece-rdcc-requests)
 212                        (index 1))
 213                    (while requests
 214                      (princ (format "%2d: %s %s (%d bytes)\n"
 215                                     index
 216                                     (car (car requests))
 217                                     (nth 1 (car requests))
 218                                     (nth 4 (car requests))))
 219                      (setq index (1+ index)
 220                            requests (cdr requests)))))
 221                (let ((number (read-string "Request#: ")))
 222                  (unless (string-match "^[0-9]+$" number)
 223                    (error "Not a number"))
 224                  (if (or (> (setq number (string-to-number number))
 225                             (length riece-rdcc-requests))
 226                          (< number 1))
 227                      (error "Invalid number"))
 228                  (nth (1- number) riece-rdcc-requests))))
 229             (default-name (expand-file-name
 230                            (nth 1 request) default-directory)))
 231        (list request
 232              (expand-file-name
 233               (read-file-name
 234                (concat "Save as (default "
 235                        (file-name-nondirectory default-name) ") ")
 236                (file-name-directory default-name)
 237                default-name))))))
 238   (let* (selective-display
 239          (coding-system-for-read 'binary)
 240          (coding-system-for-write 'binary)
 241          (process (open-network-stream
 242                    "DCC" (generate-new-buffer " *DCC*")
 243                    (riece-rdcc-decode-address (nth 2 request))
 244                    (nth 3 request))))
 245     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 246     (with-current-buffer (process-buffer process)
 247       (if (fboundp 'set-buffer-multibyte)
 248           (set-buffer-multibyte nil))
 249       (buffer-disable-undo)
 250       (erase-buffer)
 251       (make-local-variable 'riece-rdcc-request-user)
 252       (setq riece-rdcc-request-user (car request))
 253       (make-local-variable 'riece-rdcc-request-file)
 254       (setq riece-rdcc-request-file file)
 255       (make-local-variable 'riece-rdcc-request-size)
 256       (setq riece-rdcc-request-size (nth 4 request)))
 257     (set-process-filter process #'riece-rdcc-filter)
 258     (set-process-sentinel process #'riece-rdcc-sentinel)))
 259
 260 (defun riece-handle-dcc-request (prefix target message)
 261   (let ((case-fold-search t))
 262     (when (string-match
 263            "SEND \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 264            message)
 265       (let ((file (match-string 1 message))
 266             (address (match-string 2 message))
 267             (port (string-to-number (match-string 3 message)))
 268             (size (string-to-number (match-string 4 message)))
 269             (buffer (if (riece-channel-p target)
 270                         (cdr (riece-identity-assoc
 271                               (riece-make-identity target)
 272                               riece-channel-buffer-alist))))
 273             (user (riece-prefix-nickname prefix)))
 274         (setq riece-rdcc-requests
 275               (cons (list user file address port size)
 276                     riece-rdcc-requests))
 277         (riece-insert-change buffer (format "DCC SEND from %s\n" user))
 278         (riece-insert-change
 279          (if (and riece-channel-buffer-mode
 280                   (not (eq buffer riece-channel-buffer)))
 281              (list riece-dialogue-buffer riece-others-buffer)
 282            riece-dialogue-buffer)
 283          (concat
 284           (riece-concat-server-name
 285            (format "DCC SEND from %s (%s) to %s"
 286                    user
 287                    (riece-strip-user-at-host
 288                     (riece-prefix-user-at-host prefix))
 289                    target))
 290           "\n")))
 291       t)))
 292
 293 (defun riece-rdcc-requires ()
 294   '(riece-ctcp))
 295
 296 (defvar riece-dialogue-mode-map)
 297 (defun riece-rdcc-insinuate ()
 298   (add-to-list 'riece-ctcp-additional-clientinfo "DCC" t)
 299   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request)
 300   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 301   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 302
 303 (provide 'riece-rdcc)
 304
 305 ;;; riece-rdcc.el ends here