cgit.sxemacs.org Git - riece/blob - lisp/riece-layout.el

   1 ;;; riece-layout.el --- layout management
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;;      TAKAHASHI "beatmaria" Kaoru <kaoru@kaisei.org>
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-globals)
  28 (require 'riece-misc)
  29
  30 (defgroup riece-layout nil
  31   "Manage window layouts"
  32   :prefix "riece-"
  33   :group 'riece)
  34
  35 (defcustom riece-layout "default"
  36   "Current layout setting."
  37   :type 'string
  38   :group 'riece-layout)
  39
  40 (defcustom riece-layout-alist
  41   '(("middle-right" riece-configure-windows right middle)
  42     ("middle-left" riece-configure-windows left middle)
  43     ("top-right" riece-configure-windows right top)
  44     ("top-left" riece-configure-windows left top)
  45     ("bottom-right" riece-configure-windows right bottom)
  46     ("bottom-left" riece-configure-windows left bottom)
  47     ("top" riece-configure-windows-top)
  48     ("default" . "middle-right"))
  49   "An alist mapping the names to layout functions.
  50 An element of this alist is either in the following forms:
  51
  52 (NAME CONFIGURE-FUNCTION [PARAMETERS])
  53 (NAME1 . NAME2)
  54
  55 In the first form, NAME is a string which specifies the layout
  56 setting, and CONFIGURE-FUNCTION is a function which does window
  57 splitting, etc.  PARAMETERS are collected and passed to CONFIGURE-FUNCTION.
  58 In the second form, NAME1 is an alias for NAME2."
  59   :type 'list
  60   :group 'riece-layout)
  61
  62 (defun riece-redraw-layout (&optional force)
  63   "Reconfigure windows with the current layout.
  64 If optional argument FORCE is non-nil, window reconfiguration will
  65 happen unconditionally."
  66   (let ((layout (cdr (assoc riece-layout riece-layout-alist))))
  67     (unless layout
  68       (error "No such layout!"))
  69     (if (stringp layout)
  70         (let ((riece-layout layout))
  71           (riece-redraw-layout force))
  72       (if (or force
  73               (riece-reconfigure-windows-predicate))
  74           (apply (car layout) (cdr layout))))))
  75
  76 (defun riece-set-window-points ()
  77   (if (get-buffer-window riece-user-list-buffer)
  78       (with-current-buffer riece-user-list-buffer
  79         (unless (riece-frozen riece-user-list-buffer)
  80           (set-window-start (get-buffer-window riece-user-list-buffer)
  81                             (point-min)))))
  82   (if (get-buffer-window riece-channel-list-buffer)
  83       (with-current-buffer riece-channel-list-buffer
  84         (unless (riece-frozen riece-channel-list-buffer)
  85           (set-window-start (get-buffer-window riece-channel-list-buffer)
  86                             (point-min))))))
  87
  88 (defun riece-reconfigure-windows-predicate ()
  89   "Return t, if window reconfiguration is needed.
  90 This function is used by \"default\" layout."
  91   (memq (window-buffer (selected-window))
  92         riece-buffer-list))
  93
  94 (defun riece-configure-windows (hpos vpos)
  95   (let ((buffer (window-buffer))
  96         (show-user-list
  97          (and riece-user-list-buffer-mode
  98               riece-current-channel
  99               ;; User list buffer is nuisance for private conversation.
 100               (riece-channel-p (riece-identity-prefix
 101                                 riece-current-channel)))))
 102     ;; Can't expand minibuffer to full frame.
 103     (if (eq (selected-window) (minibuffer-window))
 104         (other-window 1))
 105     (delete-other-windows)
 106     (if (and riece-current-channel
 107              (or show-user-list riece-channel-list-buffer-mode))
 108         (let ((rest-window (split-window (selected-window)
 109                                          (if (eq hpos 'left)
 110                                              (- (window-width)
 111                                                 (/ (window-width) 5))
 112                                            (/ (window-width) 5))
 113                                          t)))
 114           (when (eq hpos 'left)
 115             (setq rest-window (selected-window))
 116             (other-window 1))
 117           (if (and show-user-list riece-channel-list-buffer-mode)
 118               (progn
 119                 (set-window-buffer (split-window)
 120                                    riece-channel-list-buffer)
 121                 (set-window-buffer (selected-window)
 122                                    riece-user-list-buffer))
 123             (if show-user-list
 124                 (set-window-buffer (selected-window)
 125                                    riece-user-list-buffer)
 126               (if riece-channel-list-buffer-mode
 127                   (set-window-buffer (selected-window)
 128                                      riece-channel-list-buffer))))
 129           (select-window rest-window)))
 130     (if (and riece-current-channel
 131              riece-channel-buffer-mode)
 132         (progn
 133           (if (eq vpos 'top)
 134               (let ((rest-window (split-window nil 4)))
 135                 (set-window-buffer (selected-window)
 136                                    riece-command-buffer)
 137                 (select-window rest-window)
 138                 (set-window-buffer (split-window rest-window)
 139                                    riece-others-buffer)
 140                 (set-window-buffer (selected-window)
 141                                    riece-channel-buffer))
 142             (if (eq vpos 'middle)
 143                 (let ((rest-window (split-window)))
 144                   (set-window-buffer (selected-window)
 145                                      riece-channel-buffer)
 146                   (set-window-buffer (split-window rest-window 4)
 147                                      riece-others-buffer)
 148                   (set-window-buffer rest-window
 149                                      riece-command-buffer))
 150               (let ((rest-window (split-window nil (- (window-height) 4))))
 151                 (set-window-buffer (selected-window)
 152                                    riece-others-buffer)
 153                 (set-window-buffer (split-window)
 154                                    riece-channel-buffer)
 155                 (set-window-buffer rest-window
 156                                    riece-command-buffer))))
 157           (with-current-buffer riece-channel-buffer
 158             (setq truncate-partial-width-windows nil))
 159           (with-current-buffer riece-others-buffer
 160             (setq truncate-partial-width-windows nil)))
 161       (if (eq vpos 'bottom)
 162           (progn
 163             (set-window-buffer (selected-window)
 164                                riece-command-buffer)
 165             (set-window-buffer (split-window (selected-window) 4)
 166                                riece-dialogue-buffer))
 167         (set-window-buffer (split-window (selected-window) 4)
 168                            riece-dialogue-buffer)
 169         (set-window-buffer (selected-window)
 170                            riece-command-buffer)))
 171     (riece-set-window-points)
 172     (select-window (or (get-buffer-window buffer)
 173                        (get-buffer-window riece-command-buffer)))))
 174
 175 (defun riece-configure-windows-top (&optional plist)
 176   "Candidate of `riece-configure-windows-function'.
 177 PLIST accept :command-height, :user-list-width, and :channel-list-width."
 178   (let ((command-height (or (plist-get plist :command-height) 4))
 179         (user-list-width (or (plist-get plist :user-list-width) (+ 9 1 1)))
 180         (channel-list-width (or (plist-get plist :channel-list-width) 18))
 181         (buffer (window-buffer))
 182         (show-user-list
 183          (and riece-user-list-buffer-mode
 184               riece-current-channel
 185               ;; User list buffer is nuisance for private conversation.
 186               (riece-channel-p (riece-identity-prefix
 187                                 riece-current-channel)))))
 188     ;; Can't expand minibuffer to full frame.
 189     (when (eq (selected-window) (minibuffer-window))
 190       (other-window 1))
 191     (delete-other-windows)
 192     ;; top of frame
 193     (let ((rest-window (split-window (selected-window) command-height)))
 194       (set-window-buffer (selected-window)
 195                          riece-command-buffer)
 196       (select-window rest-window))
 197     ;; middle of frame (vertical-spilit when need)
 198     (when (or (and riece-current-channel riece-channel-buffer-mode)
 199               show-user-list)
 200       (let ((rest-window
 201              (split-window (selected-window)
 202                            (/ (* 5 (+ (window-height) command-height)) 8))))
 203         (cond
 204          ;; channel-buffer + user-list
 205          ((and show-user-list
 206                (and riece-current-channel riece-channel-buffer-mode))
 207           (let ((user-list-window (split-window (selected-window) nil t)))
 208             (set-window-buffer (selected-window) riece-channel-buffer)
 209             (set-window-buffer user-list-window riece-user-list-buffer)
 210             (select-window user-list-window)
 211             (shrink-window-horizontally (- (window-width) user-list-width))
 212             (setq truncate-partial-width-windows nil)))
 213          ;; only user-list
 214          (show-user-list
 215           (set-window-buffer (selected-window) riece-user-list-buffer))
 216          ;; only channel-buffer
 217          (riece-channel-buffer-mode
 218           (set-window-buffer (selected-window) riece-channel-buffer)))
 219         (select-window rest-window)))
 220     ;; bottom of frame
 221     (if (and riece-current-channel
 222              riece-channel-list-buffer-mode)
 223         (let ((channel-list-window (split-window (selected-window) nil t)))
 224           (set-window-buffer (selected-window) riece-others-buffer)
 225           (set-window-buffer channel-list-window riece-channel-list-buffer)
 226           (select-window channel-list-window)
 227           (shrink-window-horizontally (- (window-width) channel-list-width))
 228           (setq truncate-partial-width-windows nil))
 229       (set-window-buffer (selected-window) riece-dialogue-buffer))
 230     (riece-set-window-points)
 231     (select-window (or (get-buffer-window buffer)
 232                        (get-buffer-window riece-command-buffer)))))
 233
 234 (provide 'riece-layout)
 235
 236 ;;; riece-layout.el ends here