Remove non-free old and crusty clearcase pkg
[packages] / xemacs-packages / gnus / lisp / hashcash.el
1 ;;; hashcash.el --- Add hashcash payments to email
2
3 ;; Copyright (C) 2002, 2003, 2005 Free Software Foundation
4 ;; Copyright (C) 1997--2002 Paul E. Foley
5
6 ;; Maintainer: Paul Foley <mycroft@actrix.gen.nz>
7 ;; Keywords: mail, hashcash
8
9 ;; Released under the GNU General Public License
10 ;;   (http://www.gnu.org/licenses/gpl.html)
11
12 ;;; Commentary:
13
14 ;; The hashcash binary is at http://www.cypherspace.org/hashcash/
15 ;;
16 ;; Call mail-add-payment to add a hashcash payment to a mail message
17 ;; in the current buffer.
18 ;;
19 ;; To automatically add payments to all outgoing mail:
20 ;;    (add-hook 'message-send-hook 'mail-add-payment)
21
22 ;;; Code:
23
24 (eval-and-compile
25  (autoload 'executable-find "executable"))
26
27 (defgroup hashcash nil
28   "Hashcash configuration."
29   :group 'mail)
30
31 (defcustom hashcash-default-payment 0
32   "*The default number of bits to pay to unknown users.
33 If this is zero, no payment header will be generated.
34 See `hashcash-payment-alist'."
35   :type 'integer
36   :group 'hashcash)
37
38 (defcustom hashcash-payment-alist '()
39   "*An association list mapping email addresses to payment amounts.
40 Elements may consist of (ADDR AMOUNT) or (ADDR STRING AMOUNT), where
41 ADDR is the email address of the intended recipient and AMOUNT is
42 the value of hashcash payment to be made to that user.  STRING, if
43 present, is the string to be hashed; if not present ADDR will be used."
44   :group 'hashcash)
45
46 (defcustom hashcash-default-accept-payment 10
47   "*The default minimum number of bits to accept on incoming payments."
48   :type 'integer
49   :group 'hashcash)
50
51 (defcustom hashcash-accept-resources `((,user-mail-address nil))
52   "*An association list mapping hashcash resources to payment amounts.
53 Resources named here are to be accepted in incoming payments.  If the
54 corresponding AMOUNT is NIL, the value of `hashcash-default-accept-payment'
55 is used instead."
56   :group 'hashcash)
57
58 (defcustom hashcash-path (executable-find "hashcash")
59   "*The path to the hashcash binary."
60   :group 'hashcash)
61
62 (defcustom hashcash-double-spend-database "hashcash.db"
63   "*The path to the double-spending database."
64   :group 'hashcash)
65
66 (defcustom hashcash-in-news nil
67   "*Specifies whether or not hashcash payments should be made to newsgroups."
68   :type 'boolean
69   :group 'hashcash)
70
71 (require 'mail-utils)
72
73 (eval-and-compile
74  (if (fboundp 'point-at-bol)
75      (defalias 'hashcash-point-at-bol 'point-at-bol)
76    (defalias 'hashcash-point-at-bol 'line-beginning-position))
77
78  (if (fboundp 'point-at-eol)
79      (defalias 'hashcash-point-at-eol 'point-at-eol)
80    (defalias 'hashcash-point-at-eol 'line-end-position)))
81
82 (defun hashcash-strip-quoted-names (addr)
83   (setq addr (mail-strip-quoted-names addr))
84   (if (and addr (string-match "\\`\\([^+@]+\\)\\+[^@]*\\(@.+\\)" addr))
85       (concat (match-string 1 addr) (match-string 2 addr))
86     addr))
87
88 (defun hashcash-payment-required (addr)
89   "Return the hashcash payment value required for the given address."
90   (let ((val (assoc addr hashcash-payment-alist)))
91     (or (nth 2 val) (nth 1 val) hashcash-default-payment)))
92
93 (defun hashcash-payment-to (addr)
94   "Return the string with which hashcash payments should collide."
95   (let ((val (assoc addr hashcash-payment-alist)))
96     (or (nth 1 val) (nth 0 val) addr)))
97
98 (defun hashcash-generate-payment (str val)
99   "Generate a hashcash payment by finding a VAL-bit collison on STR."
100   (if (> val 0)
101       (save-excursion
102         (set-buffer (get-buffer-create " *hashcash*"))
103         (erase-buffer)
104         (call-process hashcash-path nil t nil
105                       "-m" "-q" "-b" (number-to-string val) str)
106         (goto-char (point-min))
107         (buffer-substring (hashcash-point-at-bol) (hashcash-point-at-eol)))
108     nil))
109
110 (defun hashcash-check-payment (token str val)
111   "Check the validity of a hashcash payment."
112   (zerop (call-process hashcash-path nil nil nil "-c"
113                        "-d" "-f" hashcash-double-spend-database
114                        "-b" (number-to-string val)
115                        "-r" str
116                        token)))
117
118 (defun hashcash-version (token)
119   "Find the format version of a hashcash token."
120   ;; Version 1.2 looks like n:yymmdd:rrrrr:xxxxxxxxxxxxxxxx
121   ;;   This carries its own version number embedded in the token,
122   ;;   so no further format number changes should be necessary
123   ;;   in the X-Payment header.
124   ;;
125   ;; Version 1.1 looks like yymmdd:rrrrr:xxxxxxxxxxxxxxxx
126   ;;   You need to upgrade your hashcash binary.
127   ;;
128   ;; Version 1.0 looked like nnnnnrrrrrxxxxxxxxxxxxxxxx
129   ;;   This is no longer supported.
130   (cond ((equal (aref token 1) ?:) 1.2)
131         ((equal (aref token 6) ?:) 1.1)
132         (t (error "Unknown hashcash format version"))))
133
134 ;;;###autoload
135 (defun hashcash-insert-payment (arg)
136   "Insert X-Payment and X-Hashcash headers with a payment for ARG"
137   (interactive "sPay to: ")
138   (let ((pay (hashcash-generate-payment (hashcash-payment-to arg)
139                                         (hashcash-payment-required arg))))
140     (when pay
141 ;      (insert-before-markers "X-Payment: hashcash "
142 ;                            (number-to-string (hashcash-version pay)) " "
143 ;                            pay "\n")
144       (insert-before-markers "X-Hashcash: " pay "\n"))))
145
146 ;;;###autoload
147 (defun hashcash-verify-payment (token &optional resource amount)
148   "Verify a hashcash payment"
149   (let ((key (if (< (hashcash-version token) 1.2)
150                  (nth 1 (split-string token ":"))
151                  (nth 2 (split-string token ":")))))
152     (cond ((null resource)
153            (let ((elt (assoc key hashcash-accept-resources)))
154              (and elt (hashcash-check-payment token (car elt)
155                         (or (cadr elt) hashcash-default-accept-payment)))))
156           ((equal token key)
157            (hashcash-check-payment token resource
158                                 (or amount hashcash-default-accept-payment)))
159           (t nil))))
160
161 ;;;###autoload
162 (defun mail-add-payment (&optional arg)
163   "Add X-Payment: and X-Hashcash: headers with a hashcash payment
164 for each recipient address.  Prefix arg sets default payment temporarily."
165   (interactive "P")
166   (let ((hashcash-default-payment (if arg (prefix-numeric-value arg)
167                                     hashcash-default-payment))
168         (addrlist nil))
169     (save-excursion
170       (save-restriction
171         (goto-char (point-min))
172         (search-forward mail-header-separator)
173         (beginning-of-line)
174         (narrow-to-region (point-min) (point))
175         (let ((to (hashcash-strip-quoted-names (mail-fetch-field "To" nil t)))
176               (cc (hashcash-strip-quoted-names (mail-fetch-field "Cc" nil t)))
177               (ng (hashcash-strip-quoted-names (mail-fetch-field "Newsgroups"
178                                                                  nil t))))
179           (when to
180             (setq addrlist (split-string to ",[ \t\n]*")))
181           (when cc
182             (setq addrlist (nconc addrlist (split-string cc ",[ \t\n]*"))))
183           (when (and hashcash-in-news ng)
184             (setq addrlist (nconc addrlist (split-string ng ",[ \t\n]*")))))
185         (when addrlist
186           (mapcar #'hashcash-insert-payment addrlist))))) ; mapc
187   t)
188
189 ;;;###autoload
190 (defun mail-check-payment (&optional arg)
191   "Look for a valid X-Payment: or X-Hashcash: header.
192 Prefix arg sets default accept amount temporarily."
193   (interactive "P")
194   (let ((hashcash-default-accept-payment (if arg (prefix-numeric-value arg)
195                                            hashcash-default-accept-payment))
196         (version (hashcash-version (hashcash-generate-payment "x" 1))))
197     (save-excursion
198       (goto-char (point-min))
199       (search-forward "\n\n")
200       (beginning-of-line)
201       (let ((end (point))
202             (ok nil))
203         (goto-char (point-min))
204         (while (and (not ok) (search-forward "X-Payment: hashcash " end t))
205           (let ((value (split-string
206                           (buffer-substring (point) (hashcash-point-at-eol))
207                           " ")))
208             (when (equal (car value) (number-to-string version))
209               (setq ok (hashcash-verify-payment (cadr value))))))
210         (goto-char (point-min))
211         (while (and (not ok) (search-forward "X-Hashcash: " end t))
212           (setq ok (hashcash-verify-payment
213                     (buffer-substring (point) (hashcash-point-at-eol)))))
214         (when ok
215           (message "Payment valid"))
216         ok))))
217
218 (provide 'hashcash)
219
220 ;;; arch-tag: 0e7fe983-a124-4392-9788-0dbcbd2c4d62