cgit.sxemacs.org Git - gnus/blob - lisp/sieve-mode.el

   1 ;;; sieve-mode.el --- Sieve code editing commands for Emacs
   2 ;; Copyright (C) 2001 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <simon@josefsson.org>
   5
   6 ;; This file is not part of GNU Emacs, but the same permissions apply.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contain editing mode functions and font-lock support for
  26 ;; editing Sieve scripts.  It sets up C-mode with support for
  27 ;; sieve-style #-comments and a lightly hacked syntax table.  It was
  28 ;; strongly influenced by awk-mode.el.
  29 ;;
  30 ;; Put something similar to the following in your .emacs to use this file:
  31 ;;
  32 ;; (load "~/lisp/sieve")
  33 ;; (setq auto-mode-alist (cons '("\\.siv\\'" . sieve-mode) auto-mode-alist))
  34 ;;
  35 ;; References:
  36 ;;
  37 ;; RFC 3028,
  38 ;; "Sieve: A Mail Filtering Language",
  39 ;; by Tim Showalter.
  40 ;;
  41 ;; Release history:
  42 ;;
  43 ;; 2001-03-02 version 1.0 posted to gnu.emacs.sources
  44 ;;            version 1.1 change file extension into ".siv" (official one)
  45 ;;                        added keymap and menubar to hook into sieve-manage
  46 ;; 2001-10-31 version 1.2 committed to Oort Gnus
  47 ;;
  48 ;; $Id: sieve-mode.el,v 1.7 2001/03/07 17:47:23 jas Exp $
  49
  50 ;;; Code:
  51
  52 (autoload 'sieve-manage "sieve-manage")
  53 (autoload 'sieve-upload "sieve-manage")
  54 (require 'easymenu)
  55 (eval-when-compile
  56   (require 'font-lock))
  57
  58 (defgroup sieve nil
  59   "Sieve."
  60   :group 'languages)
  61
  62 (defcustom sieve-mode-hook nil
  63   "Hook run in sieve mode buffers."
  64   :group 'sieve
  65   :type 'hook)
  66
  67 ;; Font-lock
  68
  69 (defconst sieve-font-lock-keywords
  70   (eval-when-compile
  71     (list
  72      ;; control commands
  73      (cons (regexp-opt '("require" "if" "else" "elsif" "stop"))
  74            'font-lock-keyword-face)
  75      ;; action commands
  76      (cons (regexp-opt '("fileinto" "redirect" "reject" "keep" "discard"))
  77            'font-lock-keyword-face)
  78      ;; test commands
  79      (cons (regexp-opt '("address" "allof" "anyof" "exists" "false"
  80                          "true" "header" "not" "size" "envelope"))
  81            'font-lock-builtin-face)
  82      (cons "\\Sw+:\\sw+" 'font-lock-constant-face))))
  83
  84 ;; Syntax table
  85
  86 (defvar sieve-mode-syntax-table nil
  87   "Syntax table in use in sieve-mode buffers.")
  88
  89 (if sieve-mode-syntax-table
  90     ()
  91   (setq sieve-mode-syntax-table (make-syntax-table))
  92   (modify-syntax-entry ?\\ "\\" sieve-mode-syntax-table)
  93   (modify-syntax-entry ?\n ">   " sieve-mode-syntax-table)
  94   (modify-syntax-entry ?\f ">   " sieve-mode-syntax-table)
  95   (modify-syntax-entry ?\# "<   " sieve-mode-syntax-table)
  96   (modify-syntax-entry ?/ "." sieve-mode-syntax-table)
  97   (modify-syntax-entry ?* "." sieve-mode-syntax-table)
  98   (modify-syntax-entry ?+ "." sieve-mode-syntax-table)
  99   (modify-syntax-entry ?- "." sieve-mode-syntax-table)
 100   (modify-syntax-entry ?= "." sieve-mode-syntax-table)
 101   (modify-syntax-entry ?% "." sieve-mode-syntax-table)
 102   (modify-syntax-entry ?< "." sieve-mode-syntax-table)
 103   (modify-syntax-entry ?> "." sieve-mode-syntax-table)
 104   (modify-syntax-entry ?& "." sieve-mode-syntax-table)
 105   (modify-syntax-entry ?| "." sieve-mode-syntax-table)
 106   (modify-syntax-entry ?_ "_" sieve-mode-syntax-table)
 107   (modify-syntax-entry ?\' "\"" sieve-mode-syntax-table))
 108
 109 ;; Key map definition
 110
 111 (defvar sieve-mode-map
 112   (let ((map (make-sparse-keymap)))
 113     (define-key map "\C-c\C-l" 'sieve-upload)
 114     (define-key map "\C-c\C-m" 'sieve-manage)
 115     map)
 116   "Key map used in sieve mode.")
 117
 118 ;; Menu definition
 119
 120 (defvar sieve-mode-menu nil
 121   "Menubar used in sieve mode.")
 122
 123 ;; Code for Sieve editing mode.
 124
 125 ;;;###autoload
 126 (define-derived-mode sieve-mode c-mode "Sieve"
 127   "Major mode for editing Sieve code.
 128 This is much like C mode except for the syntax of comments.  Its keymap
 129 inherits from C mode's and it has the same variables for customizing
 130 indentation.  It has its own abbrev table and its own syntax table.
 131
 132 Turning on Sieve mode runs `sieve-mode-hook'."
 133   (set (make-local-variable 'paragraph-start) (concat "$\\|" page-delimiter))
 134   (set (make-local-variable 'paragraph-separate) paragraph-start)
 135   (set (make-local-variable 'comment-start) "#")
 136   (set (make-local-variable 'comment-end) "")
 137   ;;(set (make-local-variable 'comment-start-skip) "\\(^\\|\\s-\\);?#+ *")
 138   (set (make-local-variable 'comment-start-skip) "#+ *")
 139   (set (make-local-variable 'font-lock-defaults)
 140        '(sieve-font-lock-keywords nil nil ((?_ . "w"))))
 141   (easy-menu-add-item nil nil sieve-mode-menu))
 142
 143 ;; Menu
 144
 145 (easy-menu-define sieve-mode-menu sieve-mode-map
 146   "Sieve Menu."
 147   '("Sieve"
 148     ["Upload script" sieve-upload t]
 149     ["Manage scripts on server" sieve-manage t]))
 150
 151 (provide 'sieve-mode)
 152
 153 ;; sieve-mode.el ends here