cgit.sxemacs.org Git - riece/blob - lisp/riece-lsdb.el

   1 ;;; riece-lsdb.el --- help register nicknames in LSDB rolodex program -*- lexical-binding: t -*-
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; NOTE: This is an add-on module for Riece.
  28
  29 ;;; Code:
  30
  31 (require 'riece-identity)
  32 (require 'riece-misc)
  33
  34 (eval-when-compile
  35   (autoload 'lsdb-maybe-load-hash-tables "lsdb")
  36   (autoload 'lsdb-rebuild-secondary-hash-tables "lsdb")
  37   (autoload 'lsdb-lookup-records "lsdb")
  38   (autoload 'lsdb-puthash "lsdb")
  39   (autoload 'lsdb-maphash "lsdb")
  40   (autoload 'lsdb-gethash "lsdb")
  41   (autoload 'lsdb-display-records "lsdb")
  42   (autoload 'lsdb-update-record "lsdb"))
  43
  44 (defvar riece-lsdb-cache nil)
  45
  46 (defconst riece-lsdb-description
  47   "Help register nicknames in LSDB rolodex program.")
  48
  49 (defun riece-lsdb-update-cache (record)
  50   (let ((irc (cdr (assq 'irc record))))
  51     (while irc
  52       (lsdb-puthash (car irc)
  53                     (cons (car record)
  54                           (lsdb-gethash (car irc) riece-lsdb-cache))
  55                     riece-lsdb-cache)
  56       (setq irc (cdr irc)))))
  57
  58 (defun riece-lsdb-delete-cache (record)
  59   (let ((irc (cdr (assq 'irc record))))
  60     (while irc
  61       (lsdb-puthash (car irc)
  62                     (delete (car record)
  63                             (lsdb-gethash (car irc) riece-lsdb-cache))
  64                     riece-lsdb-cache)
  65       (setq irc (cdr irc)))))
  66
  67 (defun riece-lsdb-lookup-records (user)
  68   (lsdb-maybe-load-hash-tables)
  69   (unless riece-lsdb-cache
  70     (lsdb-rebuild-secondary-hash-tables))
  71   (let ((names (lsdb-gethash (riece-format-identity user t)
  72                              riece-lsdb-cache))
  73         records)
  74     (while names
  75       (setq records (append records (lsdb-lookup-records (car names))))
  76       (setq names (cdr names)))
  77     records))
  78
  79 (defun riece-lsdb-display-records (user)
  80   (interactive
  81    (let ((completion-ignore-case t))
  82      (list (riece-completing-read-identity
  83             "User: "
  84             (riece-get-users-on-server (riece-current-server-name))))))
  85   (let ((records (riece-lsdb-lookup-records user)))
  86     (if records
  87         (lsdb-display-records records)
  88       (message "No entry for `%s'" (riece-format-identity user t)))))
  89
  90 (defvar lsdb-hash-table)
  91 (defun riece-lsdb-add-user (user full-name)
  92   (interactive
  93    (let ((completion-ignore-case t)
  94          (table lsdb-hash-table))
  95      (unless (vectorp table)
  96        (setq table (make-vector 29 0))
  97        (lsdb-maphash (lambda (key _value)
  98                        (intern key table))
  99                      lsdb-hash-table))
 100      (list (riece-completing-read-identity
 101             "User: "
 102             (riece-get-users-on-server (riece-current-server-name)))
 103            (completing-read "Full name: " table))))
 104   (let* ((record (lsdb-gethash full-name lsdb-hash-table))
 105          (irc (riece-format-identity user t))
 106          (old (cdr (assq 'irc record))))
 107     ;; Remove all properties before adding entry.
 108     (set-text-properties 0 (length irc) nil irc)
 109     (unless (member irc old)
 110       (lsdb-update-record (list full-name
 111                                 ;; LSDB does not allow empty 'net entry.
 112                                 (or (nth 1 (assq 'net (lsdb-lookup-records
 113                                                        full-name)))
 114                                     ""))
 115                           (list (cons 'irc (cons irc old)))))))
 116
 117 (defvar riece-command-mode-map)
 118 (defvar lsdb-secondary-hash-tables)
 119 (defvar lsdb-after-update-record-functions)
 120 (defvar lsdb-after-delete-record-functions)
 121 (defun riece-lsdb-insinuate ()
 122   (require 'lsdb)
 123   (add-to-list 'lsdb-secondary-hash-tables
 124                'riece-lsdb-cache)
 125   (add-to-list 'lsdb-after-update-record-functions
 126                'riece-lsdb-update-cache)
 127   (add-to-list 'lsdb-after-delete-record-functions
 128                'riece-lsdb-delete-cache))
 129
 130 (defun riece-lsdb-uninstall ()
 131   (setq lsdb-secondary-hash-tables
 132         (delq 'riece-lsdb-cache lsdb-secondary-hash-tables)
 133         lsdb-after-update-record-functions
 134         (delq 'riece-lsdb-update-cache lsdb-after-update-record-functions)
 135         lsdb-after-delete-record-functions
 136         (delq 'riece-lsdb-delete-cache lsdb-after-delete-record-functions)))
 137
 138 (defun riece-lsdb-enable ()
 139   (define-key riece-command-mode-map
 140     "\C-c\C-ll" 'riece-lsdb-display-records)
 141   (define-key riece-command-mode-map
 142     "\C-c\C-la" 'riece-lsdb-add-user))
 143
 144 (defun riece-lsdb-disable ()
 145   (define-key riece-command-mode-map
 146     "\C-c\C-ll" nil)
 147   (define-key riece-command-mode-map
 148     "\C-c\C-la" nil))
 149
 150 (provide 'riece-lsdb)
 151
 152 ;;; riece-lsdb.el ends here