cgit.sxemacs.org Git - gnus/blob - lisp/sieve-mode.el

   1 ;;; sieve-mode.el --- Sieve code editing commands for Emacs
   2 ;; Copyright (C) 2001, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <simon@josefsson.org>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contain editing mode functions and font-lock support for
  26 ;; editing Sieve scripts.  It sets up C-mode with support for
  27 ;; sieve-style #-comments and a lightly hacked syntax table.  It was
  28 ;; strongly influenced by awk-mode.el.
  29 ;;
  30 ;; Put something similar to the following in your .emacs to use this file:
  31 ;;
  32 ;; (load "~/lisp/sieve")
  33 ;; (setq auto-mode-alist (cons '("\\.siv\\'" . sieve-mode) auto-mode-alist))
  34 ;;
  35 ;; References:
  36 ;;
  37 ;; RFC 3028,
  38 ;; "Sieve: A Mail Filtering Language",
  39 ;; by Tim Showalter.
  40 ;;
  41 ;; Release history:
  42 ;;
  43 ;; 2001-03-02 version 1.0 posted to gnu.emacs.sources
  44 ;;            version 1.1 change file extension into ".siv" (official one)
  45 ;;                        added keymap and menubar to hook into sieve-manage
  46 ;; 2001-10-31 version 1.2 committed to Oort Gnus
  47
  48 ;;; Code:
  49
  50 (autoload 'sieve-manage "sieve")
  51 (autoload 'sieve-upload "sieve")
  52 (autoload 'c-mode "cc-mode")
  53 (require 'easymenu)
  54 (eval-when-compile
  55   (require 'font-lock))
  56
  57 (defgroup sieve nil
  58   "Sieve."
  59   :group 'languages)
  60
  61 (defcustom sieve-mode-hook nil
  62   "Hook run in sieve mode buffers."
  63   :group 'sieve
  64   :type 'hook)
  65
  66 ;; Font-lock
  67
  68 (defvar sieve-control-commands-face 'sieve-control-commands-face
  69   "Face name used for Sieve Control Commands.")
  70
  71 (defface sieve-control-commands-face
  72   '((((type tty) (class color)) (:foreground "blue" :weight light))
  73     (((class grayscale) (background light)) (:foreground "LightGray" :bold t))
  74     (((class grayscale) (background dark)) (:foreground "DimGray" :bold t))
  75     (((class color) (background light)) (:foreground "Orchid"))
  76     (((class color) (background dark)) (:foreground "LightSteelBlue"))
  77     (t (:bold t)))
  78   "Face used for Sieve Control Commands.")
  79
  80 (defvar sieve-action-commands-face 'sieve-action-commands-face
  81   "Face name used for Sieve Action Commands.")
  82
  83 (defface sieve-action-commands-face
  84   '((((type tty) (class color)) (:foreground "blue" :weight bold))
  85     (((class color) (background light)) (:foreground "Blue"))
  86     (((class color) (background dark)) (:foreground "LightSkyBlue"))
  87     (t (:inverse-video t :bold t)))
  88   "Face used for Sieve Action Commands.")
  89
  90 (defvar sieve-test-commands-face 'sieve-test-commands-face
  91   "Face name used for Sieve Test Commands.")
  92
  93 (defface sieve-test-commands-face
  94   '((((type tty) (class color)) (:foreground "magenta"))
  95     (((class grayscale) (background light))
  96      (:foreground "LightGray" :bold t :underline t))
  97     (((class grayscale) (background dark))
  98      (:foreground "Gray50" :bold t :underline t))
  99     (((class color) (background light)) (:foreground "CadetBlue"))
 100     (((class color) (background dark)) (:foreground "Aquamarine"))
 101     (t (:bold t :underline t)))
 102   "Face used for Sieve Test Commands.")
 103
 104 (defvar sieve-tagged-arguments-face 'sieve-tagged-arguments-face
 105   "Face name used for Sieve Tagged Arguments.")
 106
 107 (defface sieve-tagged-arguments-face
 108   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
 109     (((class grayscale) (background light)) (:foreground "LightGray" :bold t))
 110     (((class grayscale) (background dark)) (:foreground "DimGray" :bold t))
 111     (((class color) (background light)) (:foreground "Purple"))
 112     (((class color) (background dark)) (:foreground "Cyan"))
 113     (t (:bold t)))
 114   "Face used for Sieve Tagged Arguments.")
 115
 116
 117 (defconst sieve-font-lock-keywords
 118   (eval-when-compile
 119     (list
 120      ;; control commands
 121      (cons (regexp-opt '("require" "if" "else" "elsif" "stop"))
 122            'sieve-control-commands-face)
 123      ;; action commands
 124      (cons (regexp-opt '("fileinto" "redirect" "reject" "keep" "discard"))
 125            'sieve-action-commands-face)
 126      ;; test commands
 127      (cons (regexp-opt '("address" "allof" "anyof" "exists" "false"
 128                          "true" "header" "not" "size" "envelope"))
 129            'sieve-test-commands-face)
 130      (cons "\\Sw+:\\sw+"
 131            'sieve-tagged-arguments-face))))
 132
 133 ;; Syntax table
 134
 135 (defvar sieve-mode-syntax-table nil
 136   "Syntax table in use in sieve-mode buffers.")
 137
 138 (if sieve-mode-syntax-table
 139     ()
 140   (setq sieve-mode-syntax-table (make-syntax-table))
 141   (modify-syntax-entry ?\\ "\\" sieve-mode-syntax-table)
 142   (modify-syntax-entry ?\n ">   " sieve-mode-syntax-table)
 143   (modify-syntax-entry ?\f ">   " sieve-mode-syntax-table)
 144   (modify-syntax-entry ?\# "<   " sieve-mode-syntax-table)
 145   (modify-syntax-entry ?/ "." sieve-mode-syntax-table)
 146   (modify-syntax-entry ?* "." sieve-mode-syntax-table)
 147   (modify-syntax-entry ?+ "." sieve-mode-syntax-table)
 148   (modify-syntax-entry ?- "." sieve-mode-syntax-table)
 149   (modify-syntax-entry ?= "." sieve-mode-syntax-table)
 150   (modify-syntax-entry ?% "." sieve-mode-syntax-table)
 151   (modify-syntax-entry ?< "." sieve-mode-syntax-table)
 152   (modify-syntax-entry ?> "." sieve-mode-syntax-table)
 153   (modify-syntax-entry ?& "." sieve-mode-syntax-table)
 154   (modify-syntax-entry ?| "." sieve-mode-syntax-table)
 155   (modify-syntax-entry ?_ "_" sieve-mode-syntax-table)
 156   (modify-syntax-entry ?\' "\"" sieve-mode-syntax-table))
 157
 158 ;; Key map definition
 159
 160 (defvar sieve-mode-map
 161   (let ((map (make-sparse-keymap)))
 162     (define-key map "\C-c\C-l" 'sieve-upload)
 163     (define-key map "\C-c\C-c" 'sieve-upload-and-bury)
 164     (define-key map "\C-c\C-m" 'sieve-manage)
 165     map)
 166   "Key map used in sieve mode.")
 167
 168 ;; Menu definition
 169
 170 (defvar sieve-mode-menu nil
 171   "Menubar used in sieve mode.")
 172
 173 ;; Code for Sieve editing mode.
 174
 175 ;;;###autoload
 176 (define-derived-mode sieve-mode c-mode "Sieve"
 177   "Major mode for editing Sieve code.
 178 This is much like C mode except for the syntax of comments.  Its keymap
 179 inherits from C mode's and it has the same variables for customizing
 180 indentation.  It has its own abbrev table and its own syntax table.
 181
 182 Turning on Sieve mode runs `sieve-mode-hook'."
 183   (set (make-local-variable 'paragraph-start) (concat "$\\|" page-delimiter))
 184   (set (make-local-variable 'paragraph-separate) paragraph-start)
 185   (set (make-local-variable 'comment-start) "#")
 186   (set (make-local-variable 'comment-end) "")
 187   ;;(set (make-local-variable 'comment-start-skip) "\\(^\\|\\s-\\);?#+ *")
 188   (set (make-local-variable 'comment-start-skip) "#+ *")
 189   (unless (featurep 'xemacs)
 190     (set (make-local-variable 'font-lock-defaults)
 191          '(sieve-font-lock-keywords nil nil ((?_ . "w")))))
 192   (easy-menu-add-item nil nil sieve-mode-menu))
 193
 194 ;; Menu
 195
 196 (easy-menu-define sieve-mode-menu sieve-mode-map
 197   "Sieve Menu."
 198   '("Sieve"
 199     ["Upload script" sieve-upload t]
 200     ["Manage scripts on server" sieve-manage t]))
 201
 202 (provide 'sieve-mode)
 203
 204 ;; sieve-mode.el ends here