cgit.sxemacs.org Git - riece/blob - lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- DCC file sending protocol support (written in Ruby)
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; NOTE: This is an add-on module for Riece.
  27
  28 ;;; Code:
  29
  30 (require 'riece-globals)
  31 (require 'riece-misc)
  32 (require 'riece-channel)
  33 (require 'riece-identity)
  34 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  35 (require 'riece-ruby)
  36
  37 (defgroup riece-rdcc nil
  38   "DCC written in Ruby."
  39   :prefix "riece-"
  40   :group 'riece)
  41
  42 (defcustom riece-rdcc-server-address nil
  43   "Local address of the DCC server.
  44 Only used for sending files."
  45   :type 'string
  46   :group 'riece-rdcc)
  47
  48 (defcustom riece-rdcc-send-program
  49   '("\
  50 require 'socket'
  51 address = " address "
  52 unless address
  53   sock = UDPSocket.new
  54   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  55   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  56 end
  57 server = TCPServer.new(address, 0)
  58 output(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  59 session = server.accept
  60 if session
  61   total = 0
  62   File.open(" file ") {|file|
  63     while (bytes = file.read(" block-size "))
  64       total += bytes.length
  65       output(total)
  66       session.write(bytes)
  67       begin
  68         buf = session.read(4)
  69       end until buf.unpack('N')[0] == total
  70     end
  71   }
  72   session.close
  73 end
  74 ")
  75   "Ruby program to send file with DCC."
  76   :type 'list
  77   :group 'riece-rdcc)
  78
  79 (defcustom riece-rdcc-decode-address-program
  80   '("\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  81     address " >> 8 & 0xFF}.#{" address " & 0xFF}\"")
  82   "Ruby program to numeric IP address."
  83   :type 'list
  84   :group 'riece-rdcc)
  85
  86 (defcustom riece-rdcc-save-directory nil
  87   "Default directory where received files are saved in."
  88   :type 'directory
  89   :group 'riece-rdcc)
  90
  91 (defcustom riece-rdcc-block-size 1024
  92   "Number of bytes sent as a block."
  93   :type 'integer
  94   :group 'riece-rdcc)
  95
  96 (defvar riece-rdcc-requests nil)
  97
  98 (defvar riece-rdcc-request-user nil)
  99 (defvar riece-rdcc-request-file nil)
 100 (defvar riece-rdcc-request-size nil)
 101
 102 (defvar riece-rdcc-temp-file nil)
 103 (defvar riece-rdcc-received-size nil)
 104
 105 (defconst riece-rdcc-description
 106   "DCC file sending protocol support (written in Ruby.)")
 107
 108 (defvar temporary-file-directory)
 109 (defvar jka-compr-compression-info-list)
 110 (defvar jam-zcat-filename-list)
 111
 112 (defun riece-rdcc-output-handler (name output time)
 113   (if (string-match "\\([0-9]+\\) \\([0-9]+\\)" output)
 114       (let ((address (match-string 1 output))
 115             (port (match-string 2 output)))
 116         (riece-send-string
 117          (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 118                  (riece-identity-prefix
 119                   (riece-ruby-property name 'riece-rdcc-request-user))
 120                  (file-name-nondirectory
 121                   (riece-ruby-property name 'riece-rdcc-request-file))
 122                  address port
 123                  (riece-ruby-property name 'riece-rdcc-request-size)))))
 124   (riece-ruby-set-output-handler name #'riece-rdcc-output-handler-2))
 125
 126 (defun riece-rdcc-output-handler-2 (name output time)
 127   (message "Sending %s...(%s/%d)"
 128            (riece-ruby-property name 'riece-rdcc-request-file)
 129            (string-to-number output)
 130            (riece-ruby-property name 'riece-rdcc-request-size)))
 131
 132 (defun riece-rdcc-exit-handler (name)
 133   (message "Sending %s...done"
 134            (riece-ruby-property name 'riece-rdcc-request-file)))
 135
 136 (defun riece-command-dcc-send (user file)
 137   (interactive
 138    (let ((completion-ignore-case t))
 139      (list (riece-completing-read-identity
 140             "User: "
 141             (riece-get-users-on-server (riece-current-server-name)))
 142            (expand-file-name (read-file-name "File: ")))))
 143   (let ((name (riece-ruby-execute
 144                (riece-ruby-substitute-variables
 145                 riece-rdcc-send-program
 146                 (list (cons 'address
 147                             (if riece-rdcc-server-address
 148                                 (concat "'" riece-rdcc-server-address
 149                                         "'")
 150                               "nil"))
 151                       (cons 'file
 152                             (concat "'" file "'"))
 153                       (cons 'block-size
 154                             (number-to-string
 155                              riece-rdcc-block-size)))))))
 156     (riece-ruby-set-property name 'riece-rdcc-request-user user)
 157     (riece-ruby-set-property name 'riece-rdcc-request-file file)
 158     (riece-ruby-set-property name 'riece-rdcc-request-size
 159                              (nth 7 (file-attributes file)))
 160     (riece-ruby-set-output-handler name #'riece-rdcc-output-handler)
 161     (riece-ruby-set-exit-handler name #'riece-rdcc-exit-handler)))
 162
 163 (defun riece-rdcc-filter (process input)
 164   (save-excursion
 165     (set-buffer (process-buffer process))
 166     (erase-buffer)
 167     (insert input)
 168     (let ((coding-system-for-write 'binary)
 169           jka-compr-compression-info-list jam-zcat-filename-list)
 170       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 171     (setq riece-rdcc-received-size (+ (buffer-size) riece-rdcc-received-size))
 172     (process-send-string
 173      process
 174      (format "%c%c%c%c"
 175              (lsh riece-rdcc-received-size -24)
 176              (logand (lsh riece-rdcc-received-size -16) 255)
 177              (logand (lsh riece-rdcc-received-size -8) 255)
 178              (logand riece-rdcc-received-size 255)))
 179     (message "Receiving %s from %s...(%s/%s)"
 180              (file-name-nondirectory riece-rdcc-request-file)
 181              riece-rdcc-request-user
 182              (riece-rdcc-format-size riece-rdcc-received-size)
 183              (riece-rdcc-format-size riece-rdcc-request-size))
 184     (if (= riece-rdcc-received-size riece-rdcc-request-size)
 185         (set-process-filter process nil))))
 186
 187 (defun riece-rdcc-sentinel (process status)
 188   (save-excursion
 189     (set-buffer (process-buffer process))
 190     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 191       (error "Premature end of file"))
 192     (message "Receiving %s from %s...done"
 193              (file-name-nondirectory riece-rdcc-request-file)
 194              riece-rdcc-request-user)
 195     (condition-case nil
 196         (progn
 197           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 198           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 199       (file-already-exists
 200        (error "Can't save %s.  Temporarily saved in %s"
 201               riece-rdcc-request-file riece-rdcc-temp-file))))
 202   (kill-buffer (process-buffer process)))
 203
 204 (defun riece-rdcc-decode-address (address)
 205   (let ((name (riece-ruby-execute
 206                (riece-ruby-substitute-variables
 207                 riece-rdcc-decode-address-program
 208                 (list (cons 'address address)))))
 209         response)
 210     (while (equal (nth 2 (setq response (riece-ruby-inspect name))) "running")
 211       (accept-process-output riece-ruby-process))
 212     (riece-ruby-clear name)
 213     (nth 1 response)))
 214
 215 (defun riece-command-dcc-receive (request file)
 216   (interactive
 217    (progn
 218      (unless riece-rdcc-requests
 219        (error "No request"))
 220      (let* ((request
 221              (if (= (length riece-rdcc-requests) 1)
 222                  (car riece-rdcc-requests)
 223                (with-output-to-temp-buffer "*Help*"
 224                  (let ((requests riece-rdcc-requests)
 225                        (index 1))
 226                    (while requests
 227                      (princ (format "%2d: %s %s (%d bytes)\n"
 228                                     index
 229                                     (car (car requests))
 230                                     (nth 1 (car requests))
 231                                     (nth 4 (car requests))))
 232                      (setq index (1+ index)
 233                            requests (cdr requests)))))
 234                (let ((number (read-string "Request#: ")))
 235                  (unless (string-match "^[0-9]+$" number)
 236                    (error "Not a number"))
 237                  (if (or (> (setq number (string-to-number number))
 238                             (length riece-rdcc-requests))
 239                          (< number 1))
 240                      (error "Invalid number"))
 241                  (nth (1- number) riece-rdcc-requests))))
 242             (default-name (expand-file-name
 243                            (convert-standard-filename (nth 1 request))
 244                            (or riece-rdcc-save-directory
 245                                default-directory))))
 246        (list request
 247              (expand-file-name
 248               (read-file-name
 249                (concat "Save as (default "
 250                        (file-name-nondirectory default-name) ") ")
 251                (file-name-directory default-name)
 252                default-name))))))
 253   (let* ((temp-file (expand-file-name
 254                      (file-name-nondirectory file)
 255                      (expand-file-name (make-temp-name "riece-rdcc")
 256                                        (if (featurep 'xemacs)
 257                                            (temp-directory)
 258                                          temporary-file-directory))))
 259          (orig-mode (default-file-modes))
 260          selective-display
 261          (coding-system-for-read 'binary)
 262          (coding-system-for-write 'binary)
 263          process)
 264     (unwind-protect
 265         (progn
 266           (set-default-file-modes 448)
 267           ;; This may throw an error.
 268           (make-directory (file-name-directory temp-file)))
 269       (set-default-file-modes orig-mode))
 270     (setq process (open-network-stream
 271                    "DCC" (generate-new-buffer " *DCC*")
 272                    (riece-rdcc-decode-address (nth 2 request))
 273                    (nth 3 request)))
 274     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 275     (with-current-buffer (process-buffer process)
 276       (if (fboundp 'set-buffer-multibyte)
 277           (set-buffer-multibyte nil))
 278       (buffer-disable-undo)
 279       (erase-buffer)
 280       (make-local-variable 'riece-rdcc-request-user)
 281       (setq riece-rdcc-request-user (car request))
 282       (make-local-variable 'riece-rdcc-request-file)
 283       (setq riece-rdcc-request-file file)
 284       (make-local-variable 'riece-rdcc-request-size)
 285       (setq riece-rdcc-request-size (nth 4 request))
 286       (make-local-variable 'riece-rdcc-temp-file)
 287       (setq riece-rdcc-temp-file temp-file)
 288       (make-local-variable 'riece-rdcc-received-size)
 289       (setq riece-rdcc-received-size 0))
 290     (set-process-filter process #'riece-rdcc-filter)
 291     (set-process-sentinel process #'riece-rdcc-sentinel)))
 292
 293 (defun riece-rdcc-format-size (size)
 294   (if (< size 1024)
 295       (format "%0.1f" size)
 296     (setq size (/ size 1024.0))
 297     (if (< size 1024)
 298         (format "%0.1fKB" size)
 299       (setq size (/ size 1024.0))
 300       (if (< size 1024)
 301           (format "%0.1fMB" size)
 302         (format "%0.1fGB" (/ size 1024.0))))))
 303
 304 (defun riece-handle-dcc-request (prefix target message)
 305   (let ((case-fold-search t))
 306     (when (and (get 'riece-rdcc 'riece-addon-enabled)
 307                (string-match
 308                 "SEND \\(\\([^ ]+\\)\\|\"\\(.+\\)\"\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 309                 message))
 310       (let ((file (or (match-string 2 message)
 311                       (match-string 3 message)))
 312             (address (match-string 4 message))
 313             (port (string-to-number (match-string 5 message)))
 314             (size (string-to-number (match-string 6 message)))
 315             (buffer (if (riece-channel-p target)
 316                         (riece-channel-buffer (riece-make-identity
 317                                                target riece-server-name))))
 318             (user (riece-prefix-nickname prefix)))
 319         (setq riece-rdcc-requests
 320               (cons (list user file address port size)
 321                     riece-rdcc-requests))
 322         (message "%s"
 323                  (with-current-buffer (window-buffer (selected-window))
 324                    (substitute-command-keys
 325                     (format
 326                      "Type \\[riece-command-dcc-receive] to receive"
 327                      user))))
 328         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 329                                             user file
 330                                             (riece-rdcc-format-size size)))
 331         (riece-insert-change
 332          (if (and riece-channel-buffer-mode
 333                   (not (eq buffer riece-channel-buffer)))
 334              (list riece-dialogue-buffer riece-others-buffer)
 335            riece-dialogue-buffer)
 336          (concat
 337           (riece-concat-server-name
 338            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 339                    user
 340                    (riece-strip-user-at-host
 341                     (riece-prefix-user-at-host prefix))
 342                    (riece-decode-coding-string target)
 343                    file
 344                    (riece-rdcc-format-size size)))
 345           "\n")))
 346       t)))
 347
 348 (defun riece-rdcc-requires ()
 349   '(riece-ctcp))
 350
 351 (defvar riece-dialogue-mode-map)
 352 (defun riece-rdcc-insinuate ()
 353   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 354   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 355
 356 (defun riece-rdcc-uninstall ()
 357   (setq riece-ctcp-additional-clientinfo
 358         (delete "DCC" riece-ctcp-additional-clientinfo))
 359   (remove-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 360
 361 (defun riece-rdcc-enable ()
 362   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 363   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 364
 365 (defun riece-rdcc-disable ()
 366   (define-key riece-dialogue-mode-map "\C-ds" nil)
 367   (define-key riece-dialogue-mode-map "\C-dr" nil))
 368
 369 (provide 'riece-rdcc)
 370
 371 ;;; riece-rdcc.el ends here