cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93
  94 (defvar shr-map
  95   (let ((map (make-sparse-keymap)))
  96     (define-key map "a" 'shr-show-alt-text)
  97     (define-key map "i" 'shr-browse-image)
  98     (define-key map "I" 'shr-insert-image)
  99     (define-key map "u" 'shr-copy-url)
 100     (define-key map "v" 'shr-browse-url)
 101     (define-key map "o" 'shr-save-contents)
 102     (define-key map "\r" 'shr-browse-url)
 103     map))
 104
 105 ;; Public functions and commands.
 106
 107 ;;;###autoload
 108 (defun shr-insert-document (dom)
 109   (setq shr-content-cache nil)
 110   (let ((shr-state nil)
 111         (shr-start nil))
 112     (shr-descend (shr-transform-dom dom))))
 113
 114 (defun shr-copy-url ()
 115   "Copy the URL under point to the kill ring.
 116 If called twice, then try to fetch the URL and see whether it
 117 redirects somewhere else."
 118   (interactive)
 119   (let ((url (get-text-property (point) 'shr-url)))
 120     (cond
 121      ((not url)
 122       (message "No URL under point"))
 123      ;; Resolve redirected URLs.
 124      ((equal url (car kill-ring))
 125       (url-retrieve
 126        url
 127        (lambda (a)
 128          (when (and (consp a)
 129                     (eq (car a) :redirect))
 130            (with-temp-buffer
 131              (insert (cadr a))
 132              (goto-char (point-min))
 133              ;; Remove common tracking junk from the URL.
 134              (when (re-search-forward ".utm_.*" nil t)
 135                (replace-match "" t t))
 136              (message "Copied %s" (buffer-string))
 137              (copy-region-as-kill (point-min) (point-max)))))))
 138      ;; Copy the URL to the kill ring.
 139      (t
 140       (with-temp-buffer
 141         (insert url)
 142         (copy-region-as-kill (point-min) (point-max))
 143         (message "Copied %s" url))))))
 144
 145 (defun shr-show-alt-text ()
 146   "Show the ALT text of the image under point."
 147   (interactive)
 148   (let ((text (get-text-property (point) 'shr-alt)))
 149     (if (not text)
 150         (message "No image under point")
 151       (message "%s" text))))
 152
 153 (defun shr-browse-image ()
 154   "Browse the image under point."
 155   (interactive)
 156   (let ((url (get-text-property (point) 'shr-image)))
 157     (if (not url)
 158         (message "No image under point")
 159       (message "Browsing %s..." url)
 160       (browse-url url))))
 161
 162 (defun shr-insert-image ()
 163   "Insert the image under point into the buffer."
 164   (interactive)
 165   (let ((url (get-text-property (point) 'shr-image)))
 166     (if (not url)
 167         (message "No image under point")
 168       (message "Inserting %s..." url)
 169       (url-retrieve url 'shr-image-fetched
 170                     (list (current-buffer) (1- (point)) (point-marker))
 171                     t))))
 172
 173 ;;; Utility functions.
 174
 175 (defun shr-transform-dom (dom)
 176   (let ((result (list (pop dom))))
 177     (dolist (arg (pop dom))
 178       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 179                   (cdr arg))
 180             result))
 181     (dolist (sub dom)
 182       (if (stringp sub)
 183           (push (cons :text sub) result)
 184         (push (shr-transform-dom sub) result)))
 185     (nreverse result)))
 186
 187 (defun shr-descend (dom)
 188   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 189     (if (fboundp function)
 190         (funcall function (cdr dom))
 191       (shr-generic (cdr dom)))))
 192
 193 (defun shr-generic (cont)
 194   (dolist (sub cont)
 195     (cond
 196      ((eq (car sub) :text)
 197       (shr-insert (cdr sub)))
 198      ((listp (cdr sub))
 199       (shr-descend sub)))))
 200
 201 (defun shr-insert (text)
 202   (when (and (eq shr-state 'image)
 203              (not (string-match "\\`[ \t\n]+\\'" text)))
 204     (insert "\n")
 205     (setq shr-state nil))
 206   (cond
 207    ((eq shr-folding-mode 'none)
 208     (insert text))
 209    (t
 210     (when (and (string-match "\\`[ \t\n]" text)
 211                (not (bolp))
 212                (not (eq (char-after (1- (point))) ? )))
 213       (insert " "))
 214     (dolist (elem (split-string text))
 215       (when (and (bolp)
 216                  (> shr-indentation 0))
 217         (shr-indent))
 218       ;; The shr-start is a special variable that is used to pass
 219       ;; upwards the first point in the buffer where the text really
 220       ;; starts.
 221       (unless shr-start
 222         (setq shr-start (point)))
 223       ;; No space is needed behind a wide character categorized as
 224       ;; kinsoku-bol, between characters both categorized as nospace,
 225       ;; or at the beginning of a line.
 226       (let (prev)
 227         (when (and (eq (preceding-char) ? )
 228                    (or (= (line-beginning-position) (1- (point)))
 229                        (and (aref fill-find-break-point-function-table
 230                                   (setq prev (char-after (- (point) 2))))
 231                             (aref (char-category-set prev) ?>))
 232                        (and (aref fill-nospace-between-words-table prev)
 233                             (aref fill-nospace-between-words-table
 234                                   (aref elem 0)))))
 235           (delete-char -1)))
 236       (insert elem)
 237       (while (> (current-column) shr-width)
 238         (unless (prog1
 239                     (shr-find-fill-point)
 240                   (when (eq (preceding-char) ? )
 241                     (delete-char -1))
 242                   (insert "\n"))
 243           (put-text-property (1- (point)) (point) 'shr-break t)
 244           ;; No space is needed at the beginning of a line.
 245           (when (eq (following-char) ? )
 246             (delete-char 1)))
 247         (when (> shr-indentation 0)
 248           (shr-indent))
 249         (end-of-line))
 250       (insert " "))
 251     (unless (string-match "[ \t\n]\\'" text)
 252       (delete-char -1)))))
 253
 254 (defun shr-find-fill-point ()
 255   (when (> (move-to-column shr-width) shr-width)
 256     (backward-char 1))
 257   (let (failed)
 258     (while (not
 259             (or (setq failed (= (current-column) shr-indentation))
 260                 (eq (preceding-char) ? )
 261                 (eq (following-char) ? )
 262                 (aref fill-find-break-point-function-table (preceding-char))))
 263       (backward-char 1))
 264     (if failed
 265         ;; There's no breakable point, so we give it up.
 266         (progn
 267           (end-of-line)
 268           (while (aref fill-find-break-point-function-table (preceding-char))
 269             (backward-char 1))
 270           nil)
 271       (or (eolp)
 272           ;; Don't put kinsoku-bol characters at the beginning of a line,
 273           ;; or kinsoku-eol characters at the end of a line,
 274           (let ((count 4))
 275             (if (or shr-kinsoku-shorten
 276                     (and (aref (char-category-set (preceding-char)) ?<)
 277                          (progn
 278                            (setq count (1- count))
 279                            (backward-char 1)
 280                            t)))
 281                 (while (and
 282                         (>= (setq count (1- count)) 0)
 283                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 284                         (or (aref (char-category-set (preceding-char)) ?<)
 285                             (aref (char-category-set (following-char)) ?>)))
 286                   (backward-char 1))
 287               (while (and (>= (setq count (1- count)) 0)
 288                           (aref (char-category-set (following-char)) ?>))
 289                 (forward-char 1)))
 290             (when (eq (following-char) ? )
 291               (forward-char 1))
 292             t)))))
 293
 294 (defun shr-ensure-newline ()
 295   (unless (zerop (current-column))
 296     (insert "\n")))
 297
 298 (defun shr-ensure-paragraph ()
 299   (unless (bobp)
 300     (if (<= (current-column) shr-indentation)
 301         (unless (save-excursion
 302                   (forward-line -1)
 303                   (looking-at " *$"))
 304           (insert "\n"))
 305       (if (save-excursion
 306             (beginning-of-line)
 307             (looking-at " *$"))
 308           (insert "\n")
 309         (insert "\n\n")))))
 310
 311 (defun shr-indent ()
 312   (when (> shr-indentation 0)
 313     (insert (make-string shr-indentation ? ))))
 314
 315 (defun shr-fontize-cont (cont &rest types)
 316   (let (shr-start)
 317     (shr-generic cont)
 318     (dolist (type types)
 319       (shr-add-font (or shr-start (point)) (point) type))))
 320
 321 (defun shr-add-font (start end type)
 322   (let ((overlay (make-overlay start end)))
 323     (overlay-put overlay 'face type)))
 324
 325 (defun shr-browse-url ()
 326   "Browse the URL under point."
 327   (interactive)
 328   (let ((url (get-text-property (point) 'shr-url)))
 329     (if (not url)
 330         (message "No link under point")
 331       (browse-url url))))
 332
 333 (defun shr-save-contents (directory)
 334   "Save the contents from URL in a file."
 335   (interactive "DSave contents of URL to directory: ")
 336   (let ((url (get-text-property (point) 'shr-url)))
 337     (if (not url)
 338         (message "No link under point")
 339       (url-retrieve (shr-encode-url url)
 340                     'shr-store-contents (list url directory)))))
 341
 342 (defun shr-store-contents (status url directory)
 343   (unless (plist-get status :error)
 344     (when (or (search-forward "\n\n" nil t)
 345               (search-forward "\r\n\r\n" nil t))
 346       (write-region (point) (point-max)
 347                     (expand-file-name (file-name-nondirectory url)
 348                                       directory)))))
 349
 350 (defun shr-image-fetched (status buffer start end)
 351   (when (and (buffer-name buffer)
 352              (not (plist-get status :error)))
 353     (url-store-in-cache (current-buffer))
 354     (when (or (search-forward "\n\n" nil t)
 355               (search-forward "\r\n\r\n" nil t))
 356       (let ((data (buffer-substring (point) (point-max))))
 357         (with-current-buffer buffer
 358           (let ((alt (buffer-substring start end))
 359                 (inhibit-read-only t))
 360             (delete-region start end)
 361             (shr-put-image data start alt))))))
 362   (kill-buffer (current-buffer)))
 363
 364 (defun shr-put-image (data point alt)
 365   (if (not (display-graphic-p))
 366       (insert alt)
 367     (let ((image (ignore-errors
 368                    (shr-rescale-image data))))
 369       (when image
 370         (put-image image point alt)))))
 371
 372 (defun shr-rescale-image (data)
 373   (if (or (not (fboundp 'imagemagick-types))
 374           (not (get-buffer-window (current-buffer))))
 375       (create-image data nil t)
 376     (let* ((image (create-image data nil t))
 377            (size (image-size image t))
 378            (width (car size))
 379            (height (cdr size))
 380            (edges (window-inside-pixel-edges
 381                    (get-buffer-window (current-buffer))))
 382            (window-width (truncate (* shr-max-image-proportion
 383                                       (- (nth 2 edges) (nth 0 edges)))))
 384            (window-height (truncate (* shr-max-image-proportion
 385                                        (- (nth 3 edges) (nth 1 edges)))))
 386            scaled-image)
 387       (when (> height window-height)
 388         (setq image (or (create-image data 'imagemagick t
 389                                       :height window-height)
 390                         image))
 391         (setq size (image-size image t)))
 392       (when (> (car size) window-width)
 393         (setq image (or
 394                      (create-image data 'imagemagick t
 395                                    :width window-width)
 396                      image)))
 397       image)))
 398
 399 (defun shr-get-image-data (url)
 400   "Get image data for URL.
 401 Return a string with image data."
 402   (with-temp-buffer
 403     (mm-disable-multibyte)
 404     (when (ignore-errors
 405             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 406             t)
 407       (when (or (search-forward "\n\n" nil t)
 408                 (search-forward "\r\n\r\n" nil t))
 409         (buffer-substring (point) (point-max))))))
 410
 411 (defun shr-heading (cont &rest types)
 412   (shr-ensure-paragraph)
 413   (apply #'shr-fontize-cont cont types)
 414   (shr-ensure-paragraph))
 415
 416 ;;; Tag-specific rendering rules.
 417
 418 (defun shr-tag-p (cont)
 419   (shr-ensure-paragraph)
 420   (shr-indent)
 421   (shr-generic cont)
 422   (shr-ensure-paragraph))
 423
 424 (defun shr-tag-b (cont)
 425   (shr-fontize-cont cont 'bold))
 426
 427 (defun shr-tag-i (cont)
 428   (shr-fontize-cont cont 'italic))
 429
 430 (defun shr-tag-em (cont)
 431   (shr-fontize-cont cont 'bold))
 432
 433 (defun shr-tag-u (cont)
 434   (shr-fontize-cont cont 'underline))
 435
 436 (defun shr-tag-s (cont)
 437   (shr-fontize-cont cont 'strike-through))
 438
 439 (defun shr-tag-span (cont)
 440   (let ((start (point))
 441         (color (cdr (assq 'color (shr-parse-style (cdr (assq :style cont)))))))
 442     (shr-generic cont)
 443     (when color
 444       (let ((overlay (make-overlay start (point))))
 445         (overlay-put overlay 'face (cons 'foreground-color color))))))
 446
 447 (defun shr-parse-style (style)
 448   (when style
 449     (let ((plist nil))
 450       (dolist (elem (split-string style ";"))
 451         (when elem
 452           (setq elem (split-string elem ":"))
 453           (when (and (car elem)
 454                      (cadr elem))
 455             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 456                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 457               (push (cons (intern name obarray)
 458                           value)
 459                     plist)))))
 460       plist)))
 461
 462 (defun shr-tag-a (cont)
 463   (let ((url (cdr (assq :href cont)))
 464         (start (point))
 465         shr-start)
 466     (shr-generic cont)
 467     (widget-convert-button
 468      'url-link (or shr-start start) (point)
 469      :help-echo url
 470      :keymap shr-map
 471      url)
 472     (put-text-property (or shr-start start) (point) 'shr-url url)))
 473
 474 (defun shr-encode-url (url)
 475   "Encode URL."
 476   (browse-url-url-encode-chars url "[)$ ]"))
 477
 478 (defun shr-tag-img (cont)
 479   (when cont
 480     (when (and (> (current-column) 0)
 481                (not (eq shr-state 'image)))
 482       (insert "\n"))
 483     (let ((alt (cdr (assq :alt cont)))
 484           (url (cdr (assq :src cont))))
 485       (let ((start (point-marker)))
 486         (when (zerop (length alt))
 487           (setq alt "[img]"))
 488         (cond
 489          ((and (not shr-inhibit-images)
 490                (string-match "\\`cid:" url))
 491           (let ((url (substring url (match-end 0)))
 492                 image)
 493             (if (or (not shr-content-function)
 494                     (not (setq image (funcall shr-content-function url))))
 495                 (insert alt)
 496               (shr-put-image image (point) alt))))
 497          ((or shr-inhibit-images
 498               (and shr-blocked-images
 499                    (string-match shr-blocked-images url)))
 500           (setq shr-start (point))
 501           (let ((shr-state 'space))
 502             (if (> (length alt) 8)
 503                 (shr-insert (substring alt 0 8))
 504               (shr-insert alt))))
 505          ((url-is-cached (shr-encode-url url))
 506           (shr-put-image (shr-get-image-data url) (point) alt))
 507          (t
 508           (insert alt)
 509           (ignore-errors
 510             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 511                           (list (current-buffer) start (point-marker))
 512                           t))))
 513         (insert " ")
 514         (put-text-property start (point) 'keymap shr-map)
 515         (put-text-property start (point) 'shr-alt alt)
 516         (put-text-property start (point) 'shr-image url)
 517         (setq shr-state 'image)))))
 518
 519 (defun shr-tag-pre (cont)
 520   (let ((shr-folding-mode 'none))
 521     (shr-ensure-newline)
 522     (shr-indent)
 523     (shr-generic cont)
 524     (shr-ensure-newline)))
 525
 526 (defun shr-tag-blockquote (cont)
 527   (shr-ensure-paragraph)
 528   (shr-indent)
 529   (let ((shr-indentation (+ shr-indentation 4)))
 530     (shr-generic cont))
 531   (shr-ensure-paragraph))
 532
 533 (defun shr-tag-ul (cont)
 534   (shr-ensure-paragraph)
 535   (let ((shr-list-mode 'ul))
 536     (shr-generic cont))
 537   (shr-ensure-paragraph))
 538
 539 (defun shr-tag-ol (cont)
 540   (shr-ensure-paragraph)
 541   (let ((shr-list-mode 1))
 542     (shr-generic cont))
 543   (shr-ensure-paragraph))
 544
 545 (defun shr-tag-li (cont)
 546   (shr-ensure-paragraph)
 547   (shr-indent)
 548   (let* ((bullet
 549           (if (numberp shr-list-mode)
 550               (prog1
 551                   (format "%d " shr-list-mode)
 552                 (setq shr-list-mode (1+ shr-list-mode)))
 553             "* "))
 554          (shr-indentation (+ shr-indentation (length bullet))))
 555     (insert bullet)
 556     (shr-generic cont)))
 557
 558 (defun shr-tag-br (cont)
 559   (unless (bobp)
 560     (insert "\n")
 561     (shr-indent))
 562   (shr-generic cont))
 563
 564 (defun shr-tag-h1 (cont)
 565   (shr-heading cont 'bold 'underline))
 566
 567 (defun shr-tag-h2 (cont)
 568   (shr-heading cont 'bold))
 569
 570 (defun shr-tag-h3 (cont)
 571   (shr-heading cont 'italic))
 572
 573 (defun shr-tag-h4 (cont)
 574   (shr-heading cont))
 575
 576 (defun shr-tag-h5 (cont)
 577   (shr-heading cont))
 578
 579 (defun shr-tag-h6 (cont)
 580   (shr-heading cont))
 581
 582 (defun shr-tag-hr (cont)
 583   (shr-ensure-newline)
 584   (insert (make-string shr-width shr-hr-line) "\n"))
 585
 586 ;;; Table rendering algorithm.
 587
 588 ;; Table rendering is the only complicated thing here.  We do this by
 589 ;; first counting how many TDs there are in each TR, and registering
 590 ;; how wide they think they should be ("width=45%", etc).  Then we
 591 ;; render each TD separately (this is done in temporary buffers, so
 592 ;; that we can use all the rendering machinery as if we were in the
 593 ;; main buffer).  Now we know how much space each TD really takes, so
 594 ;; we then render everything again with the new widths, and finally
 595 ;; insert all these boxes into the main buffer.
 596 (defun shr-tag-table-1 (cont)
 597   (setq cont (or (cdr (assq 'tbody cont))
 598                  cont))
 599   (let* ((shr-inhibit-images t)
 600          (shr-kinsoku-shorten t)
 601          ;; Find all suggested widths.
 602          (columns (shr-column-specs cont))
 603          ;; Compute how many characters wide each TD should be.
 604          (suggested-widths (shr-pro-rate-columns columns))
 605          ;; Do a "test rendering" to see how big each TD is (this can
 606          ;; be smaller (if there's little text) or bigger (if there's
 607          ;; unbreakable text).
 608          (sketch (shr-make-table cont suggested-widths))
 609          (sketch-widths (shr-table-widths sketch suggested-widths)))
 610     ;; This probably won't work very well.
 611     (when (> (+ (loop for width across sketch-widths
 612                       summing (1+ width))
 613                 shr-indentation 1)
 614              (frame-width))
 615       (setq truncate-lines t))
 616     ;; Then render the table again with these new "hard" widths.
 617     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 618   ;; Finally, insert all the images after the table.  The Emacs buffer
 619   ;; model isn't strong enough to allow us to put the images actually
 620   ;; into the tables.
 621   (dolist (elem (shr-find-elements cont 'img))
 622     (shr-tag-img (cdr elem))))
 623
 624 (defun shr-tag-table (cont)
 625   (shr-ensure-paragraph)
 626   (let* ((caption (cdr (assq 'caption cont)))
 627          (header (cdr (assq 'thead cont)))
 628          (body (or (cdr (assq 'tbody cont)) cont))
 629          (footer (cdr (assq 'tfoot cont)))
 630          (nheader (if header (shr-max-columns header)))
 631          (nbody (if body (shr-max-columns body)))
 632          (nfooter (if footer (shr-max-columns footer))))
 633     (shr-tag-table-1
 634      (nconc
 635       (if caption `((tr (td ,@caption))))
 636       (if header
 637           (if footer
 638               ;; header + body + footer
 639               (if (= nheader nbody)
 640                   (if (= nbody nfooter)
 641                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 642                     (if (= nfooter 1)
 643                         `((tr (td (table (tbody ,@header ,@body))))
 644                           ,@footer)
 645                       `((tr (td (table (tbody ,@header ,@body))))
 646                         (tr (td (table (tbody ,@footer)))))))
 647                 (if (= nbody nfooter)
 648                     `((tr (td (table (tbody ,@header))))
 649                       (tr (td (table (tbody ,@body ,@footer)))))
 650                   (if (= nfooter 1)
 651                       `((tr (td (table (tbody ,@header))))
 652                         (tr (td (table (tbody ,@body))))
 653                         ,@footer)
 654                     `((tr (td (table (tbody ,@header))))
 655                       (tr (td (table (tbody ,@body))))
 656                       (tr (td (table (tbody ,@footer))))))))
 657             ;; header + body
 658             (if (= nheader nbody)
 659                 `((tr (td (table (tbody ,@header ,@body)))))
 660               (if (= nheader 1)
 661                   `(,@header (tr (td (table (tbody ,@body)))))
 662                 `((tr (td (table (tbody ,@header))))
 663                   (tr (td (table (tbody ,@body))))))))
 664         (if footer
 665             ;; body + footer
 666             (if (= nbody nfooter)
 667                 `((tr (td (table (tbody ,@body ,@footer)))))
 668               (if (= nfooter 1)
 669                   `((tr (td (table (tbody ,@body)))) ,@footer)
 670                 `((tr (td (table (tbody ,@body))))
 671                   (tr (td (table (tbody ,@footer)))))))
 672           body))))))
 673
 674 (defun shr-find-elements (cont type)
 675   (let (result)
 676     (dolist (elem cont)
 677       (cond ((eq (car elem) type)
 678              (push elem result))
 679             ((consp (cdr elem))
 680              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 681     (nreverse result)))
 682
 683 (defun shr-insert-table (table widths)
 684   (shr-insert-table-ruler widths)
 685   (dolist (row table)
 686     (let ((start (point))
 687           (height (let ((max 0))
 688                     (dolist (column row)
 689                       (setq max (max max (cadr column))))
 690                     max)))
 691       (dotimes (i height)
 692         (shr-indent)
 693         (insert "|\n"))
 694       (dolist (column row)
 695         (goto-char start)
 696         (let ((lines (nth 2 column))
 697               (overlay-lines (nth 3 column))
 698               overlay overlay-line)
 699           (dolist (line lines)
 700             (setq overlay-line (pop overlay-lines))
 701             (end-of-line)
 702             (insert line "|")
 703             (dolist (overlay overlay-line)
 704               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 705                                      (- (point) (nth 1 overlay) 1)))
 706                     (properties (nth 2 overlay)))
 707                 (while properties
 708                   (overlay-put o (pop properties) (pop properties)))))
 709             (forward-line 1))
 710           ;; Add blank lines at padding at the bottom of the TD,
 711           ;; possibly.
 712           (dotimes (i (- height (length lines)))
 713             (end-of-line)
 714             (insert (make-string (string-width (car lines)) ? ) "|")
 715             (forward-line 1)))))
 716     (shr-insert-table-ruler widths)))
 717
 718 (defun shr-insert-table-ruler (widths)
 719   (when (and (bolp)
 720              (> shr-indentation 0))
 721     (shr-indent))
 722   (insert shr-table-corner)
 723   (dotimes (i (length widths))
 724     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 725   (insert "\n"))
 726
 727 (defun shr-table-widths (table suggested-widths)
 728   (let* ((length (length suggested-widths))
 729          (widths (make-vector length 0))
 730          (natural-widths (make-vector length 0)))
 731     (dolist (row table)
 732       (let ((i 0))
 733         (dolist (column row)
 734           (aset widths i (max (aref widths i)
 735                               (car column)))
 736           (aset natural-widths i (max (aref natural-widths i)
 737                                       (cadr column)))
 738           (setq i (1+ i)))))
 739     (let ((extra (- (apply '+ (append suggested-widths nil))
 740                     (apply '+ (append widths nil))))
 741           (expanded-columns 0))
 742       (when (> extra 0)
 743         (dotimes (i length)
 744           ;; If the natural width is wider than the rendered width, we
 745           ;; want to allow the column to expand.
 746           (when (> (aref natural-widths i) (aref widths i))
 747             (setq expanded-columns (1+ expanded-columns))))
 748         (dotimes (i length)
 749           (when (> (aref natural-widths i) (aref widths i))
 750             (aset widths i (min
 751                             (1+ (aref natural-widths i))
 752                             (+ (/ extra expanded-columns)
 753                                (aref widths i))))))))
 754     widths))
 755
 756 (defun shr-make-table (cont widths &optional fill)
 757   (let ((trs nil))
 758     (dolist (row cont)
 759       (when (eq (car row) 'tr)
 760         (let ((tds nil)
 761               (columns (cdr row))
 762               (i 0)
 763               column)
 764           (while (< i (length widths))
 765             (setq column (pop columns))
 766             (when (or (memq (car column) '(td th))
 767                       (null column))
 768               (push (shr-render-td (cdr column) (aref widths i) fill)
 769                     tds)
 770               (setq i (1+ i))))
 771           (push (nreverse tds) trs))))
 772     (nreverse trs)))
 773
 774 (defun shr-render-td (cont width fill)
 775   (with-temp-buffer
 776     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 777       (if cache
 778           (insert cache)
 779         (let ((shr-width width)
 780               (shr-indentation 0))
 781           (shr-generic cont))
 782         (delete-region
 783          (point)
 784          (+ (point)
 785             (skip-chars-backward " \t\n")))
 786         (push (cons (cons width cont) (buffer-string))
 787               shr-content-cache)))
 788     (goto-char (point-min))
 789     (let ((max 0))
 790       (while (not (eobp))
 791         (end-of-line)
 792         (setq max (max max (current-column)))
 793         (forward-line 1))
 794       (when fill
 795         (goto-char (point-min))
 796         ;; If the buffer is totally empty, then put a single blank
 797         ;; line here.
 798         (if (zerop (buffer-size))
 799             (insert (make-string width ? ))
 800           ;; Otherwise, fill the buffer.
 801           (while (not (eobp))
 802             (end-of-line)
 803             (when (> (- width (current-column)) 0)
 804               (insert (make-string (- width (current-column)) ? )))
 805             (forward-line 1))))
 806       (if fill
 807           (list max
 808                 (count-lines (point-min) (point-max))
 809                 (split-string (buffer-string) "\n")
 810                 (shr-collect-overlays))
 811         (list max
 812               (shr-natural-width))))))
 813
 814 (defun shr-natural-width ()
 815   (goto-char (point-min))
 816   (let ((current 0)
 817         (max 0))
 818     (while (not (eobp))
 819       (end-of-line)
 820       (setq current (+ current (current-column)))
 821       (unless (get-text-property (point) 'shr-break)
 822         (setq max (max max current)
 823               current 0))
 824       (forward-line 1))
 825     max))
 826
 827 (defun shr-collect-overlays ()
 828   (save-excursion
 829     (goto-char (point-min))
 830     (let ((overlays nil))
 831       (while (not (eobp))
 832         (push (shr-overlays-in-region (point) (line-end-position))
 833               overlays)
 834         (forward-line 1))
 835       (nreverse overlays))))
 836
 837 (defun shr-overlays-in-region (start end)
 838   (let (result)
 839     (dolist (overlay (overlays-in start end))
 840       (push (list (if (> start (overlay-start overlay))
 841                       (- end start)
 842                     (- end (overlay-start overlay)))
 843                   (if (< end (overlay-end overlay))
 844                       0
 845                     (- end (overlay-end overlay)))
 846                   (overlay-properties overlay))
 847             result))
 848     (nreverse result)))
 849
 850 (defun shr-pro-rate-columns (columns)
 851   (let ((total-percentage 0)
 852         (widths (make-vector (length columns) 0)))
 853     (dotimes (i (length columns))
 854       (setq total-percentage (+ total-percentage (aref columns i))))
 855     (setq total-percentage (/ 1.0 total-percentage))
 856     (dotimes (i (length columns))
 857       (aset widths i (max (truncate (* (aref columns i)
 858                                        total-percentage
 859                                        (- shr-width (1+ (length columns)))))
 860                           10)))
 861     widths))
 862
 863 ;; Return a summary of the number and shape of the TDs in the table.
 864 (defun shr-column-specs (cont)
 865   (let ((columns (make-vector (shr-max-columns cont) 1)))
 866     (dolist (row cont)
 867       (when (eq (car row) 'tr)
 868         (let ((i 0))
 869           (dolist (column (cdr row))
 870             (when (memq (car column) '(td th))
 871               (let ((width (cdr (assq :width (cdr column)))))
 872                 (when (and width
 873                            (string-match "\\([0-9]+\\)%" width))
 874                   (aset columns i
 875                         (/ (string-to-number (match-string 1 width))
 876                            100.0))))
 877               (setq i (1+ i)))))))
 878     columns))
 879
 880 (defun shr-count (cont elem)
 881   (let ((i 0))
 882     (dolist (sub cont)
 883       (when (eq (car sub) elem)
 884         (setq i (1+ i))))
 885     i))
 886
 887 (defun shr-max-columns (cont)
 888   (let ((max 0))
 889     (dolist (row cont)
 890       (when (eq (car row) 'tr)
 891         (setq max (max max (+ (shr-count (cdr row) 'td)
 892                               (shr-count (cdr row) 'th))))))
 893     max))
 894
 895 (provide 'shr)
 896
 897 ;;; shr.el ends here