cgit.sxemacs.org Git - packages/blob - xemacs-packages/auctex/configure.ac

   1 AC_INIT(auctex,11.84,bug-auctex@gnu.org)
   2
   3 AC_CHECK_PROGS_REQUIRED(MAKECMD, make, [make not found, aborting!])
   4 AC_PROG_MAKE_SET
   5 AC_PROG_INSTALL
   6
   7 AC_DATE_VERSION_FROM_CHANGELOG(AUCTEXDATE,AUCTEXVERSION)
   8 AC_SUBST(AUCTEXDATE)
   9 AC_SUBST(AUCTEXVERSION)
  10
  11 EMACS_PROG_EMACS
  12
  13 if test ${EMACS_FLAVOR} = xemacs
  14 then
  15   EMACS_CHECK_VERSION(21,4)
  16 else
  17   EMACS_CHECK_VERSION(21,1)
  18 fi
  19
  20 EMACS_CHECK_MULE
  21
  22 # The Debian package uses `--disable-build-dir-test'; normal users should
  23 # never need to modify the default behavior.
  24 AC_ARG_ENABLE([build-dir-test],
  25   [  --enable-build-dir-test test for build directory inside `load-path'
  26                           (on by default)],
  27   [if ! [[ "X-${enableval}" = "X-no" ]]
  28      then VALID_BUILD_DIR
  29    fi],
  30   [VALID_BUILD_DIR])
  31
  32 if test ${EMACS_FLAVOR} = "xemacs"  ; then
  33    EMACS_PATH_PACKAGEDIR
  34 else
  35    packagedir=no
  36 fi
  37
  38 if test "X${packagedir}" = Xno
  39 then
  40    EMACS_PATH_LISPDIR
  41    AC_MSG_CHECKING(what file to use for auctex startup)
  42    AC_ARG_WITH(auctexstartfile,
  43    [[  --with-auctexstartfile=FILE    What file to use for auctex startup.]],
  44    [[ auctexstartfile="${withval}" ]],
  45    [ _tmpdir_="${lispdir}"
  46      AC_FULL_EXPAND(_tmpdir_)
  47      if test -d "${_tmpdir_}/site-start.d"
  48      then
  49        auctexstartfile="${lispdir}/site-start.d/auctex.el"
  50      else
  51        auctexstartfile="${lispdir}/auctex.el"
  52      fi])
  53    AC_MSG_RESULT([[${auctexstartfile}]])
  54    packagelispdir="${lispdir}/auctex"
  55    packagedatadir="${packagelispdir}"
  56    texsitedir="${lispdir}"
  57 else
  58    #lispdir is only used for determining relative files.
  59    lispdir="${packagedir}"
  60    packagelispdir="${packagedir}/lisp/auctex"
  61    texsitedir="$packagelispdir"
  62    auctexstartfile="${packagelispdir}"/auto-autoloads.el
  63    packagedatadir="${packagedir}/etc/auctex"
  64    infodir="${packagedir}/info"
  65    INSTALL_INFO=:
  66 fi
  67
  68 AC_SUBST(auctexstartfile)
  69
  70 AC_MSG_CHECKING([where the package lisp files go])
  71 AC_ARG_WITH(packagelispdir,
  72 [[  --with-packagelispdir=DIR
  73                         Directory for the package lisp files.]],
  74   [packagelispdir=["${withval}"]])
  75 AC_LISPIFY_DIR(packagelispdir,[["${texsitedir}/tex-site.el"]])
  76 AC_MSG_RESULT([[${packagelispdir}]])
  77
  78 AC_MSG_CHECKING([where the data files go])
  79 AC_ARG_WITH(packagedatadir,
  80 [[  --with-packagedatadir=DIR         Where the data files go.]],
  81   [packagedatadir=["${withval}"]])
  82 AC_LISPIFY_DIR(packagedatadir,[["${texsitedir}/tex-site.el"]])
  83 AC_MSG_RESULT([[${packagedatadir}]])
  84
  85 AC_LISPIFY_DIR(texsite,[["${auctexstartfile}"]],tex-site.el)
  86
  87 AC_MSG_CHECKING(where the info files go)
  88 AC_MSG_RESULT([[${infodir}]])
  89
  90 AC_SUBST(packagedir)
  91
  92 if test $EMACS_FLAVOR = "xemacs" -a "$infodir" = '${prefix}/info'; then
  93   if test $packagedir != 'no'; then
  94    infodir='${packagedir}/info'
  95   fi
  96 fi
  97
  98 AUCTEX_AUTO_DIR
  99 AC_LISPIFY_DIR(autodir,"${texsitedir}/tex-site.el")
 100
 101 AC_PATH_PROG(TEX, tex, :)
 102 AC_PATH_PROG(PDFTEX, pdftex, :)
 103 AC_PATH_PROG(DVIPS, dvips, :)
 104
 105 AC_ARG_VAR(PERL,[Perl executable.  If set to :, some documentation
 106 cannot be regenerated, but installation of an unmodified tarball will
 107 succeed.])
 108
 109 if test "x$PERL" = x
 110 then
 111    AC_PATH_PROG(PERL, perl, :)
 112 fi
 113
 114 AC_ARG_VAR(MAKEINFO,[Makeinfo executable.  If set to :, some documentation
 115 cannot be regenerated, but installation of an unmodified tarball will
 116 succeed.])
 117
 118 AC_PATH_PROG(MAKEINFO, makeinfo, :)
 119 AC_PATH_PROG(TEXI2HTML, texi2html, :)
 120 AC_PATH_PROG(TEXI2DVI, texi2dvi, :)
 121 AC_PATH_PROG(TEXI2PDF, texi2pdf, :)
 122
 123 AC_ARG_VAR(INSTALL_INFO, [install-info executable.  Set to : to skip making a dir file.  This is the default when installing into an XEmacs package.])
 124
 125 if test "X${INSTALL_INFO}" = X
 126 then
 127   AC_PATH_PROG(INSTALL_INFO, install-info, :, ${PATH} /usr/sbin /sbin)
 128 fi
 129
 130 AC_ARG_ENABLE(preview,
 131   [  --disable-preview       disable inclusion of preview-latex],
 132   [preview_enabled="$enableval"],
 133   [preview_enabled="yes"])
 134 AC_SUBST(preview_enabled)
 135
 136 if test "X${preview_enabled}" = Xyes
 137 then
 138   auctexdir=..; export auctexdir
 139   export PDFTEX
 140   export DVIPS
 141   # Export unquoted variables.
 142   TEX_UNQUOTED="$TEX"
 143   export TEX_UNQUOTED
 144   packagedir_unquoted="$packagedir"
 145   export packagedir_unquoted
 146   packagelispdir_unquoted="$packagelispdir"
 147   export packagelispdir_unquoted
 148   packagedatadir_unquoted="$packagedatadir"
 149   export packagedatadir_unquoted
 150   EMACS_UNQUOTED="$EMACS"
 151   export EMACS_UNQUOTED
 152   AC_CONFIG_SUBDIRS(preview)
 153 fi
 154 AC_SUBST(subdirs)
 155
 156 AC_SHELL_QUOTIFY(prefix)
 157 AC_SHELL_QUOTIFY(localstatedir)
 158 AC_SHELL_QUOTIFY(packagedir)
 159 AC_SHELL_QUOTIFY(packagelispdir)
 160 AC_SHELL_QUOTIFY(packagedatadir)
 161 AC_SHELL_QUOTIFY(lispdir)
 162 AC_SHELL_QUOTIFY(infodir)
 163 AC_SHELL_QUOTIFY(datadir)
 164 AC_SHELL_QUOTIFY(autodir)
 165 AC_SHELL_QUOTIFY(auctexstartfile)
 166 AC_SHELL_QUOTIFY(EMACS)
 167 AC_SHELL_QUOTIFY(INSTALL_INFO)
 168 AC_SHELL_QUOTIFY(PERL)
 169 AC_SHELL_QUOTIFY(MAKEINFO)
 170 AC_SHELL_QUOTIFY(TEX)
 171 AC_SHELL_QUOTIFY(PDFTEX)
 172 AC_SHELL_QUOTIFY(DVIPS)
 173 AC_SHELL_QUOTIFY(TEXI2HTML)
 174 AC_SHELL_QUOTIFY(TEXI2DVI)
 175 AC_SHELL_QUOTIFY(TEXI2PDF)
 176
 177 AC_OUTPUT(Makefile tex-site.el.out:tex-site.el.in doc/Makefile auctex.el)
 178
 179
 180 cat >&2 <<EOF
 181
 182 Congratulations!  Configuration of AUCTeX is complete.
 183
 184 Type "make" at the prompt to build.
 185 EOF