cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   3
   4 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (eval-and-compile
  35   (autoload 'mm-url-insert "mm-url"))
  36
  37 (defgroup spam-report nil
  38   "Spam reporting configuration.")
  39
  40 (defcustom spam-report-gmane-regex nil
  41   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  42 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  43 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  44 instead."
  45   :type '(radio (const nil)
  46                 (regexp :format "%t: %v\n" :size 0 :value "^nntp\+.*:gmane\."))
  47   :group 'spam-report)
  48
  49 (defcustom spam-report-gmane-spam-header
  50   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  51   "String matching Gmane spam-reporting header.  Two match groups are needed."
  52   :type 'regexp
  53   :group 'spam-report)
  54
  55 (defcustom spam-report-gmane-use-article-number t
  56   "Whether the article number (faster!) or the header should be used."
  57   :type 'boolean
  58   :group 'spam-report)
  59
  60 (defcustom spam-report-url-ping-function
  61   'spam-report-url-ping-plain
  62   "Function to use for url ping spam reporting.
  63 The function must accept the arguments `host' and `report'."
  64   :type '(choice
  65           (const :tag "Connect directly"
  66                  spam-report-url-ping-plain)
  67           (const :tag "Use the external program specified in `mm-url-program'"
  68                  spam-report-url-ping-mm-url)
  69           (const :tag "Store request URLs in `spam-report-requests-file'"
  70                  spam-report-url-to-file)
  71           (function :tag "User defined function" nil))
  72   :group 'spam-report)
  73
  74 (defcustom spam-report-requests-file
  75   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  76   ;; Is there a convention for the extension of such a file?
  77   ;; Should we use `spam-directory'?
  78   "File where spam report request are stored."
  79   :type 'file
  80   :group 'spam-report)
  81
  82 (defcustom spam-report-resend-to (or
  83                                   (when (length user-mail-address)
  84                                     user-mail-address)
  85                                   "nonexistent-user-please-fix@invalid.domain")
  86   "Email address that spam articles are resent to when reporting."
  87   :type 'string
  88   :group 'spam-report)
  89
  90 (defvar spam-report-url-ping-temp-agent-function nil
  91   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  92 This variable will store the value of `spam-report-url-ping-function' from
  93 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  94 undo that change.")
  95
  96 (defun spam-report-resend (articles)
  97   "Report an article as spam by resending via email."
  98   (dolist (article articles)
  99     (gnus-message 6
 100                   "Reporting spam article %d to <%s>..."
 101                   article spam-report-resend-to)
 102     ;; This is ganked from the `gnus-summary-resend-message' function.
 103     ;; It involves rendering the SPAM, which is undesirable, but there does
 104     ;; not seem to be a nicer way to achieve this.
 105     ;; select this particular article
 106     (gnus-summary-select-article nil nil nil article)
 107     ;; resend it to the destination address
 108     (save-excursion
 109       (set-buffer gnus-original-article-buffer)
 110       (message-resend spam-report-resend-to))))
 111
 112 (defun spam-report-gmane (&rest articles)
 113   "Report an article as spam through Gmane"
 114   (dolist (article articles)
 115     (when (and gnus-newsgroup-name
 116                (or (null spam-report-gmane-regex)
 117                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 118       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
 119       (if spam-report-gmane-use-article-number
 120           (spam-report-url-ping
 121            "spam.gmane.org"
 122            (format "/%s:%d"
 123                    (gnus-group-real-name gnus-newsgroup-name)
 124                    article))
 125         (with-current-buffer nntp-server-buffer
 126           (gnus-request-head article gnus-newsgroup-name)
 127           (goto-char (point-min))
 128           (if (re-search-forward spam-report-gmane-spam-header nil t)
 129               (let* ((host (match-string 1))
 130                      (report (match-string 2))
 131                      (url (format "http://%s%s" host report)))
 132                 (gnus-message 7 "Reporting spam through URL %s..." url)
 133                 (spam-report-url-ping host report))
 134             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 135                           article)))))))
 136
 137 (defun spam-report-url-ping (host report)
 138   "Ping a host through HTTP, addressing a specific GET resource using
 139 the function specified by `spam-report-url-ping-function'."
 140   (funcall spam-report-url-ping-function host report))
 141
 142 (defun spam-report-url-ping-plain (host report)
 143   "Ping a host through HTTP, addressing a specific GET resource."
 144   (let ((tcp-connection))
 145     (with-temp-buffer
 146       (or (setq tcp-connection
 147                 (open-network-stream
 148                  "URL ping"
 149                  (buffer-name)
 150                  host
 151                  80))
 152           (error "Could not open connection to %s" host))
 153       (set-marker (process-mark tcp-connection) (point-min))
 154       (process-send-string
 155        tcp-connection
 156        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 157                report (gnus-emacs-version) host)))))
 158
 159 ;;;###autoload
 160 (defun spam-report-process-queue (&optional file keep)
 161   "Report all queued requests from `spam-report-requests-file'.
 162
 163 If FILE is given, use it instead of `spam-report-requests-file'.
 164 If KEEP is t, leave old requests in the file.  If KEEP is the
 165 symbol `ask', query before flushing the queue file."
 166   (interactive
 167    (list (read-file-name
 168           "File: "
 169           (file-name-directory spam-report-requests-file)
 170           spam-report-requests-file
 171           nil
 172           (file-name-nondirectory spam-report-requests-file))
 173          current-prefix-arg))
 174   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 175       (error (concat "Cannot process requests when "
 176                      "`spam-report-url-ping-function' is "
 177                      "`spam-report-url-to-file'."))
 178     (gnus-message 7 "Processing requests using `%s'."
 179                   spam-report-url-ping-function))
 180   (or file (setq file spam-report-requests-file))
 181   (save-excursion
 182     (set-buffer (find-file-noselect file))
 183     (goto-char (point-min))
 184     (while (and (not (eobp))
 185                 (re-search-forward
 186                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 187       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 188       (forward-line 1))
 189     (if (or (eq keep nil)
 190             (and (eq keep 'ask)
 191                  (y-or-n-p
 192                   (format
 193                    "Flush requests from `%s'? " (current-buffer)))))
 194         (progn
 195           (gnus-message 7 "Flushing request file `%s'"
 196                         spam-report-requests-file)
 197           (erase-buffer)
 198           (save-buffer)
 199           (kill-buffer (current-buffer)))
 200       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 201
 202 ;;;###autoload
 203 (defun spam-report-url-ping-mm-url (host report)
 204   "Ping a host through HTTP, addressing a specific GET resource. Use
 205 the external program specified in `mm-url-program' to connect to
 206 server."
 207   (with-temp-buffer
 208     (let ((url (concat "http://" host report)))
 209       (mm-url-insert url t))))
 210
 211 ;;;###autoload
 212 (defun spam-report-url-to-file (host report)
 213   "Collect spam report requests in `spam-report-requests-file'.
 214 Customize `spam-report-url-ping-function' to use this function."
 215   (let ((url (concat "http://" host report))
 216         (file spam-report-requests-file))
 217     (gnus-make-directory (file-name-directory file))
 218     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 219     (with-temp-buffer
 220       (insert url)
 221       (newline)
 222       (append-to-file (point-min) (point-max) file))))
 223
 224 ;;;###autoload
 225 (defun spam-report-agentize ()
 226   "Add spam-report support to the Agent.
 227 Spam reports will be queued with \\[spam-report-url-to-file] when
 228 the Agent is unplugged, and will be submitted in a batch when the
 229 Agent is plugged."
 230   (interactive)
 231   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 232   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 233
 234 ;;;###autoload
 235 (defun spam-report-deagentize ()
 236   "Remove spam-report support from the Agent.
 237 Spam reports will be queued with the method used when
 238 \\[spam-report-agentize] was run."
 239   (interactive)
 240   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 241   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 242
 243 (defun spam-report-plug-agent ()
 244   "Adjust spam report settings for plugged state.
 245 Process queued spam reports."
 246   ;; Process the queue, unless the user only wanted to report to a file
 247   ;; anyway.
 248   (unless (equal spam-report-url-ping-temp-agent-function
 249                  'spam-report-url-to-file)
 250     (spam-report-process-queue))
 251   ;; Set the reporting function, if we have memorized something otherwise,
 252   ;; stick with plain URL reporting.
 253   (setq spam-report-url-ping-function
 254         (or spam-report-url-ping-temp-agent-function
 255             'spam-report-url-ping-plain)))
 256
 257 (defun spam-report-unplug-agent ()
 258   "Restore spam report settings for unplugged state."
 259   ;; save the old value
 260   (setq spam-report-url-ping-temp-agent-function
 261         spam-report-url-ping-function)
 262   ;; store all reports to file
 263   (setq spam-report-url-ping-function
 264         'spam-report-url-to-file))
 265
 266 (provide 'spam-report)
 267
 268 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 269 ;;; spam-report.el ends here.