cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-spam-header
  53   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  54   "String matching Gmane spam-reporting header.  Two match groups are needed."
  55   :type 'regexp
  56   :group 'spam-report)
  57
  58 (defcustom spam-report-gmane-use-article-number t
  59   "Whether the article number (faster!) or the header should be used."
  60   :type 'boolean
  61   :group 'spam-report)
  62
  63 (defcustom spam-report-url-ping-function
  64   'spam-report-url-ping-plain
  65   "Function to use for url ping spam reporting.
  66 The function must accept the arguments `host' and `report'."
  67   :type '(choice
  68           (const :tag "Connect directly"
  69                  spam-report-url-ping-plain)
  70           (const :tag "Use the external program specified in `mm-url-program'"
  71                  spam-report-url-ping-mm-url)
  72           (const :tag "Store request URLs in `spam-report-requests-file'"
  73                  spam-report-url-to-file)
  74           (function :tag "User defined function" nil))
  75   :group 'spam-report)
  76
  77 (defcustom spam-report-requests-file
  78   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  79   ;; Is there a convention for the extension of such a file?
  80   ;; Should we use `spam-directory'?
  81   "File where spam report request are stored."
  82   :type 'file
  83   :group 'spam-report)
  84
  85 (defcustom spam-report-resend-to nil
  86   "Email address that spam articles are resent to when reporting.
  87 If not set, the user will be prompted to enter a value which will be
  88 saved for future use."
  89   :type 'string
  90   :group 'spam-report)
  91
  92 (defvar spam-report-url-ping-temp-agent-function nil
  93   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  94 This variable will store the value of `spam-report-url-ping-function' from
  95 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  96 undo that change.")
  97
  98 (defun spam-report-resend (articles &optional ham)
  99   "Report an article as spam by resending via email.
 100 Reports is as ham when HAM is set."
 101   (dolist (article articles)
 102     (gnus-message 6
 103                   "Reporting %s article %d to <%s>..."
 104                   (if ham "ham" "spam")
 105                   article spam-report-resend-to)
 106     (unless spam-report-resend-to
 107       (customize-set-variable
 108        spam-report-resend-to
 109        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 110     ;; This is ganked from the `gnus-summary-resend-message' function.
 111     ;; It involves rendering the SPAM, which is undesirable, but there does
 112     ;; not seem to be a nicer way to achieve this.
 113     ;; select this particular article
 114     (gnus-summary-select-article nil nil nil article)
 115     ;; resend it to the destination address
 116     (save-excursion
 117       (set-buffer gnus-original-article-buffer)
 118       (message-resend spam-report-resend-to))))
 119
 120 (defun spam-report-resend-ham (articles)
 121   "Report an article as ham by resending via email."
 122   (spam-report-resend articles t))
 123
 124 (defun spam-report-gmane (&rest articles)
 125   "Report an article as spam through Gmane."
 126   (interactive (gnus-summary-work-articles current-prefix-arg))
 127   (dolist (article articles)
 128     (when (and gnus-newsgroup-name
 129                (or (null spam-report-gmane-regex)
 130                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 131       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
 132       (if spam-report-gmane-use-article-number
 133           (spam-report-url-ping
 134            "spam.gmane.org"
 135            (format "/%s:%d"
 136                    (gnus-group-real-name gnus-newsgroup-name)
 137                    article))
 138         (with-current-buffer nntp-server-buffer
 139           (gnus-request-head article gnus-newsgroup-name)
 140           (goto-char (point-min))
 141           (if (re-search-forward spam-report-gmane-spam-header nil t)
 142               (let* ((host (match-string 1))
 143                      (report (match-string 2))
 144                      (url (format "http://%s%s" host report)))
 145                 (gnus-message 7 "Reporting spam through URL %s..." url)
 146                 (spam-report-url-ping host report))
 147             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 148                           article)))))))
 149
 150
 151 (defun spam-report-url-ping (host report)
 152   "Ping a host through HTTP, addressing a specific GET resource using
 153 the function specified by `spam-report-url-ping-function'."
 154   (funcall spam-report-url-ping-function host report))
 155
 156 (defun spam-report-url-ping-plain (host report)
 157   "Ping a host through HTTP, addressing a specific GET resource."
 158   (let ((tcp-connection))
 159     (with-temp-buffer
 160       (or (setq tcp-connection
 161                 (open-network-stream
 162                  "URL ping"
 163                  (buffer-name)
 164                  host
 165                  80))
 166           (error "Could not open connection to %s" host))
 167       (set-marker (process-mark tcp-connection) (point-min))
 168       (process-send-string
 169        tcp-connection
 170        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 171                report (gnus-emacs-version) host)))))
 172
 173 ;;;###autoload
 174 (defun spam-report-process-queue (&optional file keep)
 175   "Report all queued requests from `spam-report-requests-file'.
 176
 177 If FILE is given, use it instead of `spam-report-requests-file'.
 178 If KEEP is t, leave old requests in the file.  If KEEP is the
 179 symbol `ask', query before flushing the queue file."
 180   (interactive
 181    (list (read-file-name
 182           "File: "
 183           (file-name-directory spam-report-requests-file)
 184           spam-report-requests-file
 185           nil
 186           (file-name-nondirectory spam-report-requests-file))
 187          current-prefix-arg))
 188   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 189       (error (concat "Cannot process requests when "
 190                      "`spam-report-url-ping-function' is "
 191                      "`spam-report-url-to-file'."))
 192     (gnus-message 7 "Processing requests using `%s'."
 193                   spam-report-url-ping-function))
 194   (or file (setq file spam-report-requests-file))
 195   (save-excursion
 196     (set-buffer (find-file-noselect file))
 197     (goto-char (point-min))
 198     (while (and (not (eobp))
 199                 (re-search-forward
 200                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 201       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 202       (forward-line 1))
 203     (if (or (eq keep nil)
 204             (and (eq keep 'ask)
 205                  (y-or-n-p
 206                   (format
 207                    "Flush requests from `%s'? " (current-buffer)))))
 208         (progn
 209           (gnus-message 7 "Flushing request file `%s'"
 210                         spam-report-requests-file)
 211           (erase-buffer)
 212           (save-buffer)
 213           (kill-buffer (current-buffer)))
 214       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 215
 216 ;;;###autoload
 217 (defun spam-report-url-ping-mm-url (host report)
 218   "Ping a host through HTTP, addressing a specific GET resource. Use
 219 the external program specified in `mm-url-program' to connect to
 220 server."
 221   (with-temp-buffer
 222     (let ((url (format "http://%s%s" host report)))
 223       (mm-url-insert url t))))
 224
 225 ;;;###autoload
 226 (defun spam-report-url-to-file (host report)
 227   "Collect spam report requests in `spam-report-requests-file'.
 228 Customize `spam-report-url-ping-function' to use this function."
 229   (let ((url (format "http://%s%s" host report))
 230         (file spam-report-requests-file))
 231     (gnus-make-directory (file-name-directory file))
 232     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 233     (with-temp-buffer
 234       (insert url)
 235       (newline)
 236       (append-to-file (point-min) (point-max) file))))
 237
 238 ;;;###autoload
 239 (defun spam-report-agentize ()
 240   "Add spam-report support to the Agent.
 241 Spam reports will be queued with \\[spam-report-url-to-file] when
 242 the Agent is unplugged, and will be submitted in a batch when the
 243 Agent is plugged."
 244   (interactive)
 245   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 246   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 247
 248 ;;;###autoload
 249 (defun spam-report-deagentize ()
 250   "Remove spam-report support from the Agent.
 251 Spam reports will be queued with the method used when
 252 \\[spam-report-agentize] was run."
 253   (interactive)
 254   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 255   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 256
 257 (defun spam-report-plug-agent ()
 258   "Adjust spam report settings for plugged state.
 259 Process queued spam reports."
 260   ;; Process the queue, unless the user only wanted to report to a file
 261   ;; anyway.
 262   (unless (equal spam-report-url-ping-temp-agent-function
 263                  'spam-report-url-to-file)
 264     (spam-report-process-queue))
 265   ;; Set the reporting function, if we have memorized something otherwise,
 266   ;; stick with plain URL reporting.
 267   (setq spam-report-url-ping-function
 268         (or spam-report-url-ping-temp-agent-function
 269             'spam-report-url-ping-plain)))
 270
 271 (defun spam-report-unplug-agent ()
 272   "Restore spam report settings for unplugged state."
 273   ;; save the old value
 274   (setq spam-report-url-ping-temp-agent-function
 275         spam-report-url-ping-function)
 276   ;; store all reports to file
 277   (setq spam-report-url-ping-function
 278         'spam-report-url-to-file))
 279
 280 (provide 'spam-report)
 281
 282 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 283 ;;; spam-report.el ends here.