cgit.sxemacs.org Git - riece/blob - lisp/riece-keyword.el

   1 ;;; riece-keyword.el --- detect keywords in IRC buffers
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; NOTE: This is an add-on module for Riece.
  28
  29 ;;; Code:
  30
  31 (require 'riece-message)
  32
  33 (defgroup riece-keyword nil
  34   "Detect keywords in IRC buffers."
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defcustom riece-keywords nil
  39   "Keywords to be highlightened."
  40   :type '(repeat (choice (string :tag "Keyword")
  41                          (cons (string :tag "Regexp")
  42                                (integer :tag "Match"))))
  43   :group 'riece-keyword)
  44
  45 (defcustom riece-notify-keyword-functions nil
  46   "Functions used to notify keyword match."
  47   :type '(repeat function)
  48   :group 'riece-keyword)
  49
  50 (make-obsolete-variable 'riece-notify-keyword-functions
  51                         'riece-keyword-notify-functions)
  52
  53 (defcustom riece-keyword-notify-functions nil
  54   "Functions used to notify keyword match.
  55 Two arguments are passed to each function: the keyword used to match
  56 and the matched message object."
  57   :type '(repeat function)
  58   :group 'riece-keyword)
  59
  60 (defface riece-keyword-face
  61   '((((class color))
  62      (:foreground "red" :underline t))
  63     (t
  64      (:underline t)))
  65   "Face used for highlightening matching keyword."
  66   :group 'riece-highlight-faces)
  67 (defvar riece-keyword-face 'riece-keyword-face)
  68
  69 (defconst riece-keyword-description
  70   "Detect keywords in IRC buffers.")
  71
  72 ;;; The old XEmacs package doesn't have autoload setting for regexp-opt.
  73 (autoload 'regexp-opt "regexp-opt")
  74 (defun riece-keyword-message-filter (message)
  75   (if (and (get 'riece-keyword 'riece-addon-enabled)
  76            riece-keywords
  77            ;; Ignore messages which belongs to myself.
  78            (not (riece-message-own-p message)))
  79       (let* (keywords
  80              (alist
  81               (nconc
  82                (delq nil (mapcar
  83                           (lambda (matcher)
  84                             (if (stringp matcher)
  85                                 (ignore
  86                                  (setq keywords (cons matcher keywords)))
  87                               matcher))
  88                           riece-keywords))
  89                (if keywords
  90                    (list (cons (regexp-opt keywords) 0)))))
  91              index)
  92         (while alist
  93           (setq index 0)
  94           (while (and (< index (length (riece-message-text message)))
  95                       (string-match (car (car alist))
  96                                     (riece-message-text message) index))
  97             (put-text-property (match-beginning (cdr (car alist)))
  98                                (match-end (cdr (car alist)))
  99                                'riece-overlay-face riece-keyword-face
 100                                (riece-message-text message))
 101             (save-match-data
 102               (run-hook-with-args 'riece-notify-keyword-functions
 103                                   (match-string (cdr (car alist))
 104                                                 (riece-message-text message)))
 105               (run-hook-with-args 'riece-keyword-notify-functions
 106                                   (cdr (car alist))
 107                                   message))
 108             (setq index (1+ (match-end (cdr (car alist))))))
 109           (setq alist (cdr alist)))))
 110   message)
 111
 112 (defun riece-keyword-requires ()
 113   (if (memq 'riece-highlight riece-addons)
 114       '(riece-highlight)))
 115
 116 (defun riece-keyword-insinuate ()
 117   (add-hook 'riece-message-filter-functions 'riece-keyword-message-filter))
 118
 119 (defun riece-keyword-uninstall ()
 120   (remove-hook 'riece-message-filter-functions 'riece-keyword-message-filter))
 121
 122 (provide 'riece-keyword)
 123
 124 ;;; riece-keyword.el ends here