cgit.sxemacs.org Git - gnus/blob - lisp/sieve-manage.el

   1 ;;; sieve-manage.el --- Implementation of the managesive protocol in elisp
   2
   3 ;; Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   4 ;;   2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library provides an elisp API for the managesieve network
  26 ;; protocol.
  27 ;;
  28 ;; It uses the SASL library for authentication, which means it
  29 ;; supports DIGEST-MD5, CRAM-MD5, SCRAM-MD5, NTLM, PLAIN and LOGIN
  30 ;; methods.  STARTTLS is not well tested, but should be easy to get to
  31 ;; work if someone wants.
  32 ;;
  33 ;; The API should be fairly obvious for anyone familiar with the
  34 ;; managesieve protocol, interface functions include:
  35 ;;
  36 ;; `sieve-manage-open'
  37 ;; open connection to managesieve server, returning a buffer to be
  38 ;; used by all other API functions.
  39 ;;
  40 ;; `sieve-manage-opened'
  41 ;; check if a server is open or not
  42 ;;
  43 ;; `sieve-manage-close'
  44 ;; close a server connection.
  45 ;;
  46 ;; `sieve-manage-listscripts'
  47 ;; `sieve-manage-deletescript'
  48 ;; `sieve-manage-getscript'
  49 ;; performs managesieve protocol actions
  50 ;;
  51 ;; and that's it.  Example of a managesieve session in *scratch*:
  52 ;;
  53 ;; (with-current-buffer (sieve-manage-open "mail.example.com")
  54 ;;   (sieve-manage-authenticate)
  55 ;;   (sieve-manage-listscripts))
  56 ;;
  57 ;; => ((active . "main") "vacation")
  58 ;;
  59 ;; References:
  60 ;;
  61 ;; draft-martin-managesieve-02.txt,
  62 ;; "A Protocol for Remotely Managing Sieve Scripts",
  63 ;; by Tim Martin.
  64 ;;
  65 ;; Release history:
  66 ;;
  67 ;; 2001-10-31 Committed to Oort Gnus.
  68 ;; 2002-07-27 Added DELETESCRIPT.  Suggested by Ned Ludd.
  69 ;; 2002-08-03 Use SASL library.
  70
  71 ;;; Code:
  72
  73 ;; For Emacs <22.2 and XEmacs.
  74 (eval-and-compile
  75   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  76
  77 (if (locate-library "password-cache")
  78     (require 'password-cache)
  79   (require 'password))
  80
  81 (eval-when-compile
  82   (require 'cl)                         ; caddr
  83   (require 'sasl)
  84   (require 'starttls))
  85 (autoload 'sasl-find-mechanism "sasl")
  86 (autoload 'starttls-open-stream "starttls")
  87 (autoload 'auth-source-user-or-password "auth-source")
  88
  89 ;; User customizable variables:
  90
  91 (defgroup sieve-manage nil
  92   "Low-level Managesieve protocol issues."
  93   :group 'mail
  94   :prefix "sieve-")
  95
  96 (defcustom sieve-manage-log "*sieve-manage-log*"
  97   "Name of buffer for managesieve session trace."
  98   :type 'string
  99   :group 'sieve-manage)
 100
 101 (defcustom sieve-manage-server-eol "\r\n"
 102   "The EOL string sent from the server."
 103   :type 'string
 104   :group 'sieve-manage)
 105
 106 (defcustom sieve-manage-client-eol "\r\n"
 107   "The EOL string we send to the server."
 108   :type 'string
 109   :group 'sieve-manage)
 110
 111 (defcustom sieve-manage-streams '(network starttls shell)
 112   "Priority of streams to consider when opening connection to server."
 113   :group 'sieve-manage)
 114
 115 (defcustom sieve-manage-stream-alist
 116   '((network   sieve-manage-network-p          sieve-manage-network-open)
 117     (shell     sieve-manage-shell-p            sieve-manage-shell-open)
 118     (starttls  sieve-manage-starttls-p         sieve-manage-starttls-open))
 119   "Definition of network streams.
 120
 121 \(NAME CHECK OPEN)
 122
 123 NAME names the stream, CHECK is a function returning non-nil if the
 124 server support the stream and OPEN is a function for opening the
 125 stream."
 126   :group 'sieve-manage)
 127
 128 (defcustom sieve-manage-authenticators '(digest-md5
 129                                          cram-md5
 130                                          scram-md5
 131                                          ntlm
 132                                          plain
 133                                          login)
 134   "Priority of authenticators to consider when authenticating to server."
 135   :group 'sieve-manage)
 136
 137 (defcustom sieve-manage-authenticator-alist
 138   '((cram-md5   sieve-manage-cram-md5-p       sieve-manage-cram-md5-auth)
 139     (digest-md5 sieve-manage-digest-md5-p     sieve-manage-digest-md5-auth)
 140     (scram-md5  sieve-manage-scram-md5-p      sieve-manage-scram-md5-auth)
 141     (ntlm       sieve-manage-ntlm-p           sieve-manage-ntlm-auth)
 142     (plain      sieve-manage-plain-p          sieve-manage-plain-auth)
 143     (login      sieve-manage-login-p          sieve-manage-login-auth))
 144   "Definition of authenticators.
 145
 146 \(NAME CHECK AUTHENTICATE)
 147
 148 NAME names the authenticator.  CHECK is a function returning non-nil if
 149 the server support the authenticator and AUTHENTICATE is a function
 150 for doing the actual authentication."
 151   :group 'sieve-manage)
 152
 153 (defcustom sieve-manage-default-port 2000
 154   "Default port number or service name for managesieve protocol."
 155   :type 'integer
 156   :group 'sieve-manage)
 157
 158 (defcustom sieve-manage-default-stream 'network
 159   "Default stream type to use for `sieve-manage'.
 160 Must be a name of a stream in `sieve-manage-stream-alist'."
 161   :type 'symbol
 162   :group 'sieve-manage)
 163
 164 ;; Internal variables:
 165
 166 (defconst sieve-manage-local-variables '(sieve-manage-server
 167                                          sieve-manage-port
 168                                          sieve-manage-auth
 169                                          sieve-manage-stream
 170                                          sieve-manage-process
 171                                          sieve-manage-client-eol
 172                                          sieve-manage-server-eol
 173                                          sieve-manage-capability))
 174 (defconst sieve-manage-coding-system-for-read 'binary)
 175 (defconst sieve-manage-coding-system-for-write 'binary)
 176 (defvar sieve-manage-stream nil)
 177 (defvar sieve-manage-auth nil)
 178 (defvar sieve-manage-server nil)
 179 (defvar sieve-manage-port nil)
 180 (defvar sieve-manage-state 'closed
 181   "Managesieve state.
 182 Valid states are `closed', `initial', `nonauth', and `auth'.")
 183 (defvar sieve-manage-process nil)
 184 (defvar sieve-manage-capability nil)
 185
 186 ;; Internal utility functions
 187
 188 (defmacro sieve-manage-disable-multibyte ()
 189   "Enable multibyte in the current buffer."
 190   (unless (featurep 'xemacs)
 191     '(set-buffer-multibyte nil)))
 192
 193 (defun sieve-manage-erase (&optional p buffer)
 194   (let ((buffer (or buffer (current-buffer))))
 195     (and sieve-manage-log
 196          (with-current-buffer (get-buffer-create sieve-manage-log)
 197            (sieve-manage-disable-multibyte)
 198            (buffer-disable-undo)
 199            (goto-char (point-max))
 200            (insert-buffer-substring buffer (with-current-buffer buffer
 201                                              (point-min))
 202                                     (or p (with-current-buffer buffer
 203                                             (point-max)))))))
 204   (delete-region (point-min) (or p (point-max))))
 205
 206 (defun sieve-manage-open-1 (buffer)
 207   (with-current-buffer buffer
 208     (sieve-manage-erase)
 209     (setq sieve-manage-state 'initial
 210           sieve-manage-process
 211           (condition-case ()
 212               (funcall (nth 2 (assq sieve-manage-stream
 213                                     sieve-manage-stream-alist))
 214                        "sieve" buffer sieve-manage-server sieve-manage-port)
 215             ((error quit) nil)))
 216     (when sieve-manage-process
 217       (while (and (eq sieve-manage-state 'initial)
 218                   (memq (process-status sieve-manage-process) '(open run)))
 219         (message "Waiting for response from %s..." sieve-manage-server)
 220         (accept-process-output sieve-manage-process 1))
 221       (message "Waiting for response from %s...done" sieve-manage-server)
 222       (and (memq (process-status sieve-manage-process) '(open run))
 223            sieve-manage-process))))
 224
 225 ;; Streams
 226
 227 (defun sieve-manage-network-p (buffer)
 228   t)
 229
 230 (defun sieve-manage-network-open (name buffer server port)
 231   (let* ((port (or port sieve-manage-default-port))
 232          (coding-system-for-read sieve-manage-coding-system-for-read)
 233          (coding-system-for-write sieve-manage-coding-system-for-write)
 234          (process (open-network-stream name buffer server port)))
 235     (when process
 236       (while (and (memq (process-status process) '(open run))
 237                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 238                   (goto-char (point-min))
 239                   (not (sieve-manage-parse-greeting-1)))
 240         (accept-process-output process 1)
 241         (sit-for 1))
 242       (sieve-manage-erase nil buffer)
 243       (when (memq (process-status process) '(open run))
 244         process))))
 245
 246 (defun sieve-manage-starttls-p (buffer)
 247   (condition-case ()
 248       (progn
 249         (require 'starttls)
 250         (call-process "starttls"))
 251     (error nil)))
 252
 253 (defun sieve-manage-starttls-open (name buffer server port)
 254   (let* ((port (or port sieve-manage-default-port))
 255          (coding-system-for-read sieve-manage-coding-system-for-read)
 256          (coding-system-for-write sieve-manage-coding-system-for-write)
 257          (process (starttls-open-stream name buffer server port))
 258          done)
 259     (when process
 260       (while (and (memq (process-status process) '(open run))
 261                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 262                   (goto-char (point-min))
 263                   (not (sieve-manage-parse-greeting-1)))
 264         (accept-process-output process 1)
 265         (sit-for 1))
 266       (sieve-manage-erase nil buffer)
 267       (sieve-manage-send "STARTTLS")
 268       (starttls-negotiate process))
 269     (when (memq (process-status process) '(open run))
 270       process)))
 271
 272 ;; Authenticators
 273 (defun sieve-sasl-auth (buffer mech)
 274   "Login to server using the SASL MECH method."
 275   (message "sieve: Authenticating using %s..." mech)
 276   (with-current-buffer buffer
 277     (let* ((user-password (auth-source-user-or-password
 278                            '("login" "password")
 279                            sieve-manage-server
 280                            "sieve" nil t))
 281            (client (sasl-make-client (sasl-find-mechanism (list mech))
 282                                      (car user-password) "sieve" sieve-manage-server))
 283            (sasl-read-passphrase
 284             ;; We *need* to copy the password, because sasl will modify it
 285             ;; somehow.
 286             `(lambda (prompt) ,(copy-sequence (cadr user-password))))
 287            (step (sasl-next-step client nil))
 288            (tag (sieve-manage-send
 289                  (concat
 290                   "AUTHENTICATE \""
 291                   mech
 292                   "\""
 293                   (and (sasl-step-data step)
 294                        (concat
 295                         " \""
 296                         (base64-encode-string
 297                          (sasl-step-data step)
 298                          'no-line-break)
 299                         "\"")))))
 300            data rsp)
 301       (catch 'done
 302         (while t
 303           (setq rsp nil)
 304           (goto-char (point-min))
 305           (while (null (or (progn
 306                              (setq rsp (sieve-manage-is-string))
 307                              (if (not (and rsp (looking-at
 308                                                 sieve-manage-server-eol)))
 309                                  (setq rsp nil)
 310                                (goto-char (match-end 0))
 311                                rsp))
 312                            (setq rsp (sieve-manage-is-okno))))
 313             (accept-process-output sieve-manage-process 1)
 314             (goto-char (point-min)))
 315           (sieve-manage-erase)
 316           (when (sieve-manage-ok-p rsp)
 317             (when (and (cadr rsp)
 318                        (string-match "^SASL \"\\([^\"]+\\)\"" (cadr rsp)))
 319               (sasl-step-set-data
 320                step (base64-decode-string (match-string 1 (cadr rsp)))))
 321             (if (and (setq step (sasl-next-step client step))
 322                      (setq data (sasl-step-data step)))
 323                 ;; We got data for server but it's finished
 324                 (error "Server not ready for SASL data: %s" data)
 325               ;; The authentication process is finished.
 326               (throw 'done t)))
 327           (unless (stringp rsp)
 328             (error "Server aborted SASL authentication: %s" (caddr rsp)))
 329           (sasl-step-set-data step (base64-decode-string rsp))
 330           (setq step (sasl-next-step client step))
 331           (sieve-manage-send
 332            (if (sasl-step-data step)
 333                (concat "\""
 334                        (base64-encode-string (sasl-step-data step)
 335                                              'no-line-break)
 336                        "\"")
 337              ""))))
 338       (message "sieve: Login using %s...done" mech))))
 339
 340 (defun sieve-manage-cram-md5-p (buffer)
 341   (sieve-manage-capability "SASL" "CRAM-MD5" buffer))
 342
 343 (defun sieve-manage-cram-md5-auth (buffer)
 344   "Login to managesieve server using the CRAM-MD5 SASL method."
 345   (sieve-sasl-auth buffer "CRAM-MD5"))
 346
 347 (defun sieve-manage-digest-md5-p (buffer)
 348   (sieve-manage-capability "SASL" "DIGEST-MD5" buffer))
 349
 350 (defun sieve-manage-digest-md5-auth (buffer)
 351   "Login to managesieve server using the DIGEST-MD5 SASL method."
 352   (sieve-sasl-auth buffer "DIGEST-MD5"))
 353
 354 (defun sieve-manage-scram-md5-p (buffer)
 355   (sieve-manage-capability "SASL" "SCRAM-MD5" buffer))
 356
 357 (defun sieve-manage-scram-md5-auth (buffer)
 358   "Login to managesieve server using the SCRAM-MD5 SASL method."
 359   (sieve-sasl-auth buffer "SCRAM-MD5"))
 360
 361 (defun sieve-manage-ntlm-p (buffer)
 362   (sieve-manage-capability "SASL" "NTLM" buffer))
 363
 364 (defun sieve-manage-ntlm-auth (buffer)
 365   "Login to managesieve server using the NTLM SASL method."
 366   (sieve-sasl-auth buffer "NTLM"))
 367
 368 (defun sieve-manage-plain-p (buffer)
 369   (sieve-manage-capability "SASL" "PLAIN" buffer))
 370
 371 (defun sieve-manage-plain-auth (buffer)
 372   "Login to managesieve server using the PLAIN SASL method."
 373   (sieve-sasl-auth buffer "PLAIN"))
 374
 375 (defun sieve-manage-login-p (buffer)
 376   (sieve-manage-capability "SASL" "LOGIN" buffer))
 377
 378 (defun sieve-manage-login-auth (buffer)
 379   "Login to managesieve server using the LOGIN SASL method."
 380   (sieve-sasl-auth buffer "LOGIN"))
 381
 382 ;; Managesieve API
 383
 384 (defun sieve-manage-open (server &optional port stream auth buffer)
 385   "Open a network connection to a managesieve SERVER (string).
 386 Optional argument PORT is port number (integer) on remote server.
 387 Optional argument STREAM is any of `sieve-manage-streams' (a symbol).
 388 Optional argument AUTH indicates authenticator to use, see
 389 `sieve-manage-authenticators' for available authenticators.
 390 If nil, chooses the best stream the server is capable of.
 391 Optional argument BUFFER is buffer (buffer, or string naming buffer)
 392 to work in."
 393   (or port (setq port sieve-manage-default-port))
 394   (setq buffer (or buffer (format " *sieve* %s:%s" server port)))
 395   (with-current-buffer (get-buffer-create buffer)
 396     (mapc 'make-local-variable sieve-manage-local-variables)
 397     (sieve-manage-disable-multibyte)
 398     (buffer-disable-undo)
 399     (setq sieve-manage-server (or server sieve-manage-server))
 400     (setq sieve-manage-port port)
 401     (setq sieve-manage-stream (or stream sieve-manage-stream))
 402     (message "sieve: Connecting to %s..." sieve-manage-server)
 403     (if (let ((sieve-manage-stream
 404                (or sieve-manage-stream sieve-manage-default-stream)))
 405           (sieve-manage-open-1 buffer))
 406         ;; Choose stream.
 407         (let (stream-changed)
 408           (message "sieve: Connecting to %s...done" sieve-manage-server)
 409           (when (null sieve-manage-stream)
 410             (let ((streams sieve-manage-streams))
 411               (while (setq stream (pop streams))
 412                 (if (funcall (nth 1 (assq stream
 413                                           sieve-manage-stream-alist)) buffer)
 414                     (setq stream-changed
 415                           (not (eq (or sieve-manage-stream
 416                                        sieve-manage-default-stream)
 417                                    stream))
 418                           sieve-manage-stream stream
 419                           streams nil)))
 420               (unless sieve-manage-stream
 421                 (error "Couldn't figure out a stream for server"))))
 422           (when stream-changed
 423             (message "sieve: Reconnecting with stream `%s'..."
 424                      sieve-manage-stream)
 425             (sieve-manage-close buffer)
 426             (if (sieve-manage-open-1 buffer)
 427                 (message "sieve: Reconnecting with stream `%s'...done"
 428                          sieve-manage-stream)
 429               (message "sieve: Reconnecting with stream `%s'...failed"
 430                        sieve-manage-stream))
 431             (setq sieve-manage-capability nil))
 432           (if (sieve-manage-opened buffer)
 433               ;; Choose authenticator
 434               (when (and (null sieve-manage-auth)
 435                          (not (eq sieve-manage-state 'auth)))
 436                 (let ((auths sieve-manage-authenticators))
 437                   (while (setq auth (pop auths))
 438                     (if (funcall (nth 1 (assq
 439                                          auth
 440                                          sieve-manage-authenticator-alist))
 441                                  buffer)
 442                         (setq sieve-manage-auth auth
 443                               auths nil)))
 444                   (unless sieve-manage-auth
 445                     (error "Couldn't figure out authenticator for server"))))))
 446       (message "sieve: Connecting to %s...failed" sieve-manage-server))
 447     (when (sieve-manage-opened buffer)
 448       (sieve-manage-erase)
 449       buffer)))
 450
 451 (defun sieve-manage-authenticate (&optional buffer)
 452   "Authenticate on server in BUFFER.
 453 Return `sieve-manage-state' value."
 454   (with-current-buffer (or buffer (current-buffer))
 455     (if (eq sieve-manage-state 'nonauth)
 456         (when (funcall (nth 2 (assq sieve-manage-auth
 457                                     sieve-manage-authenticator-alist))
 458                        (current-buffer))
 459           (setq sieve-manage-state 'auth))
 460       sieve-manage-state)))
 461
 462 (defun sieve-manage-opened (&optional buffer)
 463   "Return non-nil if connection to managesieve server in BUFFER is open.
 464 If BUFFER is nil then the current buffer is used."
 465   (and (setq buffer (get-buffer (or buffer (current-buffer))))
 466        (buffer-live-p buffer)
 467        (with-current-buffer buffer
 468          (and sieve-manage-process
 469               (memq (process-status sieve-manage-process) '(open run))))))
 470
 471 (defun sieve-manage-close (&optional buffer)
 472   "Close connection to managesieve server in BUFFER.
 473 If BUFFER is nil, the current buffer is used."
 474   (with-current-buffer (or buffer (current-buffer))
 475     (when (sieve-manage-opened)
 476       (sieve-manage-send "LOGOUT")
 477       (sit-for 1))
 478     (when (and sieve-manage-process
 479                (memq (process-status sieve-manage-process) '(open run)))
 480       (delete-process sieve-manage-process))
 481     (setq sieve-manage-process nil)
 482     (sieve-manage-erase)
 483     t))
 484
 485 (defun sieve-manage-capability (&optional name value buffer)
 486   "Check if capability NAME of server BUFFER match VALUE.
 487 If it does, return the server value of NAME. If not returns nil.
 488 If VALUE is nil, do not check VALUE and return server value.
 489 If NAME is nil, return the full server list of capabilities."
 490   (with-current-buffer (or buffer (current-buffer))
 491     (if (null name)
 492         sieve-manage-capability
 493       (let ((server-value (cadr (assoc name sieve-manage-capability))))
 494         (when (or (null value)
 495                   (and server-value
 496                        (string-match value server-value)))
 497           server-value)))))
 498
 499 (defun sieve-manage-listscripts (&optional buffer)
 500   (with-current-buffer (or buffer (current-buffer))
 501     (sieve-manage-send "LISTSCRIPTS")
 502     (sieve-manage-parse-listscripts)))
 503
 504 (defun sieve-manage-havespace (name size &optional buffer)
 505   (with-current-buffer (or buffer (current-buffer))
 506     (sieve-manage-send (format "HAVESPACE \"%s\" %s" name size))
 507     (sieve-manage-parse-okno)))
 508
 509 (defun sieve-manage-putscript (name content &optional buffer)
 510   (with-current-buffer (or buffer (current-buffer))
 511     (sieve-manage-send (format "PUTSCRIPT \"%s\" {%d+}%s%s" name
 512                                ;; Here we assume that the coding-system will
 513                                ;; replace each char with a single byte.
 514                                ;; This is always the case if `content' is
 515                                ;; a unibyte string.
 516                                (length content)
 517                                sieve-manage-client-eol content))
 518     (sieve-manage-parse-okno)))
 519
 520 (defun sieve-manage-deletescript (name &optional buffer)
 521   (with-current-buffer (or buffer (current-buffer))
 522     (sieve-manage-send (format "DELETESCRIPT \"%s\"" name))
 523     (sieve-manage-parse-okno)))
 524
 525 (defun sieve-manage-getscript (name output-buffer &optional buffer)
 526   (with-current-buffer (or buffer (current-buffer))
 527     (sieve-manage-send (format "GETSCRIPT \"%s\"" name))
 528     (let ((script (sieve-manage-parse-string)))
 529       (sieve-manage-parse-crlf)
 530       (with-current-buffer output-buffer
 531         (insert script))
 532       (sieve-manage-parse-okno))))
 533
 534 (defun sieve-manage-setactive (name &optional buffer)
 535   (with-current-buffer (or buffer (current-buffer))
 536     (sieve-manage-send (format "SETACTIVE \"%s\"" name))
 537     (sieve-manage-parse-okno)))
 538
 539 ;; Protocol parsing routines
 540
 541 (defun sieve-manage-ok-p (rsp)
 542   (string= (downcase (or (car-safe rsp) "")) "ok"))
 543
 544 (defsubst sieve-manage-forward ()
 545   (or (eobp) (forward-char)))
 546
 547 (defun sieve-manage-is-okno ()
 548   (when (looking-at (concat
 549                      "^\\(OK\\|NO\\)\\( (\\([^)]+\\))\\)?\\( \\(.*\\)\\)?"
 550                      sieve-manage-server-eol))
 551     (let ((status (match-string 1))
 552           (resp-code (match-string 3))
 553           (response (match-string 5)))
 554       (when response
 555         (goto-char (match-beginning 5))
 556         (setq response (sieve-manage-is-string)))
 557       (list status resp-code response))))
 558
 559 (defun sieve-manage-parse-okno ()
 560   (let (rsp)
 561     (while (null rsp)
 562       (accept-process-output (get-buffer-process (current-buffer)) 1)
 563       (goto-char (point-min))
 564       (setq rsp (sieve-manage-is-okno)))
 565     (sieve-manage-erase)
 566     rsp))
 567
 568 (defun sieve-manage-parse-capability-1 ()
 569   "Accept a managesieve greeting."
 570   (let (str)
 571     (while (setq str (sieve-manage-is-string))
 572       (if (eq (char-after) ? )
 573           (progn
 574             (sieve-manage-forward)
 575             (push (list str (sieve-manage-is-string))
 576                   sieve-manage-capability))
 577         (push (list str) sieve-manage-capability))
 578       (forward-line)))
 579   (when (re-search-forward (concat "^OK.*" sieve-manage-server-eol) nil t)
 580     (setq sieve-manage-state 'nonauth)))
 581
 582 (defalias 'sieve-manage-parse-greeting-1 'sieve-manage-parse-capability-1)
 583
 584 (defun sieve-manage-is-string ()
 585   (cond ((looking-at "\"\\([^\"]+\\)\"")
 586          (prog1
 587              (match-string 1)
 588            (goto-char (match-end 0))))
 589         ((looking-at (concat "{\\([0-9]+\\+?\\)}" sieve-manage-server-eol))
 590          (let ((pos (match-end 0))
 591                (len (string-to-number (match-string 1))))
 592            (if (< (point-max) (+ pos len))
 593                nil
 594              (goto-char (+ pos len))
 595              (buffer-substring pos (+ pos len)))))))
 596
 597 (defun sieve-manage-parse-string ()
 598   (let (rsp)
 599     (while (null rsp)
 600       (accept-process-output (get-buffer-process (current-buffer)) 1)
 601       (goto-char (point-min))
 602       (setq rsp (sieve-manage-is-string)))
 603     (sieve-manage-erase (point))
 604     rsp))
 605
 606 (defun sieve-manage-parse-crlf ()
 607   (when (looking-at sieve-manage-server-eol)
 608     (sieve-manage-erase (match-end 0))))
 609
 610 (defun sieve-manage-parse-listscripts ()
 611   (let (tmp rsp data)
 612     (while (null rsp)
 613       (while (null (or (setq rsp (sieve-manage-is-okno))
 614                        (setq tmp (sieve-manage-is-string))))
 615         (accept-process-output (get-buffer-process (current-buffer)) 1)
 616         (goto-char (point-min)))
 617       (when tmp
 618         (while (not (looking-at (concat "\\( ACTIVE\\)?"
 619                                         sieve-manage-server-eol)))
 620           (accept-process-output (get-buffer-process (current-buffer)) 1)
 621           (goto-char (point-min)))
 622         (if (match-string 1)
 623             (push (cons 'active tmp) data)
 624           (push tmp data))
 625         (goto-char (match-end 0))
 626         (setq tmp nil)))
 627     (sieve-manage-erase)
 628     (if (sieve-manage-ok-p rsp)
 629         data
 630       rsp)))
 631
 632 (defun sieve-manage-send (cmdstr)
 633   (setq cmdstr (concat cmdstr sieve-manage-client-eol))
 634   (and sieve-manage-log
 635        (with-current-buffer (get-buffer-create sieve-manage-log)
 636          (sieve-manage-disable-multibyte)
 637          (buffer-disable-undo)
 638          (goto-char (point-max))
 639          (insert cmdstr)))
 640   (process-send-string sieve-manage-process cmdstr))
 641
 642 (provide 'sieve-manage)
 643
 644 ;; sieve-manage.el ends here