tls.el: Compilation fix
[gnus] / lisp / tls.el
1 ;;; tls.el --- TLS/SSL support via wrapper around GnuTLS
2
3 ;; Copyright (C) 1996-1999, 2002-2015 Free Software Foundation, Inc.
4
5 ;; Author: Simon Josefsson <simon@josefsson.org>
6 ;; Keywords: comm, tls, gnutls, ssl
7
8 ;; This file is part of GNU Emacs.
9
10 ;; GNU Emacs is free software: you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation, either version 3 of the License, or
13 ;; (at your option) any later version.
14
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
22
23 ;;; Commentary:
24
25 ;; This package implements a simple wrapper around "gnutls-cli" to
26 ;; make Emacs support TLS/SSL.
27 ;;
28 ;; Usage is the same as `open-network-stream', i.e.:
29 ;;
30 ;; (setq tmp (open-tls-stream "test" (current-buffer) "news.mozilla.org" 563))
31 ;; ...
32 ;; #<process test>
33 ;; (process-send-string tmp "mode reader\n")
34 ;; 200 secnews.netscape.com Netscape-Collabra/3.52 03615 NNRP ready ...
35 ;; nil
36 ;; (process-send-string tmp "quit\n")
37 ;; 205
38 ;; nil
39
40 ;; To use this package as a replacement for ssl.el by William M. Perry
41 ;; <wmperry@cs.indiana.edu>, you need to evaluate the following:
42 ;;
43 ;; (defalias 'open-ssl-stream 'open-tls-stream)
44
45 ;;; Code:
46
47 (autoload 'format-spec "format-spec")
48 (autoload 'format-spec-make "format-spec")
49
50 (defgroup tls nil
51   "Transport Layer Security (TLS) parameters."
52   :group 'comm)
53
54 (defcustom tls-end-of-info
55   (concat
56    "\\("
57    ;; `openssl s_client' regexp.  See ssl/ssl_txt.c lines 219-220.
58    ;; According to apps/s_client.c line 1515 `---' is always the last
59    ;; line that is printed by s_client before the real data.
60    "^    Verify return code: .+\n---\n\\|"
61    ;; `gnutls' regexp. See src/cli.c lines 721-.
62    "^- Simple Client Mode:\n"
63    "\\(\n\\|"                           ; ignore blank lines
64    ;; According to GnuTLS v2.1.5 src/cli.c lines 640-650 and 705-715
65    ;; in `main' the handshake will start after this message.  If the
66    ;; handshake fails, the programs will abort.
67    "^\\*\\*\\* Starting TLS handshake\n\\)*"
68    "\\)")
69   "Regexp matching end of TLS client informational messages.
70 Client data stream begins after the last character matched by
71 this.  The default matches `openssl s_client' (version 0.9.8c)
72 and `gnutls-cli' (version 2.0.1) output."
73   :version "22.2"
74   :type 'regexp
75   :group 'tls)
76
77 (defcustom tls-program '("gnutls-cli --insecure -p %p %h"
78                          "gnutls-cli --insecure -p %p %h --protocols ssl3"
79                          "openssl s_client -connect %h:%p -no_ssl2 -ign_eof")
80   "List of strings containing commands to start TLS stream to a host.
81 Each entry in the list is tried until a connection is successful.
82 %h is replaced with server hostname, %p with port to connect to.
83 The program should read input on stdin and write output to stdout.
84
85 See `tls-checktrust' on how to check trusted root certs.
86
87 Also see `tls-success' for what the program should output after
88 successful negotiation."
89   :type
90   '(choice
91     (const :tag "Default list of commands"
92            ("gnutls-cli --insecure -p %p %h"
93             "gnutls-cli --insecure -p %p %h --protocols ssl3"
94             "openssl s_client -connect %h:%p -no_ssl2 -ign_eof"))
95     (list :tag "Choose commands"
96           :value
97           ("gnutls-cli --insecure -p %p %h"
98            "gnutls-cli --insecure -p %p %h --protocols ssl3"
99            "openssl s_client -connect %h:%p -no_ssl2 -ign_eof")
100           (set :inline t
101                ;; FIXME: add brief `:tag "..."' descriptions.
102                ;; (repeat :inline t :tag "Other" (string))
103                ;; See `tls-checktrust':
104                (const "gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h")
105                (const "gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h --protocols ssl3")
106                (const "openssl s_client -connect %h:%p -CAfile /etc/ssl/certs/ca-certificates.crt -no_ssl2 -ign_eof")
107                ;; No trust check:
108                (const "gnutls-cli --insecure -p %p %h")
109                (const "gnutls-cli --insecure -p %p %h --protocols ssl3")
110                (const "openssl s_client -connect %h:%p -no_ssl2 -ign_eof"))
111           (repeat :inline t :tag "Other" (string)))
112     (list :tag "List of commands"
113           (repeat :tag "Command" (string))))
114   :version "22.1"
115   :group 'tls)
116
117 (defcustom tls-process-connection-type nil
118   "Value for `process-connection-type' to use when starting TLS process."
119   :version "22.1"
120   :type 'boolean
121   :group 'tls)
122
123 (defcustom tls-success "- Handshake was completed\\|SSL handshake has read "
124   "Regular expression indicating completed TLS handshakes.
125 The default is what GnuTLS's \"gnutls-cli\" or OpenSSL's
126 \"openssl s_client\" outputs."
127   :version "22.1"
128   :type 'regexp
129   :group 'tls)
130
131 (defcustom tls-checktrust nil
132   "Indicate if certificates should be checked against trusted root certs.
133 If this is `ask', the user can decide whether to accept an
134 untrusted certificate.  You may have to adapt `tls-program' in
135 order to make this feature work properly, i.e., to ensure that
136 the external program knows about the root certificates you
137 consider trustworthy, e.g.:
138
139 \(setq tls-program
140       '(\"gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h\"
141         \"gnutls-cli --x509cafile /etc/ssl/certs/ca-certificates.crt -p %p %h --protocols ssl3\"
142         \"openssl s_client -connect %h:%p -CAfile /etc/ssl/certs/ca-certificates.crt -no_ssl2 -ign_eof\"))"
143   :type '(choice (const :tag "Always" t)
144                  (const :tag "Never" nil)
145                  (const :tag "Ask" ask))
146   :version "23.1" ;; No Gnus
147   :group 'tls)
148
149 (defcustom tls-untrusted
150   "- Peer's certificate is NOT trusted\\|Verify return code: \\([^0] \\|.[^ ]\\)"
151   "Regular expression indicating failure of TLS certificate verification.
152 The default is what GnuTLS's \"gnutls-cli\" or OpenSSL's
153 \"openssl s_client\" return in the event of unsuccessful
154 verification."
155   :type 'regexp
156   :version "23.1" ;; No Gnus
157   :group 'tls)
158
159 (defcustom tls-hostmismatch
160   "# The hostname in the certificate does NOT match"
161   "Regular expression indicating a host name mismatch in certificate.
162 When the host name specified in the certificate doesn't match the
163 name of the host you are connecting to, gnutls-cli issues a
164 warning to this effect.  There is no such feature in openssl.  Set
165 this to nil if you want to ignore host name mismatches."
166   :type 'regexp
167   :version "23.1" ;; No Gnus
168   :group 'tls)
169
170 (defcustom tls-certtool-program "certtool"
171   "Name of GnuTLS certtool.
172 Used by `tls-certificate-information'."
173   :version "22.1"
174   :type 'string
175   :group 'tls)
176
177 (if (fboundp 'format-message)
178     (defalias 'tls-format-message 'format-message)
179   ;; for Emacs < 25, and XEmacs, don't worry about quote translation.
180   (defalias 'tls-format-message 'format))
181
182 (defun tls-certificate-information (der)
183   "Parse X.509 certificate in DER format into an assoc list."
184   (let ((certificate (concat "-----BEGIN CERTIFICATE-----\n"
185                              (base64-encode-string der)
186                              "\n-----END CERTIFICATE-----\n"))
187         (exit-code 0))
188     (with-current-buffer (get-buffer-create " *certtool*")
189       (erase-buffer)
190       (insert certificate)
191       (setq exit-code (condition-case ()
192                           (call-process-region (point-min) (point-max)
193                                                tls-certtool-program
194                                                t (list (current-buffer) nil) t
195                                                "--certificate-info")
196                         (error -1)))
197       (if (/= exit-code 0)
198           nil
199         (let ((vals nil))
200           (goto-char (point-min))
201           (while (re-search-forward "^\\([^:]+\\): \\(.*\\)" nil t)
202             (push (cons (match-string 1) (match-string 2)) vals))
203           (nreverse vals))))))
204
205 (defun open-tls-stream (name buffer host port)
206   "Open a TLS connection for a port to a host.
207 Returns a subprocess-object to represent the connection.
208 Input and output work as for subprocesses; `delete-process' closes it.
209 Args are NAME BUFFER HOST PORT.
210 NAME is name for process.  It is modified if necessary to make it unique.
211 BUFFER is the buffer (or buffer name) to associate with the process.
212  Process output goes at end of that buffer, unless you specify
213  an output stream or filter function to handle the output.
214  BUFFER may be also nil, meaning that this process is not associated
215  with any buffer
216 Third arg is name of the host to connect to, or its IP address.
217 Fourth arg PORT is an integer specifying a port to connect to."
218   (let ((cmds tls-program)
219         (use-temp-buffer (null buffer))
220         process cmd done)
221     (if use-temp-buffer
222         (setq buffer (generate-new-buffer " TLS"))
223       ;; BUFFER is a string but does not exist as a buffer object.
224       (unless (and (get-buffer buffer)
225                    (buffer-name (get-buffer buffer)))
226         (generate-new-buffer buffer)))
227     (with-current-buffer buffer
228       (message "Opening TLS connection to `%s'..." host)
229       (while (and (not done) (setq cmd (pop cmds)))
230         (let ((process-connection-type tls-process-connection-type)
231               (formatted-cmd
232                (format-spec
233                 cmd
234                 (format-spec-make
235                  ?h host
236                  ?p (if (integerp port)
237                         (int-to-string port)
238                       port)))))
239           (message "Opening TLS connection with `%s'..." formatted-cmd)
240           (setq process (start-process
241                          name buffer shell-file-name shell-command-switch
242                          formatted-cmd))
243           (while (and process
244                       (memq (process-status process) '(open run))
245                       (progn
246                         (goto-char (point-min))
247                         (not (setq done (re-search-forward
248                                          tls-success nil t)))))
249             (unless (accept-process-output process 1)
250               (sit-for 1)))
251           (message "Opening TLS connection with `%s'...%s" formatted-cmd
252                    (if done "done" "failed"))
253           (if (not done)
254               (delete-process process)
255             ;; advance point to after all informational messages that
256             ;; `openssl s_client' and `gnutls' print
257             (let ((start-of-data nil))
258               (while
259                   (not (setq start-of-data
260                              ;; the string matching `tls-end-of-info'
261                              ;; might come in separate chunks from
262                              ;; `accept-process-output', so start the
263                              ;; search where `tls-success' ended
264                              (save-excursion
265                                (if (re-search-forward tls-end-of-info nil t)
266                                    (match-end 0)))))
267                 (accept-process-output process 1))
268               (if start-of-data
269                   ;; move point to start of client data
270                   (goto-char start-of-data)))
271             (setq done process))))
272       (when (and done
273                  (or
274                   (and tls-checktrust
275                        (save-excursion
276                          (goto-char (point-min))
277                          (re-search-forward tls-untrusted nil t))
278                        (or
279                         (and (not (eq tls-checktrust 'ask))
280                              (message "The certificate presented by `%s' is \
281 NOT trusted." host))
282                         (not (yes-or-no-p
283                               (tls-format-message "\
284 The certificate presented by `%s' is NOT trusted. Accept anyway? " host)))))
285                   (and tls-hostmismatch
286                        (save-excursion
287                          (goto-char (point-min))
288                          (re-search-forward tls-hostmismatch nil t))
289                        (not (yes-or-no-p
290                              (format "Host name in certificate doesn't \
291 match `%s'. Connect anyway? " host))))))
292         (setq done nil)
293         (delete-process process))
294       ;; Delete all the informational messages that could confuse
295       ;; future uses of `buffer'.
296       (delete-region (point-min) (point)))
297     (message "Opening TLS connection to `%s'...%s"
298              host (if done "done" "failed"))
299     (when use-temp-buffer
300       (if done (set-process-buffer process nil))
301       (kill-buffer buffer))
302     done))
303
304 (provide 'tls)
305
306 ;;; tls.el ends here