Remove non-free old and crusty clearcase pkg
[packages] / xemacs-packages / gnus / lisp / gnus-cache.el
1 ;;; gnus-cache.el --- cache interface for Gnus
2
3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
5
6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
7 ;; Keywords: news
8
9 ;; This file is part of GNU Emacs.
10
11 ;; GNU Emacs is free software; you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation; either version 3, or (at your option)
14 ;; any later version.
15
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
19 ;; GNU General Public License for more details.
20
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
24 ;; Boston, MA 02110-1301, USA.
25
26 ;;; Commentary:
27
28 ;;; Code:
29
30 (eval-when-compile (require 'cl))
31
32 (require 'gnus)
33 (require 'gnus-int)
34 (require 'gnus-range)
35 (require 'gnus-start)
36 (eval-when-compile
37   (if (not (fboundp 'gnus-agent-load-alist))
38       (defun gnus-agent-load-alist (group)))
39   (require 'gnus-sum))
40
41 (defcustom gnus-cache-active-file
42   (expand-file-name "active" gnus-cache-directory)
43   "*The cache active file."
44   :group 'gnus-cache
45   :type 'file)
46
47 (defcustom gnus-cache-enter-articles '(ticked dormant)
48   "Classes of articles to enter into the cache."
49   :group 'gnus-cache
50   :type '(set (const ticked) (const dormant) (const unread) (const read)))
51
52 (defcustom gnus-cache-remove-articles '(read)
53   "Classes of articles to remove from the cache."
54   :group 'gnus-cache
55   :type '(set (const ticked) (const dormant) (const unread) (const read)))
56
57 (defcustom gnus-cacheable-groups nil
58   "*Groups that match this regexp will be cached.
59
60 If you only want to cache your nntp groups, you could set this
61 variable to \"^nntp\".
62
63 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
64 it's not cached."
65   :group 'gnus-cache
66   :type '(choice (const :tag "off" nil)
67                  regexp))
68
69 (defcustom gnus-uncacheable-groups nil
70   "*Groups that match this regexp will not be cached.
71
72 If you want to avoid caching your nnml groups, you could set this
73 variable to \"^nnml\".
74
75 If a group matches both gnus-cacheable-groups and gnus-uncacheable-groups
76 it's not cached."
77   :group 'gnus-cache
78   :type '(choice (const :tag "off" nil)
79                  regexp))
80
81 (defvar gnus-cache-overview-coding-system 'raw-text
82   "Coding system used on Gnus cache files.")
83
84 (defvar gnus-cache-coding-system 'raw-text
85   "Coding system used on Gnus cache files.")
86
87 \f
88
89 ;;; Internal variables.
90
91 (defvar gnus-cache-removable-articles nil)
92 (defvar gnus-cache-buffer nil)
93 (defvar gnus-cache-active-hashtb nil)
94 (defvar gnus-cache-active-altered nil)
95
96 (eval-and-compile
97   (autoload 'nnml-generate-nov-databases-1 "nnml")
98   (autoload 'nnvirtual-find-group-art "nnvirtual"))
99
100 \f
101
102 ;;; Functions called from Gnus.
103
104 (defun gnus-cache-open ()
105   "Initialize the cache."
106   (when (or (file-exists-p gnus-cache-directory)
107             (and gnus-use-cache
108                  (not (eq gnus-use-cache 'passive))))
109     (gnus-cache-read-active)))
110
111 ;; Complexities of byte-compiling make this kludge necessary.  Eeek.
112 (ignore-errors
113   (gnus-add-shutdown 'gnus-cache-close 'gnus))
114
115 (defun gnus-cache-close ()
116   "Shut down the cache."
117   (gnus-cache-write-active)
118   (gnus-cache-save-buffers)
119   (setq gnus-cache-active-hashtb nil))
120
121 (defun gnus-cache-save-buffers ()
122   ;; save the overview buffer if it exists and has been modified
123   ;; delete empty cache subdirectories
124   (when gnus-cache-buffer
125     (let ((buffer (cdr gnus-cache-buffer))
126           (overview-file (gnus-cache-file-name
127                           (car gnus-cache-buffer) ".overview")))
128       ;; write the overview only if it was modified
129       (when (and (buffer-live-p buffer) (buffer-modified-p buffer))
130         (with-current-buffer buffer
131           (if (> (buffer-size) 0)
132               ;; Non-empty overview, write it to a file.
133               (let ((coding-system-for-write
134                      gnus-cache-overview-coding-system))
135                 (gnus-write-buffer overview-file))
136             ;; Empty overview file, remove it
137             (when (file-exists-p overview-file)
138               (delete-file overview-file))
139             ;; If possible, remove group's cache subdirectory.
140             (condition-case nil
141                 ;; FIXME: we can detect the error type and warn the user
142                 ;; of any inconsistencies (articles w/o nov entries?).
143                 ;; for now, just be conservative...delete only if safe -- sj
144                 (delete-directory (file-name-directory overview-file))
145               (error nil)))))
146       ;; Kill the buffer -- it's either unmodified or saved.
147       (gnus-kill-buffer buffer)
148       (setq gnus-cache-buffer nil))))
149
150 (defun gnus-cache-possibly-enter-article
151   (group article ticked dormant unread &optional force)
152   (when (and (or force (not (eq gnus-use-cache 'passive)))
153              (numberp article)
154              (> article 0))             ; This might be a dummy article.
155     (let ((number article) file headers)
156       ;; If this is a virtual group, we find the real group.
157       (when (gnus-virtual-group-p group)
158         (let ((result (nnvirtual-find-group-art
159                        (gnus-group-real-name group) article)))
160           (setq group (car result)
161                 number (cdr result))))
162       (when (and number
163                  (> number 0)           ; Reffed article.
164                  (or force
165                      (and (gnus-cache-fully-p group)
166                           (gnus-cache-member-of-class
167                            gnus-cache-enter-articles ticked dormant unread)))
168                  (not (file-exists-p (setq file (gnus-cache-file-name
169                                                  group number)))))
170         ;; Possibly create the cache directory.
171         (gnus-make-directory (file-name-directory file))
172         ;; Save the article in the cache.
173         (if (file-exists-p file)
174             t                           ; The article already is saved.
175           (save-excursion
176             (set-buffer nntp-server-buffer)
177             (require 'gnus-art)
178             (let ((gnus-use-cache nil)
179                   (gnus-article-decode-hook nil))
180               (gnus-request-article-this-buffer number group))
181             (when (> (buffer-size) 0)
182               (let ((coding-system-for-write gnus-cache-coding-system))
183                 (gnus-write-buffer file))
184               (nnheader-remove-body)
185               (setq headers (nnheader-parse-naked-head))
186               (mail-header-set-number headers number)
187               (gnus-cache-change-buffer group)
188               (set-buffer (cdr gnus-cache-buffer))
189               (goto-char (point-max))
190               (forward-line -1)
191               (while (condition-case ()
192                          (when (not (bobp))
193                            (> (read (current-buffer)) number))
194                        (error
195                         ;; The line was malformed, so we just remove it!!
196                         (gnus-delete-line)
197                         t))
198                 (forward-line -1))
199               (if (bobp)
200                   (if (not (eobp))
201                       (progn
202                         (beginning-of-line)
203                         (when (< (read (current-buffer)) number)
204                           (forward-line 1)))
205                     (beginning-of-line))
206                 (forward-line 1))
207               (beginning-of-line)
208               (nnheader-insert-nov headers)
209               ;; Update the active info.
210               (set-buffer gnus-summary-buffer)
211               (gnus-cache-possibly-update-active group (cons number number))
212               (setq gnus-newsgroup-cached
213                     (gnus-add-to-sorted-list gnus-newsgroup-cached article))
214               (gnus-summary-update-secondary-mark article))
215             t))))))
216
217 (defun gnus-cache-enter-remove-article (article)
218   "Mark ARTICLE for later possible removal."
219   (when article
220     (push article gnus-cache-removable-articles)))
221
222 (defun gnus-cache-possibly-remove-articles ()
223   "Possibly remove some of the removable articles."
224   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
225       (gnus-cache-possibly-remove-articles-1)
226     (let ((arts gnus-cache-removable-articles)
227           ga)
228       (while arts
229         (when (setq ga (nnvirtual-find-group-art
230                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
231           (let ((gnus-cache-removable-articles (list (cdr ga)))
232                 (gnus-newsgroup-name (car ga)))
233             (gnus-cache-possibly-remove-articles-1)))))
234     (setq gnus-cache-removable-articles nil)))
235
236 (defun gnus-cache-possibly-remove-articles-1 ()
237   "Possibly remove some of the removable articles."
238   (when (gnus-cache-fully-p gnus-newsgroup-name)
239     (let ((articles gnus-cache-removable-articles)
240           (cache-articles gnus-newsgroup-cached)
241           article)
242       (gnus-cache-change-buffer gnus-newsgroup-name)
243       (while articles
244         (when (memq (setq article (pop articles)) cache-articles)
245           ;; The article was in the cache, so we see whether we are
246           ;; supposed to remove it from the cache.
247           (gnus-cache-possibly-remove-article
248            article (memq article gnus-newsgroup-marked)
249            (memq article gnus-newsgroup-dormant)
250            (or (memq article gnus-newsgroup-unreads)
251                (memq article gnus-newsgroup-unselected))))))
252     ;; The overview file might have been modified, save it
253     ;; safe because we're only called at group exit anyway.
254     (gnus-cache-save-buffers)))
255
256 (defun gnus-cache-request-article (article group)
257   "Retrieve ARTICLE in GROUP from the cache."
258   (let ((file (gnus-cache-file-name group article))
259         (buffer-read-only nil))
260     (when (file-exists-p file)
261       (erase-buffer)
262       (gnus-kill-all-overlays)
263       (let ((coding-system-for-read gnus-cache-coding-system))
264         (insert-file-contents file))
265       t)))
266
267 (defun gnus-cache-possibly-alter-active (group active)
268   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
269   (when gnus-cache-active-hashtb
270     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
271       (when cache-active
272         (when (< (car cache-active) (car active))
273           (setcar active (car cache-active)))
274         (when (> (cdr cache-active) (cdr active))
275           (setcdr active (cdr cache-active)))))))
276
277 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
278   "Retrieve the headers for ARTICLES in GROUP."
279   (let ((cached
280          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
281     (if (not cached)
282         ;; No cached articles here, so we just retrieve them
283         ;; the normal way.
284         (let ((gnus-use-cache nil))
285           (gnus-retrieve-headers articles group fetch-old))
286       (let ((uncached-articles (gnus-sorted-difference articles cached))
287             (cache-file (gnus-cache-file-name group ".overview"))
288             type)
289         ;; We first retrieve all the headers that we don't have in
290         ;; the cache.
291         (let ((gnus-use-cache nil))
292           (when uncached-articles
293             (setq type (and articles
294                             (gnus-retrieve-headers
295                              uncached-articles group fetch-old)))))
296         (gnus-cache-save-buffers)
297         ;; Then we insert the cached headers.
298         (save-excursion
299           (cond
300            ((not (file-exists-p cache-file))
301             ;; There are no cached headers.
302             type)
303            ((null type)
304             ;; There were no uncached headers (or retrieval was
305             ;; unsuccessful), so we use the cached headers exclusively.
306             (set-buffer nntp-server-buffer)
307             (erase-buffer)
308             (let ((coding-system-for-read
309                    gnus-cache-overview-coding-system))
310               (insert-file-contents cache-file))
311             'nov)
312            ((eq type 'nov)
313             ;; We have both cached and uncached NOV headers, so we
314             ;; braid them.
315             (gnus-cache-braid-nov group cached)
316             type)
317            (t
318             ;; We braid HEADs.
319             (gnus-cache-braid-heads group (gnus-sorted-intersection
320                                            cached articles))
321             type)))))))
322
323 (defun gnus-cache-enter-article (&optional n)
324   "Enter the next N articles into the cache.
325 If not given a prefix, use the process marked articles instead.
326 Returns the list of articles entered."
327   (interactive "P")
328   (let ((articles (gnus-summary-work-articles n))
329         article out)
330     (while (setq article (pop articles))
331       (gnus-summary-remove-process-mark article)
332       (if (natnump article)
333           (when (gnus-cache-possibly-enter-article
334                  gnus-newsgroup-name article
335                  nil nil nil t)
336             (setq gnus-newsgroup-undownloaded (delq article gnus-newsgroup-undownloaded))
337             (push article out))
338         (gnus-message 2 "Can't cache article %d" article))
339       (gnus-summary-update-download-mark article)
340       (gnus-summary-update-secondary-mark article))
341     (gnus-summary-next-subject 1)
342     (gnus-summary-position-point)
343     (nreverse out)))
344
345 (defun gnus-cache-remove-article (&optional n)
346   "Remove the next N articles from the cache.
347 If not given a prefix, use the process marked articles instead.
348 Returns the list of articles removed."
349   (interactive "P")
350   (gnus-cache-change-buffer gnus-newsgroup-name)
351   (let ((articles (gnus-summary-work-articles n))
352         article out)
353     (while articles
354       (setq article (pop articles))
355       (gnus-summary-remove-process-mark article)
356       (when (gnus-cache-possibly-remove-article article nil nil nil t)
357         (when gnus-newsgroup-agentized
358           (let ((alist (gnus-agent-load-alist gnus-newsgroup-name)))
359             (unless (cdr (assoc article alist))
360               (setq gnus-newsgroup-undownloaded
361                     (gnus-add-to-sorted-list
362                      gnus-newsgroup-undownloaded article)))))
363         (push article out))
364       (gnus-summary-update-download-mark article)
365       (gnus-summary-update-secondary-mark article))
366     (gnus-summary-next-subject 1)
367     (gnus-summary-position-point)
368     (nreverse out)))
369
370 (defun gnus-cached-article-p (article)
371   "Say whether ARTICLE is cached in the current group."
372   (memq article gnus-newsgroup-cached))
373
374 (defun gnus-summary-insert-cached-articles ()
375   "Insert all the articles cached for this group into the current buffer."
376   (interactive)
377   (let ((gnus-verbose (max 6 gnus-verbose)))
378     (if (not gnus-newsgroup-cached)
379         (gnus-message 3 "No cached articles for this group")
380       (gnus-summary-goto-subjects gnus-newsgroup-cached))))
381
382 (defun gnus-summary-limit-include-cached ()
383   "Limit the summary buffer to articles that are cached."
384   (interactive)
385   (let ((gnus-verbose (max 6 gnus-verbose)))
386     (if gnus-newsgroup-cached
387         (progn
388           (gnus-summary-limit gnus-newsgroup-cached)
389           (gnus-summary-position-point))
390       (gnus-message 3 "No cached articles for this group"))))
391
392 ;;; Internal functions.
393
394 (defun gnus-cache-change-buffer (group)
395   (and gnus-cache-buffer
396        ;; See if the current group's overview cache has been loaded.
397        (or (string= group (car gnus-cache-buffer))
398            ;; Another overview cache is current, save it.
399            (gnus-cache-save-buffers)))
400   ;; if gnus-cache buffer is nil, create it
401   (unless gnus-cache-buffer
402     ;; Create cache buffer
403     (save-excursion
404       (setq gnus-cache-buffer
405             (cons group
406                   (set-buffer (gnus-get-buffer-create
407                                " *gnus-cache-overview*"))))
408       ;; Insert the contents of this group's cache overview.
409       (erase-buffer)
410       (let ((file (gnus-cache-file-name group ".overview")))
411         (when (file-exists-p file)
412           (nnheader-insert-file-contents file)))
413       ;; We have a fresh (empty/just loaded) buffer,
414       ;; mark it as unmodified to save a redundant write later.
415       (set-buffer-modified-p nil))))
416
417 ;; Return whether an article is a member of a class.
418 (defun gnus-cache-member-of-class (class ticked dormant unread)
419   (or (and ticked (memq 'ticked class))
420       (and dormant (memq 'dormant class))
421       (and unread (memq 'unread class))
422       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
423
424 (defun gnus-cache-file-name (group article)
425   (setq group (gnus-group-decoded-name group))
426   (expand-file-name
427    (if (stringp article) article (int-to-string article))
428    (file-name-as-directory
429     (expand-file-name
430      (nnheader-translate-file-chars
431       (if (gnus-use-long-file-name 'not-cache)
432           group
433         (let ((group (nnheader-replace-duplicate-chars-in-string
434                       (nnheader-replace-chars-in-string group ?/ ?_)
435                       ?. ?_)))
436           ;; Translate the first colon into a slash.
437           (when (string-match ":" group)
438                   (setq group (concat (substring group 0 (match-beginning 0))
439                                       "/" (substring group (match-end 0)))))
440           (nnheader-replace-chars-in-string group ?. ?/)))
441       t)
442      gnus-cache-directory))))
443
444 (defun gnus-cache-update-article (group article)
445   "If ARTICLE is in the cache, remove it and re-enter it."
446   (gnus-cache-change-buffer group)
447   (when (gnus-cache-possibly-remove-article article nil nil nil t)
448     (let ((gnus-use-cache nil))
449       (gnus-cache-possibly-enter-article
450        gnus-newsgroup-name article
451        nil nil nil t))))
452
453 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
454                                                    &optional force)
455   "Possibly remove ARTICLE from the cache."
456   (let ((group gnus-newsgroup-name)
457         (number article)
458         file)
459     ;; If this is a virtual group, we find the real group.
460     (when (gnus-virtual-group-p group)
461       (let ((result (nnvirtual-find-group-art
462                      (gnus-group-real-name group) article)))
463         (setq group (car result)
464               number (cdr result))))
465     (setq file (gnus-cache-file-name group number))
466     (when (and (file-exists-p file)
467                (or force
468                    (gnus-cache-member-of-class
469                     gnus-cache-remove-articles ticked dormant unread)))
470       (save-excursion
471         (delete-file file)
472         (set-buffer (cdr gnus-cache-buffer))
473         (goto-char (point-min))
474         (when (or (looking-at (concat (int-to-string number) "\t"))
475                   (search-forward (concat "\n" (int-to-string number) "\t")
476                                   (point-max) t))
477           (gnus-delete-line)))
478       (unless (setq gnus-newsgroup-cached
479                     (delq article gnus-newsgroup-cached))
480         (gnus-sethash gnus-newsgroup-name nil gnus-cache-active-hashtb)
481         (setq gnus-cache-active-altered t))
482       (gnus-summary-update-secondary-mark article)
483       t)))
484
485 (defun gnus-cache-articles-in-group (group)
486   "Return a sorted list of cached articles in GROUP."
487   (let ((dir (file-name-directory (gnus-cache-file-name group 1)))
488         articles)
489     (when (file-exists-p dir)
490       (setq articles
491             (sort (mapcar (lambda (name) (string-to-number name))
492                           (directory-files dir nil "^[0-9]+$" t))
493                   '<))
494       ;; Update the cache active file, just to synch more.
495       (if articles
496           (progn
497             (gnus-cache-update-active group (car articles) t)
498             (gnus-cache-update-active group (car (last articles))))
499         (when (gnus-gethash group gnus-cache-active-hashtb)
500           (gnus-sethash group nil gnus-cache-active-hashtb)
501           (setq gnus-cache-active-altered t)))
502       articles)))
503
504 (defun gnus-cache-braid-nov (group cached &optional file)
505   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*"))
506         beg end)
507     (gnus-cache-save-buffers)
508     (save-excursion
509       (set-buffer cache-buf)
510       (erase-buffer)
511       (let ((coding-system-for-read
512              gnus-cache-overview-coding-system))
513         (insert-file-contents
514          (or file (gnus-cache-file-name group ".overview"))))
515       (goto-char (point-min))
516       (insert "\n")
517       (goto-char (point-min)))
518     (set-buffer nntp-server-buffer)
519     (goto-char (point-min))
520     (while cached
521       (while (and (not (eobp))
522                   (< (read (current-buffer)) (car cached)))
523         (forward-line 1))
524       (beginning-of-line)
525       (set-buffer cache-buf)
526       (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
527                           nil t)
528           (setq beg (gnus-point-at-bol)
529                 end (progn (end-of-line) (point)))
530         (setq beg nil))
531       (set-buffer nntp-server-buffer)
532       (when beg
533         (insert-buffer-substring cache-buf beg end)
534         (insert "\n"))
535       (setq cached (cdr cached)))
536     (kill-buffer cache-buf)))
537
538 (defun gnus-cache-braid-heads (group cached)
539   (let ((cache-buf (gnus-get-buffer-create " *gnus-cache*")))
540     (save-excursion
541       (set-buffer cache-buf)
542       (erase-buffer))
543     (set-buffer nntp-server-buffer)
544     (goto-char (point-min))
545     (while cached
546       (while (and (not (eobp))
547                   (looking-at "2.. +\\([0-9]+\\) ")
548                   (< (progn (goto-char (match-beginning 1))
549                             (read (current-buffer)))
550                      (car cached)))
551         (search-forward "\n.\n" nil 'move))
552       (beginning-of-line)
553       (set-buffer cache-buf)
554       (erase-buffer)
555       (let ((coding-system-for-read
556              gnus-cache-coding-system))
557         (insert-file-contents (gnus-cache-file-name group (car cached))))
558       (goto-char (point-min))
559       (insert "220 ")
560       (princ (car cached) (current-buffer))
561       (insert " Article retrieved.\n")
562       (search-forward "\n\n" nil 'move)
563       (delete-region (point) (point-max))
564       (forward-char -1)
565       (insert ".")
566       (set-buffer nntp-server-buffer)
567       (insert-buffer-substring cache-buf)
568       (setq cached (cdr cached)))
569     (kill-buffer cache-buf)))
570
571 ;;;###autoload
572 (defun gnus-jog-cache ()
573   "Go through all groups and put the articles into the cache.
574
575 Usage:
576 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
577   (interactive)
578   (let ((gnus-mark-article-hook nil)
579         (gnus-expert-user t)
580         (nnmail-spool-file nil)
581         (mail-sources nil)
582         (gnus-use-dribble-file nil)
583         (gnus-novice-user nil)
584         (gnus-large-newsgroup nil))
585     ;; Start Gnus.
586     (gnus)
587     ;; Go through all groups...
588     (gnus-group-mark-buffer)
589     (gnus-group-iterate nil
590       (lambda (group)
591         (let (gnus-auto-select-next)
592           (gnus-summary-read-group group nil t)
593           ;; ... and enter the articles into the cache.
594           (when (eq major-mode 'gnus-summary-mode)
595             (gnus-uu-mark-buffer)
596             (gnus-cache-enter-article)
597             (kill-buffer (current-buffer))))))))
598
599 (defun gnus-cache-read-active (&optional force)
600   "Read the cache active file."
601   (gnus-make-directory gnus-cache-directory)
602   (if (or (not (file-exists-p gnus-cache-active-file))
603           (zerop (nth 7 (file-attributes gnus-cache-active-file)))
604           force)
605       ;; There is no active file, so we generate one.
606       (gnus-cache-generate-active)
607     ;; We simply read the active file.
608     (save-excursion
609       (gnus-set-work-buffer)
610       (nnheader-insert-file-contents gnus-cache-active-file)
611       (gnus-active-to-gnus-format
612        nil (setq gnus-cache-active-hashtb
613                  (gnus-make-hashtable
614                   (count-lines (point-min) (point-max)))))
615       (setq gnus-cache-active-altered nil))))
616
617 (defun gnus-cache-write-active (&optional force)
618   "Write the active hashtb to the active file."
619   (when (or force
620             (and gnus-cache-active-hashtb
621                  gnus-cache-active-altered))
622     (gnus-write-active-file gnus-cache-active-file gnus-cache-active-hashtb t)
623     ;; Mark the active hashtb as unaltered.
624     (setq gnus-cache-active-altered nil)))
625
626 (defun gnus-cache-possibly-update-active (group active)
627   "Update active info bounds of GROUP with ACTIVE if necessary.
628 The update is performed if ACTIVE contains a higher or lower bound
629 than the current."
630   (let ((lower t) (higher t))
631     (if gnus-cache-active-hashtb
632         (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
633           (when cache-active
634             (unless (< (car active) (car cache-active))
635               (setq lower nil))
636             (unless (> (cdr active) (cdr cache-active))
637               (setq higher nil))))
638       (gnus-cache-read-active))
639     (when lower
640       (gnus-cache-update-active group (car active) t))
641     (when higher
642       (gnus-cache-update-active group (cdr active)))))
643
644 (defun gnus-cache-update-active (group number &optional low)
645   "Update the upper bound of the active info of GROUP to NUMBER.
646 If LOW, update the lower bound instead."
647   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
648     (if (null active)
649         ;; We just create a new active entry for this group.
650         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
651       ;; Update the lower or upper bound.
652       (if low
653           (setcar active number)
654         (setcdr active number)))
655     ;; Mark the active hashtb as altered.
656     (setq gnus-cache-active-altered t)))
657
658 ;;;###autoload
659 (defun gnus-cache-generate-active (&optional directory)
660   "Generate the cache active file."
661   (interactive)
662   (let* ((top (null directory))
663          (directory (expand-file-name (or directory gnus-cache-directory)))
664          (files (directory-files directory 'full))
665          (group
666           (if top
667               ""
668             (string-match
669              (concat "^" (regexp-quote
670                           (file-name-as-directory
671                            (expand-file-name gnus-cache-directory))))
672              (directory-file-name directory))
673             (nnheader-replace-chars-in-string
674              (substring (directory-file-name directory) (match-end 0))
675              ?/ ?.)))
676          nums alphs)
677     (when top
678       (gnus-message 5 "Generating the cache active file...")
679       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
680     (when (string-match "^\\(nn[^_]+\\)_" group)
681       (setq group (replace-match "\\1:" t nil group)))
682     ;; Separate articles from all other files and directories.
683     (while files
684       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
685           (push (string-to-number (file-name-nondirectory (pop files))) nums)
686         (push (pop files) alphs)))
687     ;; If we have nums, then this is probably a valid group.
688     (when (setq nums (sort nums '<))
689       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
690                     gnus-cache-active-hashtb))
691     ;; Go through all the other files.
692     (while alphs
693       (when (and (file-directory-p (car alphs))
694                  (not (string-match "^\\."
695                                     (file-name-nondirectory (car alphs)))))
696         ;; We descend directories.
697         (gnus-cache-generate-active (car alphs)))
698       (setq alphs (cdr alphs)))
699     ;; Write the new active file.
700     (when top
701       (gnus-cache-write-active t)
702       (gnus-message 5 "Generating the cache active file...done"))))
703
704 ;;;###autoload
705 (defun gnus-cache-generate-nov-databases (dir)
706   "Generate NOV files recursively starting in DIR."
707   (interactive (list gnus-cache-directory))
708   (gnus-cache-close)
709   (let ((nnml-generate-active-function 'identity))
710     (nnml-generate-nov-databases-1 dir))
711   (gnus-cache-open))
712
713 (defun gnus-cache-move-cache (dir)
714   "Move the cache tree to somewhere else."
715   (interactive "FMove the cache tree to: ")
716   (rename-file gnus-cache-directory dir))
717
718 (defun gnus-cache-fully-p (&optional group)
719   "Returns non-nil if the cache should be fully used.
720 If GROUP is non-nil, also cater to `gnus-cacheable-groups' and
721 `gnus-uncacheable-groups'."
722   (and gnus-use-cache
723        (not (eq gnus-use-cache 'passive))
724        (if (null group)
725            t
726          (and (or (not gnus-cacheable-groups)
727                   (string-match gnus-cacheable-groups group))
728               (or (not gnus-uncacheable-groups)
729                   (not (string-match gnus-uncacheable-groups group)))))))
730
731 ;;;###autoload
732 (defun gnus-cache-rename-group (old-group new-group)
733   "Rename OLD-GROUP as NEW-GROUP.
734 Always updates the cache, even when disabled, as the old cache
735 files would corrupt Gnus when the cache was next enabled.  It
736 depends on the caller to determine whether group renaming is
737 supported."
738   (let ((old-dir (gnus-cache-file-name old-group ""))
739         (new-dir (gnus-cache-file-name new-group "")))
740     (gnus-rename-file old-dir new-dir t))
741
742   (let ((no-save gnus-cache-active-hashtb))
743     (unless gnus-cache-active-hashtb
744       (gnus-cache-read-active))
745     (let* ((old-group-hash-value
746             (gnus-gethash old-group gnus-cache-active-hashtb))
747            (new-group-hash-value
748             (gnus-gethash new-group gnus-cache-active-hashtb))
749            (delta
750             (or old-group-hash-value new-group-hash-value)))
751       (gnus-sethash new-group old-group-hash-value gnus-cache-active-hashtb)
752       (gnus-sethash old-group nil gnus-cache-active-hashtb)
753
754       (if no-save
755           (setq gnus-cache-active-altered delta)
756         (gnus-cache-write-active delta)))))
757
758 ;;;###autoload
759 (defun gnus-cache-delete-group (group)
760   "Delete GROUP from the cache.
761 Always updates the cache, even when disabled, as the old cache
762 files would corrupt gnus when the cache was next enabled.
763 Depends upon the caller to determine whether group deletion is
764 supported."
765   (let ((dir (gnus-cache-file-name group "")))
766     (gnus-delete-directory dir))
767
768   (let ((no-save gnus-cache-active-hashtb))
769     (unless gnus-cache-active-hashtb
770       (gnus-cache-read-active))
771     (let* ((group-hash-value (gnus-gethash group gnus-cache-active-hashtb)))
772       (gnus-sethash group nil gnus-cache-active-hashtb)
773
774       (if no-save
775           (setq gnus-cache-active-altered group-hash-value)
776         (gnus-cache-write-active group-hash-value)))))
777
778 (provide 'gnus-cache)
779
780 ;;; arch-tag: 05a79442-8c58-4e65-bd0a-3cbb1b89a33a
781 ;;; gnus-cache.el ends here