cgit.sxemacs.org Git - riece/blob - lisp/riece-filter.el

   1 ;;; riece-filter.el --- process filter and sentinel
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-handle)
  28 (require 'riece-misc)
  29 (require 'riece-server)                 ;riece-close-server
  30 (require 'riece-identity)
  31 (require 'riece-debug)
  32
  33 (defun riece-handle-numeric-reply (prefix number name string)
  34   (let ((base-number (* (/ number 100) 100))
  35         function)
  36     (setq function (intern-soft (format "riece-handle-%03d-message" number)))
  37     (unless (and function
  38                  (symbol-function function))
  39       (setq function
  40             (intern-soft
  41              (format "riece-handle-default-%03d-message" base-number))))
  42     (if (and function
  43              (symbol-function function))
  44         (riece-ignore-errors (symbol-name function)
  45           (funcall function prefix number name
  46                    (riece-decode-coding-string string))))))
  47
  48 (defun riece-handle-message (prefix message string)
  49   (if (and prefix
  50            (string-match "![^\x00\x0d\x0a @]+@" prefix))
  51       (riece-user-set-user-at-host
  52        (riece-get-user (substring prefix 0 (match-beginning 0)))
  53        (riece-parse-user-at-host (substring prefix (1+ (match-beginning 0))))))
  54   (setq message (downcase message)
  55         string (riece-decode-coding-string string))
  56   (let ((function (intern-soft (concat "riece-handle-" message "-message")))
  57         (hook (intern (concat "riece-" message "-hook")))
  58         (after-hook (intern (concat "riece-after-" message "-hook"))))
  59     (unless (riece-ignore-errors (symbol-name hook)
  60               (run-hook-with-args-until-success hook prefix string))
  61       (if function
  62           (riece-ignore-errors (symbol-name function)
  63             (funcall function prefix string)))
  64       (riece-ignore-errors (symbol-name after-hook)
  65         (run-hook-with-args-until-success after-hook prefix string)))))
  66
  67 (defun riece-chomp-string (string)
  68   (if (string-match "\r?\n\\'" string)
  69       (substring string 0 (match-beginning 0))
  70     string))
  71
  72 (defun riece-filter (process input)
  73   (save-excursion
  74     (set-buffer (process-buffer process))
  75     (goto-char riece-read-point)
  76     (unless riece-debug
  77       (delete-region (riece-line-beginning-position) (point-min))
  78       (setq riece-read-point (point)))
  79     (insert input)
  80     (goto-char (prog1 riece-read-point
  81                  (setq riece-read-point (point))))
  82     (beginning-of-line)
  83     (while (and (not (eobp))
  84                 (looking-at ".*\n"))    ;the input line is not finished
  85       (save-excursion
  86         (if (looking-at
  87              ":\\([^ ]+\\) +\\([0-5][0-9][0-9]\\) +\\([^ ]+\\) +\\(.*\\)\n")
  88             (riece-handle-numeric-reply
  89              (match-string 1)           ;prefix
  90              (string-to-number (match-string 2)) ;number
  91              (match-string 3)           ;name
  92              (riece-chomp-string (match-string 4)))             ;reply string
  93           (if (looking-at "\\(:\\([^ ]+\\) +\\)?\\([^ ]+\\) +\\(.*\\)\n")
  94               (riece-handle-message
  95                (match-string 2)         ;optional prefix
  96                (match-string 3)         ;command
  97                (riece-chomp-string (match-string 4)))   ;params & trailing
  98             (if riece-debug
  99                 (message "Weird message from server: %s"
 100                          (buffer-substring (point) (progn
 101                                                      (end-of-line)
 102                                                      (point))))))))
 103       (forward-line))))
 104
 105 (eval-when-compile
 106   (autoload 'riece-exit "riece"))
 107 (defun riece-sentinel (process status)
 108   (if riece-reconnect-with-password
 109       (let ((server-name
 110              (with-current-buffer (process-buffer process)
 111                riece-server-name)))
 112         (riece-close-server-process process)
 113         (riece-open-server
 114          (if (equal server-name "")
 115              riece-server
 116            (riece-server-name-to-server server-name))
 117          server-name))
 118     (let ((server-name (with-current-buffer (process-buffer process)
 119                          riece-server-name)))
 120       (if riece-debug
 121           (if (equal server-name "")
 122               (message "Connection closed: %s"
 123                        (substring status 0 (1- (length status))))
 124             (message "Connection to \"%s\" closed: %s"
 125                      server-name (substring status 0 (1- (length status)))))
 126         (if (equal server-name "")
 127             (message "Connection closed")
 128           (message "Connection to \"%s\" closed" server-name)))
 129       (let ((channels riece-current-channels))
 130         (while channels
 131           (if (and (car channels)
 132                    (equal (riece-identity-server (car channels))
 133                           server-name))
 134               (riece-part-channel (car channels)))
 135           (setq channels (cdr channels))))
 136       (riece-redisplay-buffers)
 137       (riece-close-server-process process)
 138       ;; If no server process is available, exit.
 139       (unless riece-server-process-alist
 140         (riece-exit)))))
 141
 142 (provide 'riece-filter)
 143
 144 ;;; riece-filter.el ends here