cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network, spam, mail, gmane, report
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-use-article-number t
  53   "Whether the article number (faster!) or the header should be used.
  54
  55 You must set this to nil if you don't read Gmane groups directly
  56 from news.gmane.org, e.g. when using local newsserver such as
  57 leafnode."
  58   :type 'boolean
  59   :group 'spam-report)
  60
  61 (defcustom spam-report-url-ping-function
  62   'spam-report-url-ping-plain
  63   "Function to use for url ping spam reporting.
  64 The function must accept the arguments `host' and `report'."
  65   :type '(choice
  66           (const :tag "Connect directly"
  67                  spam-report-url-ping-plain)
  68           (const :tag "Use the external program specified in `mm-url-program'"
  69                  spam-report-url-ping-mm-url)
  70           (const :tag "Store request URLs in `spam-report-requests-file'"
  71                  spam-report-url-to-file)
  72           (function :tag "User defined function" nil))
  73   :group 'spam-report)
  74
  75 (defcustom spam-report-requests-file
  76   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  77   ;; Is there a convention for the extension of such a file?
  78   ;; Should we use `spam-directory'?
  79   "File where spam report request are stored."
  80   :type 'file
  81   :group 'spam-report)
  82
  83 (defcustom spam-report-resend-to nil
  84   "Email address that spam articles are resent to when reporting.
  85 If not set, the user will be prompted to enter a value which will be
  86 saved for future use."
  87   :type 'string
  88   :group 'spam-report)
  89
  90 (defvar spam-report-url-ping-temp-agent-function nil
  91   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  92 This variable will store the value of `spam-report-url-ping-function' from
  93 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  94 undo that change.")
  95
  96 (defun spam-report-resend (articles &optional ham)
  97   "Report an article as spam by resending via email.
  98 Reports is as ham when HAM is set."
  99   (dolist (article articles)
 100     (gnus-message 6
 101                   "Reporting %s article %d to <%s>..."
 102                   (if ham "ham" "spam")
 103                   article spam-report-resend-to)
 104     (unless spam-report-resend-to
 105       (customize-set-variable
 106        spam-report-resend-to
 107        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 108     ;; This is ganked from the `gnus-summary-resend-message' function.
 109     ;; It involves rendering the SPAM, which is undesirable, but there does
 110     ;; not seem to be a nicer way to achieve this.
 111     ;; select this particular article
 112     (gnus-summary-select-article nil nil nil article)
 113     ;; resend it to the destination address
 114     (save-excursion
 115       (set-buffer gnus-original-article-buffer)
 116       (message-resend spam-report-resend-to))))
 117
 118 (defun spam-report-resend-ham (articles)
 119   "Report an article as ham by resending via email."
 120   (spam-report-resend articles t))
 121
 122 (defun spam-report-gmane-ham (&rest articles)
 123   "Report ARTICLES as ham (unregister) through Gmane."
 124   (interactive (gnus-summary-work-articles current-prefix-arg))
 125   (dolist (article articles)
 126     (spam-report-gmane-internal t article)))
 127
 128 (defun spam-report-gmane-spam (&rest articles)
 129   "Report ARTICLES as spam through Gmane."
 130   (interactive (gnus-summary-work-articles current-prefix-arg))
 131   (dolist (article articles)
 132     (spam-report-gmane-internal nil article)))
 133
 134 ;; `spam-report-gmane' was an interactive entry point, so we should provide an
 135 ;; alias.
 136 (defalias 'spam-report-gmane 'spam-report-gmane-spam)
 137
 138 (defun spam-report-gmane-internal (unspam article)
 139   "Report ARTICLE as spam or not-spam through Gmane, depending on UNSPAM."
 140   (when (and gnus-newsgroup-name
 141              (or (null spam-report-gmane-regex)
 142                  (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 143     (let ((rpt-host (if unspam "unspam.gmane.org" "spam.gmane.org")))
 144       (gnus-message 6 "Reporting article %d to %s..." article rpt-host)
 145       (if spam-report-gmane-use-article-number
 146           (spam-report-url-ping
 147            rpt-host
 148            (format "/%s:%d"
 149                    (gnus-group-real-name gnus-newsgroup-name)
 150                    article))
 151         (with-current-buffer nntp-server-buffer
 152           (gnus-request-head article gnus-newsgroup-name)
 153           (let ((case-fold-search t)
 154                 field host report url)
 155             ;; First check for X-Report-Spam because it's more specific to
 156             ;; spam reporting than Archived-At.  OTOH, all new articles on
 157             ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 158             ;; mind :-)).
 159             ;;
 160             ;; There might be more than one Archived-At header so we need to
 161             ;; find (and transform) the one related to Gmane.
 162             (setq field (or (gnus-fetch-field "X-Report-Spam")
 163                             (gnus-fetch-field "X-Report-Unspam")
 164                             (gnus-fetch-field "Archived-At")))
 165             (when (stringp field)
 166               (setq host
 167                     (progn
 168                       (string-match
 169                        (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 170                                "\\(/[^:/]+[:/][0-9]+\\)")
 171                        field)
 172                       (match-string 1 field)))
 173               (setq report (match-string 2 field))
 174               (when (string-equal "permalink.gmane.org" host)
 175                 (setq host rpt-host)
 176                 (setq report (gnus-replace-in-string
 177                               report "/\\([0-9]+\\)$" ":\\1")))
 178               (setq url (format "http://%s%s" host report)))
 179             (if (not (and host report url))
 180                 (gnus-message
 181                  3 "Could not find a spam report header in article %d..."
 182                  article)
 183               (gnus-message 7 "Reporting article through URL %s..." url)
 184               (spam-report-url-ping host report))))))))
 185
 186 (defun spam-report-url-ping (host report)
 187   "Ping a host through HTTP, addressing a specific GET resource using
 188 the function specified by `spam-report-url-ping-function'."
 189   ;; Example:
 190   ;; host: "spam.gmane.org"
 191   ;; report: "/gmane.some.group:123456"
 192   (funcall spam-report-url-ping-function host report))
 193
 194 (defcustom spam-report-user-mail-address
 195   (and (stringp user-mail-address)
 196        (gnus-replace-in-string user-mail-address "@" "<at>"))
 197   "Mail address of this user used for spam reports to Gmane.
 198 This is initialized based on `user-mail-address'."
 199   :type '(choice string
 200                  (const :tag "Don't expose address" nil))
 201   :version "23.0" ;; No Gnus
 202   :group 'spam-report)
 203
 204 (defvar spam-report-user-agent
 205   (if spam-report-user-mail-address
 206       (format "%s (%s) %s" "spam-report.el"
 207               spam-report-user-mail-address
 208               (gnus-extended-version))
 209     (format "%s %s" "spam-report.el"
 210             (gnus-extended-version))))
 211
 212 (defun spam-report-url-ping-plain (host report)
 213   "Ping a host through HTTP, addressing a specific GET resource."
 214   (let ((tcp-connection))
 215     (with-temp-buffer
 216       (or (setq tcp-connection
 217                 (open-network-stream
 218                  "URL ping"
 219                  (buffer-name)
 220                  host
 221                  80))
 222           (error "Could not open connection to %s" host))
 223       (set-marker (process-mark tcp-connection) (point-min))
 224       (process-send-string
 225        tcp-connection
 226        (format "GET %s HTTP/1.1\nUser-Agent: %s\nHost: %s\n\n"
 227                report spam-report-user-agent host)))))
 228
 229 ;;;###autoload
 230 (defun spam-report-process-queue (&optional file keep)
 231   "Report all queued requests from `spam-report-requests-file'.
 232
 233 If FILE is given, use it instead of `spam-report-requests-file'.
 234 If KEEP is t, leave old requests in the file.  If KEEP is the
 235 symbol `ask', query before flushing the queue file."
 236   (interactive
 237    (list (read-file-name
 238           "File: "
 239           (file-name-directory spam-report-requests-file)
 240           spam-report-requests-file
 241           nil
 242           (file-name-nondirectory spam-report-requests-file))
 243          current-prefix-arg))
 244   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 245       (error (concat "Cannot process requests when "
 246                      "`spam-report-url-ping-function' is "
 247                      "`spam-report-url-to-file'."))
 248     (gnus-message 7 "Processing requests using `%s'."
 249                   spam-report-url-ping-function))
 250   (or file (setq file spam-report-requests-file))
 251   (save-excursion
 252     (set-buffer (find-file-noselect file))
 253     (goto-char (point-min))
 254     (while (and (not (eobp))
 255                 (re-search-forward
 256                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 257       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 258       (forward-line 1))
 259     (if (or (eq keep nil)
 260             (and (eq keep 'ask)
 261                  (y-or-n-p
 262                   (format
 263                    "Flush requests from `%s'? " (current-buffer)))))
 264         (progn
 265           (gnus-message 7 "Flushing request file `%s'"
 266                         spam-report-requests-file)
 267           (erase-buffer)
 268           (save-buffer)
 269           (kill-buffer (current-buffer)))
 270       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 271
 272 ;;;###autoload
 273 (defun spam-report-url-ping-mm-url (host report)
 274   "Ping a host through HTTP, addressing a specific GET resource. Use
 275 the external program specified in `mm-url-program' to connect to
 276 server."
 277   (with-temp-buffer
 278     (let ((url (format "http://%s%s" host report)))
 279       (mm-url-insert url t))))
 280
 281 ;;;###autoload
 282 (defun spam-report-url-to-file (host report)
 283   "Collect spam report requests in `spam-report-requests-file'.
 284 Customize `spam-report-url-ping-function' to use this function."
 285   (let ((url (format "http://%s%s" host report))
 286         (file spam-report-requests-file))
 287     (gnus-make-directory (file-name-directory file))
 288     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 289     (with-temp-buffer
 290       (insert url)
 291       (newline)
 292       (append-to-file (point-min) (point-max) file))))
 293
 294 ;;;###autoload
 295 (defun spam-report-agentize ()
 296   "Add spam-report support to the Agent.
 297 Spam reports will be queued with \\[spam-report-url-to-file] when
 298 the Agent is unplugged, and will be submitted in a batch when the
 299 Agent is plugged."
 300   (interactive)
 301   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 302   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 303
 304 ;;;###autoload
 305 (defun spam-report-deagentize ()
 306   "Remove spam-report support from the Agent.
 307 Spam reports will be queued with the method used when
 308 \\[spam-report-agentize] was run."
 309   (interactive)
 310   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 311   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 312
 313 (defun spam-report-plug-agent ()
 314   "Adjust spam report settings for plugged state.
 315 Process queued spam reports."
 316   ;; Process the queue, unless the user only wanted to report to a file
 317   ;; anyway.
 318   (unless (equal spam-report-url-ping-temp-agent-function
 319                  'spam-report-url-to-file)
 320     (spam-report-process-queue))
 321   ;; Set the reporting function, if we have memorized something otherwise,
 322   ;; stick with plain URL reporting.
 323   (setq spam-report-url-ping-function
 324         (or spam-report-url-ping-temp-agent-function
 325             'spam-report-url-ping-plain)))
 326
 327 (defun spam-report-unplug-agent ()
 328   "Restore spam report settings for unplugged state."
 329   ;; save the old value
 330   (setq spam-report-url-ping-temp-agent-function
 331         spam-report-url-ping-function)
 332   ;; store all reports to file
 333   (setq spam-report-url-ping-function
 334         'spam-report-url-to-file))
 335
 336 (provide 'spam-report)
 337
 338 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 339 ;;; spam-report.el ends here.