cgit.sxemacs.org Git - gnus/blob - lisp/time-date.el

   1 ;;; time-date.el --- Date and time handling functions
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu Umeda <umerin@mse.kyutech.ac.jp>
   8 ;; Keywords: mail news util
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Time values come in three formats.  The oldest format is a cons
  28 ;; cell of the form (HIGH . LOW).  This format is obsolete, but still
  29 ;; supported.  The two other formats are the lists (HIGH LOW) and
  30 ;; (HIGH LOW MICRO).  The first two formats specify HIGH * 2^16 + LOW
  31 ;; seconds; the third format specifies HIGH * 2^16 + LOW + MICRO /
  32 ;; 1000000 seconds.  We should have 0 <= MICRO < 1000000 and 0 <= LOW
  33 ;; < 2^16.  If the time value represents a point in time, then HIGH is
  34 ;; nonnegative.  If the time value is a time difference, then HIGH can
  35 ;; be negative as well.  The macro `with-decoded-time-value' and the
  36 ;; function `encode-time-value' make it easier to deal with these
  37 ;; three formats.  See `time-subtract' for an example of how to use
  38 ;; them.
  39
  40 ;;; Code:
  41
  42 (defmacro with-decoded-time-value (varlist &rest body)
  43   "Decode a time value and bind it according to VARLIST, then eval BODY.
  44
  45 The value of the last form in BODY is returned.
  46
  47 Each element of the list VARLIST is a list of the form
  48 \(HIGH-SYMBOL LOW-SYMBOL MICRO-SYMBOL [TYPE-SYMBOL] TIME-VALUE).
  49 The time value TIME-VALUE is decoded and the result it bound to
  50 the symbols HIGH-SYMBOL, LOW-SYMBOL and MICRO-SYMBOL.
  51
  52 The optional TYPE-SYMBOL is bound to the type of the time value.
  53 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH
  54 LOW), and type 2 is the list (HIGH LOW MICRO)."
  55   (declare (indent 1)
  56            (debug ((&rest (symbolp symbolp symbolp &or [symbolp form] form))
  57                    body)))
  58   (if varlist
  59       (let* ((elt (pop varlist))
  60              (high (pop elt))
  61              (low (pop elt))
  62              (micro (pop elt))
  63              (type (unless (eq (length elt) 1)
  64                      (pop elt)))
  65              (time-value (car elt))
  66              (gensym (make-symbol "time")))
  67         `(let* ,(append `((,gensym ,time-value)
  68                           (,high (pop ,gensym))
  69                           ,low ,micro)
  70                         (when type `(,type)))
  71            (if (consp ,gensym)
  72                (progn
  73                  (setq ,low (pop ,gensym))
  74                  (if ,gensym
  75                      ,(append `(setq ,micro (car ,gensym))
  76                               (when type `(,type 2)))
  77                    ,(append `(setq ,micro 0)
  78                             (when type `(,type 1)))))
  79              ,(append `(setq ,low ,gensym ,micro 0)
  80                       (when type `(,type 0))))
  81            (with-decoded-time-value ,varlist ,@body)))
  82     `(progn ,@body)))
  83
  84 (defun encode-time-value (high low micro type)
  85   "Encode HIGH, LOW, and MICRO into a time value of type TYPE.
  86 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH LOW),
  87 and type 2 is the list (HIGH LOW MICRO)."
  88   (cond
  89    ((eq type 0) (cons high low))
  90    ((eq type 1) (list high low))
  91    ((eq type 2) (list high low micro))))
  92
  93 (autoload 'parse-time-string "parse-time")
  94 (autoload 'timezone-make-date-arpa-standard "timezone")
  95
  96 ;;;###autoload
  97 ;; `parse-time-string' isn't sufficiently general or robust.  It fails
  98 ;; to grok some of the formats that timezone does (e.g. dodgy
  99 ;; post-2000 stuff from some Elms) and either fails or returns bogus
 100 ;; values.  timezone-make-date-arpa-standard should help.
 101 (defun date-to-time (date)
 102   "Parse a string DATE that represents a date-time and return a time value.
 103 If DATE lacks timezone information, GMT is assumed."
 104   (condition-case ()
 105       (apply 'encode-time (parse-time-string date))
 106     (error (condition-case ()
 107                (apply 'encode-time
 108                       (parse-time-string
 109                        (timezone-make-date-arpa-standard date)))
 110              (error (error "Invalid date: %s" date))))))
 111
 112 ;; Bit of a mess.  Emacs has float-time since at least 21.1.
 113 ;; This file is synced to Gnus, and XEmacs packages may have been written
 114 ;; using time-to-seconds from the Gnus library.
 115 ;;;###autoload(if (and (fboundp 'float-time)
 116 ;;;###autoload         (subrp (symbol-function 'float-time)))
 117 ;;;###autoload    (progn
 118 ;;;###autoload      (defalias 'time-to-seconds 'float-time)
 119 ;;;###autoload      (make-obsolete 'time-to-seconds 'float-time "21.1"))
 120 ;;;###autoload  (autoload 'time-to-seconds "time-date"))
 121
 122 (eval-and-compile
 123   (unless (and (fboundp 'float-time)
 124                (subrp (symbol-function 'float-time)))
 125     (defun time-to-seconds (time)
 126       "Convert time value TIME to a floating point number."
 127       (with-decoded-time-value ((high low micro time))
 128         (+ (* 1.0 high 65536)
 129            low
 130            (/ micro 1000000.0))))))
 131
 132 (eval-when-compile
 133   (unless (fboundp 'with-no-warnings)
 134     (defmacro with-no-warnings (&rest body)
 135       `(progn ,@body))))
 136
 137 ;;;###autoload
 138 (defun seconds-to-time (seconds)
 139   "Convert SECONDS (a floating point number) to a time value."
 140   (list (floor seconds 65536)
 141         (floor (mod seconds 65536))
 142         (floor (* (- seconds (ffloor seconds)) 1000000))))
 143
 144 ;;;###autoload
 145 (defun time-less-p (t1 t2)
 146   "Say whether time value T1 is less than time value T2."
 147   (with-decoded-time-value ((high1 low1 micro1 t1)
 148                             (high2 low2 micro2 t2))
 149     (or (< high1 high2)
 150         (and (= high1 high2)
 151              (or (< low1 low2)
 152                  (and (= low1 low2)
 153                       (< micro1 micro2)))))))
 154
 155 ;;;###autoload
 156 (defun days-to-time (days)
 157   "Convert DAYS into a time value."
 158   (let* ((seconds (* 1.0 days 60 60 24))
 159          (high (condition-case nil (floor (/ seconds 65536))
 160                  (range-error most-positive-fixnum))))
 161     (list high (condition-case nil (floor (- seconds (* 1.0 high 65536)))
 162                  (range-error 65535)))))
 163
 164 ;;;###autoload
 165 (defun time-since (time)
 166   "Return the time elapsed since TIME.
 167 TIME should be either a time value or a date-time string."
 168   (when (stringp time)
 169     ;; Convert date strings to internal time.
 170     (setq time (date-to-time time)))
 171   (time-subtract (current-time) time))
 172
 173 ;;;###autoload
 174 (defalias 'subtract-time 'time-subtract)
 175
 176 ;;;###autoload
 177 (defun time-subtract (t1 t2)
 178   "Subtract two time values, T1 minus T2.
 179 Return the difference in the format of a time value."
 180   (with-decoded-time-value ((high low micro type t1)
 181                             (high2 low2 micro2 type2 t2))
 182     (setq high (- high high2)
 183           low (- low low2)
 184           micro (- micro micro2)
 185           type (max type type2))
 186     (when (< micro 0)
 187       (setq low (1- low)
 188             micro (+ micro 1000000)))
 189     (when (< low 0)
 190       (setq high (1- high)
 191             low (+ low 65536)))
 192     (encode-time-value high low micro type)))
 193
 194 ;;;###autoload
 195 (defun time-add (t1 t2)
 196   "Add two time values T1 and T2.  One should represent a time difference."
 197   (with-decoded-time-value ((high low micro type t1)
 198                             (high2 low2 micro2 type2 t2))
 199     (setq high (+ high high2)
 200           low (+ low low2)
 201           micro (+ micro micro2)
 202           type (max type type2))
 203     (when (>= micro 1000000)
 204       (setq low (1+ low)
 205             micro (- micro 1000000)))
 206     (when (>= low 65536)
 207       (setq high (1+ high)
 208             low (- low 65536)))
 209     (encode-time-value high low micro type)))
 210
 211 ;;;###autoload
 212 (defun date-to-day (date)
 213   "Return the number of days between year 1 and DATE.
 214 DATE should be a date-time string."
 215   (time-to-days (date-to-time date)))
 216
 217 ;;;###autoload
 218 (defun days-between (date1 date2)
 219   "Return the number of days between DATE1 and DATE2.
 220 DATE1 and DATE2 should be date-time strings."
 221   (- (date-to-day date1) (date-to-day date2)))
 222
 223 ;;;###autoload
 224 (defun date-leap-year-p (year)
 225   "Return t if YEAR is a leap year."
 226   (or (and (zerop (% year 4))
 227            (not (zerop (% year 100))))
 228       (zerop (% year 400))))
 229
 230 ;;;###autoload
 231 (defun time-to-day-in-year (time)
 232   "Return the day number within the year corresponding to TIME."
 233   (let* ((tim (decode-time time))
 234          (month (nth 4 tim))
 235          (day (nth 3 tim))
 236          (year (nth 5 tim))
 237          (day-of-year (+ day (* 31 (1- month)))))
 238     (when (> month 2)
 239       (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 240       (when (date-leap-year-p year)
 241         (setq day-of-year (1+ day-of-year))))
 242     day-of-year))
 243
 244 ;;;###autoload
 245 (defun time-to-days (time)
 246   "The number of days between the Gregorian date 0001-12-31bce and TIME.
 247 TIME should be a time value.
 248 The Gregorian date Sunday, December 31, 1bce is imaginary."
 249   (let* ((tim (decode-time time))
 250          (month (nth 4 tim))
 251          (day (nth 3 tim))
 252          (year (nth 5 tim)))
 253     (+ (time-to-day-in-year time)       ;       Days this year
 254        (* 365 (1- year))                ;       + Days in prior years
 255        (/ (1- year) 4)                  ;       + Julian leap years
 256        (- (/ (1- year) 100))            ;       - century years
 257        (/ (1- year) 400))))             ;       + Gregorian leap years
 258
 259 (eval-and-compile
 260   (if (and (fboundp 'float-time)
 261            (subrp (symbol-function 'float-time)))
 262       (defun time-to-number-of-days (time)
 263         "Return the number of days represented by TIME.
 264 The number of days will be returned as a floating point number."
 265         (/ (float-time time) (* 60 60 24)))
 266     (defun time-to-number-of-days (time)
 267       "Return the number of days represented by TIME.
 268 The number of days will be returned as a floating point number."
 269       (/ (with-no-warnings (time-to-seconds time)) (* 60 60 24)))))
 270
 271 ;;;###autoload
 272 (defun safe-date-to-time (date)
 273   "Parse a string DATE that represents a date-time and return a time value.
 274 If DATE is malformed, return a time value of zeros."
 275   (condition-case ()
 276       (date-to-time date)
 277     (error '(0 0))))
 278
 279 \f
 280 ;;;###autoload
 281 (defun format-seconds (string seconds)
 282   "Use format control STRING to format the number SECONDS.
 283 The valid format specifiers are:
 284 %y is the number of (365-day) years.
 285 %d is the number of days.
 286 %h is the number of hours.
 287 %m is the number of minutes.
 288 %s is the number of seconds.
 289 %z is a non-printing control flag (see below).
 290 %% is a literal \"%\".
 291
 292 Upper-case specifiers are followed by the unit-name (e.g. \"years\").
 293 Lower-case specifiers return only the unit.
 294
 295 \"%\" may be followed by a number specifying a width, with an
 296 optional leading \".\" for zero-padding.  For example, \"%.3Y\" will
 297 return something of the form \"001 year\".
 298
 299 The \"%z\" specifier does not print anything.  When it is used, specifiers
 300 must be given in order of decreasing size.  To the left of \"%z\", nothing
 301 is output until the first non-zero unit is encountered.
 302
 303 This function does not work for SECONDS greater than `most-positive-fixnum'."
 304   (let ((start 0)
 305         (units '(("y" "year"   31536000)
 306                  ("d" "day"       86400)
 307                  ("h" "hour"       3600)
 308                  ("m" "minute"       60)
 309                  ("s" "second"        1)
 310                  ("z")))
 311         (case-fold-search t)
 312         spec match usedunits zeroflag larger prev name unit num zeropos)
 313     (while (string-match "%\\.?[0-9]*\\(.\\)" string start)
 314       (setq start (match-end 0)
 315             spec (match-string 1 string))
 316       (unless (string-equal spec "%")
 317         ;; `assoc-string' is not available in XEmacs.  So when compiling
 318         ;; Gnus (`time-date.el' is part of Gnus) with XEmacs, we get
 319         ;; a warning here.  But `format-seconds' is not used anywhere in
 320         ;; Gnus so it's not a real problem. --rsteib
 321         (or (setq match (assoc-string spec units t))
 322             (error "Bad format specifier: `%s'" spec))
 323         (if (assoc-string spec usedunits t)
 324             (error "Multiple instances of specifier: `%s'" spec))
 325         (if (string-equal (car match) "z")
 326             (setq zeroflag t)
 327           (unless larger
 328             (setq unit (nth 2 match)
 329                   larger (and prev (> unit prev))
 330                   prev unit)))
 331         (push match usedunits)))
 332     (and zeroflag larger
 333          (error "Units are not in decreasing order of size"))
 334     (dolist (u units)
 335       (setq spec (car u)
 336             name (cadr u)
 337             unit (nth 2 u))
 338       (when (string-match (format "%%\\(\\.?[0-9]+\\)?\\(%s\\)" spec) string)
 339         (if (string-equal spec "z")     ; must be last in units
 340             (setq string
 341                   (replace-regexp-in-string
 342                    "%z" ""
 343                    (substring string (min (or zeropos (match-end 0))
 344                                           (match-beginning 0)))))
 345           ;; Cf article-make-date-line in gnus-art.
 346           (setq num (floor seconds unit)
 347                 seconds (- seconds (* num unit)))
 348           ;; Start position of the first non-zero unit.
 349           (or zeropos
 350               (setq zeropos (unless (zerop num) (match-beginning 0))))
 351           (setq string
 352                 (replace-match
 353                  (format (concat "%" (match-string 1 string) "d%s") num
 354                          (if (string-equal (match-string 2 string) spec)
 355                              ""       ; lower-case, no unit-name
 356                            (format " %s%s" name
 357                                    (if (= num 1) "" "s"))))
 358                  t t string))))))
 359   (replace-regexp-in-string "%%" "%" string))
 360
 361
 362 (provide 'time-date)
 363
 364 ;;; time-date.el ends here