cgit.sxemacs.org Git - gnus/blob - lisp/spam.el

   1 ;;; spam.el --- Identifying spam
   2 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam control under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; The integration with Gnus is not yet complete.  See various `FIXME'
  31 ;;; comments, below, for supplementary explanations or discussions.
  32
  33 ;;; Several TODO items are marked as such
  34
  35 ;; TODO: spam scores, detection of spam in newsgroups, cross-server splitting,
  36 ;; remote processing, training through files
  37
  38 ;;; Code:
  39
  40 (eval-when-compile (require 'cl))
  41
  42 (require 'gnus-sum)
  43
  44 (require 'gnus-uu)                      ; because of key prefix issues
  45 ;;; for the definitions of group content classification and spam processors
  46 (require 'gnus)
  47 (require 'message)              ;for the message-fetch-field functions
  48
  49 ;; for nnimap-split-download-body-default
  50 (eval-when-compile (require 'nnimap))
  51
  52 ;; autoload query-dig
  53 (eval-and-compile
  54   (autoload 'query-dig "dig"))
  55
  56 ;; autoload spam-report
  57 (eval-and-compile
  58   (autoload 'spam-report-gmane "spam-report"))
  59
  60 ;; autoload gnus-registry
  61 (eval-and-compile
  62   (autoload 'gnus-registry-group-count "gnus-registry")
  63   (autoload 'gnus-registry-add-group "gnus-registry")
  64   (autoload 'gnus-registry-store-extra-entry "gnus-registry")
  65   (autoload 'gnus-registry-fetch-extra "gnus-registry"))
  66
  67 ;; autoload query-dns
  68 (eval-and-compile
  69   (autoload 'query-dns "dns"))
  70
  71 ;;; Main parameters.
  72
  73 (defgroup spam nil
  74   "Spam configuration.")
  75
  76 (defcustom spam-directory (nnheader-concat gnus-directory "spam/")
  77   "Directory for spam whitelists and blacklists."
  78   :type 'directory
  79   :group 'spam)
  80
  81 (defcustom spam-move-spam-nonspam-groups-only t
  82   "Whether spam should be moved in non-spam groups only.
  83 When t, only ham and unclassified groups will have their spam moved
  84 to the spam-process-destination.  When nil, spam will also be moved from
  85 spam groups."
  86   :type 'boolean
  87   :group 'spam)
  88
  89 (defcustom spam-process-ham-in-nonham-groups nil
  90   "Whether ham should be processed in non-ham groups."
  91   :type 'boolean
  92   :group 'spam)
  93
  94 (defcustom spam-log-to-registry nil
  95   "Whether spam/ham processing should be logged in the registry."
  96   :type 'boolean
  97   :group 'spam)
  98
  99 (defcustom spam-split-symbolic-return nil
 100   "Whether `spam-split' should work with symbols or group names."
 101   :type 'boolean
 102   :group 'spam)
 103
 104 (defcustom spam-split-symbolic-return-positive nil
 105   "Whether `spam-split' should ALWAYS work with symbols or group names.
 106 Do not set this if you use `spam-split' in a fancy split
 107   method."
 108   :type 'boolean
 109   :group 'spam)
 110
 111 (defcustom spam-process-ham-in-spam-groups nil
 112   "Whether ham should be processed in spam groups."
 113   :type 'boolean
 114   :group 'spam)
 115
 116 (defcustom spam-mark-only-unseen-as-spam t
 117   "Whether only unseen articles should be marked as spam in spam groups.
 118 When nil, all unread articles in a spam group are marked as
 119 spam.  Set this if you want to leave an article unread in a spam group
 120 without losing it to the automatic spam-marking process."
 121   :type 'boolean
 122   :group 'spam)
 123
 124 (defcustom spam-mark-ham-unread-before-move-from-spam-group nil
 125   "Whether ham should be marked unread before it's moved.
 126 The article is moved out of a spam group according to ham-process-destination.
 127 This variable is an official entry in the international Longest Variable Name
 128 Competition."
 129   :type 'boolean
 130   :group 'spam)
 131
 132 (defcustom spam-disable-spam-split-during-ham-respool nil
 133   "Whether `spam-split' should be ignored while resplitting ham.
 134 This is useful to prevent ham from ending up in the same spam
 135 group after the resplit.  Don't set this to t if you have `spam-split' as the
 136 last rule in your split configuration."
 137   :type 'boolean
 138   :group 'spam)
 139
 140 (defcustom spam-autodetect-recheck-messages nil
 141   "Should spam.el recheck all meessages when autodetecting?
 142 Normally this is nil, so only unseen messages will be checked."
 143   :type 'boolean
 144   :group 'spam)
 145
 146 (defcustom spam-whitelist (expand-file-name "whitelist" spam-directory)
 147   "The location of the whitelist.
 148 The file format is one regular expression per line.
 149 The regular expression is matched against the address."
 150   :type 'file
 151   :group 'spam)
 152
 153 (defcustom spam-blacklist (expand-file-name "blacklist" spam-directory)
 154   "The location of the blacklist.
 155 The file format is one regular expression per line.
 156 The regular expression is matched against the address."
 157   :type 'file
 158   :group 'spam)
 159
 160 (defcustom spam-use-dig t
 161   "Whether `query-dig' should be used instead of `query-dns'."
 162   :type 'boolean
 163   :group 'spam)
 164
 165 (defcustom spam-use-blacklist nil
 166   "Whether the blacklist should be used by `spam-split'."
 167   :type 'boolean
 168   :group 'spam)
 169
 170 (defcustom spam-blacklist-ignored-regexes nil
 171   "Regular expressions that the blacklist should ignore."
 172   :type '(repeat (regexp :tag "Regular expression to ignore when blacklisting"))
 173   :group 'spam)
 174
 175 (defcustom spam-use-whitelist nil
 176   "Whether the whitelist should be used by `spam-split'."
 177   :type 'boolean
 178   :group 'spam)
 179
 180 (defcustom spam-use-whitelist-exclusive nil
 181   "Whether whitelist-exclusive should be used by `spam-split'.
 182 Exclusive whitelisting means that all messages from senders not in the whitelist
 183 are considered spam."
 184   :type 'boolean
 185   :group 'spam)
 186
 187 (defcustom spam-use-blackholes nil
 188   "Whether blackholes should be used by `spam-split'."
 189   :type 'boolean
 190   :group 'spam)
 191
 192 (defcustom spam-use-hashcash nil
 193   "Whether hashcash payments should be detected by `spam-split'."
 194   :type 'boolean
 195   :group 'spam)
 196
 197 (defcustom spam-use-regex-headers nil
 198   "Whether a header regular expression match should be used by `spam-split'.
 199 Also see the variables `spam-regex-headers-spam' and `spam-regex-headers-ham'."
 200   :type 'boolean
 201   :group 'spam)
 202
 203 (defcustom spam-use-regex-body nil
 204   "Whether a body regular expression match should be used by `spam-split'.
 205 Also see the variables `spam-regex-body-spam' and `spam-regex-body-ham'."
 206   :type 'boolean
 207   :group 'spam)
 208
 209 (defcustom spam-use-bogofilter-headers nil
 210   "Whether bogofilter headers should be used by `spam-split'.
 211 Enable this if you pre-process messages with Bogofilter BEFORE Gnus sees them."
 212   :type 'boolean
 213   :group 'spam)
 214
 215 (defcustom spam-use-bogofilter nil
 216   "Whether bogofilter should be invoked by `spam-split'.
 217 Enable this if you want Gnus to invoke Bogofilter on new messages."
 218   :type 'boolean
 219   :group 'spam)
 220
 221 (defcustom spam-use-BBDB nil
 222   "Whether BBDB should be used by `spam-split'."
 223   :type 'boolean
 224   :group 'spam)
 225
 226 (defcustom spam-use-BBDB-exclusive nil
 227   "Whether BBDB-exclusive should be used by `spam-split'.
 228 Exclusive BBDB means that all messages from senders not in the BBDB are
 229 considered spam."
 230   :type 'boolean
 231   :group 'spam)
 232
 233 (defcustom spam-use-ifile nil
 234   "Whether ifile should be used by `spam-split'."
 235   :type 'boolean
 236   :group 'spam)
 237
 238 (defcustom spam-use-stat nil
 239   "Whether `spam-stat' should be used by `spam-split'."
 240   :type 'boolean
 241   :group 'spam)
 242
 243 (defcustom spam-use-spamoracle nil
 244   "Whether spamoracle should be used by `spam-split'."
 245   :type 'boolean
 246   :group 'spam)
 247
 248 (defcustom spam-use-spamassassin nil
 249   "Whether spamassassin should be invoked by `spam-split'.
 250 Enable this if you want Gnus to invoke SpamAssassin on new messages."
 251   :type 'boolean
 252   :group 'spam)
 253
 254 (defcustom spam-use-spamassassin-headers nil
 255   "Whether spamassassin headers should be checked by `spam-split'.
 256 Enable this if you pre-process messages with SpamAssassin BEFORE Gnus sees
 257 them."
 258   :type 'boolean
 259   :group 'spam)
 260
 261 (defcustom spam-install-hooks (or
 262                                spam-use-dig
 263                                spam-use-blacklist
 264                                spam-use-whitelist
 265                                spam-use-whitelist-exclusive
 266                                spam-use-blackholes
 267                                spam-use-hashcash
 268                                spam-use-regex-headers
 269                                spam-use-regex-body
 270                                spam-use-bogofilter
 271                                spam-use-bogofilter-headers
 272                                spam-use-spamassassin
 273                                spam-use-spamassassin-headers
 274                                spam-use-BBDB
 275                                spam-use-BBDB-exclusive
 276                                spam-use-ifile
 277                                spam-use-stat
 278                                spam-use-spamoracle)
 279   "Whether the spam hooks should be installed.
 280 Default to t if one of the spam-use-* variables is set."
 281   :group 'spam
 282   :type 'boolean)
 283
 284 (defcustom spam-split-group "spam"
 285   "Group name where incoming spam should be put by `spam-split'."
 286   :type 'string
 287   :group 'spam)
 288
 289 ;;; TODO: deprecate this variable, it's confusing since it's a list of strings,
 290 ;;; not regular expressions
 291 (defcustom spam-junk-mailgroups (cons
 292                                  spam-split-group
 293                                  '("mail.junk" "poste.pourriel"))
 294   "Mailgroups with spam contents.
 295 All unmarked article in such group receive the spam mark on group entry."
 296   :type '(repeat (string :tag "Group"))
 297   :group 'spam)
 298
 299 (defcustom spam-blackhole-servers '("bl.spamcop.net" "relays.ordb.org"
 300                                     "dev.null.dk" "relays.visi.com")
 301   "List of blackhole servers."
 302   :type '(repeat (string :tag "Server"))
 303   :group 'spam)
 304
 305 (defcustom spam-blackhole-good-server-regex nil
 306   "String matching IP addresses that should not be checked in the blackholes."
 307   :type '(radio (const nil)
 308                 (regexp :format "%t: %v\n" :size 0))
 309   :group 'spam)
 310
 311 (defcustom spam-face 'gnus-splash-face
 312   "Face for spam-marked articles."
 313   :type 'face
 314   :group 'spam)
 315
 316 (defcustom spam-regex-headers-spam '("^X-Spam-Flag: YES")
 317   "Regular expression for positive header spam matches."
 318   :type '(repeat (regexp :tag "Regular expression to match spam header"))
 319   :group 'spam)
 320
 321 (defcustom spam-regex-headers-ham '("^X-Spam-Flag: NO")
 322   "Regular expression for positive header ham matches."
 323   :type '(repeat (regexp :tag "Regular expression to match ham header"))
 324   :group 'spam)
 325
 326 (defcustom spam-regex-body-spam '()
 327   "Regular expression for positive body spam matches."
 328   :type '(repeat (regexp :tag "Regular expression to match spam body"))
 329   :group 'spam)
 330
 331 (defcustom spam-regex-body-ham '()
 332   "Regular expression for positive body ham matches."
 333   :type '(repeat (regexp :tag "Regular expression to match ham body"))
 334   :group 'spam)
 335
 336 (defgroup spam-ifile nil
 337   "Spam ifile configuration."
 338   :group 'spam)
 339
 340 (defcustom spam-ifile-path (executable-find "ifile")
 341   "File path of the ifile executable program."
 342   :type '(choice (file :tag "Location of ifile")
 343                  (const :tag "ifile is not installed"))
 344   :group 'spam-ifile)
 345
 346 (defcustom spam-ifile-database-path nil
 347   "File path of the ifile database."
 348   :type '(choice (file :tag "Location of the ifile database")
 349                  (const :tag "Use the default"))
 350   :group 'spam-ifile)
 351
 352 (defcustom spam-ifile-spam-category "spam"
 353   "Name of the spam ifile category."
 354   :type 'string
 355   :group 'spam-ifile)
 356
 357 (defcustom spam-ifile-ham-category nil
 358   "Name of the ham ifile category.
 359 If nil, the current group name will be used."
 360   :type '(choice (string :tag "Use a fixed category")
 361                  (const :tag "Use the current group name"))
 362   :group 'spam-ifile)
 363
 364 (defcustom spam-ifile-all-categories nil
 365   "Whether the ifile check will return all categories, or just spam.
 366 Set this to t if you want to use the `spam-split' invocation of ifile as
 367 your main source of newsgroup names."
 368   :type 'boolean
 369   :group 'spam-ifile)
 370
 371 (defgroup spam-bogofilter nil
 372   "Spam bogofilter configuration."
 373   :group 'spam)
 374
 375 (defcustom spam-bogofilter-path (executable-find "bogofilter")
 376   "File path of the Bogofilter executable program."
 377   :type '(choice (file :tag "Location of bogofilter")
 378                  (const :tag "Bogofilter is not installed"))
 379   :group 'spam-bogofilter)
 380
 381 (defcustom spam-bogofilter-header "X-Bogosity"
 382   "The header that Bogofilter inserts in messages."
 383   :type 'string
 384   :group 'spam-bogofilter)
 385
 386 (defcustom spam-bogofilter-spam-switch "-s"
 387   "The switch that Bogofilter uses to register spam messages."
 388   :type 'string
 389   :group 'spam-bogofilter)
 390
 391 (defcustom spam-bogofilter-ham-switch "-n"
 392   "The switch that Bogofilter uses to register ham messages."
 393   :type 'string
 394   :group 'spam-bogofilter)
 395
 396 (defcustom spam-bogofilter-spam-strong-switch "-S"
 397   "The switch that Bogofilter uses to unregister ham messages."
 398   :type 'string
 399   :group 'spam-bogofilter)
 400
 401 (defcustom spam-bogofilter-ham-strong-switch "-N"
 402   "The switch that Bogofilter uses to unregister spam messages."
 403   :type 'string
 404   :group 'spam-bogofilter)
 405
 406 (defcustom spam-bogofilter-bogosity-positive-spam-header "^\\(Yes\\|Spam\\)"
 407   "The regex on `spam-bogofilter-header' for positive spam identification."
 408   :type 'regexp
 409   :group 'spam-bogofilter)
 410
 411 (defcustom spam-bogofilter-database-directory nil
 412   "Directory path of the Bogofilter databases."
 413   :type '(choice (directory
 414                   :tag "Location of the Bogofilter database directory")
 415                  (const :tag "Use the default"))
 416   :group 'spam-bogofilter)
 417
 418 (defgroup spam-spamoracle nil
 419   "Spam spamoracle configuration."
 420   :group 'spam)
 421
 422 (defcustom spam-spamoracle-database nil
 423   "Location of spamoracle database file.
 424 When nil, use the default spamoracle database."
 425   :type '(choice (directory :tag "Location of spamoracle database file.")
 426                  (const :tag "Use the default"))
 427   :group 'spam-spamoracle)
 428
 429 (defcustom spam-spamoracle-binary (executable-find "spamoracle")
 430   "Location of the spamoracle binary."
 431   :type '(choice (directory :tag "Location of the spamoracle binary")
 432                  (const :tag "Use the default"))
 433   :group 'spam-spamoracle)
 434
 435 (defgroup spam-spamassassin nil
 436   "Spam SpamAssassin configuration."
 437   :group 'spam)
 438
 439 (defcustom spam-spamassassin-path (executable-find "spamassassin")
 440   "File path of the spamassassin executable program.
 441 Hint: set this to \"spamc\" if you have spamd running.  See the spamc and
 442 spamd man pages for more information on these programs."
 443   :type '(choice (file :tag "Location of spamc")
 444                  (const :tag "spamassassin is not installed"))
 445   :group 'spam-spamassassin)
 446
 447 (defcustom spam-spamassassin-arguments ()
 448   "Arguments to pass to the spamassassin executable.
 449 This must be a list.  For example, `(\"-C\" \"configfile\")'."
 450   :type '(restricted-sexp :match-alternatives (listp))
 451   :group 'spam-spamassassin)
 452
 453 (defcustom spam-spamassassin-spam-flag-header "X-Spam-Flag"
 454   "The header inserted by SpamAssassin to flag spam."
 455   :type 'string
 456   :group 'spam-spamassassin)
 457
 458 (defcustom spam-spamassassin-positive-spam-flag-header "YES"
 459   "The regex on `spam-spamassassin-spam-flag-header' for positive spam
 460 identification"
 461   :type 'string
 462   :group 'spam-spamassassin)
 463
 464 (defcustom spam-spamassassin-spam-status-header "X-Spam-Status"
 465   "The header inserted by SpamAssassin, giving extended scoring information"
 466   :type 'string
 467   :group 'spam-spamassassin)
 468
 469 (defcustom spam-sa-learn-path (executable-find "sa-learn")
 470   "File path of the sa-learn executable program."
 471   :type '(choice (file :tag "Location of spamassassin")
 472                  (const :tag "spamassassin is not installed"))
 473   :group 'spam-spamassassin)
 474
 475 (defcustom spam-sa-learn-rebuild t
 476   "Whether sa-learn should rebuild the database every time it is called
 477 Enable this if you want sa-learn to rebuild the database automatically.  Doing
 478 this will slightly increase the running time of the spam registration process.
 479 If you choose not to do this, you will have to run \"sa-learn --rebuild\" in
 480 order for SpamAssassin to recognize the new registered spam."
 481   :type 'boolean
 482   :group 'spam-spamassassin)
 483
 484 (defcustom spam-sa-learn-spam-switch "--spam"
 485   "The switch that sa-learn uses to register spam messages"
 486   :type 'string
 487   :group 'spam-spamassassin)
 488
 489 (defcustom spam-sa-learn-ham-switch "--ham"
 490   "The switch that sa-learn uses to register ham messages"
 491   :type 'string
 492   :group 'spam-spamassassin)
 493
 494 (defcustom spam-sa-learn-unregister-switch "--forget"
 495   "The switch that sa-learn uses to unregister messages messages"
 496   :type 'string
 497   :group 'spam-spamassassin)
 498
 499 ;;; Key bindings for spam control.
 500
 501 (gnus-define-keys gnus-summary-mode-map
 502   "St" spam-generic-score
 503   "Sx" gnus-summary-mark-as-spam
 504   "Mst" spam-generic-score
 505   "Msx" gnus-summary-mark-as-spam
 506   "\M-d" gnus-summary-mark-as-spam)
 507
 508 (defvar spam-cache-lookups t
 509   "Whether spam.el will try to cache lookups using `spam-caches'.")
 510
 511 (defvar spam-caches (make-hash-table
 512                      :size 10
 513                      :test 'equal)
 514   "Cache of spam detection entries.")
 515
 516 (defvar spam-old-ham-articles nil
 517   "List of old ham articles, generated when a group is entered.")
 518
 519 (defvar spam-old-spam-articles nil
 520   "List of old spam articles, generated when a group is entered.")
 521
 522 (defvar spam-split-disabled nil
 523   "If non-nil, `spam-split' is disabled, and always returns nil.")
 524
 525 (defvar spam-split-last-successful-check nil
 526   "Internal variable.
 527 `spam-split' will set this to nil or a spam-use-XYZ check if it
 528 finds ham or spam.")
 529
 530 ;; convenience functions
 531 (defun spam-clear-cache (symbol)
 532   "Clear the spam-caches entry for a check."
 533   (remhash symbol spam-caches))
 534
 535 (defun spam-xor (a b)
 536   "Logical A xor B."
 537   (and (or a b) (not (and a b))))
 538
 539 (defun spam-group-ham-mark-p (group mark &optional spam)
 540   "Checks if MARK is considered a ham mark in GROUP."
 541   (when (stringp group)
 542     (let* ((marks (spam-group-ham-marks group spam))
 543            (marks (if (symbolp mark)
 544                       marks
 545                     (mapcar 'symbol-value marks))))
 546       (memq mark marks))))
 547
 548 (defun spam-group-spam-mark-p (group mark)
 549   "Checks if MARK is considered a spam mark in GROUP."
 550   (spam-group-ham-mark-p group mark t))
 551
 552 (defun spam-group-ham-marks (group &optional spam)
 553   "In GROUP, get all the ham marks."
 554   (when (stringp group)
 555     (let* ((marks (if spam
 556                       (gnus-parameter-spam-marks group)
 557                     (gnus-parameter-ham-marks group)))
 558            (marks (car marks))
 559            (marks (if (listp (car marks)) (car marks) marks)))
 560       marks)))
 561
 562 (defun spam-group-spam-marks (group)
 563   "In GROUP, get all the spam marks."
 564   (spam-group-ham-marks group t))
 565
 566 (defun spam-group-spam-contents-p (group)
 567   "Is GROUP a spam group?"
 568   (if (stringp group)
 569       (or (member group spam-junk-mailgroups)
 570           (memq 'gnus-group-spam-classification-spam
 571                 (gnus-parameter-spam-contents group)))
 572     nil))
 573
 574 (defun spam-group-ham-contents-p (group)
 575   "Is GROUP a ham group?"
 576   (if (stringp group)
 577       (memq 'gnus-group-spam-classification-ham
 578             (gnus-parameter-spam-contents group))
 579     nil))
 580
 581 (defvar spam-list-of-processors
 582   '((gnus-group-spam-exit-processor-report-gmane spam spam-use-gmane)
 583     (gnus-group-spam-exit-processor-bogofilter   spam spam-use-bogofilter)
 584     (gnus-group-spam-exit-processor-blacklist    spam spam-use-blacklist)
 585     (gnus-group-spam-exit-processor-ifile        spam spam-use-ifile)
 586     (gnus-group-spam-exit-processor-stat         spam spam-use-stat)
 587     (gnus-group-spam-exit-processor-spamoracle   spam spam-use-spamoracle)
 588     (gnus-group-spam-exit-processor-spamassassin spam spam-use-spamassassin)
 589     (gnus-group-ham-exit-processor-ifile         ham spam-use-ifile)
 590     (gnus-group-ham-exit-processor-bogofilter    ham spam-use-bogofilter)
 591     (gnus-group-ham-exit-processor-stat          ham spam-use-stat)
 592     (gnus-group-ham-exit-processor-whitelist     ham spam-use-whitelist)
 593     (gnus-group-ham-exit-processor-BBDB          ham spam-use-BBDB)
 594     (gnus-group-ham-exit-processor-copy          ham spam-use-ham-copy)
 595     (gnus-group-ham-exit-processor-spamassassin  ham spam-use-spamassassin)
 596     (gnus-group-ham-exit-processor-spamoracle    ham spam-use-spamoracle))
 597   "The `spam-list-of-processors' list.
 598 This list contains pairs associating a ham/spam exit processor
 599 variable with a classification and a spam-use-* variable.")
 600
 601 (defun spam-group-processor-p (group processor)
 602   (if (and (stringp group)
 603            (symbolp processor))
 604       (or (member processor (nth 0 (gnus-parameter-spam-process group)))
 605           (spam-group-processor-multiple-p
 606            group
 607            (cdr-safe (assoc processor spam-list-of-processors))))
 608     nil))
 609
 610 (defun spam-group-processor-multiple-p (group processor-info)
 611   (let* ((classification (nth 0 processor-info))
 612          (check (nth 1 processor-info))
 613          (parameters (nth 0 (gnus-parameter-spam-process group)))
 614          found)
 615     (dolist (parameter parameters)
 616       (when (and (null found)
 617                  (listp parameter)
 618                  (eq classification (nth 0 parameter))
 619                  (eq check (nth 1 parameter)))
 620         (setq found t)))
 621     found))
 622
 623 (defun spam-group-spam-processor-report-gmane-p (group)
 624   (spam-group-processor-p group 'gnus-group-spam-exit-processor-report-gmane))
 625
 626 (defun spam-group-spam-processor-bogofilter-p (group)
 627   (spam-group-processor-p group 'gnus-group-spam-exit-processor-bogofilter))
 628
 629 (defun spam-group-spam-processor-blacklist-p (group)
 630   (spam-group-processor-p group 'gnus-group-spam-exit-processor-blacklist))
 631
 632 (defun spam-group-spam-processor-ifile-p (group)
 633   (spam-group-processor-p group 'gnus-group-spam-exit-processor-ifile))
 634
 635 (defun spam-group-ham-processor-ifile-p (group)
 636   (spam-group-processor-p group 'gnus-group-ham-exit-processor-ifile))
 637
 638 (defun spam-group-spam-processor-spamoracle-p (group)
 639   (spam-group-processor-p group 'gnus-group-spam-exit-processor-spamoracle))
 640
 641 (defun spam-group-ham-processor-bogofilter-p (group)
 642   (spam-group-processor-p group 'gnus-group-ham-exit-processor-bogofilter))
 643
 644 (defun spam-group-spam-processor-stat-p (group)
 645   (spam-group-processor-p group 'gnus-group-spam-exit-processor-stat))
 646
 647 (defun spam-group-ham-processor-stat-p (group)
 648   (spam-group-processor-p group 'gnus-group-ham-exit-processor-stat))
 649
 650 (defun spam-group-ham-processor-whitelist-p (group)
 651   (spam-group-processor-p group 'gnus-group-ham-exit-processor-whitelist))
 652
 653 (defun spam-group-ham-processor-BBDB-p (group)
 654   (spam-group-processor-p group 'gnus-group-ham-exit-processor-BBDB))
 655
 656 (defun spam-group-ham-processor-copy-p (group)
 657   (spam-group-processor-p group 'gnus-group-ham-exit-processor-copy))
 658
 659 (defun spam-group-ham-processor-spamoracle-p (group)
 660   (spam-group-processor-p group 'gnus-group-ham-exit-processor-spamoracle))
 661
 662 (defun spam-report-articles-gmane (n)
 663   "Report the current message as spam.
 664 Respects the process/prefix convention."
 665   (interactive "P")
 666   (dolist (article (gnus-summary-work-articles n))
 667     (gnus-summary-remove-process-mark article)
 668     (spam-report-gmane article)))
 669
 670 (defun spam-generic-score ()
 671   (interactive)
 672   "Invoke whatever scoring method we can."
 673   (if (or
 674        spam-use-spamassassin
 675        spam-use-spamassassin-headers)
 676       (spam-spamassassin-score)
 677     (spam-bogofilter-score)))
 678
 679 ;;; Summary entry and exit processing.
 680
 681 (defun spam-summary-prepare ()
 682   (setq spam-old-ham-articles
 683         (spam-list-articles gnus-newsgroup-articles 'ham))
 684   (setq spam-old-spam-articles
 685         (spam-list-articles gnus-newsgroup-articles 'spam))
 686   (spam-mark-junk-as-spam-routine))
 687
 688 ;; The spam processors are invoked for any group, spam or ham or neither
 689 (defun spam-summary-prepare-exit ()
 690   (unless gnus-group-is-exiting-without-update-p
 691     (gnus-message 6 "Exiting summary buffer and applying spam rules")
 692
 693     ;; first of all, unregister any articles that are no longer ham or spam
 694     ;; we have to iterate over the processors, or else we'll be too slow
 695     (dolist (classification '(spam ham))
 696       (let* ((old-articles (if (eq classification 'spam)
 697                                spam-old-spam-articles
 698                              spam-old-ham-articles))
 699              (new-articles (spam-list-articles
 700                             gnus-newsgroup-articles
 701                             classification))
 702              (changed-articles (gnus-set-difference old-articles new-articles)))
 703         ;; now that we have the changed articles, we go through the processors
 704         (dolist (processor-param spam-list-of-processors)
 705           (let ((processor (nth 0 processor-param))
 706                 (processor-classification (nth 1 processor-param))
 707                 (check (nth 2 processor-param))
 708                 unregister-list)
 709             (dolist (article changed-articles)
 710               (let ((id (spam-fetch-field-message-id-fast article)))
 711                 (when (spam-log-unregistration-needed-p
 712                        id 'process classification check)
 713                   (push article unregister-list))))
 714             ;; call spam-register-routine with specific articles to unregister,
 715             ;; when there are articles to unregister and the check is enabled
 716             (when (and unregister-list (symbol-value check))
 717               (spam-register-routine classification check t unregister-list))))))
 718
 719     ;; find all the spam processors applicable to this group
 720     (dolist (processor-param spam-list-of-processors)
 721       (let ((processor (nth 0 processor-param))
 722             (classification (nth 1 processor-param))
 723             (check (nth 2 processor-param)))
 724         (when (and (eq 'spam classification)
 725                    (spam-group-processor-p gnus-newsgroup-name processor))
 726           (spam-register-routine classification check))))
 727
 728     (if spam-move-spam-nonspam-groups-only
 729         (when (not (spam-group-spam-contents-p gnus-newsgroup-name))
 730           (spam-mark-spam-as-expired-and-move-routine
 731            (gnus-parameter-spam-process-destination gnus-newsgroup-name)))
 732       (gnus-message 5 "Marking spam as expired and moving it to %s"
 733                     gnus-newsgroup-name)
 734       (spam-mark-spam-as-expired-and-move-routine
 735        (gnus-parameter-spam-process-destination gnus-newsgroup-name)))
 736
 737     ;; now we redo spam-mark-spam-as-expired-and-move-routine to only
 738     ;; expire spam, in case the above did not expire them
 739     (gnus-message 5 "Marking spam as expired without moving it")
 740     (spam-mark-spam-as-expired-and-move-routine nil)
 741
 742     (when (or (spam-group-ham-contents-p gnus-newsgroup-name)
 743               (and (spam-group-spam-contents-p gnus-newsgroup-name)
 744                    spam-process-ham-in-spam-groups)
 745               spam-process-ham-in-nonham-groups)
 746       ;; find all the ham processors applicable to this group
 747       (dolist (processor-param spam-list-of-processors)
 748         (let ((processor (nth 0 processor-param))
 749               (classification (nth 1 processor-param))
 750               (check (nth 2 processor-param)))
 751           (when (and (eq 'ham classification)
 752                      (spam-group-processor-p gnus-newsgroup-name processor))
 753             (spam-register-routine classification check)))))
 754
 755     (when (spam-group-ham-processor-copy-p gnus-newsgroup-name)
 756       (gnus-message 5 "Copying ham")
 757       (spam-ham-copy-routine
 758        (gnus-parameter-ham-process-destination gnus-newsgroup-name)))
 759
 760     ;; now move all ham articles out of spam groups
 761     (when (spam-group-spam-contents-p gnus-newsgroup-name)
 762       (gnus-message 5 "Moving ham messages from spam group")
 763       (spam-ham-move-routine
 764        (gnus-parameter-ham-process-destination gnus-newsgroup-name))))
 765
 766   (setq spam-old-ham-articles nil)
 767   (setq spam-old-spam-articles nil))
 768
 769 (defun spam-mark-junk-as-spam-routine ()
 770   ;; check the global list of group names spam-junk-mailgroups and the
 771   ;; group parameters
 772   (when (spam-group-spam-contents-p gnus-newsgroup-name)
 773     (gnus-message 5 "Marking %s articles as spam"
 774                   (if spam-mark-only-unseen-as-spam
 775                       "unseen"
 776                     "unread"))
 777     (let ((articles (if spam-mark-only-unseen-as-spam
 778                         gnus-newsgroup-unseen
 779                       gnus-newsgroup-unreads)))
 780       (dolist (article articles)
 781         (gnus-summary-mark-article article gnus-spam-mark)))))
 782
 783 (defun spam-mark-spam-as-expired-and-move-routine (&rest groups)
 784   (if (and (car-safe groups) (listp (car-safe groups)))
 785       (apply 'spam-mark-spam-as-expired-and-move-routine (car groups))
 786     (gnus-summary-kill-process-mark)
 787     (let ((articles gnus-newsgroup-articles)
 788           (backend-supports-deletions
 789            (gnus-check-backend-function
 790             'request-move-article gnus-newsgroup-name))
 791           article tomove deletep)
 792       (dolist (article articles)
 793         (when (eq (gnus-summary-article-mark article) gnus-spam-mark)
 794           (gnus-summary-mark-article article gnus-expirable-mark)
 795           (push article tomove)))
 796
 797       ;; now do the actual copies
 798       (dolist (group groups)
 799         (when (and tomove
 800                    (stringp group))
 801           (dolist (article tomove)
 802             (gnus-summary-set-process-mark article))
 803           (when tomove
 804             (if (or (not backend-supports-deletions)
 805                     (> (length groups) 1))
 806                 (progn
 807                   (gnus-summary-copy-article nil group)
 808                   (setq deletep t))
 809               (gnus-summary-move-article nil group)))))
 810
 811       ;; now delete the articles, if there was a copy done, and the
 812       ;; backend allows it
 813       (when (and deletep backend-supports-deletions)
 814         (dolist (article tomove)
 815           (gnus-summary-set-process-mark article))
 816         (when tomove
 817           (let ((gnus-novice-user nil)) ; don't ask me if I'm sure
 818             (gnus-summary-delete-article nil))))
 819
 820       (gnus-summary-yank-process-mark))))
 821
 822 (defun spam-ham-copy-or-move-routine (copy groups)
 823   (gnus-summary-kill-process-mark)
 824   (let ((todo (spam-list-articles gnus-newsgroup-articles 'ham))
 825         (backend-supports-deletions
 826          (gnus-check-backend-function
 827           'request-move-article gnus-newsgroup-name))
 828         (respool-method (gnus-find-method-for-group gnus-newsgroup-name))
 829         article mark todo deletep respool)
 830
 831     (when (member 'respool groups)
 832       (setq respool t)                  ; boolean for later
 833       (setq groups '("fake"))) ; when respooling, groups are dynamic so fake it
 834
 835     ;; now do the actual move
 836     (dolist (group groups)
 837       (when (and todo (stringp group))
 838         (dolist (article todo)
 839           (when spam-mark-ham-unread-before-move-from-spam-group
 840             (gnus-summary-mark-article article gnus-unread-mark))
 841           (gnus-summary-set-process-mark article))
 842
 843         (if respool                        ; respooling is with a "fake" group
 844             (let ((spam-split-disabled
 845                    (or spam-split-disabled
 846                        spam-disable-spam-split-during-ham-respool)))
 847               (gnus-summary-respool-article nil respool-method))
 848           (if (or (not backend-supports-deletions) ; else, we are not respooling
 849                   (> (length groups) 1))
 850               (progn                ; if copying, copy and set deletep
 851                 (gnus-summary-copy-article nil group)
 852                 (setq deletep t))
 853             (gnus-summary-move-article nil group))))) ; else move articles
 854
 855     ;; now delete the articles, unless a) copy is t, and there was a copy done
 856     ;;                                 b) a move was done to a single group
 857     ;;                                 c) backend-supports-deletions is nil
 858     (unless copy
 859       (when (and deletep backend-supports-deletions)
 860         (dolist (article todo)
 861           (gnus-summary-set-process-mark article))
 862         (when todo
 863           (let ((gnus-novice-user nil)) ; don't ask me if I'm sure
 864             (gnus-summary-delete-article nil))))))
 865
 866   (gnus-summary-yank-process-mark))
 867
 868 (defun spam-ham-copy-routine (&rest groups)
 869   (if (and (car-safe groups) (listp (car-safe groups)))
 870       (apply 'spam-ham-copy-routine (car groups))
 871     (spam-ham-copy-or-move-routine t groups)))
 872
 873 (defun spam-ham-move-routine (&rest groups)
 874   (if (and (car-safe groups) (listp (car-safe groups)))
 875       (apply 'spam-ham-move-routine (car groups))
 876     (spam-ham-copy-or-move-routine nil groups)))
 877
 878 (defun spam-get-article-as-string (article)
 879   (when (numberp article)
 880     (with-temp-buffer
 881       (gnus-request-article-this-buffer
 882        article
 883        gnus-newsgroup-name)
 884       (buffer-string))))
 885
 886 ;; disabled for now
 887 ;; (defun spam-get-article-as-filename (article)
 888 ;;   (let ((article-filename))
 889 ;;     (when (numberp article)
 890 ;;       (nnml-possibly-change-directory
 891 ;;        (gnus-group-real-name gnus-newsgroup-name))
 892 ;;       (setq article-filename (expand-file-name
 893 ;;                              (int-to-string article) nnml-current-directory)))
 894 ;;     (if (file-exists-p article-filename)
 895 ;;      article-filename
 896 ;;       nil)))
 897
 898 (defun spam-fetch-field-fast (article field &optional prepared-data-header)
 899   "Fetch a field quickly, using the internal gnus-data-list function"
 900   (when (numberp article)
 901     (let* ((data-header (or prepared-data-header
 902                             (spam-fetch-article-header article))))
 903       (if (arrayp data-header)
 904         (cond
 905          ((equal field 'from)
 906           (mail-header-from data-header))
 907          ((equal field 'message-id)
 908           (mail-header-message-id data-header))
 909          ((equal field 'subject)
 910           (mail-header-subject data-header))
 911          ((equal field 'references)
 912           (mail-header-references data-header))
 913          ((equal field 'date)
 914           (mail-header-date data-header))
 915          ((equal field 'xref)
 916           (mail-header-xref data-header))
 917          ((equal field 'extra)
 918           (mail-header-extra data-header))
 919          (t
 920           nil))
 921         (gnus-error 5 "Article %d has a nil data header" article)))))
 922
 923 (defun spam-fetch-field-from-fast (article &optional prepared-data-header)
 924   (spam-fetch-field-fast article 'from prepared-data-header))
 925
 926 (defun spam-fetch-field-subject-fast (article &optional prepared-data-header)
 927   (spam-fetch-field-fast article 'subject prepared-data-header))
 928
 929 (defun spam-fetch-field-message-id-fast (article &optional prepared-data-header)
 930   (spam-fetch-field-fast article 'message-id prepared-data-header))
 931
 932 (defun spam-generate-fake-headers (article)
 933   (let ((dh (spam-fetch-article-header article)))
 934     (if dh
 935         (concat
 936          (format
 937           (concat "From: %s\nSubject: %s\nMessage-ID: %s\n"
 938                   "Date: %s\nReferences: %s\nXref: %s\n")
 939           (spam-fetch-field-fast article 'from dh)
 940           (spam-fetch-field-fast article 'subject dh)
 941           (spam-fetch-field-fast article 'message-id dh)
 942           (spam-fetch-field-fast article 'date dh)
 943           (spam-fetch-field-fast article 'references dh)
 944           (spam-fetch-field-fast article 'xref dh))
 945          (when (spam-fetch-field-fast article 'extra dh)
 946            (format "%s\n" (spam-fetch-field-fast article 'extra dh))))
 947       (gnus-error
 948        5
 949        "spam-generate-fake-headers: article %d didn't have a valid header"
 950        article))))
 951
 952 (defun spam-fetch-article-header (article)
 953   (save-excursion
 954     (set-buffer gnus-summary-buffer)
 955     (nth 3 (assq article gnus-newsgroup-data))))
 956
 957 \f
 958 ;;;; Spam determination.
 959
 960 (defvar spam-list-of-checks
 961   '((spam-use-blacklist                 .       spam-check-blacklist)
 962     (spam-use-regex-headers             .       spam-check-regex-headers)
 963     (spam-use-regex-body                .       spam-check-regex-body)
 964     (spam-use-whitelist                 .       spam-check-whitelist)
 965     (spam-use-BBDB                      .       spam-check-BBDB)
 966     (spam-use-BBDB-exclusive            .       spam-check-BBDB)
 967     (spam-use-ifile                     .       spam-check-ifile)
 968     (spam-use-spamoracle                .       spam-check-spamoracle)
 969     (spam-use-stat                      .       spam-check-stat)
 970     (spam-use-blackholes                .       spam-check-blackholes)
 971     (spam-use-hashcash                  .       spam-check-hashcash)
 972     (spam-use-spamassassin-headers      .       spam-check-spamassassin-headers)
 973     (spam-use-spamassassin              .       spam-check-spamassassin)
 974     (spam-use-bogofilter-headers        .       spam-check-bogofilter-headers)
 975     (spam-use-bogofilter                .       spam-check-bogofilter))
 976   "The spam-list-of-checks list contains pairs associating a
 977 parameter variable with a spam checking function.  If the
 978 parameter variable is true, then the checking function is called,
 979 and its value decides what happens.  Each individual check may
 980 return nil, t, or a mailgroup name.  The value nil means that the
 981 check does not yield a decision, and so, that further checks are
 982 needed.  The value t means that the message is definitely not
 983 spam, and that further spam checks should be inhibited.
 984 Otherwise, a mailgroup name or the symbol 'spam (depending on
 985 spam-split-symbolic-return) is returned where the mail should go,
 986 and further checks are also inhibited.  The usual mailgroup name
 987 is the value of `spam-split-group', meaning that the message is
 988 definitely a spam.")
 989
 990 (defvar spam-list-of-statistical-checks
 991   '(spam-use-ifile
 992     spam-use-regex-body
 993     spam-use-stat
 994     spam-use-bogofilter
 995     spam-use-blackholes
 996     spam-use-spamassassin
 997     spam-use-spamoracle)
 998   "The spam-list-of-statistical-checks list contains all the mail
 999 splitters that need to have the full message body available.
1000 Note that you should fetch extra headers if you don't like this,
1001 e.g. fetch the 'Received' header for spam-use-blackholes.")
1002
1003 (defun spam-split (&rest specific-checks)
1004   "Split this message into the `spam' group if it is spam.
1005 This function can be used as an entry in the variable `nnmail-split-fancy',
1006 for example like this: (: spam-split).  It can take checks as
1007 parameters.  A string as a parameter will set the
1008 spam-split-group to that string.
1009
1010 See the Info node `(gnus)Fancy Mail Splitting' for more details."
1011   (interactive)
1012   (setq spam-split-last-successful-check nil)
1013   (unless spam-split-disabled
1014     (let ((spam-split-group-choice spam-split-group))
1015       (dolist (check specific-checks)
1016         (when (stringp check)
1017           (setq spam-split-group-choice check)
1018           (setq specific-checks (delq check specific-checks))))
1019
1020       (let ((spam-split-group spam-split-group-choice))
1021         (save-excursion
1022           (save-restriction
1023             (dolist (check spam-list-of-statistical-checks)
1024               (when (and (symbolp check)
1025                          (or (symbol-value check)
1026                              (memq check specific-checks)))
1027                 (widen)
1028                 (gnus-message 8 "spam-split: widening the buffer (%s requires it)"
1029                               (symbol-name check))
1030                 (return)))
1031             ;;   (progn (widen) (debug (buffer-string)))
1032             (let ((list-of-checks spam-list-of-checks)
1033                   decision)
1034               (while (and list-of-checks (not decision))
1035                 (let ((pair (pop list-of-checks)))
1036                   (when (or
1037                          ;; either, given specific checks, this is one of them
1038                          (and specific-checks (memq (car pair) specific-checks))
1039                          ;; or, given no specific checks, spam-use-CHECK is set
1040                          (and (null specific-checks) (symbol-value (car pair))))
1041                     (gnus-message 5 "spam-split: calling the %s function"
1042                                   (symbol-name (cdr pair)))
1043                     (setq decision (funcall (cdr pair)))
1044                     ;; if we got a decision at all, save the current check
1045                     (when decision
1046                       (setq spam-split-last-successful-check (car pair)))
1047
1048                     (when (eq decision 'spam)
1049                       (unless spam-split-symbolic-return
1050                         (gnus-error
1051                          5
1052                          (format "spam-split got %s but %s is nil"
1053                                  (symbol-name decision)
1054                                  (symbol-name spam-split-symbolic-return))))))))
1055               (if (eq decision t)
1056                   (if spam-split-symbolic-return-positive 'ham nil)
1057                 decision))))))))
1058
1059 (defun spam-find-spam ()
1060   "This function will detect spam in the current newsgroup using spam-split."
1061   (interactive)
1062
1063   (let* ((group gnus-newsgroup-name)
1064          (autodetect (gnus-parameter-spam-autodetect group))
1065          (methods (gnus-parameter-spam-autodetect-methods group))
1066          (first-method (nth 0 methods))
1067          (articles (if spam-autodetect-recheck-messages
1068                        gnus-newsgroup-articles
1069                      gnus-newsgroup-unseen))
1070          article-cannot-be-faked)
1071
1072     (dolist (check spam-list-of-statistical-checks)
1073       (when (and (symbolp check)
1074                  (memq check methods))
1075         (setq article-cannot-be-faked t)
1076         (return)))
1077
1078     (when (memq 'default methods)
1079       (setq article-cannot-be-faked t))
1080
1081     (when (and autodetect
1082                (not (equal first-method 'none)))
1083     (mapcar
1084      (lambda (article)
1085        (let ((id (spam-fetch-field-message-id-fast article))
1086              (subject (spam-fetch-field-subject-fast article))
1087              (sender (spam-fetch-field-from-fast article))
1088              registry-lookup)
1089
1090          (unless id
1091            (gnus-error 5 "Article %d has no message ID!" article))
1092
1093          (when (and id spam-log-to-registry)
1094            (setq registry-lookup (spam-log-registration-type id 'incoming))
1095            (when registry-lookup
1096              (gnus-message
1097               9
1098               "spam-find-spam: message %s was already registered incoming"
1099               id)))
1100
1101          (let* ((spam-split-symbolic-return t)
1102                 (spam-split-symbolic-return-positive t)
1103                 (fake-headers (spam-generate-fake-headers article))
1104                 (split-return
1105                  (or registry-lookup
1106                      (with-temp-buffer
1107                        (if article-cannot-be-faked
1108                            (gnus-request-article-this-buffer
1109                             article
1110                             group)
1111                          ;; else, we fake the article
1112                          (when fake-headers (insert fake-headers)))
1113                        (if (or (null first-method)
1114                                (equal first-method 'default))
1115                            (spam-split)
1116                          (apply 'spam-split methods))))))
1117            (if (equal split-return 'spam)
1118                (gnus-summary-mark-article article gnus-spam-mark))
1119
1120            (when (and id split-return spam-log-to-registry)
1121              (when (zerop (gnus-registry-group-count id))
1122                (gnus-registry-add-group
1123                 id group subject sender))
1124
1125              (unless registry-lookup
1126                (spam-log-processing-to-registry
1127                 id
1128                 'incoming
1129                 split-return
1130                 spam-split-last-successful-check
1131                 group))))))
1132     articles))))
1133
1134 (defvar spam-registration-functions
1135   ;; first the ham register, second the spam register function
1136   ;; third the ham unregister, fourth the spam unregister function
1137   '((spam-use-blacklist  nil
1138                          spam-blacklist-register-routine
1139                          nil
1140                          spam-blacklist-unregister-routine)
1141     (spam-use-whitelist  spam-whitelist-register-routine
1142                          nil
1143                          spam-whitelist-unregister-routine
1144                          nil)
1145     (spam-use-BBDB       spam-BBDB-register-routine
1146                          nil
1147                          spam-BBDB-unregister-routine
1148                          nil)
1149     (spam-use-ifile      spam-ifile-register-ham-routine
1150                          spam-ifile-register-spam-routine
1151                          spam-ifile-unregister-ham-routine
1152                          spam-ifile-unregister-spam-routine)
1153     (spam-use-spamoracle spam-spamoracle-learn-ham
1154                          spam-spamoracle-learn-spam
1155                          spam-spamoracle-unlearn-ham
1156                          spam-spamoracle-unlearn-spam)
1157     (spam-use-stat       spam-stat-register-ham-routine
1158                          spam-stat-register-spam-routine
1159                          spam-stat-unregister-ham-routine
1160                          spam-stat-unregister-spam-routine)
1161     ;; note that spam-use-gmane is not a legitimate check
1162     (spam-use-gmane      nil
1163                          spam-report-gmane-register-routine
1164                          ;; does Gmane support unregistration?
1165                          nil
1166                          nil)
1167     (spam-use-spamassassin spam-spamassassin-register-ham-routine
1168                            spam-spamassassin-register-spam-routine
1169                            spam-spamassassin-unregister-ham-routine
1170                            spam-spamassassin-unregister-spam-routine)
1171     (spam-use-bogofilter spam-bogofilter-register-ham-routine
1172                          spam-bogofilter-register-spam-routine
1173                          spam-bogofilter-unregister-ham-routine
1174                          spam-bogofilter-unregister-spam-routine))
1175   "The spam-registration-functions list contains pairs
1176 associating a parameter variable with the ham and spam
1177 registration functions, and the ham and spam unregistration
1178 functions")
1179
1180 (defun spam-classification-valid-p (classification)
1181   (or  (eq classification 'spam)
1182        (eq classification 'ham)))
1183
1184 (defun spam-process-type-valid-p (process-type)
1185   (or  (eq process-type 'incoming)
1186        (eq process-type 'process)))
1187
1188 (defun spam-registration-check-valid-p (check)
1189   (assoc check spam-registration-functions))
1190
1191 (defun spam-unregistration-check-valid-p (check)
1192   (assoc check spam-registration-functions))
1193
1194 (defun spam-registration-function (classification check)
1195   (let ((flist (cdr-safe (assoc check spam-registration-functions))))
1196     (if (eq classification 'spam)
1197         (nth 1 flist)
1198       (nth 0 flist))))
1199
1200 (defun spam-unregistration-function (classification check)
1201   (let ((flist (cdr-safe (assoc check spam-registration-functions))))
1202     (if (eq classification 'spam)
1203         (nth 3 flist)
1204       (nth 2 flist))))
1205
1206 (defun spam-list-articles (articles classification)
1207   (let ((mark-check (if (eq classification 'spam)
1208                         'spam-group-spam-mark-p
1209                       'spam-group-ham-mark-p))
1210         list mark-cache-yes mark-cache-no)
1211     (dolist (article articles)
1212       (let ((mark (gnus-summary-article-mark article)))
1213         (unless (memq mark mark-cache-no)
1214           (if (memq mark mark-cache-yes)
1215               (push article list)
1216             ;; else, we have to actually check the mark
1217             (if (funcall mark-check
1218                          gnus-newsgroup-name
1219                          mark)
1220                 (progn
1221                   (push article list)
1222                   (push mark mark-cache-yes))
1223               (push mark mark-cache-no))))))
1224     list))
1225
1226 (defun spam-register-routine (classification
1227                               check
1228                               &optional unregister
1229                               specific-articles)
1230   (when (and (spam-classification-valid-p classification)
1231              (spam-registration-check-valid-p check))
1232     (let* ((register-function
1233             (spam-registration-function classification check))
1234            (unregister-function
1235             (spam-unregistration-function classification check))
1236            (run-function (if unregister
1237                              unregister-function
1238                            register-function))
1239            (log-function (if unregister
1240                              'spam-log-undo-registration
1241                            'spam-log-processing-to-registry))
1242            article articles)
1243
1244       (when run-function
1245         ;; make list of articles, using specific-articles if given
1246         (setq articles (or specific-articles
1247                            (spam-list-articles
1248                             gnus-newsgroup-articles
1249                             classification)))
1250         ;; process them
1251         (gnus-message 5 "%s %d %s articles: classification %s, spam-check %s"
1252                       (if unregister "Unregistering" "Registering")
1253                       (length articles)
1254                       (if specific-articles "specific" "")
1255                       (symbol-name classification)
1256                       (symbol-name check))
1257         (funcall run-function articles)
1258         ;; now log all the registrations (or undo them, depending on unregister)
1259         (dolist (article articles)
1260           (funcall log-function
1261                    (spam-fetch-field-message-id-fast article)
1262                    'process
1263                    classification
1264                    check
1265                    gnus-newsgroup-name))))))
1266
1267 ;;; log a ham- or spam-processor invocation to the registry
1268 (defun spam-log-processing-to-registry (id type classification check group)
1269   (when spam-log-to-registry
1270     (if (and (stringp id)
1271              (stringp group)
1272              (spam-process-type-valid-p type)
1273              (spam-classification-valid-p classification)
1274              (spam-registration-check-valid-p check))
1275         (let ((cell-list (cdr-safe (gnus-registry-fetch-extra id type)))
1276               (cell (list classification check group)))
1277           (push cell cell-list)
1278           (gnus-registry-store-extra-entry
1279            id
1280            type
1281            cell-list))
1282
1283       (gnus-error
1284        5
1285        (format "%s call with bad ID, type, classification, spam-check, or group"
1286                "spam-log-processing-to-registry")))))
1287
1288 ;;; check if a ham- or spam-processor registration has been done
1289 (defun spam-log-registered-p (id type)
1290   (when spam-log-to-registry
1291     (if (and (stringp id)
1292              (spam-process-type-valid-p type))
1293         (cdr-safe (gnus-registry-fetch-extra id type))
1294       (progn
1295         (gnus-error
1296          5
1297          (format "%s called with bad ID, type, classification, or spam-check"
1298                  "spam-log-registered-p"))
1299         nil))))
1300
1301 ;;; check what a ham- or spam-processor registration says
1302 ;;; returns nil if conflicting registrations are found
1303 (defun spam-log-registration-type (id type)
1304   (let ((count 0)
1305         decision)
1306     (dolist (reg (spam-log-registered-p id type))
1307       (let ((classification (nth 0 reg)))
1308         (when (spam-classification-valid-p classification)
1309           (when (and decision
1310                      (not (eq classification decision)))
1311             (setq count (+ 1 count)))
1312           (setq decision classification))))
1313     (if (< 0 count)
1314         nil
1315       decision)))
1316
1317 ;;; check if a ham- or spam-processor registration needs to be undone
1318 (defun spam-log-unregistration-needed-p (id type classification check)
1319   (when spam-log-to-registry
1320     (if (and (stringp id)
1321              (spam-process-type-valid-p type)
1322              (spam-classification-valid-p classification)
1323              (spam-registration-check-valid-p check))
1324         (let ((cell-list (cdr-safe (gnus-registry-fetch-extra id type)))
1325               found)
1326           (dolist (cell cell-list)
1327             (unless found
1328               (when (and (eq classification (nth 0 cell))
1329                          (eq check (nth 1 cell)))
1330                 (setq found t))))
1331           found)
1332       (progn
1333         (gnus-error
1334          5
1335          (format "%s called with bad ID, type, classification, or spam-check"
1336                  "spam-log-unregistration-needed-p"))
1337         nil))))
1338
1339
1340 ;;; undo a ham- or spam-processor registration (the group is not used)
1341 (defun spam-log-undo-registration (id type classification check &optional group)
1342   (when (and spam-log-to-registry
1343              (spam-log-unregistration-needed-p id type classification check))
1344     (if (and (stringp id)
1345              (spam-process-type-valid-p type)
1346              (spam-classification-valid-p classification)
1347              (spam-registration-check-valid-p check))
1348         (let ((cell-list (cdr-safe (gnus-registry-fetch-extra id type)))
1349               new-cell-list found)
1350           (dolist (cell cell-list)
1351             (unless (and (eq classification (nth 0 cell))
1352                          (eq check (nth 1 cell)))
1353               (push cell new-cell-list)))
1354           (gnus-registry-store-extra-entry
1355            id
1356            type
1357            new-cell-list))
1358       (progn
1359         (gnus-error 5 (format "%s call with bad ID, type, spam-check, or group"
1360                               "spam-log-undo-registration"))
1361         nil))))
1362
1363 ;;; set up IMAP widening if it's necessary
1364 (defun spam-setup-widening ()
1365   (dolist (check spam-list-of-statistical-checks)
1366     (when (symbol-value check)
1367       (setq nnimap-split-download-body-default t))))
1368
1369 \f
1370 ;;;; Regex body
1371
1372 (defun spam-check-regex-body ()
1373   (let ((spam-regex-headers-ham spam-regex-body-ham)
1374         (spam-regex-headers-spam spam-regex-body-spam))
1375     (spam-check-regex-headers t)))
1376
1377 \f
1378 ;;;; Regex headers
1379
1380 (defun spam-check-regex-headers (&optional body)
1381   (let ((type (if body "body" "header"))
1382         (spam-split-group (if spam-split-symbolic-return
1383                               'spam
1384                             spam-split-group))
1385         ret found)
1386     (dolist (h-regex spam-regex-headers-ham)
1387       (unless found
1388         (goto-char (point-min))
1389         (when (re-search-forward h-regex nil t)
1390           (message "Ham regex %s search positive." type)
1391           (setq found t))))
1392     (dolist (s-regex spam-regex-headers-spam)
1393       (unless found
1394         (goto-char (point-min))
1395         (when (re-search-forward s-regex nil t)
1396           (message "Spam regex %s search positive." type)
1397           (setq found t)
1398           (setq ret spam-split-group))))
1399     ret))
1400
1401 \f
1402 ;;;; Blackholes.
1403
1404 (defun spam-reverse-ip-string (ip)
1405   (when (stringp ip)
1406     (mapconcat 'identity
1407                (nreverse (split-string ip "\\."))
1408                ".")))
1409
1410 (defun spam-check-blackholes ()
1411   "Check the Received headers for blackholed relays."
1412   (let ((headers (message-fetch-field "received"))
1413         (spam-split-group (if spam-split-symbolic-return
1414                               'spam
1415                             spam-split-group))
1416         ips matches)
1417     (when headers
1418       (with-temp-buffer
1419         (insert headers)
1420         (goto-char (point-min))
1421         (gnus-message 5 "Checking headers for relay addresses")
1422         (while (re-search-forward
1423                 "\\([0-9]+\\.[0-9]+\\.[0-9]+\\.[0-9]+\\)" nil t)
1424           (gnus-message 9 "Blackhole search found host IP %s." (match-string 1))
1425           (push (spam-reverse-ip-string (match-string 1))
1426                 ips)))
1427       (dolist (server spam-blackhole-servers)
1428         (dolist (ip ips)
1429           (unless (and spam-blackhole-good-server-regex
1430                        ;; match the good-server-regex against the reversed (again) IP string
1431                        (string-match
1432                         spam-blackhole-good-server-regex
1433                         (spam-reverse-ip-string ip)))
1434             (unless matches
1435               (let ((query-string (concat ip "." server)))
1436                 (if spam-use-dig
1437                     (let ((query-result (query-dig query-string)))
1438                       (when query-result
1439                         (gnus-message 5 "(DIG): positive blackhole check '%s'"
1440                                       query-result)
1441                         (push (list ip server query-result)
1442                               matches)))
1443                   ;; else, if not using dig.el
1444                   (when (query-dns query-string)
1445                     (gnus-message 5 "positive blackhole check")
1446                     (push (list ip server (query-dns query-string 'TXT))
1447                           matches)))))))))
1448     (when matches
1449       spam-split-group)))
1450 \f
1451 ;;;; Hashcash.
1452
1453 (condition-case nil
1454     (progn
1455       (require 'hashcash)
1456
1457       (defun spam-check-hashcash ()
1458         "Check the headers for hashcash payments."
1459         (mail-check-payment)))   ;mail-check-payment returns a boolean
1460
1461   (file-error (progn
1462                 (defalias 'mail-check-payment 'ignore)
1463                 (defalias 'spam-check-hashcash 'ignore))))
1464 \f
1465 ;;;; BBDB
1466
1467 ;;; original idea for spam-check-BBDB from Alexander Kotelnikov
1468 ;;; <sacha@giotto.sj.ru>
1469
1470 ;; all this is done inside a condition-case to trap errors
1471
1472 (condition-case nil
1473     (progn
1474       (require 'bbdb)
1475       (require 'bbdb-com)
1476
1477       ;; when the BBDB changes, we want to clear out our cache
1478       (defun spam-clear-cache-BBDB (&rest immaterial)
1479         (spam-clear-cache 'spam-use-BBDB))
1480
1481       (add-hook 'bbdb-change-hook 'spam-clear-cache-BBDB)
1482
1483       (defun spam-enter-ham-BBDB (addresses &optional remove)
1484         "Enter an address into the BBDB; implies ham (non-spam) sender"
1485         (dolist (from addresses)
1486           (when (stringp from)
1487             (let* ((parsed-address (gnus-extract-address-components from))
1488                    (name (or (nth 0 parsed-address) "Ham Sender"))
1489                    (remove-function (if remove
1490                                         'bbdb-delete-record-internal
1491                                       'ignore))
1492                    (net-address (nth 1 parsed-address))
1493                    (record (and net-address
1494                                 (bbdb-search-simple nil net-address))))
1495               (when net-address
1496                 (gnus-message 5 "%s address %s %s BBDB"
1497                               (if remove "Deleting" "Adding")
1498                               from
1499                               (if remove "from" "to"))
1500                 (if record
1501                     (funcall remove-function record)
1502                   (bbdb-create-internal name nil net-address nil nil
1503                                         "ham sender added by spam.el")))))))
1504
1505       (defun spam-BBDB-register-routine (articles &optional unregister)
1506         (let (addresses)
1507           (dolist (article articles)
1508             (when (stringp (spam-fetch-field-from-fast article))
1509               (push (spam-fetch-field-from-fast article) addresses)))
1510           ;; now do the register/unregister action
1511           (spam-enter-ham-BBDB addresses unregister)))
1512
1513       (defun spam-BBDB-unregister-routine (articles)
1514         (spam-BBDB-register-routine articles t))
1515
1516       (defun spam-check-BBDB ()
1517         "Mail from people in the BBDB is classified as ham or non-spam"
1518         (let ((who (message-fetch-field "from"))
1519               (spam-split-group (if spam-split-symbolic-return
1520                                     'spam
1521                                   spam-split-group))
1522               bbdb-cache bbdb-hashtable)
1523           (when spam-cache-lookups
1524             (setq bbdb-cache (gethash 'spam-use-BBDB spam-caches))
1525             (unless bbdb-cache
1526               (setq bbdb-cache
1527                     ;; this is the expanded (bbdb-hashtable) macro
1528                     ;; without the debugging support
1529                     (with-current-buffer (bbdb-buffer)
1530                       (save-excursion
1531                         (save-window-excursion
1532                           (bbdb-records nil t)
1533                           bbdb-hashtable))))
1534               (puthash 'spam-use-BBDB bbdb-cache spam-caches)))
1535           (when who
1536             (setq who (nth 1 (gnus-extract-address-components who)))
1537             (if
1538                 (if spam-cache-lookups
1539                     (symbol-value
1540                      (intern-soft who bbdb-cache))
1541                   (bbdb-search-simple nil who))
1542                 t
1543               (if spam-use-BBDB-exclusive
1544                   spam-split-group
1545                 nil))))))
1546
1547   (file-error (progn
1548                 (defalias 'bbdb-search-simple 'ignore)
1549                 (defalias 'bbdb-records 'ignore)
1550                 (defalias 'bbdb-buffer 'ignore)
1551                 (defalias 'spam-check-BBDB 'ignore)
1552                 (defalias 'spam-BBDB-register-routine 'ignore)
1553                 (defalias 'spam-enter-ham-BBDB 'ignore)
1554                 (defalias 'bbdb-create-internal 'ignore)
1555                 (defalias 'bbdb-delete-record-internal 'ignore)
1556                 (defalias 'bbdb-records 'ignore))))
1557
1558 \f
1559 ;;;; ifile
1560
1561 ;;; check the ifile backend; return nil if the mail was NOT classified
1562 ;;; as spam
1563
1564 (defun spam-get-ifile-database-parameter ()
1565   "Get the command-line parameter for ifile's database from
1566   spam-ifile-database-path."
1567   (if spam-ifile-database-path
1568       (format "--db-file=%s" spam-ifile-database-path)
1569     nil))
1570
1571 (defun spam-check-ifile ()
1572   "Check the ifile backend for the classification of this message."
1573   (let ((article-buffer-name (buffer-name))
1574         (spam-split-group (if spam-split-symbolic-return
1575                               'spam
1576                             spam-split-group))
1577         category return)
1578     (with-temp-buffer
1579       (let ((temp-buffer-name (buffer-name))
1580             (db-param (spam-get-ifile-database-parameter)))
1581         (save-excursion
1582           (set-buffer article-buffer-name)
1583           (apply 'call-process-region
1584                  (point-min) (point-max) spam-ifile-path
1585                  nil temp-buffer-name nil "-c"
1586                  (if db-param `(,db-param "-q") `("-q"))))
1587         ;; check the return now (we're back in the temp buffer)
1588         (goto-char (point-min))
1589         (if (not (eobp))
1590             (setq category (buffer-substring (point) (point-at-eol))))
1591         (when (not (zerop (length category))) ; we need a category here
1592           (if spam-ifile-all-categories
1593               (setq return category)
1594             ;; else, if spam-ifile-all-categories is not set...
1595             (when (string-equal spam-ifile-spam-category category)
1596               (setq return spam-split-group)))))) ; note return is nil otherwise
1597     return))
1598
1599 (defun spam-ifile-register-with-ifile (articles category &optional unregister)
1600   "Register an article, given as a string, with a category.
1601 Uses `gnus-newsgroup-name' if category is nil (for ham registration)."
1602   (let ((category (or category gnus-newsgroup-name))
1603         (add-or-delete-option (if unregister "-d" "-i"))
1604         (db (spam-get-ifile-database-parameter))
1605         parameters)
1606     (with-temp-buffer
1607       (dolist (article articles)
1608         (let ((article-string (spam-get-article-as-string article)))
1609           (when (stringp article-string)
1610             (insert article-string))))
1611       (apply 'call-process-region
1612              (point-min) (point-max) spam-ifile-path
1613              nil nil nil
1614              add-or-delete-option category
1615              (if db `(,db "-h") `("-h"))))))
1616
1617 (defun spam-ifile-register-spam-routine (articles &optional unregister)
1618   (spam-ifile-register-with-ifile articles spam-ifile-spam-category unregister))
1619
1620 (defun spam-ifile-unregister-spam-routine (articles)
1621   (spam-ifile-register-spam-routine articles t))
1622
1623 (defun spam-ifile-register-ham-routine (articles &optional unregister)
1624   (spam-ifile-register-with-ifile articles spam-ifile-ham-category unregister))
1625
1626 (defun spam-ifile-unregister-ham-routine (articles)
1627   (spam-ifile-register-ham-routine articles t))
1628
1629 \f
1630 ;;;; spam-stat
1631
1632 (condition-case nil
1633     (progn
1634       (let ((spam-stat-install-hooks nil))
1635         (require 'spam-stat))
1636
1637       (defun spam-check-stat ()
1638         "Check the spam-stat backend for the classification of this message"
1639         (let ((spam-split-group (if spam-split-symbolic-return
1640                                     'spam
1641                                   spam-split-group))
1642               (spam-stat-split-fancy-spam-group spam-split-group) ; override
1643               (spam-stat-buffer (buffer-name)) ; stat the current buffer
1644               category return)
1645           (spam-stat-split-fancy)))
1646
1647       (defun spam-stat-register-spam-routine (articles &optional unregister)
1648         (dolist (article articles)
1649           (let ((article-string (spam-get-article-as-string article)))
1650             (with-temp-buffer
1651               (insert article-string)
1652               (if unregister
1653                   (spam-stat-buffer-change-to-non-spam)
1654               (spam-stat-buffer-is-spam))))))
1655
1656       (defun spam-stat-unregister-spam-routine (articles)
1657         (spam-stat-register-spam-routine articles t))
1658
1659       (defun spam-stat-register-ham-routine (articles &optional unregister)
1660         (dolist (article articles)
1661           (let ((article-string (spam-get-article-as-string article)))
1662             (with-temp-buffer
1663               (insert article-string)
1664               (if unregister
1665                   (spam-stat-buffer-change-to-spam)
1666               (spam-stat-buffer-is-non-spam))))))
1667
1668       (defun spam-stat-unregister-ham-routine (articles)
1669         (spam-stat-register-ham-routine articles t))
1670
1671       (defun spam-maybe-spam-stat-load ()
1672         (when spam-use-stat (spam-stat-load)))
1673
1674       (defun spam-maybe-spam-stat-save ()
1675         (when spam-use-stat (spam-stat-save))))
1676
1677   (file-error (progn
1678                 (defalias 'spam-stat-load 'ignore)
1679                 (defalias 'spam-stat-save 'ignore)
1680                 (defalias 'spam-maybe-spam-stat-load 'ignore)
1681                 (defalias 'spam-maybe-spam-stat-save 'ignore)
1682                 (defalias 'spam-stat-register-ham-routine 'ignore)
1683                 (defalias 'spam-stat-unregister-ham-routine 'ignore)
1684                 (defalias 'spam-stat-register-spam-routine 'ignore)
1685                 (defalias 'spam-stat-unregister-spam-routine 'ignore)
1686                 (defalias 'spam-stat-buffer-is-spam 'ignore)
1687                 (defalias 'spam-stat-buffer-change-to-spam 'ignore)
1688                 (defalias 'spam-stat-buffer-is-non-spam 'ignore)
1689                 (defalias 'spam-stat-buffer-change-to-non-spam 'ignore)
1690                 (defalias 'spam-stat-split-fancy 'ignore)
1691                 (defalias 'spam-check-stat 'ignore))))
1692
1693 \f
1694
1695 ;;;; Blacklists and whitelists.
1696
1697 (defvar spam-whitelist-cache nil)
1698 (defvar spam-blacklist-cache nil)
1699
1700 (defun spam-kill-whole-line ()
1701   (beginning-of-line)
1702   (let ((kill-whole-line t))
1703     (kill-line)))
1704
1705 ;;; address can be a list, too
1706 (defun spam-enter-whitelist (address &optional remove)
1707   "Enter ADDRESS (list or single) into the whitelist.
1708 With a non-nil REMOVE, remove them."
1709   (interactive "sAddress: ")
1710   (spam-enter-list address spam-whitelist remove)
1711   (setq spam-whitelist-cache nil)
1712   (spam-clear-cache 'spam-use-whitelist))
1713
1714 ;;; address can be a list, too
1715 (defun spam-enter-blacklist (address &optional remove)
1716   "Enter ADDRESS (list or single) into the blacklist.
1717 With a non-nil REMOVE, remove them."
1718   (interactive "sAddress: ")
1719   (spam-enter-list address spam-blacklist remove)
1720   (setq spam-blacklist-cache nil)
1721   (spam-clear-cache 'spam-use-whitelist))
1722
1723 (defun spam-enter-list (addresses file &optional remove)
1724   "Enter ADDRESSES into the given FILE.
1725 Either the whitelist or the blacklist files can be used.  With
1726 REMOVE not nil, remove the ADDRESSES."
1727   (if (stringp addresses)
1728       (spam-enter-list (list addresses) file remove)
1729     ;; else, we have a list of addresses here
1730     (unless (file-exists-p (file-name-directory file))
1731       (make-directory (file-name-directory file) t))
1732     (save-excursion
1733       (set-buffer
1734        (find-file-noselect file))
1735       (dolist (a addresses)
1736         (when (stringp a)
1737           (goto-char (point-min))
1738           (if (re-search-forward (regexp-quote a) nil t)
1739               ;; found the address
1740               (when remove
1741                 (spam-kill-whole-line))
1742             ;; else, the address was not found
1743             (unless remove
1744               (goto-char (point-max))
1745               (unless (bobp)
1746                 (insert "\n"))
1747               (insert a "\n")))))
1748       (save-buffer))))
1749
1750 (defun spam-filelist-build-cache (type)
1751   (let ((cache (if (eq type 'spam-use-blacklist)
1752                    spam-blacklist-cache
1753                  spam-whitelist-cache))
1754         parsed-cache)
1755     (unless (gethash type spam-caches)
1756       (while cache
1757         (let ((address (pop cache)))
1758           (unless (zerop (length address)) ; 0 for a nil address too
1759             (setq address (regexp-quote address))
1760             ;; fix regexp-quote's treatment of user-intended regexes
1761             (while (string-match "\\\\\\*" address)
1762               (setq address (replace-match ".*" t t address))))
1763           (push address parsed-cache)))
1764       (puthash type parsed-cache spam-caches))))
1765
1766 (defun spam-filelist-check-cache (type from)
1767   (when (stringp from)
1768     (spam-filelist-build-cache type)
1769     (let (found)
1770       (dolist (address (gethash type spam-caches))
1771         (when (and address (string-match address from))
1772           (setq found t)
1773           (return)))
1774       found)))
1775
1776 ;;; returns t if the sender is in the whitelist, nil or
1777 ;;; spam-split-group otherwise
1778 (defun spam-check-whitelist ()
1779   ;; FIXME!  Should it detect when file timestamps change?
1780   (let ((spam-split-group (if spam-split-symbolic-return
1781                               'spam
1782                             spam-split-group)))
1783     (unless spam-whitelist-cache
1784       (setq spam-whitelist-cache (spam-parse-list spam-whitelist)))
1785     (if (spam-from-listed-p 'spam-use-whitelist)
1786         t
1787       (if spam-use-whitelist-exclusive
1788           spam-split-group
1789         nil))))
1790
1791 (defun spam-check-blacklist ()
1792   ;; FIXME!  Should it detect when file timestamps change?
1793   (let ((spam-split-group (if spam-split-symbolic-return
1794                               'spam
1795                             spam-split-group)))
1796     (unless spam-blacklist-cache
1797       (setq spam-blacklist-cache (spam-parse-list spam-blacklist)))
1798     (and (spam-from-listed-p 'spam-use-blacklist) spam-split-group)))
1799
1800 (defun spam-parse-list (file)
1801   (when (file-readable-p file)
1802     (let (contents address)
1803       (with-temp-buffer
1804         (insert-file-contents file)
1805         (while (not (eobp))
1806           (setq address (buffer-substring (point) (point-at-eol)))
1807           (forward-line 1)
1808           ;; insert the e-mail address if detected, otherwise the raw data
1809           (unless (zerop (length address))
1810             (let ((pure-address (nth 1 (gnus-extract-address-components address))))
1811               (push (or pure-address address) contents)))))
1812       (nreverse contents))))
1813
1814 (defun spam-from-listed-p (type)
1815   (let ((from (message-fetch-field "from"))
1816         found)
1817     (spam-filelist-check-cache type from)))
1818
1819 (defun spam-filelist-register-routine (articles blacklist &optional unregister)
1820   (let ((de-symbol (if blacklist 'spam-use-whitelist 'spam-use-blacklist))
1821         (declassification (if blacklist 'ham 'spam))
1822         (enter-function
1823          (if blacklist 'spam-enter-blacklist 'spam-enter-whitelist))
1824         (remove-function
1825          (if blacklist 'spam-enter-whitelist 'spam-enter-blacklist))
1826         from addresses unregister-list)
1827     (dolist (article articles)
1828       (let ((from (spam-fetch-field-from-fast article))
1829             (id (spam-fetch-field-message-id-fast article))
1830             sender-ignored)
1831         (when (stringp from)
1832           (dolist (ignore-regex spam-blacklist-ignored-regexes)
1833             (when (and (not sender-ignored)
1834                        (stringp ignore-regex)
1835                        (string-match ignore-regex from))
1836               (setq sender-ignored t)))
1837           ;; remember the messages we need to unregister, unless remove is set
1838           (when (and
1839                  (null unregister)
1840                  (spam-log-unregistration-needed-p
1841                   id 'process declassification de-symbol))
1842             (push from unregister-list))
1843           (unless sender-ignored
1844             (push from addresses)))))
1845
1846     (if unregister
1847         (funcall enter-function addresses t) ; unregister all these addresses
1848       ;; else, register normally and unregister what we need to
1849       (funcall remove-function unregister-list t)
1850       (dolist (article unregister-list)
1851         (spam-log-undo-registration
1852          (spam-fetch-field-message-id-fast article)
1853          'process
1854          declassification
1855          de-symbol))
1856       (funcall enter-function addresses nil))))
1857
1858 (defun spam-blacklist-unregister-routine (articles)
1859   (spam-blacklist-register-routine articles t))
1860
1861 (defun spam-blacklist-register-routine (articles &optional unregister)
1862   (spam-filelist-register-routine articles t unregister))
1863
1864 (defun spam-whitelist-unregister-routine (articles)
1865   (spam-whitelist-register-routine articles t))
1866
1867 (defun spam-whitelist-register-routine (articles &optional unregister)
1868   (spam-filelist-register-routine articles nil unregister))
1869
1870 \f
1871 ;;;; Spam-report glue
1872 (defun spam-report-gmane-register-routine (articles)
1873   (when articles
1874     (apply 'spam-report-gmane articles)))
1875
1876 \f
1877 ;;;; Bogofilter
1878 (defun spam-check-bogofilter-headers (&optional score)
1879   (let ((header (message-fetch-field spam-bogofilter-header))
1880         (spam-split-group (if spam-split-symbolic-return
1881                               'spam
1882                             spam-split-group)))
1883     (when header                        ; return nil when no header
1884       (if score                         ; scoring mode
1885           (if (string-match "spamicity=\\([0-9.]+\\)" header)
1886               (match-string 1 header)
1887             "0")
1888         ;; spam detection mode
1889         (when (string-match spam-bogofilter-bogosity-positive-spam-header
1890                             header)
1891           spam-split-group)))))
1892
1893 ;; return something sensible if the score can't be determined
1894 (defun spam-bogofilter-score ()
1895   "Get the Bogofilter spamicity score"
1896   (interactive)
1897   (save-window-excursion
1898     (gnus-summary-show-article t)
1899     (set-buffer gnus-article-buffer)
1900     (let ((score (or (spam-check-bogofilter-headers t)
1901                      (spam-check-bogofilter t))))
1902       (gnus-summary-show-article)
1903       (message "Spamicity score %s" score)
1904       (or score "0"))))
1905
1906 (defun spam-check-bogofilter (&optional score)
1907   "Check the Bogofilter backend for the classification of this message"
1908   (let ((article-buffer-name (buffer-name))
1909         (db spam-bogofilter-database-directory)
1910         return)
1911     (with-temp-buffer
1912       (let ((temp-buffer-name (buffer-name)))
1913         (save-excursion
1914           (set-buffer article-buffer-name)
1915           (apply 'call-process-region
1916                  (point-min) (point-max)
1917                  spam-bogofilter-path
1918                  nil temp-buffer-name nil
1919                  (if db `("-d" ,db "-v") `("-v"))))
1920         (setq return (spam-check-bogofilter-headers score))))
1921     return))
1922
1923 (defun spam-bogofilter-register-with-bogofilter (articles
1924                                                  spam
1925                                                  &optional unregister)
1926   "Register an article, given as a string, as spam or non-spam."
1927   (dolist (article articles)
1928     (let ((article-string (spam-get-article-as-string article))
1929           (db spam-bogofilter-database-directory)
1930           (switch (if unregister
1931                       (if spam
1932                           spam-bogofilter-spam-strong-switch
1933                         spam-bogofilter-ham-strong-switch)
1934                     (if spam
1935                         spam-bogofilter-spam-switch
1936                       spam-bogofilter-ham-switch))))
1937       (when (stringp article-string)
1938         (with-temp-buffer
1939           (insert article-string)
1940
1941           (apply 'call-process-region
1942                  (point-min) (point-max)
1943                  spam-bogofilter-path
1944                  nil nil nil switch
1945                  (if db `("-d" ,db "-v") `("-v"))))))))
1946
1947 (defun spam-bogofilter-register-spam-routine (articles &optional unregister)
1948   (spam-bogofilter-register-with-bogofilter articles t unregister))
1949
1950 (defun spam-bogofilter-unregister-spam-routine (articles)
1951   (spam-bogofilter-register-spam-routine articles t))
1952
1953 (defun spam-bogofilter-register-ham-routine (articles &optional unregister)
1954   (spam-bogofilter-register-with-bogofilter articles nil unregister))
1955
1956 (defun spam-bogofilter-unregister-ham-routine (articles)
1957   (spam-bogofilter-register-ham-routine articles t))
1958
1959
1960 \f
1961 ;;;; spamoracle
1962 (defun spam-check-spamoracle ()
1963   "Run spamoracle on an article to determine whether it's spam."
1964   (let ((article-buffer-name (buffer-name))
1965         (spam-split-group (if spam-split-symbolic-return
1966                               'spam
1967                             spam-split-group)))
1968     (with-temp-buffer
1969       (let ((temp-buffer-name (buffer-name)))
1970         (save-excursion
1971           (set-buffer article-buffer-name)
1972           (let ((status
1973                  (apply 'call-process-region
1974                         (point-min) (point-max)
1975                         spam-spamoracle-binary
1976                         nil temp-buffer-name nil
1977                         (if spam-spamoracle-database
1978                             `("-f" ,spam-spamoracle-database "mark")
1979                           '("mark")))))
1980             (if (eq 0 status)
1981                 (progn
1982                   (set-buffer temp-buffer-name)
1983                   (goto-char (point-min))
1984                   (when (re-search-forward "^X-Spam: yes;" nil t)
1985                     spam-split-group))
1986               (error "Error running spamoracle: %s" status))))))))
1987
1988 (defun spam-spamoracle-learn (articles article-is-spam-p &optional unregister)
1989   "Run spamoracle in training mode."
1990   (with-temp-buffer
1991     (let ((temp-buffer-name (buffer-name)))
1992       (save-excursion
1993         (goto-char (point-min))
1994         (dolist (article articles)
1995           (insert (spam-get-article-as-string article)))
1996         (let* ((arg (if (spam-xor unregister article-is-spam-p)
1997                         "-spam"
1998                       "-good"))
1999                (status
2000                 (apply 'call-process-region
2001                        (point-min) (point-max)
2002                        spam-spamoracle-binary
2003                        nil temp-buffer-name nil
2004                        (if spam-spamoracle-database
2005                            `("-f" ,spam-spamoracle-database
2006                              "add" ,arg)
2007                          `("add" ,arg)))))
2008           (unless (eq 0 status)
2009             (error "Error running spamoracle: %s" status)))))))
2010
2011 (defun spam-spamoracle-learn-ham (articles &optional unregister)
2012   (spam-spamoracle-learn articles nil unregister))
2013
2014 (defun spam-spamoracle-unlearn-ham (articles &optional unregister)
2015   (spam-spamoracle-learn-ham articles t))
2016
2017 (defun spam-spamoracle-learn-spam (articles &optional unregister)
2018   (spam-spamoracle-learn articles t unregister))
2019
2020 (defun spam-spamoracle-unlearn-spam (articles &optional unregister)
2021   (spam-spamoracle-learn-spam articles t))
2022
2023 \f
2024 ;;;; SpamAssassin
2025 ;;; based mostly on the bogofilter code
2026 (defun spam-check-spamassassin-headers (&optional score)
2027   "Check the SpamAssassin headers for the classification of this message."
2028   (if score                             ; scoring mode
2029       (let ((header (message-fetch-field spam-spamassassin-spam-status-header)))
2030         (when header
2031           (if (string-match "hits=\\(-?[0-9.]+\\)" header)
2032               (match-string 1 header)
2033             "0")))
2034     ;; spam detection mode
2035     (let ((header (message-fetch-field spam-spamassassin-spam-flag-header))
2036           (spam-split-group (if spam-split-symbolic-return
2037                                  'spam
2038                                spam-split-group)))
2039           (when header                  ; return nil when no header
2040             (when (string-match spam-spamassassin-positive-spam-flag-header
2041                                 header)
2042               spam-split-group)))))
2043
2044 (defun spam-check-spamassassin (&optional score)
2045   "Check the SpamAssassin backend for the classification of this message."
2046   (let ((article-buffer-name (buffer-name)))
2047     (with-temp-buffer
2048       (let ((temp-buffer-name (buffer-name)))
2049         (save-excursion
2050           (set-buffer article-buffer-name)
2051           (apply 'call-process-region
2052                  (point-min) (point-max) spam-spamassassin-path
2053                  nil temp-buffer-name nil spam-spamassassin-arguments))
2054         ;; check the return now (we're back in the temp buffer)
2055         (goto-char (point-min))
2056         (spam-check-spamassassin-headers score)))))
2057
2058 ;; return something sensible if the score can't be determined
2059 (defun spam-spamassassin-score ()
2060   "Get the SpamAssassin score"
2061   (interactive)
2062   (save-window-excursion
2063     (gnus-summary-show-article t)
2064     (set-buffer gnus-article-buffer)
2065     (let ((score (or (spam-check-spamassassin-headers t)
2066                      (spam-check-spamassassin t))))
2067       (gnus-summary-show-article)
2068       (message "SpamAssassin score %s" score)
2069       (or score "0"))))
2070
2071 (defun spam-spamassassin-register-with-sa-learn (articles spam
2072                                                  &optional unregister)
2073   "Register articles with spamassassin's sa-learn as spam or non-spam."
2074   (if articles
2075       (let ((action (if unregister spam-sa-learn-unregister-switch
2076                       (if spam spam-sa-learn-spam-switch
2077                         spam-sa-learn-ham-switch)))
2078             (summary-buffer-name (buffer-name)))
2079         (with-temp-buffer
2080           ;; group the articles into mbox format
2081           (dolist (article articles)
2082             (let (article-string)
2083               (save-excursion
2084                 (set-buffer summary-buffer-name)
2085                 (setq article-string (spam-get-article-as-string article)))
2086               (when (stringp article-string)
2087                 (insert "From \n") ; mbox separator (sa-learn only checks the
2088                                    ; first five chars, so we can get away with
2089                                    ; a bogus line))
2090                 (insert article-string)
2091                 (insert "\n"))))
2092           ;; call sa-learn on all messages at the same time
2093           (apply 'call-process-region
2094                  (point-min) (point-max)
2095                  spam-sa-learn-path
2096                  nil nil nil "--mbox"
2097                  (if spam-sa-learn-rebuild
2098                      (list action)
2099                    `("--no-rebuild" ,action)))))))
2100
2101 (defun spam-spamassassin-register-spam-routine (articles &optional unregister)
2102   (spam-spamassassin-register-with-sa-learn articles t unregister))
2103
2104 (defun spam-spamassassin-register-ham-routine (articles &optional unregister)
2105   (spam-spamassassin-register-with-sa-learn articles nil unregister))
2106
2107 (defun spam-spamassassin-unregister-spam-routine (articles)
2108   (spam-spamassassin-register-with-sa-learn articles t t))
2109
2110 (defun spam-spamassassin-unregister-ham-routine (articles)
2111   (spam-spamassassin-register-with-sa-learn articles nil t))
2112 \f
2113 ;;;; Hooks
2114
2115 ;;;###autoload
2116 (defun spam-initialize ()
2117   "Install the spam.el hooks and do other initialization"
2118   (interactive)
2119   (setq spam-install-hooks t)
2120   ;; TODO: How do we redo this every time spam-face is customized?
2121   (push '((eq mark gnus-spam-mark) . spam-face)
2122         gnus-summary-highlight)
2123   ;; Add hooks for loading and saving the spam stats
2124   (add-hook 'gnus-save-newsrc-hook 'spam-maybe-spam-stat-save)
2125   (add-hook 'gnus-get-top-new-news-hook 'spam-maybe-spam-stat-load)
2126   (add-hook 'gnus-startup-hook 'spam-maybe-spam-stat-load)
2127   (add-hook 'gnus-summary-prepare-exit-hook 'spam-summary-prepare-exit)
2128   (add-hook 'gnus-summary-prepare-hook 'spam-summary-prepare)
2129   (add-hook 'gnus-get-new-news-hook 'spam-setup-widening)
2130   (add-hook 'gnus-summary-prepared-hook 'spam-find-spam))
2131
2132 (defun spam-unload-hook ()
2133   "Uninstall the spam.el hooks"
2134   (interactive)
2135   (remove-hook 'gnus-save-newsrc-hook 'spam-maybe-spam-stat-save)
2136   (remove-hook 'gnus-get-top-new-news-hook 'spam-maybe-spam-stat-load)
2137   (remove-hook 'gnus-startup-hook 'spam-maybe-spam-stat-load)
2138   (remove-hook 'gnus-summary-prepare-exit-hook 'spam-summary-prepare-exit)
2139   (remove-hook 'gnus-summary-prepare-hook 'spam-summary-prepare)
2140   (remove-hook 'gnus-get-new-news-hook 'spam-setup-widening)
2141   (remove-hook 'gnus-summary-prepare-hook 'spam-find-spam))
2142
2143 (when spam-install-hooks
2144   (spam-initialize))
2145
2146 (provide 'spam)
2147
2148 ;;; spam.el ends here