cgit.sxemacs.org Git - riece/blob - lisp/riece-filter.el

   1 ;;; riece-filter.el --- process filter and sentinel
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-handle)
  28 (require 'riece-misc)
  29 (require 'riece-server)                 ;riece-close-server
  30 (require 'riece-identity)
  31 (require 'riece-debug)
  32
  33 (defun riece-handle-numeric-reply (prefix number name string)
  34   (let ((base-number (* (/ number 100) 100))
  35         function)
  36     (setq function (intern-soft (format "riece-handle-%03d-message" number)))
  37     (unless (and function
  38                  (symbol-function function))
  39       (setq function
  40             (intern-soft
  41              (format "riece-handle-default-%03d-message" base-number))))
  42     (if (and function
  43              (symbol-function function))
  44         (riece-funcall-ignore-errors (symbol-name function)
  45                                      function prefix number name
  46                                      (riece-decode-coding-string string)))))
  47
  48 (defun riece-handle-message (prefix message string)
  49   (if (and prefix
  50            (string-match "![^\x00\x0d\x0a @]+@" prefix))
  51       (riece-user-set-user-at-host
  52        (riece-get-user (substring prefix 0 (match-beginning 0)))
  53        (riece-parse-user-at-host (substring prefix (1+ (match-beginning 0))))))
  54   (setq message (downcase message)
  55         string (riece-decode-coding-string string))
  56   (let ((function (intern-soft (concat "riece-handle-" message "-message")))
  57         (hook (intern (concat "riece-" message "-hook")))
  58         (after-hook (intern (concat "riece-after-" message "-hook"))))
  59     (unless (riece-funcall-ignore-errors (symbol-name hook)
  60                                          #'run-hook-with-args-until-success
  61                                          hook prefix string)
  62       (if function
  63           (riece-funcall-ignore-errors (symbol-name function)
  64                                        function prefix string))
  65       (riece-funcall-ignore-errors (symbol-name after-hook)
  66                                    #'run-hook-with-args-until-success
  67                                    after-hook prefix string))))
  68
  69 (defsubst riece-chomp-string (string)
  70   (if (string-match "\r\\'" string)
  71       (substring string 0 (match-beginning 0))
  72     string))
  73
  74 (defun riece-filter (process input)
  75   (save-excursion
  76     (set-buffer (process-buffer process))
  77     (goto-char (point-max))
  78     (insert input)
  79     (goto-char riece-read-point)
  80     (beginning-of-line)
  81     (while (looking-at ".*\n")  ;the input line is finished
  82       (save-excursion
  83         (if (looking-at
  84              ":\\([^ ]+\\) +\\([0-5][0-9][0-9]\\) +\\([^ ]+\\) +\\(.*\\)")
  85             (riece-handle-numeric-reply
  86              (match-string 1)           ;prefix
  87              (string-to-number (match-string 2)) ;number
  88              (match-string 3)           ;name
  89              (riece-chomp-string (match-string 4))) ;reply string
  90           (if (looking-at "\\(:\\([^ ]+\\) +\\)?\\([^ ]+\\) +\\(.*\\)")
  91               (riece-handle-message
  92                (match-string 2)         ;optional prefix
  93                (match-string 3)         ;command
  94                (riece-chomp-string (match-string 4))) ;params & trailing
  95             (if riece-debug
  96                 (message "Weird message from server: %s"
  97                          (buffer-substring (point) (progn
  98                                                      (end-of-line)
  99                                                      (point))))))))
 100       (forward-line))
 101     (unless riece-debug
 102       (delete-region (point-min) (point)))
 103     (setq riece-read-point (point))))
 104
 105 (eval-when-compile
 106   (autoload 'riece-exit "riece"))
 107 (defun riece-sentinel (process status)
 108   (if riece-reconnect-with-password
 109       (let ((server-name
 110              (with-current-buffer (process-buffer process)
 111                riece-server-name)))
 112         (riece-close-server-process process)
 113         (riece-open-server
 114          (if (equal server-name "")
 115              riece-server
 116            (riece-server-name-to-server server-name))
 117          server-name))
 118     (let ((server-name (with-current-buffer (process-buffer process)
 119                          riece-server-name)))
 120       (if riece-debug
 121           (if (equal server-name "")
 122               (riece-debug (format "Connection closed: %s"
 123                                    (substring status 0 (1- (length status)))))
 124             (riece-debug (format "Connection to \"%s\" closed: %s"
 125                                  server-name
 126                                  (substring status 0 (1- (length status))))))
 127         (if (equal server-name "")
 128             (message "Connection closed")
 129           (message "Connection to \"%s\" closed" server-name)))
 130       (let ((channels riece-current-channels))
 131         (while channels
 132           (if (and (car channels)
 133                    (equal (riece-identity-server (car channels))
 134                           server-name))
 135               (riece-part-channel (car channels)))
 136           (setq channels (cdr channels))))
 137       (riece-redisplay-buffers)
 138       (riece-close-server-process process)
 139       ;; If no server process is available, exit.
 140       (unless riece-server-process-alist
 141         (riece-exit)))))
 142
 143 (provide 'riece-filter)
 144
 145 ;;; riece-filter.el ends here