cgit.sxemacs.org Git - riece/blob - lisp/riece-commands.el

   1 ;;; riece-commands.el --- commands available in command buffer
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-channel)
  28 (require 'riece-complete)
  29 (require 'riece-layout)
  30 (require 'riece-display)
  31 (require 'riece-server)
  32 (require 'riece-misc)
  33 (require 'riece-identity)
  34 (require 'riece-message)
  35 (require 'riece-mcat)
  36
  37 (autoload 'derived-mode-class "derived")
  38
  39 ;;; Channel movement:
  40 (defun riece-command-switch-to-channel (channel)
  41   (interactive (list (riece-completing-read-identity
  42                       (riece-mcat "Switch to channel/user: ")
  43                       riece-current-channels nil t)))
  44   (unless (equal channel riece-current-channel)
  45     (riece-switch-to-channel channel)))
  46
  47 (defun riece-command-switch-to-channel-by-number (number)
  48   (interactive
  49    (let ((command-name (symbol-name this-command)))
  50      (if (string-match "[0-9]+$" command-name)
  51          (list (string-to-number (match-string 0 command-name)))
  52        (list (string-to-number (read-string (riece-mcat "Switch to number: ")))))))
  53   (let ((channel (nth (1- number) riece-current-channels)))
  54     (if channel
  55         (riece-command-switch-to-channel channel)
  56       (error "No such number!"))))
  57
  58 (eval-and-compile
  59   (let ((number 1))
  60     (while (<= number 20)
  61       (defalias (intern (concat "riece-command-switch-to-channel-by-number-"
  62                                 (number-to-string number)))
  63         'riece-command-switch-to-channel-by-number)
  64       (setq number (1+ number)))))
  65
  66 (defun riece-command-next-channel ()
  67   "Select the next channel."
  68   (interactive)
  69   (when (> (length riece-current-channels) 1)
  70     (let ((pointer (cdr (riece-identity-member
  71                          riece-current-channel
  72                          riece-current-channels))))
  73       (while (and pointer
  74                   (null (car pointer)))
  75         (setq pointer (cdr pointer)))
  76       (when (null pointer)
  77         (setq pointer riece-current-channels)
  78         (while (and pointer
  79                     (null (car pointer)))
  80           (setq pointer (cdr pointer))))
  81       (if (car pointer)
  82           (riece-command-switch-to-channel (car pointer))
  83         (error "No such channel!")))))
  84
  85 (defun riece-command-previous-channel ()
  86   "Select the previous channel."
  87   (interactive)
  88   (when (> (length riece-current-channels) 1)
  89     (let ((pointer (riece-identity-member
  90                     riece-current-channel
  91                     riece-current-channels))
  92           (start riece-current-channels)
  93           channel)
  94       (while (and start (not (eq start pointer)))
  95         (if (car start)
  96             (setq channel (car start)))
  97         (setq start (cdr start)))
  98       (when (null channel)
  99         (setq start (copy-sequence riece-current-channels))
 100         (setq start (delq nil start))
 101         (and (> (length start) 1)
 102              (setq channel (nth (1- (length start)) start))))
 103       (if channel
 104           (riece-command-switch-to-channel channel)
 105         (error "No such channel!")))))
 106
 107 (defun riece-command-select-command-buffer ()
 108   "Select the command buffer."
 109   (interactive)
 110   (let ((window (get-buffer-window riece-command-buffer)))
 111     (if window
 112         (select-window window))))
 113
 114 (defun riece-command-configure-windows ()
 115   (interactive)
 116   "Reconfigure windows with the current layout."
 117   (riece-redisplay-buffers t))
 118
 119 (defun riece-command-suspend-resume ()
 120   (interactive)
 121   "Save or restore the current window configuration."
 122   (let ((entry (assq 'riece-window-configuration (frame-parameters))))
 123     (modify-frame-parameters (selected-frame)
 124                              (list (cons 'riece-window-configuration
 125                                          (current-window-configuration))))
 126     (if (cdr entry)
 127         (set-window-configuration (cdr entry))
 128       (delete-other-windows))
 129     (message
 130      (substitute-command-keys
 131       "\\[riece-command-suspend-resume] to get back the last windows"))))
 132
 133 (defun riece-command-change-layout (name)
 134   "Select a layout-name from all current available layouts and change
 135 the layout to the selected layout-name."
 136   (interactive (list (completing-read (riece-mcat "Change layout: ")
 137                                       riece-layout-alist)))
 138   (setq riece-layout name
 139         riece-save-variables-are-dirty t)
 140   (riece-command-configure-windows))
 141
 142 (defun riece-command-toggle-channel-buffer-mode ()
 143   (interactive)
 144   (setq riece-channel-buffer-mode
 145         (not riece-channel-buffer-mode)
 146         riece-save-variables-are-dirty t)
 147   (riece-command-configure-windows))
 148
 149 (defun riece-command-toggle-others-buffer-mode ()
 150   (interactive)
 151   (setq riece-others-buffer-mode
 152         (not riece-others-buffer-mode)
 153         riece-save-variables-are-dirty t)
 154   (riece-command-configure-windows))
 155
 156 (defun riece-command-toggle-user-list-buffer-mode ()
 157   (interactive)
 158   (setq riece-user-list-buffer-mode
 159         (not riece-user-list-buffer-mode)
 160         riece-save-variables-are-dirty t)
 161   (riece-command-configure-windows))
 162
 163 (defun riece-command-toggle-channel-list-buffer-mode ()
 164   (interactive)
 165   (setq riece-channel-list-buffer-mode
 166         (not riece-channel-list-buffer-mode)
 167         riece-save-variables-are-dirty t)
 168   (riece-command-configure-windows))
 169
 170 (defun riece-command-finger (user &optional recurse)
 171   (interactive
 172    (let* ((completion-ignore-case t)
 173           (user (riece-completing-read-identity
 174                  (riece-mcat "Finger user: ")
 175                  (riece-get-users-on-server (riece-current-server-name))
 176                  nil nil nil nil nil t)))
 177      (list user current-prefix-arg)))
 178   (if recurse
 179       (riece-send-string (format "WHOIS %s %s\r\n"
 180                                  (riece-identity-prefix user)
 181                                  (riece-identity-prefix user)))
 182     (riece-send-string (format "WHOIS %s\r\n" (riece-identity-prefix user)))))
 183
 184 (defun riece-command-topic (topic)
 185   (interactive
 186    (progn
 187      (riece-check-channel-commands-are-usable t)
 188      (list (read-from-minibuffer
 189             (riece-mcat "Set topic: ")
 190             (cons (or (riece-with-server-buffer
 191                           (riece-identity-server
 192                            riece-current-channel)
 193                         (riece-channel-get-topic
 194                          (riece-identity-prefix
 195                           riece-current-channel)))
 196                       "")
 197                   0)))))
 198   (riece-send-string (format "TOPIC %s :%s\r\n"
 199                              (riece-identity-prefix riece-current-channel)
 200                              topic)
 201                      riece-current-channel))
 202
 203 (defun riece-command-invite (user)
 204   (interactive
 205    (let ((completion-ignore-case t))
 206      (riece-check-channel-commands-are-usable t)
 207      (list (riece-completing-read-identity
 208             (riece-mcat "Invite user: ")
 209             (riece-get-users-on-server (riece-current-server-name))
 210             nil nil nil nil nil t))))
 211   (riece-send-string (format "INVITE %s :%s\r\n"
 212                              (riece-identity-prefix user)
 213                              (riece-identity-prefix riece-current-channel))))
 214
 215 (defun riece-command-kick (user &optional message)
 216   (interactive
 217    (let ((completion-ignore-case t))
 218      (riece-check-channel-commands-are-usable t)
 219      (list (completing-read
 220             (riece-mcat "Kick user: ")
 221             (riece-with-server-buffer
 222                 (riece-identity-server riece-current-channel)
 223               (riece-channel-get-users (riece-identity-prefix
 224                                         riece-current-channel))))
 225            (if current-prefix-arg
 226                (read-string "Message: ")))))
 227   (riece-send-string
 228    (if message
 229        (format "KICK %s %s :%s\r\n"
 230                (riece-identity-prefix riece-current-channel)
 231                user message)
 232      (format "KICK %s %s\r\n"
 233              (riece-identity-prefix riece-current-channel)
 234              user))
 235    riece-current-channel))
 236
 237 (defun riece-command-kick-with-ban (user pattern &optional message)
 238   (interactive
 239    (let ((completion-ignore-case t)
 240          user)
 241      (riece-check-channel-commands-are-usable t)
 242      (riece-with-server-buffer (riece-identity-server riece-current-channel)
 243        (setq user (completing-read
 244                    (riece-mcat "Kick user: ")
 245                    (riece-channel-get-users (riece-identity-prefix
 246                                              riece-current-channel))))
 247        (list
 248         user
 249         (read-from-minibuffer
 250          (riece-mcat "Ban pattern: ")
 251          (concat user "!" (riece-user-get-user-at-host user)))
 252         (if current-prefix-arg
 253             (read-string "Message: "))))))
 254   (riece-send-string (format "MODE %s :+b %s\r\n"
 255                              (riece-identity-prefix riece-current-channel)
 256                              pattern)
 257                      riece-current-channel)
 258   (riece-send-string
 259    (if message
 260        (format "KICK %s %s :%s\r\n"
 261                (riece-identity-prefix riece-current-channel)
 262                user message)
 263      (format "KICK %s %s\r\n"
 264              (riece-identity-prefix riece-current-channel)
 265              user))
 266    riece-current-channel))
 267
 268 (defun riece-command-names (pattern)
 269   (interactive
 270    (let ((completion-ignore-case t))
 271      (list (read-from-minibuffer
 272             (riece-mcat "NAMES pattern: ")
 273             (if (and riece-current-channel
 274                      (riece-channel-p (riece-identity-prefix
 275                                        riece-current-channel)))
 276                 (cons (riece-identity-prefix riece-current-channel)
 277                       0))))))
 278   (if (or (not (equal pattern ""))
 279           (yes-or-no-p (riece-mcat
 280                         "Really want to query NAMES without argument? ")))
 281       (riece-send-string (format "NAMES %s\r\n" pattern))))
 282
 283 (defun riece-command-who (pattern)
 284   (interactive
 285    (let ((completion-ignore-case t))
 286      (list (read-from-minibuffer
 287             (riece-mcat "WHO pattern: ")
 288             (if (and riece-current-channel
 289                      (riece-channel-p (riece-identity-prefix
 290                                        riece-current-channel)))
 291                 (cons (riece-identity-prefix riece-current-channel)
 292                       0))))))
 293   (if (or (not (equal pattern ""))
 294           (yes-or-no-p (riece-mcat
 295                         "Really want to query WHO without argument? ")))
 296       (riece-send-string (format "WHO %s\r\n" pattern))))
 297
 298 (defun riece-command-list (pattern)
 299   (interactive
 300    (let ((completion-ignore-case t))
 301      (list (read-from-minibuffer
 302             (riece-mcat "LIST pattern: ")
 303             (if (and riece-current-channel
 304                      (riece-channel-p (riece-identity-prefix
 305                                        riece-current-channel)))
 306                 (cons (riece-identity-prefix riece-current-channel)
 307                       0))))))
 308   (if (or (not (equal pattern ""))
 309           (yes-or-no-p (riece-mcat
 310                         "Really want to query LIST without argument? ")))
 311       (riece-send-string (format "LIST %s\r\n" pattern))))
 312
 313 (defun riece-command-change-mode (channel change)
 314   (interactive
 315    (let* ((completion-ignore-case t)
 316           (channel
 317            (if current-prefix-arg
 318                (riece-completing-read-identity
 319                 (riece-mcat "Change mode for channel/user: ")
 320                 (riece-get-identities-on-server (riece-current-server-name))
 321                 nil nil nil nil nil t)
 322              (riece-check-channel-commands-are-usable t)
 323              riece-current-channel))
 324           (riece-overriding-server-name (riece-identity-server channel))
 325           (riece-temp-minibuffer-message
 326            (concat (riece-mcat "[Available modes: ")
 327                    (riece-with-server-buffer (riece-identity-server channel)
 328                      (if (riece-channel-p (riece-identity-prefix channel))
 329                          (if riece-supported-channel-modes
 330                              (apply #'string riece-supported-channel-modes))
 331                        (if riece-supported-user-modes
 332                            (apply #'string riece-supported-user-modes))))
 333                    "]")))
 334      (list channel
 335            (read-from-minibuffer
 336             (concat (riece-concat-channel-modes
 337                      channel (riece-mcat "Mode (? for help)")) ": ")
 338             nil riece-minibuffer-map))))
 339   (if (equal change "")
 340       (riece-send-string (format "MODE %s\r\n"
 341                                  (riece-identity-prefix channel)))
 342     (riece-send-string (format "MODE %s %s\r\n"
 343                                (riece-identity-prefix channel)
 344                                change))))
 345
 346 (defun riece-command-set-operators (users &optional arg)
 347   (interactive
 348    (progn
 349      (riece-check-channel-commands-are-usable t)
 350      (let ((completion-ignore-case t))
 351        (list (riece-completing-read-multiple
 352               (if current-prefix-arg
 353                   (riece-mcat "Unset +o for users")
 354                 (riece-mcat "Set +o for users"))
 355               (riece-with-server-buffer
 356                   (riece-identity-server riece-current-channel)
 357                 (riece-channel-get-users (riece-identity-prefix
 358                                          riece-current-channel)))
 359               (if current-prefix-arg
 360                   (lambda (user)
 361                     (memq ?o (cdr user)))
 362                 (lambda (user)
 363                   (not (memq ?o (cdr user))))))
 364              current-prefix-arg))))
 365   (let (group)
 366     (while users
 367       (setq group (cons (car users) group)
 368             users (cdr users))
 369       (when (or (= (length group) 3)
 370                 (null users))
 371         (riece-send-string
 372          (format "MODE %s %c%s %s\r\n"
 373                  (riece-identity-prefix riece-current-channel)
 374                  (if current-prefix-arg
 375                      ?-
 376                    ?+)
 377                  (make-string (length group) ?o)
 378                  (mapconcat #'identity (nreverse group) " ")))
 379         (setq group nil)))))
 380
 381 (defun riece-command-set-speakers (users &optional arg)
 382   (interactive
 383    (progn
 384      (riece-check-channel-commands-are-usable t)
 385      (let ((completion-ignore-case t))
 386        (list (riece-completing-read-multiple
 387               (if current-prefix-arg
 388                   (riece-mcat "Unset +v for users")
 389                 (riece-mcat "Set +v for users"))
 390               (riece-with-server-buffer
 391                   (riece-identity-server riece-current-channel)
 392                 (riece-channel-get-users (riece-identity-prefix
 393                                           riece-current-channel)))
 394               (if current-prefix-arg
 395                   (lambda (user)
 396                     (memq ?v (cdr user)))
 397                 (lambda (user)
 398                   (not (memq ?v (cdr user))))))
 399              current-prefix-arg))))
 400   (let (group)
 401     (while users
 402       (setq group (cons (car users) group)
 403             users (cdr users))
 404       (when (or (= (length group) 3)
 405                 (null users))
 406         (riece-send-string
 407          (format "MODE %s %c%s %s\r\n"
 408                  (riece-identity-prefix riece-current-channel)
 409                  (if current-prefix-arg
 410                      ?-
 411                    ?+)
 412                  (make-string (length group) ?v)
 413                  (mapconcat #'identity (nreverse group) " ")))
 414         (setq group nil)))))
 415
 416 (defun riece-command-send-message (message notice)
 417   "Send MESSAGE to the current channel."
 418   (run-hooks 'riece-command-send-message-hook)
 419   (if (equal message "")
 420       (error (riece-mcat "No text to send")))
 421   (riece-check-channel-commands-are-usable)
 422   (if notice
 423       (progn
 424         (riece-send-string
 425          (format "NOTICE %s :%s\r\n"
 426                  (riece-identity-prefix riece-current-channel)
 427                  message)
 428          riece-current-channel)
 429         (riece-display-message
 430          (riece-make-message (riece-current-nickname) riece-current-channel
 431                              message 'notice t)))
 432     (riece-send-string
 433      (format "PRIVMSG %s :%s\r\n"
 434              (riece-identity-prefix riece-current-channel)
 435              message)
 436      riece-current-channel)
 437     (riece-display-message
 438      (riece-make-message (riece-current-nickname) riece-current-channel
 439                          message nil t))))
 440
 441 (defun riece-command-enter-message ()
 442   "Send the current line to the current channel."
 443   (interactive)
 444   (riece-command-send-message (buffer-substring
 445                                (riece-line-beginning-position)
 446                                (riece-line-end-position))
 447                               nil)
 448   (let ((next-line-add-newlines t))
 449     (next-line 1)))
 450
 451 (defun riece-command-enter-message-as-notice ()
 452   "Send the current line to the current channel as NOTICE."
 453   (interactive)
 454   (riece-command-send-message (buffer-substring
 455                                (riece-line-beginning-position)
 456                                (riece-line-end-position))
 457                               t)
 458   (let ((next-line-add-newlines t))
 459     (next-line 1)))
 460
 461 (defun riece-command-enter-message-to-user (user)
 462   "Send the current line to USER."
 463   (interactive
 464    (if (and (bolp) (eolp))
 465        (error "No text to send")
 466      (let ((completion-ignore-case t))
 467        (list (riece-completing-read-identity
 468               (riece-mcat "Message to user: ")
 469               (riece-get-users-on-server (riece-current-server-name))
 470               nil nil nil nil nil t)))))
 471   (let ((text (buffer-substring
 472                (riece-line-beginning-position)
 473                (riece-line-end-position))))
 474     (riece-send-string
 475      (format "PRIVMSG %s :%s\r\n" (riece-identity-prefix user) text)
 476      user)
 477     (riece-display-message
 478      (riece-make-message (riece-current-nickname) user text nil t)))
 479   (let ((next-line-add-newlines t))
 480     (next-line 1)))
 481
 482 (defun riece-command-join-channel (target key)
 483   (unless (riece-server-opened (riece-identity-server target))
 484     (error "%s" (substitute-command-keys
 485                  "Type \\[riece-command-open-server] to open server.")))
 486   (riece-send-string (if key
 487                          (format "JOIN %s :%s\r\n"
 488                                  (riece-identity-prefix target)
 489                                  key)
 490                        (format "JOIN %s\r\n"
 491                                (riece-identity-prefix target)))
 492                      target))
 493
 494 (defun riece-command-join-partner (target)
 495   (let ((pointer (riece-identity-member target riece-current-channels)))
 496     (if pointer
 497         (riece-command-switch-to-channel (car pointer))
 498       (riece-join-channel target)
 499       (riece-switch-to-channel target))))
 500
 501 (defun riece-command-join (target)
 502   (interactive
 503    (let ((completion-ignore-case t))
 504      (list
 505       (if riece-join-channel-candidate
 506           (let ((default (riece-format-identity
 507                           riece-join-channel-candidate)))
 508             (riece-completing-read-identity
 509              (format (riece-mcat "Join channel/user (default %s): ") default)
 510              (riece-get-identities-on-server (riece-current-server-name))
 511              nil nil nil nil default))
 512         (riece-completing-read-identity
 513          (riece-mcat "Join channel/user: ")
 514          (riece-get-identities-on-server (riece-current-server-name)))))))
 515   (let ((pointer (riece-identity-member target riece-current-channels)))
 516     (if pointer
 517         (riece-command-switch-to-channel (car pointer))
 518       (if (riece-channel-p (riece-identity-prefix target))
 519           (riece-command-join-channel target nil)
 520         (riece-command-join-partner target)))))
 521
 522 (defun riece-command-part-channel (target message)
 523   (unless (riece-server-opened (riece-identity-server target))
 524     (error "%s" (substitute-command-keys
 525                  "Type \\[riece-command-open-server] to open server.")))
 526   (riece-send-string (if message
 527                          (format "PART %s :%s\r\n"
 528                                  (riece-identity-prefix target)
 529                                  message)
 530                        (format "PART %s\r\n"
 531                                (riece-identity-prefix target)))
 532                      target))
 533
 534 (defun riece-command-part (target &optional message)
 535   (interactive
 536    (progn
 537      (riece-check-channel-commands-are-usable)
 538      (let* ((completion-ignore-case t)
 539             (target
 540              (riece-completing-read-identity
 541               (format (riece-mcat "Part from channel/user (default %s): ")
 542                       (riece-format-identity riece-current-channel))
 543               riece-current-channels nil nil nil nil
 544               (riece-format-identity riece-current-channel)))
 545             (message
 546              (if current-prefix-arg
 547                  (read-string (riece-mcat "Message: "))
 548                riece-part-message)))
 549        (list target message))))
 550   (if (riece-identity-member target riece-current-channels)
 551       (if (riece-channel-p (riece-identity-prefix target))
 552           (riece-command-part-channel target message)
 553         (riece-part-channel target))
 554     (error "You are not talking with %s" target)))
 555
 556 (defun riece-command-change-nickname (nickname)
 557   "Change your nickname to NICK."
 558   (interactive "sEnter your nickname: ")
 559   (riece-send-string (format "NICK %s\r\n" nickname)))
 560
 561 (defun riece-command-scroll-down (lines)
 562   "Scroll LINES down dialogue buffer from command buffer."
 563   (interactive "P")
 564   (let ((buffer (if (and riece-channel-buffer-mode
 565                          riece-current-channel)
 566                     riece-channel-buffer
 567                   riece-dialogue-buffer)))
 568     (if (get-buffer-window buffer)
 569         (condition-case nil
 570             (let ((other-window-scroll-buffer buffer))
 571               (scroll-other-window-down lines))
 572           (beginning-of-buffer
 573            (message (riece-mcat "Beginning of buffer")))))))
 574
 575 (defun riece-command-scroll-up (lines)
 576   "Scroll LINES up dialogue buffer from command buffer."
 577   (interactive "P")
 578   (let ((buffer (if (and riece-channel-buffer-mode
 579                          riece-current-channel)
 580                     riece-channel-buffer
 581                   riece-dialogue-buffer)))
 582     (if (get-buffer-window buffer)
 583         (condition-case nil
 584             (let ((other-window-scroll-buffer buffer))
 585               (scroll-other-window lines))
 586           (end-of-buffer
 587            (message (riece-mcat "End of buffer")))))))
 588
 589 (defun riece-command-user-list-scroll-down (lines)
 590   "Scroll LINES down user list buffer from command buffer."
 591   (interactive "P")
 592   (if (get-buffer-window riece-user-list-buffer)
 593       (condition-case nil
 594           (let ((other-window-scroll-buffer riece-user-list-buffer))
 595             (scroll-other-window-down lines))
 596         (beginning-of-buffer
 597          (message (riece-mcat "Beginning of buffer"))))))
 598
 599 (defun riece-command-user-list-scroll-up (lines)
 600   "Scroll LINES up user list buffer from command buffer."
 601   (interactive "P")
 602   (if (get-buffer-window riece-user-list-buffer)
 603       (condition-case nil
 604           (let ((other-window-scroll-buffer riece-user-list-buffer))
 605             (scroll-other-window lines))
 606         (end-of-buffer
 607          (message (riece-mcat "End of buffer"))))))
 608
 609 (defun riece-command-toggle-away (&optional message)
 610   "Mark yourself as being away."
 611   (interactive
 612    (if (and (not (riece-with-server-buffer (riece-identity-server
 613                                             (riece-current-nickname))
 614                    (riece-user-get-away (riece-identity-prefix
 615                                          (riece-current-nickname)))))
 616             current-prefix-arg)
 617        (list (read-from-minibuffer
 618               (riece-mcat "Away message: ") (cons (or riece-away-message "")
 619                                                   0)))))
 620   (if (riece-with-server-buffer (riece-identity-server
 621                                  (riece-current-nickname))
 622         (riece-user-get-away (riece-identity-prefix
 623                               (riece-current-nickname))))
 624       (riece-send-string "AWAY\r\n")
 625     (riece-send-string (format "AWAY :%s\r\n" (or message
 626                                                   riece-away-message)))))
 627
 628 (defun riece-command-toggle-freeze (&optional arg)
 629   "Prevent automatic scrolling of the dialogue window.
 630 If prefix argument ARG is non-nil, toggle frozen status."
 631   (interactive "P")
 632   (with-current-buffer (if (eq (derived-mode-class major-mode)
 633                                'riece-dialogue-mode)
 634                            (current-buffer)
 635                          (if (and riece-channel-buffer-mode
 636                                   riece-channel-buffer)
 637                              riece-channel-buffer
 638                            riece-dialogue-buffer))
 639     (setq riece-freeze (if arg
 640                            (< 0 (prefix-numeric-value arg))
 641                          (not riece-freeze)))
 642     (riece-emit-signal 'buffer-freeze-changed
 643                        (current-buffer) riece-freeze)))
 644
 645 (defun riece-command-toggle-own-freeze (&optional arg)
 646   "Prevent automatic scrolling of the dialogue window.
 647 The difference from `riece-command-freeze' is that your messages are hidden.
 648 If prefix argument ARG is non-nil, toggle frozen status."
 649   (interactive "P")
 650   (with-current-buffer (if (eq (derived-mode-class major-mode)
 651                                'riece-dialogue-mode)
 652                            (current-buffer)
 653                          (if (and riece-channel-buffer-mode
 654                                   riece-channel-buffer)
 655                              riece-channel-buffer
 656                            riece-dialogue-buffer))
 657     (if (if arg
 658             (< 0 (prefix-numeric-value arg))
 659           (not (eq riece-freeze 'own)))
 660         (setq riece-freeze 'own)
 661       (setq riece-freeze nil))
 662     (riece-emit-signal 'buffer-freeze-changed
 663                        (current-buffer) riece-freeze)))
 664
 665 (eval-when-compile
 666   (autoload 'riece-exit "riece"))
 667 (defun riece-command-quit (&optional arg)
 668   "Quit IRC."
 669   (interactive "P")
 670   (if (null riece-server-process-alist)
 671       (progn
 672         (message (riece-mcat "No server process"))
 673         (ding))
 674     (if (y-or-n-p (riece-mcat "Really quit IRC? "))
 675         (let ((message
 676                (if arg
 677                    (read-string (riece-mcat "Message: "))
 678                  riece-quit-message))
 679               (alist riece-server-process-alist))
 680           (while alist
 681             (riece-quit-server-process (cdr (car alist)) message)
 682             (setq alist (cdr alist)))))))
 683
 684 (defun riece-command-raw (command)
 685   "Enter raw IRC command, which is sent to the server."
 686   (interactive "sIRC command: ")
 687   (riece-send-string (concat command "\r\n")))
 688
 689 (defun riece-command-beginning-of-buffer ()
 690   "Scroll channel buffer to the beginning."
 691   (interactive)
 692   (let (buffer window)
 693     (setq buffer (if riece-channel-buffer-mode
 694                      riece-channel-buffer
 695                    riece-dialogue-buffer))
 696     (or (setq window (get-buffer-window buffer))
 697         (setq window (get-buffer-window riece-dialogue-buffer)
 698               buffer riece-dialogue-buffer))
 699     (when window
 700       (save-selected-window
 701         (select-window window)
 702         (goto-char (point-min))))))
 703
 704 (defun riece-command-end-of-buffer ()
 705   "Scroll channel buffer to the end."
 706   (interactive)
 707   (let (buffer window)
 708     (setq buffer (if riece-channel-buffer-mode
 709                      riece-channel-buffer
 710                    riece-dialogue-buffer))
 711     (or (setq window (get-buffer-window buffer))
 712         (setq window (get-buffer-window riece-dialogue-buffer)
 713               buffer riece-dialogue-buffer))
 714     (when window
 715       (save-selected-window
 716         (select-window window)
 717         (goto-char (point-max))))))
 718
 719 (defun riece-command-copy-region (start end)
 720   "Move current region between START and END to `kill-ring'."
 721   (interactive "r")
 722   (kill-new (buffer-substring-no-properties start end)))
 723
 724 (defun riece-command-complete-user ()
 725   "Complete a user name in the current buffer."
 726   (interactive)
 727   (let* ((completion-ignore-case t)
 728          (table (mapcar (lambda (user)
 729                           (list (riece-format-identity user t)))
 730                         (riece-get-users-on-server
 731                          (riece-current-server-name))))
 732          (current (or (current-word) ""))
 733          (completion (try-completion current table))
 734          (all (all-completions current table)))
 735     (if (eq completion t)
 736         nil
 737       (if (null completion)
 738           (message (riece-mcat "Can't find completion for \"%s\"") current)
 739         (if (equal current completion)
 740             (with-output-to-temp-buffer "*Help*"
 741               (display-completion-list all))
 742           (re-search-forward "\\>" nil t)
 743           (delete-region (point) (- (point) (length current)))
 744           (insert completion))))))
 745
 746 (defun riece-command-open-server (server-name)
 747   (interactive
 748    (list (completing-read (riece-mcat "Open server: ") riece-server-alist)))
 749   (if (riece-server-process server-name)
 750       (error "%s is already opened" server-name))
 751   (riece-open-server
 752    (riece-server-name-to-server server-name)
 753    server-name))
 754
 755 (defun riece-command-close-server (server-name &optional message)
 756   (interactive
 757    (list (completing-read (riece-mcat "Close server: ")
 758                           riece-server-process-alist)
 759          (if current-prefix-arg
 760              (read-string (riece-mcat "Message: "))
 761            riece-quit-message)))
 762   (let ((process (riece-server-process server-name)))
 763     (unless process
 764       (error "%s is not opened" server-name))
 765     (riece-quit-server-process process message)))
 766
 767 (defun riece-command-universal-server-name-argument ()
 768   (interactive)
 769   (let* ((riece-overriding-server-name
 770           (completing-read (riece-mcat "Server: ") riece-server-process-alist))
 771          (command
 772           (key-binding (read-key-sequence
 773                         (format (riece-mcat "Command to execute on \"%s\":")
 774                                 riece-overriding-server-name)))))
 775     (message "")
 776     (call-interactively command)))
 777
 778 (eval-when-compile
 779   (autoload 'riece-save-variables-files "riece"))
 780 (defun riece-command-save-variables ()
 781   "Save `riece-variables-file'."
 782   (interactive)
 783   (if (or riece-save-variables-are-dirty
 784           (y-or-n-p (riece-mcat "No changes made.  Save anyway? ")))
 785       (riece-save-variables-files)))
 786
 787 (provide 'riece-commands)
 788
 789 ;;; riece-commands.el ends here