cgit.sxemacs.org Git - packages/blob - xemacs-packages/riece/lisp/riece-filter.el

   1 ;;; riece-filter.el --- process filter and sentinel
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-handle)
  28 (require 'riece-misc)
  29 (require 'riece-server)                 ;riece-close-server
  30 (require 'riece-identity)
  31 (require 'riece-debug)
  32
  33 (defun riece-handle-numeric-reply (prefix number name string)
  34   (let ((base-number (* (/ number 100) 100))
  35         function)
  36     (setq function (intern-soft (format "riece-handle-%03d-message" number)))
  37     (unless (and function
  38                  (symbol-function function))
  39       (setq function
  40             (intern-soft
  41              (format "riece-handle-default-%03d-message" base-number))))
  42     (if (and function
  43              (symbol-function function))
  44         (riece-funcall-ignore-errors (symbol-name function)
  45                                      function prefix number name
  46                                      (riece-decode-coding-string string)))))
  47
  48 (defun riece-handle-message (prefix message string)
  49   (if (and prefix
  50            (string-match "![^\x00\x0d\x0a @]+@" prefix))
  51       (riece-user-set-user-at-host
  52        (riece-get-user (substring prefix 0 (match-beginning 0)))
  53        (riece-parse-user-at-host (substring prefix (1+ (match-beginning 0))))))
  54   (setq message (downcase message)
  55         string (riece-decode-coding-string string))
  56   (let ((function (intern-soft (concat "riece-handle-" message "-message")))
  57         (hook (intern (concat "riece-" message "-hook")))
  58         (after-hook (intern (concat "riece-after-" message "-hook"))))
  59     (unless (riece-funcall-ignore-errors (symbol-name hook)
  60                                          #'run-hook-with-args-until-success
  61                                          hook prefix string)
  62       (if function
  63           (riece-funcall-ignore-errors (symbol-name function)
  64                                        function prefix string))
  65       (riece-funcall-ignore-errors (symbol-name after-hook)
  66                                    #'run-hook-with-args-until-success
  67                                    after-hook prefix string))))
  68
  69 (defsubst riece-chomp-string (string)
  70   (if (string-match "\r\\'" string)
  71       (substring string 0 (match-beginning 0))
  72     string))
  73
  74 (defun riece-filter (process input)
  75   (save-excursion
  76     (set-buffer (process-buffer process))
  77     (goto-char (point-max))
  78     (insert input)
  79     (unless riece-filter-running
  80       (unwind-protect
  81           (progn
  82             (setq riece-filter-running t)
  83             (goto-char riece-read-point)
  84             (beginning-of-line)
  85             (while (looking-at ".*\n")  ;the input line is finished
  86               (save-excursion
  87                 (if (looking-at
  88                      ":\\([^ ]+\\) +\\([0-5][0-9][0-9]\\) +\\([^ ]+\\)\
  89  +\\(.*\\)")
  90                     (riece-handle-numeric-reply
  91                      (match-string 1)           ;prefix
  92                      (string-to-number (match-string 2)) ;number
  93                      (match-string 3)           ;name
  94                      (riece-chomp-string (match-string 4))) ;reply string
  95                   (if (looking-at "\\(:\\([^ ]+\\) +\\)?\\([^ ]+\\) +\\(.*\\)")
  96                       (riece-handle-message
  97                        (match-string 2) ;optional prefix
  98                        (match-string 3) ;command
  99                        (riece-chomp-string (match-string 4))
 100                                         ;params & trailing
 101                        )
 102                     (if riece-debug
 103                         (message "Weird message from server: %s"
 104                                  (buffer-substring (point) (progn
 105                                                              (end-of-line)
 106                                                              (point))))))))
 107               (forward-line))
 108             (unless riece-debug
 109               (delete-region (point-min) (point)))
 110             (setq riece-read-point (point)))
 111         (setq riece-filter-running nil)))))
 112
 113 (eval-when-compile
 114   (autoload 'riece-exit "riece"))
 115 (defun riece-sentinel (process status)
 116   (if riece-reconnect-with-password
 117       (let ((server-name
 118              (with-current-buffer (process-buffer process)
 119                riece-server-name)))
 120         (riece-close-server-process process)
 121         (riece-open-server
 122          (if (equal server-name "")
 123              riece-server
 124            (riece-server-name-to-server server-name))
 125          server-name))
 126     (let ((server-name (with-current-buffer (process-buffer process)
 127                          riece-server-name)))
 128       (if riece-debug
 129           (if (equal server-name "")
 130               (riece-debug (format "Connection closed: %s"
 131                                    (substring status 0 (1- (length status)))))
 132             (riece-debug (format "Connection to \"%s\" closed: %s"
 133                                  server-name
 134                                  (substring status 0 (1- (length status))))))
 135         (if (equal server-name "")
 136             (message "Connection closed")
 137           (message "Connection to \"%s\" closed" server-name)))
 138       (let ((channels riece-current-channels))
 139         (while channels
 140           (if (and (car channels)
 141                    (equal (riece-identity-server (car channels))
 142                           server-name))
 143               (riece-part-channel (car channels)))
 144           (setq channels (cdr channels))))
 145       (riece-redisplay-buffers)
 146       (riece-close-server-process process)
 147       ;; If no server process is available, exit.
 148       (unless riece-server-process-alist
 149         (riece-exit)))))
 150
 151 (provide 'riece-filter)
 152
 153 ;;; riece-filter.el ends here