cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   3
   4 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (eval-and-compile
  35   (autoload 'mm-url-insert "mm-url"))
  36
  37 (defgroup spam-report nil
  38   "Spam reporting configuration."
  39   :group 'mail
  40   :group 'news)
  41
  42 (defcustom spam-report-gmane-regex nil
  43   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  44 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  45 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  46 instead."
  47   :type '(radio (const nil)
  48                 (regexp :value "^nntp\+.*:gmane\."))
  49   :group 'spam-report)
  50
  51 (defcustom spam-report-gmane-spam-header
  52   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  53   "String matching Gmane spam-reporting header.  Two match groups are needed."
  54   :type 'regexp
  55   :group 'spam-report)
  56
  57 (defcustom spam-report-gmane-use-article-number t
  58   "Whether the article number (faster!) or the header should be used."
  59   :type 'boolean
  60   :group 'spam-report)
  61
  62 (defcustom spam-report-url-ping-function
  63   'spam-report-url-ping-plain
  64   "Function to use for url ping spam reporting.
  65 The function must accept the arguments `host' and `report'."
  66   :type '(choice
  67           (const :tag "Connect directly"
  68                  spam-report-url-ping-plain)
  69           (const :tag "Use the external program specified in `mm-url-program'"
  70                  spam-report-url-ping-mm-url)
  71           (const :tag "Store request URLs in `spam-report-requests-file'"
  72                  spam-report-url-to-file)
  73           (function :tag "User defined function" nil))
  74   :group 'spam-report)
  75
  76 (defcustom spam-report-requests-file
  77   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  78   ;; Is there a convention for the extension of such a file?
  79   ;; Should we use `spam-directory'?
  80   "File where spam report request are stored."
  81   :type 'file
  82   :group 'spam-report)
  83
  84 (defcustom spam-report-resend-to nil
  85   "Email address that spam articles are resent to when reporting.
  86 If not set, the user will be prompted to enter a value which will be
  87 saved for future use."
  88   :type 'string
  89   :group 'spam-report)
  90
  91 (defvar spam-report-url-ping-temp-agent-function nil
  92   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  93 This variable will store the value of `spam-report-url-ping-function' from
  94 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  95 undo that change.")
  96
  97 (defun spam-report-resend (articles &optional ham)
  98   "Report an article as spam by resending via email.
  99 Reports is as ham when HAM is set."
 100   (dolist (article articles)
 101     (gnus-message 6
 102                   "Reporting %s article %d to <%s>..."
 103                   (if ham "ham" "spam")
 104                   article spam-report-resend-to)
 105     (unless spam-report-resend-to
 106       (customize-set-variable
 107        spam-report-resend-to
 108        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 109     ;; This is ganked from the `gnus-summary-resend-message' function.
 110     ;; It involves rendering the SPAM, which is undesirable, but there does
 111     ;; not seem to be a nicer way to achieve this.
 112     ;; select this particular article
 113     (gnus-summary-select-article nil nil nil article)
 114     ;; resend it to the destination address
 115     (save-excursion
 116       (set-buffer gnus-original-article-buffer)
 117       (message-resend spam-report-resend-to))))
 118
 119 (defun spam-report-resend-ham (articles)
 120   "Report an article as ham by resending via email."
 121   (spam-report-resend articles t))
 122
 123 (defun spam-report-gmane (&rest articles)
 124   "Report an article as spam through Gmane."
 125   (interactive (gnus-summary-work-articles current-prefix-arg))
 126   (dolist (article articles)
 127     (when (and gnus-newsgroup-name
 128                (or (null spam-report-gmane-regex)
 129                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 130       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
 131       (if spam-report-gmane-use-article-number
 132           (spam-report-url-ping
 133            "spam.gmane.org"
 134            (format "/%s:%d"
 135                    (gnus-group-real-name gnus-newsgroup-name)
 136                    article))
 137         (with-current-buffer nntp-server-buffer
 138           (gnus-request-head article gnus-newsgroup-name)
 139           (goto-char (point-min))
 140           (if (re-search-forward spam-report-gmane-spam-header nil t)
 141               (let* ((host (match-string 1))
 142                      (report (match-string 2))
 143                      (url (format "http://%s%s" host report)))
 144                 (gnus-message 7 "Reporting spam through URL %s..." url)
 145                 (spam-report-url-ping host report))
 146             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 147                           article)))))))
 148
 149
 150 (defun spam-report-url-ping (host report)
 151   "Ping a host through HTTP, addressing a specific GET resource using
 152 the function specified by `spam-report-url-ping-function'."
 153   (funcall spam-report-url-ping-function host report))
 154
 155 (defun spam-report-url-ping-plain (host report)
 156   "Ping a host through HTTP, addressing a specific GET resource."
 157   (let ((tcp-connection))
 158     (with-temp-buffer
 159       (or (setq tcp-connection
 160                 (open-network-stream
 161                  "URL ping"
 162                  (buffer-name)
 163                  host
 164                  80))
 165           (error "Could not open connection to %s" host))
 166       (set-marker (process-mark tcp-connection) (point-min))
 167       (process-send-string
 168        tcp-connection
 169        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 170                report (gnus-emacs-version) host)))))
 171
 172 ;;;###autoload
 173 (defun spam-report-process-queue (&optional file keep)
 174   "Report all queued requests from `spam-report-requests-file'.
 175
 176 If FILE is given, use it instead of `spam-report-requests-file'.
 177 If KEEP is t, leave old requests in the file.  If KEEP is the
 178 symbol `ask', query before flushing the queue file."
 179   (interactive
 180    (list (read-file-name
 181           "File: "
 182           (file-name-directory spam-report-requests-file)
 183           spam-report-requests-file
 184           nil
 185           (file-name-nondirectory spam-report-requests-file))
 186          current-prefix-arg))
 187   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 188       (error (concat "Cannot process requests when "
 189                      "`spam-report-url-ping-function' is "
 190                      "`spam-report-url-to-file'."))
 191     (gnus-message 7 "Processing requests using `%s'."
 192                   spam-report-url-ping-function))
 193   (or file (setq file spam-report-requests-file))
 194   (save-excursion
 195     (set-buffer (find-file-noselect file))
 196     (goto-char (point-min))
 197     (while (and (not (eobp))
 198                 (re-search-forward
 199                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 200       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 201       (forward-line 1))
 202     (if (or (eq keep nil)
 203             (and (eq keep 'ask)
 204                  (y-or-n-p
 205                   (format
 206                    "Flush requests from `%s'? " (current-buffer)))))
 207         (progn
 208           (gnus-message 7 "Flushing request file `%s'"
 209                         spam-report-requests-file)
 210           (erase-buffer)
 211           (save-buffer)
 212           (kill-buffer (current-buffer)))
 213       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 214
 215 ;;;###autoload
 216 (defun spam-report-url-ping-mm-url (host report)
 217   "Ping a host through HTTP, addressing a specific GET resource. Use
 218 the external program specified in `mm-url-program' to connect to
 219 server."
 220   (with-temp-buffer
 221     (let ((url (format "http://%s%s" host report)))
 222       (mm-url-insert url t))))
 223
 224 ;;;###autoload
 225 (defun spam-report-url-to-file (host report)
 226   "Collect spam report requests in `spam-report-requests-file'.
 227 Customize `spam-report-url-ping-function' to use this function."
 228   (let ((url (format "http://%s%s" host report))
 229         (file spam-report-requests-file))
 230     (gnus-make-directory (file-name-directory file))
 231     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 232     (with-temp-buffer
 233       (insert url)
 234       (newline)
 235       (append-to-file (point-min) (point-max) file))))
 236
 237 ;;;###autoload
 238 (defun spam-report-agentize ()
 239   "Add spam-report support to the Agent.
 240 Spam reports will be queued with \\[spam-report-url-to-file] when
 241 the Agent is unplugged, and will be submitted in a batch when the
 242 Agent is plugged."
 243   (interactive)
 244   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 245   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 246
 247 ;;;###autoload
 248 (defun spam-report-deagentize ()
 249   "Remove spam-report support from the Agent.
 250 Spam reports will be queued with the method used when
 251 \\[spam-report-agentize] was run."
 252   (interactive)
 253   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 254   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 255
 256 (defun spam-report-plug-agent ()
 257   "Adjust spam report settings for plugged state.
 258 Process queued spam reports."
 259   ;; Process the queue, unless the user only wanted to report to a file
 260   ;; anyway.
 261   (unless (equal spam-report-url-ping-temp-agent-function
 262                  'spam-report-url-to-file)
 263     (spam-report-process-queue))
 264   ;; Set the reporting function, if we have memorized something otherwise,
 265   ;; stick with plain URL reporting.
 266   (setq spam-report-url-ping-function
 267         (or spam-report-url-ping-temp-agent-function
 268             'spam-report-url-ping-plain)))
 269
 270 (defun spam-report-unplug-agent ()
 271   "Restore spam report settings for unplugged state."
 272   ;; save the old value
 273   (setq spam-report-url-ping-temp-agent-function
 274         spam-report-url-ping-function)
 275   ;; store all reports to file
 276   (setq spam-report-url-ping-function
 277         'spam-report-url-to-file))
 278
 279 (provide 'spam-report)
 280
 281 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 282 ;;; spam-report.el ends here.