cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network, spam, mail, gmane, report
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-use-article-number t
  53   "Whether the article number (faster!) or the header should be used."
  54   :type 'boolean
  55   :group 'spam-report)
  56
  57 (defcustom spam-report-url-ping-function
  58   'spam-report-url-ping-plain
  59   "Function to use for url ping spam reporting.
  60 The function must accept the arguments `host' and `report'."
  61   :type '(choice
  62           (const :tag "Connect directly"
  63                  spam-report-url-ping-plain)
  64           (const :tag "Use the external program specified in `mm-url-program'"
  65                  spam-report-url-ping-mm-url)
  66           (const :tag "Store request URLs in `spam-report-requests-file'"
  67                  spam-report-url-to-file)
  68           (function :tag "User defined function" nil))
  69   :group 'spam-report)
  70
  71 (defcustom spam-report-requests-file
  72   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  73   ;; Is there a convention for the extension of such a file?
  74   ;; Should we use `spam-directory'?
  75   "File where spam report request are stored."
  76   :type 'file
  77   :group 'spam-report)
  78
  79 (defcustom spam-report-resend-to nil
  80   "Email address that spam articles are resent to when reporting.
  81 If not set, the user will be prompted to enter a value which will be
  82 saved for future use."
  83   :type 'string
  84   :group 'spam-report)
  85
  86 (defvar spam-report-url-ping-temp-agent-function nil
  87   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  88 This variable will store the value of `spam-report-url-ping-function' from
  89 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  90 undo that change.")
  91
  92 (defun spam-report-resend (articles &optional ham)
  93   "Report an article as spam by resending via email.
  94 Reports is as ham when HAM is set."
  95   (dolist (article articles)
  96     (gnus-message 6
  97                   "Reporting %s article %d to <%s>..."
  98                   (if ham "ham" "spam")
  99                   article spam-report-resend-to)
 100     (unless spam-report-resend-to
 101       (customize-set-variable
 102        spam-report-resend-to
 103        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 104     ;; This is ganked from the `gnus-summary-resend-message' function.
 105     ;; It involves rendering the SPAM, which is undesirable, but there does
 106     ;; not seem to be a nicer way to achieve this.
 107     ;; select this particular article
 108     (gnus-summary-select-article nil nil nil article)
 109     ;; resend it to the destination address
 110     (save-excursion
 111       (set-buffer gnus-original-article-buffer)
 112       (message-resend spam-report-resend-to))))
 113
 114 (defun spam-report-resend-ham (articles)
 115   "Report an article as ham by resending via email."
 116   (spam-report-resend articles t))
 117
 118 (defun spam-report-gmane-ham (&rest articles)
 119   "Report ARTICLES as ham (unregister) through Gmane."
 120   (interactive (gnus-summary-work-articles current-prefix-arg))
 121   (dolist (article articles)
 122     (spam-report-gmane-internal t article)))
 123
 124 (defun spam-report-gmane-spam (&rest articles)
 125   "Report ARTICLES as spam through Gmane."
 126   (interactive (gnus-summary-work-articles current-prefix-arg))
 127   (dolist (article articles)
 128     (spam-report-gmane-internal nil article)))
 129
 130 ;; `spam-report-gmane' was an interactive entry point, so we should provide an
 131 ;; alias.
 132 (defalias 'spam-report-gmane 'spam-report-gmane-spam)
 133
 134 (defun spam-report-gmane-internal (unspam article)
 135   "Report ARTICLE as spam or not-spam through Gmane, depending on UNSPAM."
 136   (when (and gnus-newsgroup-name
 137              (or (null spam-report-gmane-regex)
 138                  (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 139     (let ((rpt-host (if unspam "unspam.gmane.org" "spam.gmane.org")))
 140       (gnus-message 6 "Reporting article %d to %s..." article rpt-host)
 141       (if spam-report-gmane-use-article-number
 142           (spam-report-url-ping
 143            rpt-host
 144            (format "/%s:%d"
 145                    (gnus-group-real-name gnus-newsgroup-name)
 146                    article))
 147         (with-current-buffer nntp-server-buffer
 148           (gnus-request-head article gnus-newsgroup-name)
 149           (let ((case-fold-search t)
 150                 field host report url)
 151             ;; First check for X-Report-Spam because it's more specific to
 152             ;; spam reporting than Archived-At.  OTOH, all new articles on
 153             ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 154             ;; mind :-)).
 155             ;;
 156             ;; There might be more than one Archived-At header so we need to
 157             ;; find (and transform) the one related to Gmane.
 158             (setq field (or (gnus-fetch-field "X-Report-Spam")
 159                             (gnus-fetch-field "X-Report-Unspam")
 160                             (gnus-fetch-field "Archived-At")))
 161             (setq host (progn
 162                          (string-match
 163                           (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 164                                   "\\(/[^:/]+[:/][0-9]+\\)")
 165                           field)
 166                          (match-string 1 field)))
 167             (setq report (match-string 2 field))
 168             (when (string-equal "permalink.gmane.org" host)
 169               (setq host rpt-host)
 170               (setq report (gnus-replace-in-string
 171                             report "/\\([0-9]+\\)$" ":\\1")))
 172             (setq url (format "http://%s%s" host report))
 173             (if (not (and host report url))
 174                 (gnus-message
 175                  3 "Could not find a spam report header in article %d..."
 176                  article)
 177               (gnus-message 7 "Reporting article through URL %s..." url)
 178               (spam-report-url-ping host report))))))))
 179
 180 (defun spam-report-url-ping (host report)
 181   "Ping a host through HTTP, addressing a specific GET resource using
 182 the function specified by `spam-report-url-ping-function'."
 183   ;; Example:
 184   ;; host: "spam.gmane.org"
 185   ;; report: "/gmane.some.group:123456"
 186   (funcall spam-report-url-ping-function host report))
 187
 188 (defun spam-report-url-ping-plain (host report)
 189   "Ping a host through HTTP, addressing a specific GET resource."
 190   (let ((tcp-connection))
 191     (with-temp-buffer
 192       (or (setq tcp-connection
 193                 (open-network-stream
 194                  "URL ping"
 195                  (buffer-name)
 196                  host
 197                  80))
 198           (error "Could not open connection to %s" host))
 199       (set-marker (process-mark tcp-connection) (point-min))
 200       (process-send-string
 201        tcp-connection
 202        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 203                report (gnus-extended-version) host)))))
 204
 205 ;;;###autoload
 206 (defun spam-report-process-queue (&optional file keep)
 207   "Report all queued requests from `spam-report-requests-file'.
 208
 209 If FILE is given, use it instead of `spam-report-requests-file'.
 210 If KEEP is t, leave old requests in the file.  If KEEP is the
 211 symbol `ask', query before flushing the queue file."
 212   (interactive
 213    (list (read-file-name
 214           "File: "
 215           (file-name-directory spam-report-requests-file)
 216           spam-report-requests-file
 217           nil
 218           (file-name-nondirectory spam-report-requests-file))
 219          current-prefix-arg))
 220   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 221       (error (concat "Cannot process requests when "
 222                      "`spam-report-url-ping-function' is "
 223                      "`spam-report-url-to-file'."))
 224     (gnus-message 7 "Processing requests using `%s'."
 225                   spam-report-url-ping-function))
 226   (or file (setq file spam-report-requests-file))
 227   (save-excursion
 228     (set-buffer (find-file-noselect file))
 229     (goto-char (point-min))
 230     (while (and (not (eobp))
 231                 (re-search-forward
 232                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 233       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 234       (forward-line 1))
 235     (if (or (eq keep nil)
 236             (and (eq keep 'ask)
 237                  (y-or-n-p
 238                   (format
 239                    "Flush requests from `%s'? " (current-buffer)))))
 240         (progn
 241           (gnus-message 7 "Flushing request file `%s'"
 242                         spam-report-requests-file)
 243           (erase-buffer)
 244           (save-buffer)
 245           (kill-buffer (current-buffer)))
 246       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 247
 248 ;;;###autoload
 249 (defun spam-report-url-ping-mm-url (host report)
 250   "Ping a host through HTTP, addressing a specific GET resource. Use
 251 the external program specified in `mm-url-program' to connect to
 252 server."
 253   (with-temp-buffer
 254     (let ((url (format "http://%s%s" host report)))
 255       (mm-url-insert url t))))
 256
 257 ;;;###autoload
 258 (defun spam-report-url-to-file (host report)
 259   "Collect spam report requests in `spam-report-requests-file'.
 260 Customize `spam-report-url-ping-function' to use this function."
 261   (let ((url (format "http://%s%s" host report))
 262         (file spam-report-requests-file))
 263     (gnus-make-directory (file-name-directory file))
 264     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 265     (with-temp-buffer
 266       (insert url)
 267       (newline)
 268       (append-to-file (point-min) (point-max) file))))
 269
 270 ;;;###autoload
 271 (defun spam-report-agentize ()
 272   "Add spam-report support to the Agent.
 273 Spam reports will be queued with \\[spam-report-url-to-file] when
 274 the Agent is unplugged, and will be submitted in a batch when the
 275 Agent is plugged."
 276   (interactive)
 277   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 278   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 279
 280 ;;;###autoload
 281 (defun spam-report-deagentize ()
 282   "Remove spam-report support from the Agent.
 283 Spam reports will be queued with the method used when
 284 \\[spam-report-agentize] was run."
 285   (interactive)
 286   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 287   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 288
 289 (defun spam-report-plug-agent ()
 290   "Adjust spam report settings for plugged state.
 291 Process queued spam reports."
 292   ;; Process the queue, unless the user only wanted to report to a file
 293   ;; anyway.
 294   (unless (equal spam-report-url-ping-temp-agent-function
 295                  'spam-report-url-to-file)
 296     (spam-report-process-queue))
 297   ;; Set the reporting function, if we have memorized something otherwise,
 298   ;; stick with plain URL reporting.
 299   (setq spam-report-url-ping-function
 300         (or spam-report-url-ping-temp-agent-function
 301             'spam-report-url-ping-plain)))
 302
 303 (defun spam-report-unplug-agent ()
 304   "Restore spam report settings for unplugged state."
 305   ;; save the old value
 306   (setq spam-report-url-ping-temp-agent-function
 307         spam-report-url-ping-function)
 308   ;; store all reports to file
 309   (setq spam-report-url-ping-function
 310         'spam-report-url-to-file))
 311
 312 (provide 'spam-report)
 313
 314 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 315 ;;; spam-report.el ends here.