cgit.sxemacs.org Git - riece/blob - lisp/riece-addon.el

   1 ;;; riece-addon.el --- add-on management
   2 ;; Copyright (C) 1998-2004 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (require 'font-lock)
  28 (require 'riece-options)
  29 (require 'riece-compat)
  30 (require 'riece-misc)
  31 (require 'riece-addon-modules)
  32
  33 (defgroup riece-addon-list nil
  34   "Add-on listing."
  35   :tag "Addon list"
  36   :prefix "riece-addon-list-"
  37   :group 'riece)
  38
  39 (defgroup riece-addon-list-faces nil
  40   "Faces for riece-addon-list-mode."
  41   :tag "Faces"
  42   :prefix "riece-addon-list-"
  43   :group 'riece-addon-list)
  44
  45 (defface riece-addon-list-enabled-face
  46   '((((class color) (background dark))
  47      (:foreground "PaleTurquoise" :bold t))
  48     (t
  49      (:bold t)))
  50   "Face used for displaying the enabled addon."
  51   :group 'riece-addon-list-faces)
  52 (defvar riece-addon-list-enabled-face 'riece-addon-list-enabled-face)
  53
  54 (defface riece-addon-list-disabled-face
  55   '((((class color) (background dark))
  56      (:foreground "PaleTurquoise" :italic t))
  57     (t
  58      (:italic t)))
  59   "Face used for displaying the disabled addon."
  60   :group 'riece-addon-list-faces)
  61 (defvar riece-addon-list-disabled-face 'riece-addon-list-disabled-face)
  62
  63 (defface riece-addon-list-unsupported-face
  64   '((((class color) (background dark))
  65      (:foreground "PaleTurquoise"))
  66     (t
  67      ()))
  68   "Face used for displaying the unsupported addon."
  69   :group 'riece-addon-list-faces)
  70 (defvar riece-addon-list-unsupported-face 'riece-addon-list-unsupported-face)
  71
  72 (defface riece-addon-list-uninstalled-face
  73   '((t
  74      (:foreground "red")))
  75   "Face used for displaying the uninstalled addon."
  76   :group 'riece-addon-list-faces)
  77 (defvar riece-addon-list-uninstalled-face 'riece-addon-list-uninstalled-face)
  78
  79 (defface riece-addon-list-description-face
  80   '((((class color)
  81       (background dark))
  82      (:foreground "lightyellow"))
  83     (((class color)
  84       (background light))
  85      (:foreground "blue4"))
  86     (t
  87      ()))
  88   "Face used for displaying the description addon."
  89   :group 'riece-addon-list-faces)
  90 (defvar riece-addon-list-description-face 'riece-addon-list-description-face)
  91
  92 (defcustom riece-addon-list-mark-face-alist
  93   '((?+ . riece-addon-list-enabled-face)
  94     (?- . riece-addon-list-disabled-face)
  95     (?! . riece-addon-list-unsupported-face)
  96     (?  . riece-addon-list-uninstalled-face))
  97   "An alist mapping marks on riece-addon-list-buffer to faces."
  98   :type 'list
  99   :group 'riece-addon-list)
 100
 101 (defcustom riece-addon-list-font-lock-keywords
 102   '(("^\\([-+! ] [^:]+\\): \\(.*\\)"
 103      (1 (cdr (assq (aref (match-string 1) 0)
 104                    riece-addon-list-mark-face-alist)))
 105      (2 riece-addon-list-description-face)))
 106   "Default expressions to addon in riece-addon-list-mode."
 107   :type '(repeat (list string))
 108   :group 'riece-addon-list)
 109
 110 (defvar riece-addon-list-mode-map
 111   (let ((keymap (make-sparse-keymap)))
 112     (define-key keymap "+" 'riece-command-enable-addon)
 113     (define-key keymap "-" 'riece-command-disable-addon)
 114     (define-key keymap "I" 'riece-command-insinuate-addon)
 115     (define-key keymap "D" 'riece-command-uninstall-addon)
 116     (define-key keymap "n" 'next-line)
 117     (define-key keymap "p" 'previous-line)
 118     (define-key keymap " " 'scroll-up)
 119     (define-key keymap [delete] 'scroll-down)
 120     (define-key keymap "q" 'bury-buffer)
 121     keymap))
 122
 123 (defun riece-load-and-build-addon-dependencies (addons)
 124   (let ((load-path (cons riece-addon-directory load-path))
 125         dependencies)
 126     (while addons
 127       (require (car addons))            ;error will be reported here
 128       (let* ((requires
 129               (funcall (or (intern-soft
 130                             (concat (symbol-name (car addons)) "-requires"))
 131                            #'ignore)))
 132              (pointer requires)
 133              entry)
 134         ;; Increment succs' pred count.
 135         (if (setq entry (assq (car addons) dependencies))
 136             (setcar (cdr entry) (+ (length requires) (nth 1 entry)))
 137           (setq dependencies (cons (list (car addons) (length requires))
 138                                    dependencies)))
 139         ;; Merge pred's succs.
 140         (while pointer
 141           (if (setq entry (assq (car pointer) dependencies))
 142               (setcdr (cdr entry) (cons (car addons) (nthcdr 2 entry)))
 143             (setq dependencies (cons (list (car pointer) 0 (car addons))
 144                                      dependencies)))
 145           (setq pointer (cdr pointer))))
 146       (setq addons (cdr addons)))
 147     dependencies))
 148
 149 (defun riece-sort-addon-dependencies (dependencies)
 150   (let ((pointer dependencies)
 151         addons queue)
 152     (while pointer
 153       (if (zerop (nth 1 (car pointer)))
 154           (setq dependencies (delq (car pointer) dependencies)
 155                 queue (cons (car pointer) queue)))
 156       (setq pointer (cdr pointer)))
 157     (while queue
 158       (setq addons (cons (cons (car (car queue)) (nthcdr 2 (car queue)))
 159                          addons)
 160             pointer (nthcdr 2 (car queue)))
 161       (while pointer
 162         (let* ((entry (assq (car pointer) dependencies))
 163                (count (1- (nth 1 entry))))
 164           (if (zerop count)
 165               (setq dependencies (delq entry dependencies)
 166                     queue (nconc queue (list entry)))
 167             (setcar (cdr entry) count)))
 168         (setq pointer (cdr pointer)))
 169       (setq queue (cdr queue)))
 170     (if dependencies
 171         (error "Circular add-on dependency found: %S" dependencies))
 172     (nreverse addons)))
 173
 174 (defun riece-resolve-addons (addons)
 175   ;; Add files in riece-addon-directory to addons.
 176   (if (file-directory-p riece-addon-directory)
 177       (setq addons (nconc
 178                     addons
 179                     (mapcar
 180                      (lambda (name)
 181                        (unless (file-directory-p
 182                                 (expand-file-name name riece-addon-directory))
 183                          (intern (file-name-sans-extension name))))
 184                      (directory-files riece-addon-directory nil "\\`[^.]")))))
 185   ;; Sort & uniquify.
 186   (setq addons (sort addons (lambda (symbol1 symbol2)
 187                               (string-lessp (symbol-name symbol1)
 188                                             (symbol-name symbol2)))))
 189   (let ((pointer addons))
 190     (while pointer
 191       (if (memq (car pointer) (cdr pointer))
 192           (setcar pointer nil))
 193       (setq pointer (cdr pointer)))
 194     (delq nil addons))
 195   ;; Build & resolve dependencies.
 196   (riece-sort-addon-dependencies
 197    (riece-load-and-build-addon-dependencies addons)))
 198
 199 (defun riece-insinuate-addon (addon &optional verbose)
 200   (unless (assq addon riece-addon-dependencies)
 201     (setq riece-addons (cons addon riece-addons)
 202           riece-addon-dependencies (riece-resolve-addons riece-addons)))
 203   (if (get addon 'riece-addon-insinuated)
 204       (if verbose
 205           (message "Add-on %S is already insinuated" addon))
 206     (funcall (intern (concat (symbol-name addon) "-insinuate")))
 207     (put addon 'riece-addon-insinuated t)
 208     (if verbose
 209         (message "Add-on %S is insinuated" addon))))
 210
 211 (defun riece-uninstall-addon (addon &optional verbose)
 212   (if (not (get addon 'riece-addon-insinuated))
 213       (if verbose
 214           (message "Add-on %S is not insinuated" addon))
 215     (let ((entry (assq addon riece-addon-dependencies))
 216           (enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 217       (if entry
 218           (if (cdr entry)
 219               (if (= (length (cdr entry)) 1)
 220                   (error "%S depends %S" (car (cdr entry)) addon)
 221                 (error "%s depends %S" (mapconcat #'identity (cdr entry) ",")
 222                        addon))
 223             (if (and enabled
 224                      (symbol-value enabled))
 225                 (riece-disable-addon addon verbose))
 226             (funcall (or (intern-soft (concat (symbol-name addon)
 227                                               "-uninstall"))
 228                          #'ignore))
 229             (setq riece-addon-dependencies
 230                   (delq entry riece-addon-dependencies))
 231             (put addon 'riece-addon-insinuated nil)
 232             (setq riece-addons (delq addon riece-addons))))
 233       (if verbose
 234           (message "Add-on %S is uninstalled" addon)))))
 235
 236 (defun riece-enable-addon (addon &optional verbose)
 237   (unless (get addon 'riece-addon-insinuated)
 238     (error "Add-on %S is not insinuated" addon))
 239   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 240     (if (null enabled)
 241         (if verbose
 242             (message "Add-on %S doesn't support enable/disable" addon))
 243       (if (symbol-value enabled)
 244           (if verbose
 245               (message "Add-on %S is already enabled" addon))
 246         (funcall (intern (concat (symbol-name addon) "-enable")))
 247         (if verbose
 248             (message "Add-on %S enabled" addon))))))
 249
 250 (defun riece-disable-addon (addon &optional verbose)
 251   (unless (get addon 'riece-addon-insinuated)
 252     (error "Add-on %S is not insinuated" addon))
 253   (let ((enabled (intern-soft (concat (symbol-name addon) "-enabled"))))
 254     (if (null enabled)
 255         (if verbose
 256             (message "Add-on %S doesn't support enable/disable" addon))
 257       (if (symbol-value enabled)
 258           (progn
 259             (funcall (intern (concat (symbol-name addon) "-disable")))
 260             (if verbose
 261                 (message "Add-on %S disabled" addon)))
 262         (if verbose
 263             (message "Add-on %S is already enabled" addon))))))
 264
 265 (put 'riece-addon-list-mode 'font-lock-defaults
 266      '(riece-addon-list-font-lock-keywords t))
 267
 268 (defun riece-addon-list-mode ()
 269   "Major mode for displaying addon list.
 270 All normal editing commands are turned off."
 271   (kill-all-local-variables)
 272   (buffer-disable-undo)
 273   (setq major-mode 'riece-addon-list-mode
 274         mode-name "AddOns"
 275         mode-line-buffer-identification
 276         (riece-mode-line-buffer-identification '("Riece: %12b"))
 277         truncate-lines t
 278         buffer-read-only t)
 279   (use-local-map riece-addon-list-mode-map)
 280   (make-local-variable 'font-lock-defaults)
 281   (setq font-lock-defaults '(riece-addon-list-font-lock-keywords t))
 282   ;; In XEmacs, auto-initialization of font-lock is not effective
 283   ;; if buffer-file-name is not set.
 284   (font-lock-set-defaults)
 285   (run-hooks 'riece-addon-list-mode-hook))
 286
 287 (defun riece-command-list-addons ()
 288   (interactive)
 289   (set-buffer (riece-get-buffer-create "*AddOns*" 'riece-addon-list-mode))
 290   (riece-addon-list-mode)
 291   (let ((inhibit-read-only t)
 292         buffer-read-only
 293         (pointer riece-addon-dependencies)
 294         module-description-alist
 295         description enabled point)
 296     (while pointer
 297
 298       (setq description (intern-soft (concat (symbol-name (car (car pointer)))
 299                                              "-description"))
 300             module-description-alist
 301             (cons (cons (car (car pointer))
 302                         (if description
 303                             (symbol-value description)
 304                           "(no description)"))
 305                   module-description-alist)
 306             pointer (cdr pointer)))
 307     (setq pointer riece-addon-modules)
 308     (while pointer
 309       (unless (assq (car (car pointer))
 310                     module-description-alist)
 311         (setq module-description-alist
 312               (cons (car pointer) module-description-alist)))
 313       (setq pointer (cdr pointer)))
 314     (erase-buffer)
 315     (riece-kill-all-overlays)
 316     (setq pointer (sort module-description-alist
 317                         (lambda (entry1 entry2)
 318                           (string-lessp (symbol-name (car entry1))
 319                                         (symbol-name (car entry2))))))
 320     (while pointer
 321       (setq enabled (intern-soft (concat (symbol-name (car (car pointer)))
 322                                          "-enabled")))
 323       (setq point (point))
 324       (insert (format "%c %S: %s\n"
 325                       (if (not (get (car (car pointer))
 326                                     'riece-addon-insinuated))
 327                           ?
 328                         (if (null enabled)
 329                             ?!
 330                           (if (symbol-value enabled)
 331                               ?+
 332                             ?-)))
 333                       (car (car pointer))
 334                       (cdr (car pointer))))
 335       (put-text-property point (point) 'riece-addon (car (car pointer)))
 336       (setq pointer (cdr pointer)))
 337     (insert "
 338 Symbols in the leftmost column:
 339
 340   +     The add-on is enabled.
 341   -     The add-on is disabled.
 342   !     The add-on doesn't support enable/disable operation.
 343         The add-on is not insinuated.
 344 ")
 345     (insert (substitute-command-keys "
 346 Useful keys:
 347
 348   `\\[riece-command-enable-addon]' to enable the current add-on.
 349   `\\[riece-command-disable-addon]' to disable the current add-on.
 350 "))
 351     (goto-char (point-min))
 352     (pop-to-buffer (current-buffer))
 353     (delete-other-windows)))
 354
 355 (defun riece-command-enable-addon (addon)
 356   (interactive
 357    (list
 358     (or (if (eq major-mode 'riece-addon-list-mode)
 359             (get-text-property (point) 'riece-addon))
 360         (intern-soft
 361          (completing-read "Add-on: "
 362                           (mapcar (lambda (dependency)
 363                                     (list (symbol-name (car dependency))))
 364                                   riece-addon-dependencies)
 365                           (lambda (pointer)
 366                             (let ((enabled
 367                                    (intern-soft (concat (car pointer)
 368                                                         "-enabled"))))
 369                               (and enabled
 370                                    (null (symbol-value enabled)))))
 371                           t)))))
 372   (riece-enable-addon addon t)
 373   (when (eq major-mode 'riece-addon-list-mode)
 374     (riece-command-list-addons)
 375     (let ((point (point-min)))
 376       (while (and (not (eq (get-text-property point 'riece-addon) addon))
 377                   (setq point (next-single-property-change point
 378                                                            'riece-addon))))
 379       (if point
 380           (goto-char point)))))
 381
 382 (defun riece-command-disable-addon (addon)
 383   (interactive
 384    (list
 385     (or (if (eq major-mode 'riece-addon-list-mode)
 386             (get-text-property (point) 'riece-addon))
 387         (intern-soft
 388          (completing-read "Add-on: "
 389                           (mapcar (lambda (dependency)
 390                                     (list (symbol-name (car dependency))))
 391                                   riece-addon-dependencies)
 392                           (lambda (pointer)
 393                             (let ((enabled
 394                                    (intern-soft (concat (car pointer)
 395                                                         "-enabled"))))
 396                               (and enabled
 397                                    (symbol-value enabled))))
 398                           t)))))
 399   (riece-disable-addon addon t)
 400   (when (eq major-mode 'riece-addon-list-mode)
 401     (riece-command-list-addons)
 402     (let ((point (point-min)))
 403       (while (and (not (eq (get-text-property point 'riece-addon) addon))
 404                   (setq point (next-single-property-change point
 405                                                            'riece-addon))))
 406       (if point
 407           (goto-char point)))))
 408
 409 (defun riece-command-insinuate-addon (addon)
 410   (interactive
 411    (list
 412     (or (if (eq major-mode 'riece-addon-list-mode)
 413             (get-text-property (point) 'riece-addon))
 414         (intern-soft
 415          (completing-read "Add-on: "
 416                           (mapcar (lambda (dependency)
 417                                     (list (symbol-name (car dependency))))
 418                                   riece-addon-modules)
 419                           (lambda (pointer)
 420                             (get (car pointer) 'riece-addon-insinuated))
 421                           t)))))
 422   (riece-insinuate-addon addon t)
 423   (when (eq major-mode 'riece-addon-list-mode)
 424     (riece-command-list-addons)
 425     (let ((point (point-min)))
 426       (while (and (not (eq (get-text-property point 'riece-addon) addon))
 427                   (setq point (next-single-property-change point
 428                                                            'riece-addon))))
 429       (if point
 430           (goto-char point)))))
 431
 432 (defun riece-command-uninstall-addon (addon)
 433   (interactive
 434    (list
 435     (or (if (eq major-mode 'riece-addon-list-mode)
 436             (get-text-property (point) 'riece-addon))
 437         (intern-soft
 438          (completing-read "Add-on: "
 439                           (mapcar (lambda (dependency)
 440                                     (list (symbol-name (car dependency))))
 441                                   riece-addon-dependencies)
 442                           nil t)))))
 443   (riece-uninstall-addon addon t)
 444   (when (eq major-mode 'riece-addon-list-mode)
 445     (riece-command-list-addons)
 446     (let ((point (point-min)))
 447       (while (and (not (eq (get-text-property point 'riece-addon) addon))
 448                   (setq point (next-single-property-change point
 449                                                            'riece-addon))))
 450       (if point
 451           (goto-char point)))))
 452
 453 (provide 'riece-addon)
 454
 455 ;;; riece-addon.el ends here