cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- DCC file sending protocol support (written in Ruby)
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; NOTE: This is an add-on module for Riece.
  27
  28 ;;; Code:
  29
  30 (require 'riece-globals)
  31 (require 'riece-misc)
  32 (require 'riece-channel)
  33 (require 'riece-identity)
  34 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  35 (require 'riece-ruby)
  36 (require 'riece-mcat)
  37
  38 (defgroup riece-rdcc nil
  39   "DCC written in Ruby."
  40   :prefix "riece-"
  41   :group 'riece)
  42
  43 (defcustom riece-rdcc-server-address nil
  44   "Local address of the DCC server.
  45 Only used for sending files."
  46   :type 'string
  47   :group 'riece-rdcc)
  48
  49 (defcustom riece-rdcc-server-port nil
  50   "Local port of the DCC server.
  51 Only used for sending files."
  52   :type 'integer
  53   :group 'riece-rdcc)
  54
  55 (defcustom riece-rdcc-send-program
  56   '("\
  57 require 'socket'
  58 address = " address "
  59 port = " port "
  60 unless address
  61   sock = UDPSocket.new
  62   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  63   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  64 end
  65 server = TCPServer.new(address, port)
  66 output(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  67 session = server.accept
  68 if session
  69   total = 0
  70   File.open(" file ") {|file|
  71     while (bytes = file.read(" block-size "))
  72       total += bytes.length
  73       output(total)
  74       session.write(bytes)
  75       begin
  76         buf = session.read(4)
  77       end until buf.unpack('N')[0] == total
  78     end
  79   }
  80   session.close
  81 end
  82 ")
  83   "Ruby program to send file with DCC."
  84   :type 'sexp
  85   :group 'riece-rdcc)
  86
  87 (defcustom riece-rdcc-decode-address-program
  88   '("\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  89     address " >> 8 & 0xFF}.#{" address " & 0xFF}\"")
  90   "Ruby program to numeric IP address."
  91   :type 'sexp
  92   :group 'riece-rdcc)
  93
  94 (defcustom riece-rdcc-save-directory nil
  95   "Default directory where received files are saved in."
  96   :type 'directory
  97   :group 'riece-rdcc)
  98
  99 (defcustom riece-rdcc-block-size 1024
 100   "Number of bytes sent as a block."
 101   :type 'integer
 102   :group 'riece-rdcc)
 103
 104 (defvar riece-rdcc-requests nil)
 105
 106 (defvar riece-rdcc-request-user nil)
 107 (defvar riece-rdcc-request-file nil)
 108 (defvar riece-rdcc-request-size nil)
 109
 110 (defvar riece-rdcc-temp-file nil)
 111 (defvar riece-rdcc-received-size nil)
 112
 113 (defconst riece-rdcc-description
 114   "DCC file sending protocol support (written in Ruby.)")
 115
 116 (defvar temporary-file-directory)
 117 (defvar jka-compr-compression-info-list)
 118 (defvar jam-zcat-filename-list)
 119
 120 (defun riece-rdcc-output-handler (name output time)
 121   (if (string-match "\\([0-9]+\\) \\([0-9]+\\)" output)
 122       (let ((address (match-string 1 output))
 123             (port (match-string 2 output)))
 124         (riece-send-string
 125          (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 126                  (riece-identity-prefix
 127                   (riece-ruby-property name 'riece-rdcc-request-user))
 128                  (file-name-nondirectory
 129                   (riece-ruby-property name 'riece-rdcc-request-file))
 130                  address port
 131                  (riece-ruby-property name 'riece-rdcc-request-size)))))
 132   (riece-ruby-set-output-handler name #'riece-rdcc-output-handler-2))
 133
 134 (defun riece-rdcc-output-handler-2 (name output time)
 135   (message (riece-mcat "Sending %s...(%s/%d)")
 136            (riece-ruby-property name 'riece-rdcc-request-file)
 137            (string-to-number output)
 138            (riece-ruby-property name 'riece-rdcc-request-size)))
 139
 140 (defun riece-rdcc-exit-handler (name)
 141   (message (riece-mcat "Sending %s...done")
 142            (riece-ruby-property name 'riece-rdcc-request-file)))
 143
 144 (defun riece-command-dcc-send (user file)
 145   (interactive
 146    (let ((completion-ignore-case t))
 147      (list (riece-completing-read-identity
 148             (riece-mcat "User: ")
 149             (riece-get-users-on-server (riece-current-server-name)))
 150            (expand-file-name (read-file-name (riece-mcat "File: "))))))
 151   (let ((name (riece-ruby-execute
 152                (riece-ruby-substitute-variables
 153                 riece-rdcc-send-program
 154                 (list (cons 'address
 155                             (if riece-rdcc-server-address
 156                                 (concat "'" riece-rdcc-server-address
 157                                           "'")
 158                               "nil"))
 159                       (cons 'port
 160                             (if riece-rdcc-server-port
 161                                 (number-to-string riece-rdcc-server-port)
 162                               "0"))
 163                       (cons 'file
 164                             (concat "'" file "'"))
 165                       (cons 'block-size
 166                             (number-to-string
 167                              riece-rdcc-block-size)))))))
 168     (riece-ruby-set-property name 'riece-rdcc-request-user user)
 169     (riece-ruby-set-property name 'riece-rdcc-request-file file)
 170     (riece-ruby-set-property name 'riece-rdcc-request-size
 171                              (nth 7 (file-attributes file)))
 172     (riece-ruby-set-output-handler name #'riece-rdcc-output-handler)
 173     (riece-ruby-set-exit-handler name #'riece-rdcc-exit-handler)))
 174
 175 (defun riece-rdcc-filter (process input)
 176   (save-excursion
 177     (set-buffer (process-buffer process))
 178     (erase-buffer)
 179     (insert input)
 180     (let ((coding-system-for-write 'binary)
 181           jka-compr-compression-info-list jam-zcat-filename-list)
 182       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 183     (setq riece-rdcc-received-size (+ (buffer-size) riece-rdcc-received-size))
 184     (process-send-string
 185      process
 186      (format "%c%c%c%c"
 187              (lsh riece-rdcc-received-size -24)
 188              (logand (lsh riece-rdcc-received-size -16) 255)
 189              (logand (lsh riece-rdcc-received-size -8) 255)
 190              (logand riece-rdcc-received-size 255)))
 191     (message (riece-mcat "Receiving %s from %s...(%s/%s)")
 192              (file-name-nondirectory riece-rdcc-request-file)
 193              riece-rdcc-request-user
 194              (riece-rdcc-format-size riece-rdcc-received-size)
 195              (riece-rdcc-format-size riece-rdcc-request-size))
 196     (if (= riece-rdcc-received-size riece-rdcc-request-size)
 197         (set-process-filter process nil))))
 198
 199 (defun riece-rdcc-sentinel (process status)
 200   (save-excursion
 201     (set-buffer (process-buffer process))
 202     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 203       (error "Premature end of file"))
 204     (message (riece-mcat "Receiving %s from %s...done")
 205              (file-name-nondirectory riece-rdcc-request-file)
 206              riece-rdcc-request-user)
 207     (condition-case nil
 208         (progn
 209           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 210           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 211       (file-already-exists
 212        (error "Can't save %s.  Temporarily saved in %s"
 213               riece-rdcc-request-file riece-rdcc-temp-file))))
 214   (kill-buffer (process-buffer process)))
 215
 216 (defun riece-rdcc-decode-address (address)
 217   (let ((name (riece-ruby-execute
 218                (riece-ruby-substitute-variables
 219                 riece-rdcc-decode-address-program
 220                 (list (cons 'address address)))))
 221         response)
 222     (while (equal (nth 2 (setq response (riece-ruby-inspect name))) "running")
 223       (accept-process-output riece-ruby-process))
 224     (riece-ruby-clear name)
 225     (nth 1 response)))
 226
 227 (defun riece-command-dcc-receive (request file)
 228   (interactive
 229    (progn
 230      (unless riece-rdcc-requests
 231        (error "No request"))
 232      (let* ((request
 233              (if (= (length riece-rdcc-requests) 1)
 234                  (car riece-rdcc-requests)
 235                (with-output-to-temp-buffer "*Help*"
 236                  (let ((requests riece-rdcc-requests)
 237                        (index 1))
 238                    (while requests
 239                      (princ (format (riece-mcat "%2d: %s %s (%d bytes)\n")
 240                                     index
 241                                     (car (car requests))
 242                                     (nth 1 (car requests))
 243                                     (nth 4 (car requests))))
 244                      (setq index (1+ index)
 245                            requests (cdr requests)))))
 246                (let ((number (read-string "Request#: ")))
 247                  (unless (string-match "^[0-9]+$" number)
 248                    (error "Not a number"))
 249                  (if (or (> (setq number (string-to-number number))
 250                             (length riece-rdcc-requests))
 251                          (< number 1))
 252                      (error "Invalid number"))
 253                  (nth (1- number) riece-rdcc-requests))))
 254             (default-name (expand-file-name
 255                            (convert-standard-filename (nth 1 request))
 256                            (or riece-rdcc-save-directory
 257                                default-directory))))
 258        (list request
 259              (expand-file-name
 260               (read-file-name
 261                (format (riece-mcat "Save as (default %s) ")
 262                        (file-name-nondirectory default-name))
 263                (file-name-directory default-name)
 264                default-name))))))
 265   (let* ((temp-file (expand-file-name
 266                      (file-name-nondirectory file)
 267                      (expand-file-name (make-temp-name "riece-rdcc")
 268                                        (if (featurep 'xemacs)
 269                                            (temp-directory)
 270                                          temporary-file-directory))))
 271          (orig-mode (default-file-modes))
 272          selective-display
 273          (coding-system-for-read 'binary)
 274          (coding-system-for-write 'binary)
 275          process)
 276     (unwind-protect
 277         (progn
 278           (set-default-file-modes 448)
 279           ;; This may throw an error.
 280           (make-directory (file-name-directory temp-file)))
 281       (set-default-file-modes orig-mode))
 282     (setq process (open-network-stream
 283                    "DCC" (generate-new-buffer " *DCC*")
 284                    (riece-rdcc-decode-address (nth 2 request))
 285                    (nth 3 request)))
 286     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 287     (with-current-buffer (process-buffer process)
 288       (if (fboundp 'set-buffer-multibyte)
 289           (set-buffer-multibyte nil))
 290       (buffer-disable-undo)
 291       (erase-buffer)
 292       (make-local-variable 'riece-rdcc-request-user)
 293       (setq riece-rdcc-request-user (car request))
 294       (make-local-variable 'riece-rdcc-request-file)
 295       (setq riece-rdcc-request-file file)
 296       (make-local-variable 'riece-rdcc-request-size)
 297       (setq riece-rdcc-request-size (nth 4 request))
 298       (make-local-variable 'riece-rdcc-temp-file)
 299       (setq riece-rdcc-temp-file temp-file)
 300       (make-local-variable 'riece-rdcc-received-size)
 301       (setq riece-rdcc-received-size 0))
 302     (set-process-filter process #'riece-rdcc-filter)
 303     (set-process-sentinel process #'riece-rdcc-sentinel)))
 304
 305 (defun riece-rdcc-format-size (size)
 306   (if (< size 1024)
 307       (format "%0.1f" size)
 308     (setq size (/ size 1024.0))
 309     (if (< size 1024)
 310         (format "%0.1fKB" size)
 311       (setq size (/ size 1024.0))
 312       (if (< size 1024)
 313           (format "%0.1fMB" size)
 314         (format "%0.1fGB" (/ size 1024.0))))))
 315
 316 (defun riece-handle-dcc-request (prefix target message)
 317   (let ((case-fold-search t))
 318     (when (and (get 'riece-rdcc 'riece-addon-enabled)
 319                (string-match
 320                 "SEND \\(\\([^ ]+\\)\\|\"\\(.+\\)\"\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 321                 message))
 322       (let ((file (or (match-string 2 message)
 323                       (match-string 3 message)))
 324             (address (match-string 4 message))
 325             (port (string-to-number (match-string 5 message)))
 326             (size (string-to-number (match-string 6 message)))
 327             (buffer (if (riece-channel-p target)
 328                         (riece-channel-buffer (riece-make-identity
 329                                                target riece-server-name))))
 330             (user (riece-prefix-nickname prefix)))
 331         (setq riece-rdcc-requests
 332               (cons (list user file address port size)
 333                     riece-rdcc-requests))
 334         (message "%s"
 335                  (with-current-buffer (window-buffer (selected-window))
 336                    (substitute-command-keys
 337                     (format
 338                      (riece-mcat
 339                       "Type \\[riece-command-dcc-receive] to receive")
 340                      user))))
 341         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 342                                             user file
 343                                             (riece-rdcc-format-size size)))
 344         (riece-insert-change
 345          (if (and riece-channel-buffer-mode
 346                   (not (eq buffer riece-channel-buffer)))
 347              (list riece-dialogue-buffer riece-others-buffer)
 348            riece-dialogue-buffer)
 349          (concat
 350           (riece-concat-server-name
 351            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 352                    user
 353                    (riece-strip-user-at-host
 354                     (riece-prefix-user-at-host prefix))
 355                    (riece-decode-coding-string target)
 356                    file
 357                    (riece-rdcc-format-size size)))
 358           "\n")))
 359       t)))
 360
 361 (defun riece-rdcc-requires ()
 362   '(riece-ctcp))
 363
 364 (defvar riece-dialogue-mode-map)
 365 (defun riece-rdcc-insinuate ()
 366   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 367   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 368
 369 (defun riece-rdcc-uninstall ()
 370   (setq riece-ctcp-additional-clientinfo
 371         (delete "DCC" riece-ctcp-additional-clientinfo))
 372   (remove-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 373
 374 (defun riece-rdcc-enable ()
 375   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 376   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 377
 378 (defun riece-rdcc-disable ()
 379   (define-key riece-dialogue-mode-map "\C-ds" nil)
 380   (define-key riece-dialogue-mode-map "\C-dr" nil))
 381
 382 (provide 'riece-rdcc)
 383
 384 ;;; riece-rdcc.el ends here