cgit.sxemacs.org Git - gnus/blob - lisp/spam-stat.el

   1 ;;; spam-stat.el --- detecting spam based on statistics
   2
   3 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   4
   5 ;; Author: Alex Schroeder <alex@gnu.org>
   6 ;; Keywords: network
   7 ;; URL: http://www.emacswiki.org/cgi-bin/wiki.pl?SpamStat
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; This is free software; you can redistribute it and/or modify it
  12 ;; under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; This is distributed in the hope that it will be useful, but WITHOUT
  17 ;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  18 ;; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
  19 ;; License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This implements spam analysis according to Paul Graham in "A Plan
  29 ;; for Spam".  The basis for all this is a statistical distribution of
  30 ;; words for your spam and non-spam mails.  We need this information
  31 ;; in a hash-table so that the analysis can use the information when
  32 ;; looking at your mails.  Therefore, before you begin, you need tons
  33 ;; of mails (Graham uses 4000 non-spam and 4000 spam mails for his
  34 ;; experiments).
  35 ;;
  36 ;; The main interface to using spam-stat, are the following functions:
  37 ;;
  38 ;; `spam-stat-buffer-is-spam' -- called in a buffer, that buffer is
  39 ;; considered to be a new spam mail; use this for new mail that has
  40 ;; not been processed before
  41 ;;
  42 ;; `spam-stat-buffer-is-non-spam' -- called in a buffer, that buffer
  43 ;; is considered to be a new non-spam mail; use this for new mail that
  44 ;; has not been processed before
  45 ;;
  46 ;; `spam-stat-buffer-change-to-spam' -- called in a buffer, that
  47 ;; buffer is no longer considered to be normal mail but spam; use this
  48 ;; to change the status of a mail that has already been processed as
  49 ;; non-spam
  50 ;;
  51 ;; `spam-stat-buffer-change-to-non-spam' -- called in a buffer, that
  52 ;; buffer is no longer considered to be spam but normal mail; use this
  53 ;; to change the status of a mail that has already been processed as
  54 ;; spam
  55 ;;
  56 ;; `spam-stat-save' -- save the hash table to the file; the filename
  57 ;; used is stored in the variable `spam-stat-file'
  58 ;;
  59 ;; `spam-stat-load' -- load the hash table from a file; the filename
  60 ;; used is stored in the variable `spam-stat-file'
  61 ;;
  62 ;; `spam-stat-score-word' -- return the spam score for a word
  63 ;;
  64 ;; `spam-stat-score-buffer' -- return the spam score for a buffer
  65 ;;
  66 ;; `spam-stat-split-fancy' -- for fancy mail splitting; add
  67 ;; the rule (: spam-stat-split-fancy) to `nnmail-split-fancy'
  68 ;;
  69 ;; This requires the following in your ~/.gnus file:
  70 ;;
  71 ;; (require 'spam-stat)
  72 ;; (spam-stat-load)
  73
  74 ;;; Testing:
  75
  76 ;; Typical test will involve calls to the following functions:
  77 ;;
  78 ;; Reset: (spam-stat-reset)
  79 ;; Learn spam: (spam-stat-process-spam-directory "~/Mail/mail/spam")
  80 ;; Learn non-spam: (spam-stat-process-non-spam-directory "~/Mail/mail/misc")
  81 ;; Save table: (spam-stat-save)
  82 ;; File size: (nth 7 (file-attributes spam-stat-file))
  83 ;; Number of words: (hash-table-count spam-stat)
  84 ;; Test spam: (spam-stat-test-directory "~/Mail/mail/spam")
  85 ;; Test non-spam: (spam-stat-test-directory "~/Mail/mail/misc")
  86 ;; Reduce table size: (spam-stat-reduce-size)
  87 ;; Save table: (spam-stat-save)
  88 ;; File size: (nth 7 (file-attributes spam-stat-file))
  89 ;; Number of words: (hash-table-count spam-stat)
  90 ;; Test spam: (spam-stat-test-directory "~/Mail/mail/spam")
  91 ;; Test non-spam: (spam-stat-test-directory "~/Mail/mail/misc")
  92
  93 ;;; Dictionary Creation:
  94
  95 ;; Typically, you will filter away mailing lists etc. using specific
  96 ;; rules in `nnmail-split-fancy'.  Somewhere among these rules, you
  97 ;; will filter spam.  Here is how you would create your dictionary:
  98
  99 ;; Reset: (spam-stat-reset)
 100 ;; Learn spam: (spam-stat-process-spam-directory "~/Mail/mail/spam")
 101 ;; Learn non-spam: (spam-stat-process-non-spam-directory "~/Mail/mail/misc")
 102 ;; Repeat for any other non-spam group you need...
 103 ;; Reduce table size: (spam-stat-reduce-size)
 104 ;; Save table: (spam-stat-save)
 105
 106 ;;; Todo:
 107
 108 ;; Speed it up.  Integrate with Gnus such that it uses spam and expiry
 109 ;; marks to call the appropriate functions when leaving the summary
 110 ;; buffer and saves the hash table when leaving Gnus.  More testing:
 111 ;; More mails, disabling SpamAssassin, double checking algorithm, find
 112 ;; improved algorithm.
 113
 114 ;;; Thanks:
 115
 116 ;; Ted Zlatanov <tzz@lifelogs.com>
 117 ;; Jesper Harder <harder@myrealbox.com>
 118 ;; Dan Schmidt <dfan@dfan.org>
 119 ;; Lasse Rasinen <lrasinen@iki.fi>
 120 ;; Milan Zamazal <pdm@zamazal.org>
 121
 122 \f
 123
 124 ;;; Code:
 125 (require 'mail-parse)
 126
 127 (defgroup spam-stat nil
 128   "Statistical spam detection for Emacs.
 129 Use the functions to build a dictionary of words and their statistical
 130 distribution in spam and non-spam mails.  Then use a function to determine
 131 whether a buffer contains spam or not."
 132   :version "22.1"
 133   :group 'gnus)
 134
 135 (defcustom spam-stat-file "~/.spam-stat.el"
 136   "File used to save and load the dictionary.
 137 See `spam-stat-to-hash-table' for the format of the file."
 138   :type 'file
 139   :group 'spam-stat)
 140
 141 (defcustom spam-stat-install-hooks t
 142   "Whether spam-stat should install its hooks in Gnus.
 143 This is set to nil if you use spam-stat through spam.el."
 144   :type 'boolean
 145   :group 'spam-stat)
 146
 147 (defcustom spam-stat-unknown-word-score 0.2
 148   "The score to use for unknown words.
 149 Also used for words that don't appear often enough."
 150   :type 'number
 151   :group 'spam-stat)
 152
 153 (defcustom spam-stat-max-word-length 15
 154   "Only words shorter than this will be considered."
 155   :type 'integer
 156   :group 'spam-stat)
 157
 158 (defcustom spam-stat-max-buffer-length 10240
 159   "Only the beginning of buffers will be analyzed.
 160 This variable says how many characters this will be."
 161   :type 'integer
 162   :group 'spam-stat)
 163
 164 (defcustom spam-stat-split-fancy-spam-group "mail.spam"
 165   "Name of the group where spam should be stored.
 166 If `spam-stat-split-fancy' is used in fancy splitting rules.  Has
 167 no effect when spam-stat is invoked through spam.el."
 168   :type 'string
 169   :group 'spam-stat)
 170
 171 (defcustom spam-stat-split-fancy-spam-threshold 0.9
 172   "Spam score threshold in spam-stat-split-fancy."
 173   :type 'number
 174   :group 'spam-stat)
 175
 176 (defcustom spam-stat-washing-hook nil
 177   "Hook applied to each message before analysis."
 178   :type 'hook
 179   :group 'spam-stat)
 180
 181 (defcustom spam-stat-score-buffer-user-functions nil
 182   "List of additional scoring functions.
 183 Called  one by one on the buffer.
 184
 185 If all of these functions return non-nil answers, these numerical
 186 answers are added to the computed spam stat score on the buffer.  If
 187 you defun such functions, make sure they don't return the buffer in a
 188 narrowed state or such: use, for example, `save-excursion'.  Each of
 189 your functions is also passed the initial spam-stat score which might
 190 aid in your scoring.
 191
 192 Also be careful when defining such functions.  If they take a long
 193 time, they will slow down your mail splitting.  Thus, if the buffer is
 194 large, don't forget to use smaller regions, by wrapping your work in,
 195 say, `with-spam-stat-max-buffer-size'."
 196   :type '(repeat sexp)
 197   :group 'spam-stat)
 198
 199 (defcustom spam-stat-process-directory-age 90
 200   "Max. age of files to be processed in directory, in days.
 201 When using `spam-stat-process-spam-directory' or
 202 `spam-stat-process-non-spam-directory', only files that have
 203 been touched in this many days will be considered.  Without
 204 this filter, re-training spam-stat with several thousand messages
 205 will start to take a very long time."
 206   :type 'number
 207   :group 'spam-stat)
 208
 209 (defvar spam-stat-last-saved-at nil
 210   "Time stamp of last change of spam-stat-file on this run")
 211
 212 (defvar spam-stat-syntax-table
 213   (let ((table (copy-syntax-table text-mode-syntax-table)))
 214     (modify-syntax-entry ?- "w" table)
 215     (modify-syntax-entry ?_ "w" table)
 216     (modify-syntax-entry ?. "w" table)
 217     (modify-syntax-entry ?! "w" table)
 218     (modify-syntax-entry ?? "w" table)
 219     (modify-syntax-entry ?+ "w" table)
 220     table)
 221   "Syntax table used when processing mails for statistical analysis.
 222 The important part is which characters are word constituents.")
 223
 224 (defvar spam-stat-dirty nil
 225   "Whether the spam-stat database needs saving.")
 226
 227 (defvar spam-stat-buffer nil
 228   "Buffer to use for scoring while splitting.
 229 This is set by hooking into Gnus.")
 230
 231 (defvar spam-stat-buffer-name " *spam stat buffer*"
 232   "Name of the `spam-stat-buffer'.")
 233
 234 (defvar spam-stat-coding-system
 235   (if (mm-coding-system-p 'emacs-mule) 'emacs-mule 'raw-text)
 236   "Coding system used for `spam-stat-file'.")
 237
 238 ;; Hooking into Gnus
 239
 240 (defun spam-stat-store-current-buffer ()
 241   "Store a copy of the current buffer in `spam-stat-buffer'."
 242   (let ((buf (current-buffer)))
 243     (with-current-buffer (get-buffer-create spam-stat-buffer-name)
 244       (erase-buffer)
 245       (insert-buffer-substring buf)
 246       (setq spam-stat-buffer (current-buffer)))))
 247
 248 (defun spam-stat-store-gnus-article-buffer ()
 249   "Store a copy of the current article in `spam-stat-buffer'.
 250 This uses `gnus-article-buffer'."
 251   (with-current-buffer gnus-original-article-buffer
 252     (spam-stat-store-current-buffer)))
 253
 254 ;; Data -- not using defstruct in order to save space and time
 255
 256 (defvar spam-stat (make-hash-table :test 'equal)
 257   "Hash table used to store the statistics.
 258 Use `spam-stat-load' to load the file.
 259 Every word is used as a key in this table.  The value is a vector.
 260 Use `spam-stat-ngood', `spam-stat-nbad', `spam-stat-good',
 261 `spam-stat-bad', and `spam-stat-score' to access this vector.")
 262
 263 (defvar spam-stat-ngood 0
 264   "The number of good mails in the dictionary.")
 265
 266 (defvar spam-stat-nbad 0
 267   "The number of bad mails in the dictionary.")
 268
 269 (defvar spam-stat-error-holder nil
 270   "A holder for condition-case errors while scoring buffers.")
 271
 272 (defsubst spam-stat-good (entry)
 273   "Return the number of times this word belongs to good mails."
 274   (aref entry 0))
 275
 276 (defsubst spam-stat-bad (entry)
 277   "Return the number of times this word belongs to bad mails."
 278   (aref entry 1))
 279
 280 (defsubst spam-stat-score (entry)
 281   "Set the score of this word."
 282   (if entry
 283       (aref entry 2)
 284     spam-stat-unknown-word-score))
 285
 286 (defsubst spam-stat-set-good (entry value)
 287   "Set the number of times this word belongs to good mails."
 288   (aset entry 0 value))
 289
 290 (defsubst spam-stat-set-bad (entry value)
 291   "Set the number of times this word belongs to bad mails."
 292   (aset entry 1 value))
 293
 294 (defsubst spam-stat-set-score (entry value)
 295   "Set the score of this word."
 296   (aset entry 2 value))
 297
 298 (defsubst spam-stat-make-entry (good bad)
 299   "Return a vector with the given properties."
 300   (let ((entry (vector good bad nil)))
 301     (spam-stat-set-score entry (spam-stat-compute-score entry))
 302     entry))
 303
 304 ;; Computing
 305
 306 (defun spam-stat-compute-score (entry)
 307   "Compute the score of this word.  1.0 means spam."
 308    ;; promote all numbers to floats for the divisions
 309    (let* ((g (* 2.0 (spam-stat-good entry)))
 310           (b (float (spam-stat-bad entry))))
 311      (cond ((< (+ g b) 5)
 312             .2)
 313            ((= 0 spam-stat-ngood)
 314             .99)
 315            ((= 0 spam-stat-nbad)
 316             .01)
 317            (t
 318             (max .01
 319                  (min .99 (/ (/ b spam-stat-nbad)
 320                              (+ (/ g spam-stat-ngood)
 321                                 (/ b spam-stat-nbad)))))))))
 322
 323 ;; Parsing
 324
 325 (defmacro with-spam-stat-max-buffer-size (&rest body)
 326   "Narrow the buffer down to the first 4k characters, then evaluate BODY."
 327   `(save-restriction
 328      (when (> (- (point-max)
 329                  (point-min))
 330               spam-stat-max-buffer-length)
 331        (narrow-to-region (point-min)
 332                          (+ (point-min) spam-stat-max-buffer-length)))
 333      ,@body))
 334
 335 (defun spam-stat-buffer-words ()
 336   "Return a hash table of words and number of occurrences in the buffer."
 337   (run-hooks 'spam-stat-washing-hook)
 338   (with-spam-stat-max-buffer-size
 339    (with-syntax-table spam-stat-syntax-table
 340      (goto-char (point-min))
 341      (let ((result (make-hash-table :test 'equal))
 342            word count)
 343        (while (re-search-forward "\\w+" nil t)
 344          (setq word (match-string-no-properties 0)
 345                count (1+ (gethash word result 0)))
 346          (when (< (length word) spam-stat-max-word-length)
 347            (puthash word count result)))
 348        result))))
 349
 350 (defun spam-stat-buffer-is-spam ()
 351   "Consider current buffer to be a new spam mail."
 352   (setq spam-stat-nbad (1+ spam-stat-nbad))
 353   (maphash
 354    (lambda (word count)
 355      (let ((entry (gethash word spam-stat)))
 356        (if entry
 357            (spam-stat-set-bad entry (+ count (spam-stat-bad entry)))
 358          (setq entry (spam-stat-make-entry 0 count)))
 359        (spam-stat-set-score entry (spam-stat-compute-score entry))
 360        (puthash word entry spam-stat)))
 361    (spam-stat-buffer-words))
 362   (setq spam-stat-dirty t))
 363
 364 (defun spam-stat-buffer-is-non-spam ()
 365   "Consider current buffer to be a new non-spam mail."
 366   (setq spam-stat-ngood (1+ spam-stat-ngood))
 367   (maphash
 368    (lambda (word count)
 369      (let ((entry (gethash word spam-stat)))
 370        (if entry
 371            (spam-stat-set-good entry (+ count (spam-stat-good entry)))
 372          (setq entry (spam-stat-make-entry count 0)))
 373        (spam-stat-set-score entry (spam-stat-compute-score entry))
 374        (puthash word entry spam-stat)))
 375    (spam-stat-buffer-words))
 376   (setq spam-stat-dirty t))
 377
 378 (defun spam-stat-buffer-change-to-spam ()
 379   "Consider current buffer no longer normal mail but spam."
 380   (setq spam-stat-nbad (1+ spam-stat-nbad)
 381         spam-stat-ngood (1- spam-stat-ngood))
 382   (maphash
 383    (lambda (word count)
 384      (let ((entry (gethash word spam-stat)))
 385        (if (not entry)
 386            (gnus-message 8 "This buffer has unknown words in it")
 387          (spam-stat-set-good entry (- (spam-stat-good entry) count))
 388          (spam-stat-set-bad entry (+ (spam-stat-bad entry) count))
 389          (spam-stat-set-score entry (spam-stat-compute-score entry))
 390          (puthash word entry spam-stat))))
 391    (spam-stat-buffer-words))
 392   (setq spam-stat-dirty t))
 393
 394 (defun spam-stat-buffer-change-to-non-spam ()
 395   "Consider current buffer no longer spam but normal mail."
 396   (setq spam-stat-nbad (1- spam-stat-nbad)
 397         spam-stat-ngood (1+ spam-stat-ngood))
 398   (maphash
 399    (lambda (word count)
 400      (let ((entry (gethash word spam-stat)))
 401        (if (not entry)
 402            (gnus-message 8 "This buffer has unknown words in it")
 403          (spam-stat-set-good entry (+ (spam-stat-good entry) count))
 404          (spam-stat-set-bad entry (- (spam-stat-bad entry) count))
 405          (spam-stat-set-score entry (spam-stat-compute-score entry))
 406          (puthash word entry spam-stat))))
 407    (spam-stat-buffer-words))
 408   (setq spam-stat-dirty t))
 409
 410 ;; Saving and Loading
 411
 412 (defun spam-stat-save (&optional force)
 413   "Save the `spam-stat' hash table as lisp file.
 414 With a prefix argument save unconditionally."
 415   (interactive "P")
 416   (when (or force spam-stat-dirty)
 417     (let ((coding-system-for-write spam-stat-coding-system))
 418       (with-temp-file spam-stat-file
 419         (let ((standard-output (current-buffer))
 420               (font-lock-maximum-size 0))
 421           (insert (format ";-*- coding: %s; -*-\n" spam-stat-coding-system))
 422           (insert (format "(setq spam-stat-ngood %d spam-stat-nbad %d
 423 spam-stat (spam-stat-to-hash-table '(" spam-stat-ngood spam-stat-nbad))
 424           (maphash (lambda (word entry)
 425                      (prin1 (list word
 426                                   (spam-stat-good entry)
 427                                   (spam-stat-bad entry))))
 428                    spam-stat)
 429           (insert ")))"))))
 430     (message "Saved %s."  spam-stat-file)
 431     (setq spam-stat-dirty nil
 432           spam-stat-last-saved-at (nth 5 (file-attributes spam-stat-file)))))
 433
 434 (defun spam-stat-load ()
 435   "Read the `spam-stat' hash table from disk."
 436   ;; TODO: maybe we should warn the user if spam-stat-dirty is t?
 437   (let ((coding-system-for-read spam-stat-coding-system))
 438     (cond (spam-stat-dirty (message "Spam stat not loaded: spam-stat-dirty t"))
 439           ((or (not (boundp 'spam-stat-last-saved-at))
 440                (null spam-stat-last-saved-at)
 441                (not (equal spam-stat-last-saved-at
 442                            (nth 5 (file-attributes spam-stat-file)))))
 443            (progn
 444              (load-file spam-stat-file)
 445              (setq spam-stat-dirty nil
 446                    spam-stat-last-saved-at
 447                    (nth 5 (file-attributes spam-stat-file)))))
 448           (t (message "Spam stat file not loaded: no change in disk..")))))
 449
 450 (defun spam-stat-to-hash-table (entries)
 451   "Turn list ENTRIES into a hash table and store as `spam-stat'.
 452 Every element in ENTRIES has the form \(WORD GOOD BAD) where WORD is
 453 the word string, NGOOD is the number of good mails it has appeared in,
 454 NBAD is the number of bad mails it has appeared in, GOOD is the number
 455 of times it appeared in good mails, and BAD is the number of times it
 456 has appeared in bad mails."
 457   (let ((table (make-hash-table :size (length entries)
 458                                 :test 'equal)))
 459     (mapc (lambda (l)
 460             (puthash (car l)
 461                      (spam-stat-make-entry (nth 1 l) (nth 2 l))
 462                      table))
 463           entries)
 464     table))
 465
 466 (defun spam-stat-reset ()
 467   "Reset `spam-stat' to an empty hash-table.
 468 This deletes all the statistics."
 469   (interactive)
 470   (setq spam-stat (make-hash-table :test 'equal)
 471         spam-stat-ngood 0
 472         spam-stat-nbad 0)
 473   (setq spam-stat-dirty t))
 474
 475 ;; Scoring buffers
 476
 477 (defvar spam-stat-score-data nil
 478   "Raw data used in the last run of `spam-stat-score-buffer'.")
 479
 480 (defsubst spam-stat-score-word (word)
 481   "Return score for WORD.
 482 The default score for unknown words is stored in
 483 `spam-stat-unknown-word-score'."
 484   (spam-stat-score (gethash word spam-stat)))
 485
 486 (defun spam-stat-buffer-words-with-scores ()
 487   "Process current buffer, return the 15 most conspicuous words.
 488 These are the words whose spam-stat differs the most from 0.5.
 489 The list returned contains elements of the form \(WORD SCORE DIFF),
 490 where DIFF is the difference between SCORE and 0.5."
 491   (let (result word score)
 492     (maphash (lambda (word ignore)
 493                (setq score (spam-stat-score-word word)
 494                      result (cons (list word score (abs (- score 0.5)))
 495                                   result)))
 496              (spam-stat-buffer-words))
 497     (setq result (sort result (lambda (a b) (< (nth 2 b) (nth 2 a)))))
 498     (setcdr (nthcdr 14 result) nil)
 499     result))
 500
 501 (defun spam-stat-score-buffer ()
 502   "Return a score describing the spam-probability for this buffer.
 503 Add user supplied modifications if supplied."
 504   (interactive) ; helps in debugging.
 505   (setq spam-stat-score-data (spam-stat-buffer-words-with-scores))
 506   (let* ((probs (mapcar 'cadr spam-stat-score-data))
 507          (prod (apply #'* probs))
 508          (score0
 509           (/ prod (+ prod (apply #'* (mapcar #'(lambda (x) (- 1 x))
 510                                              probs)))))
 511          (score1s
 512           (condition-case
 513               spam-stat-error-holder
 514               (spam-stat-score-buffer-user score0)
 515             (error nil)))
 516          (ans
 517           (if score1s (+ score0 score1s) score0)))
 518     (when (interactive-p)
 519       (message "%S" ans))
 520     ans))
 521
 522 (defun spam-stat-score-buffer-user (&rest args)
 523   (let* ((scores
 524           (mapcar
 525            (lambda (fn)
 526              (apply fn args))
 527            spam-stat-score-buffer-user-functions)))
 528     (if (memq nil scores) nil
 529       (apply #'+ scores))))
 530
 531 (defun spam-stat-split-fancy ()
 532   "Return the name of the spam group if the current mail is spam.
 533 Use this function on `nnmail-split-fancy'.  If you are interested in
 534 the raw data used for the last run of `spam-stat-score-buffer',
 535 check the variable `spam-stat-score-data'."
 536   (condition-case spam-stat-error-holder
 537       (progn
 538         (set-buffer spam-stat-buffer)
 539         (goto-char (point-min))
 540         (when (> (spam-stat-score-buffer) spam-stat-split-fancy-spam-threshold)
 541           (when (boundp 'nnmail-split-trace)
 542             (mapc (lambda (entry)
 543                     (push entry nnmail-split-trace))
 544                   spam-stat-score-data))
 545           spam-stat-split-fancy-spam-group))
 546     (error (message "Error in spam-stat-split-fancy: %S" spam-stat-error-holder)
 547            nil)))
 548
 549 ;; Testing
 550
 551 (defun spam-stat-strip-xref ()
 552   "Strip the the Xref header."
 553   (save-restriction
 554     (mail-narrow-to-head)
 555     (when (re-search-forward "^Xref:.*\n" nil t)
 556       (delete-region (match-beginning 0) (match-end 0)))))
 557
 558 (defun spam-stat-process-directory (dir func)
 559   "Process all the regular files in directory DIR using function FUNC."
 560   (let* ((files (directory-files dir t "^[^.]"))
 561          (max (/ (length files) 100.0))
 562          (count 0))
 563     (with-temp-buffer
 564       (dolist (f files)
 565         (when (and (file-readable-p f)
 566                    (file-regular-p f)
 567                    (> (nth 7 (file-attributes f)) 0)
 568                    (< (time-to-number-of-days (time-since (nth 5 (file-attributes f))))
 569                       spam-stat-process-directory-age))
 570           (setq count (1+ count))
 571           (message "Reading %s: %.2f%%" dir (/ count max))
 572           (insert-file-contents-literally f)
 573           (spam-stat-strip-xref)
 574           (funcall func)
 575           (erase-buffer))))))
 576
 577 (defun spam-stat-process-spam-directory (dir)
 578   "Process all the regular files in directory DIR as spam."
 579   (interactive "D")
 580   (spam-stat-process-directory dir 'spam-stat-buffer-is-spam))
 581
 582 (defun spam-stat-process-non-spam-directory (dir)
 583   "Process all the regular files in directory DIR as non-spam."
 584   (interactive "D")
 585   (spam-stat-process-directory dir 'spam-stat-buffer-is-non-spam))
 586
 587 (defun spam-stat-count ()
 588   "Return size of `spam-stat'."
 589   (interactive)
 590   (hash-table-count spam-stat))
 591
 592 (defun spam-stat-test-directory (dir &optional verbose)
 593   "Test all the regular files in directory DIR for spam.
 594 If the result is 1.0, then all files are considered spam.
 595 If the result is 0.0, non of the files is considered spam.
 596 You can use this to determine error rates.
 597
 598 If VERBOSE is non-nil display names of files detected as spam or
 599 non-spam in a temporary buffer.  If it is the symbol `ham',
 600 display non-spam files; otherwise display spam files."
 601   (interactive "DDirectory: ")
 602   (let* ((files (directory-files dir t "^[^.]"))
 603          display-files
 604          buffer-score
 605          (total (length files))
 606          (score 0.0); float
 607          (max (/ total 100.0)); float
 608          (count 0))
 609     (with-temp-buffer
 610       (dolist (f files)
 611         (when (and (file-readable-p f)
 612                    (file-regular-p f)
 613                    (> (nth 7 (file-attributes f)) 0))
 614           (setq count (1+ count))
 615           (message "Reading %.2f%%, score %.2f"
 616                    (/ count max) (/ score count))
 617           (insert-file-contents-literally f)
 618           (setq buffer-score (spam-stat-score-buffer))
 619           (when (> buffer-score 0.9)
 620             (setq score (1+ score)))
 621           (when verbose
 622             (if (> buffer-score 0.9)
 623                 (unless (eq verbose 'ham) (push f display-files))
 624               (when (eq verbose 'ham) (push f display-files))))
 625           (erase-buffer))))
 626     (when display-files
 627       (with-output-to-temp-buffer "*spam-stat results*"
 628         (dolist (file display-files)
 629           (princ file)
 630           (terpri))))
 631     (message "Final score: %d / %d = %f" score total (/ score total))))
 632
 633 ;; Shrinking the dictionary
 634
 635 (defun spam-stat-reduce-size (&optional count)
 636   "Reduce the size of `spam-stat'.
 637 This removes all words that occur less than COUNT from the dictionary.
 638 COUNT defaults to 5"
 639   (interactive)
 640   (setq count (or count 5))
 641   (maphash (lambda (key entry)
 642              (when (< (+ (spam-stat-good entry)
 643                          (spam-stat-bad entry))
 644                       count)
 645                (remhash key spam-stat)))
 646            spam-stat)
 647   (setq spam-stat-dirty t))
 648
 649 (defun spam-stat-install-hooks-function ()
 650   "Install the spam-stat function hooks."
 651   (interactive)
 652   (add-hook 'nnmail-prepare-incoming-message-hook
 653             'spam-stat-store-current-buffer)
 654   (add-hook 'gnus-select-article-hook
 655             'spam-stat-store-gnus-article-buffer))
 656
 657 (when spam-stat-install-hooks
 658   (spam-stat-install-hooks-function))
 659
 660 (defun spam-stat-unload-hook ()
 661   "Uninstall the spam-stat function hooks."
 662   (interactive)
 663   (remove-hook 'nnmail-prepare-incoming-message-hook
 664                'spam-stat-store-current-buffer)
 665   (remove-hook 'gnus-select-article-hook
 666                'spam-stat-store-gnus-article-buffer))
 667
 668 (add-hook 'spam-stat-unload-hook 'spam-stat-unload-hook)
 669
 670 (provide 'spam-stat)
 671
 672 ;;; arch-tag: ff1d2200-8ddb-42fb-bb7b-1b5e20448554
 673 ;;; spam-stat.el ends here