cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93 (defvar shr-table-depth 0)
  94
  95 (defvar shr-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map "a" 'shr-show-alt-text)
  98     (define-key map "i" 'shr-browse-image)
  99     (define-key map "I" 'shr-insert-image)
 100     (define-key map "u" 'shr-copy-url)
 101     (define-key map "v" 'shr-browse-url)
 102     (define-key map "o" 'shr-save-contents)
 103     (define-key map "\r" 'shr-browse-url)
 104     map))
 105
 106 ;; Public functions and commands.
 107
 108 ;;;###autoload
 109 (defun shr-insert-document (dom)
 110   (setq shr-content-cache nil)
 111   (let ((shr-state nil)
 112         (shr-start nil))
 113     (shr-descend (shr-transform-dom dom))))
 114
 115 (defun shr-copy-url ()
 116   "Copy the URL under point to the kill ring.
 117 If called twice, then try to fetch the URL and see whether it
 118 redirects somewhere else."
 119   (interactive)
 120   (let ((url (get-text-property (point) 'shr-url)))
 121     (cond
 122      ((not url)
 123       (message "No URL under point"))
 124      ;; Resolve redirected URLs.
 125      ((equal url (car kill-ring))
 126       (url-retrieve
 127        url
 128        (lambda (a)
 129          (when (and (consp a)
 130                     (eq (car a) :redirect))
 131            (with-temp-buffer
 132              (insert (cadr a))
 133              (goto-char (point-min))
 134              ;; Remove common tracking junk from the URL.
 135              (when (re-search-forward ".utm_.*" nil t)
 136                (replace-match "" t t))
 137              (message "Copied %s" (buffer-string))
 138              (copy-region-as-kill (point-min) (point-max)))))))
 139      ;; Copy the URL to the kill ring.
 140      (t
 141       (with-temp-buffer
 142         (insert url)
 143         (copy-region-as-kill (point-min) (point-max))
 144         (message "Copied %s" url))))))
 145
 146 (defun shr-show-alt-text ()
 147   "Show the ALT text of the image under point."
 148   (interactive)
 149   (let ((text (get-text-property (point) 'shr-alt)))
 150     (if (not text)
 151         (message "No image under point")
 152       (message "%s" text))))
 153
 154 (defun shr-browse-image ()
 155   "Browse the image under point."
 156   (interactive)
 157   (let ((url (get-text-property (point) 'shr-image)))
 158     (if (not url)
 159         (message "No image under point")
 160       (message "Browsing %s..." url)
 161       (browse-url url))))
 162
 163 (defun shr-insert-image ()
 164   "Insert the image under point into the buffer."
 165   (interactive)
 166   (let ((url (get-text-property (point) 'shr-image)))
 167     (if (not url)
 168         (message "No image under point")
 169       (message "Inserting %s..." url)
 170       (url-retrieve url 'shr-image-fetched
 171                     (list (current-buffer) (1- (point)) (point-marker))
 172                     t))))
 173
 174 ;;; Utility functions.
 175
 176 (defun shr-transform-dom (dom)
 177   (let ((result (list (pop dom))))
 178     (dolist (arg (pop dom))
 179       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 180                   (cdr arg))
 181             result))
 182     (dolist (sub dom)
 183       (if (stringp sub)
 184           (push (cons :text sub) result)
 185         (push (shr-transform-dom sub) result)))
 186     (nreverse result)))
 187
 188 (defun shr-descend (dom)
 189   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 190     (if (fboundp function)
 191         (funcall function (cdr dom))
 192       (shr-generic (cdr dom)))))
 193
 194 (defun shr-generic (cont)
 195   (dolist (sub cont)
 196     (cond
 197      ((eq (car sub) :text)
 198       (shr-insert (cdr sub)))
 199      ((listp (cdr sub))
 200       (shr-descend sub)))))
 201
 202 (defun shr-insert (text)
 203   (when (and (eq shr-state 'image)
 204              (not (string-match "\\`[ \t\n]+\\'" text)))
 205     (insert "\n")
 206     (setq shr-state nil))
 207   (cond
 208    ((eq shr-folding-mode 'none)
 209     (insert text))
 210    (t
 211     (when (and (string-match "\\`[ \t\n]" text)
 212                (not (bolp))
 213                (not (eq (char-after (1- (point))) ? )))
 214       (insert " "))
 215     (dolist (elem (split-string text))
 216       (when (and (bolp)
 217                  (> shr-indentation 0))
 218         (shr-indent))
 219       ;; The shr-start is a special variable that is used to pass
 220       ;; upwards the first point in the buffer where the text really
 221       ;; starts.
 222       (unless shr-start
 223         (setq shr-start (point)))
 224       ;; No space is needed behind a wide character categorized as
 225       ;; kinsoku-bol, between characters both categorized as nospace,
 226       ;; or at the beginning of a line.
 227       (let (prev)
 228         (when (and (eq (preceding-char) ? )
 229                    (or (= (line-beginning-position) (1- (point)))
 230                        (and (aref fill-find-break-point-function-table
 231                                   (setq prev (char-after (- (point) 2))))
 232                             (aref (char-category-set prev) ?>))
 233                        (and (aref fill-nospace-between-words-table prev)
 234                             (aref fill-nospace-between-words-table
 235                                   (aref elem 0)))))
 236           (delete-char -1)))
 237       (insert elem)
 238       (while (> (current-column) shr-width)
 239         (unless (prog1
 240                     (shr-find-fill-point)
 241                   (when (eq (preceding-char) ? )
 242                     (delete-char -1))
 243                   (insert "\n"))
 244           (put-text-property (1- (point)) (point) 'shr-break t)
 245           ;; No space is needed at the beginning of a line.
 246           (when (eq (following-char) ? )
 247             (delete-char 1)))
 248         (when (> shr-indentation 0)
 249           (shr-indent))
 250         (end-of-line))
 251       (insert " "))
 252     (unless (string-match "[ \t\n]\\'" text)
 253       (delete-char -1)))))
 254
 255 (defun shr-find-fill-point ()
 256   (when (> (move-to-column shr-width) shr-width)
 257     (backward-char 1))
 258   (let (failed)
 259     (while (not
 260             (or (setq failed (= (current-column) shr-indentation))
 261                 (eq (preceding-char) ? )
 262                 (eq (following-char) ? )
 263                 (aref fill-find-break-point-function-table (preceding-char))))
 264       (backward-char 1))
 265     (if failed
 266         ;; There's no breakable point, so we give it up.
 267         (progn
 268           (end-of-line)
 269           (while (aref fill-find-break-point-function-table (preceding-char))
 270             (backward-char 1))
 271           nil)
 272       (or (eolp)
 273           ;; Don't put kinsoku-bol characters at the beginning of a line,
 274           ;; or kinsoku-eol characters at the end of a line,
 275           (let ((count 4))
 276             (if (or shr-kinsoku-shorten
 277                     (and (aref (char-category-set (preceding-char)) ?<)
 278                          (progn
 279                            (setq count (1- count))
 280                            (backward-char 1)
 281                            t)))
 282                 (while (and
 283                         (>= (setq count (1- count)) 0)
 284                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 285                         (or (aref (char-category-set (preceding-char)) ?<)
 286                             (aref (char-category-set (following-char)) ?>)))
 287                   (backward-char 1))
 288               (while (and (>= (setq count (1- count)) 0)
 289                           (aref (char-category-set (following-char)) ?>))
 290                 (forward-char 1)))
 291             (when (eq (following-char) ? )
 292               (forward-char 1))
 293             t)))))
 294
 295 (defun shr-ensure-newline ()
 296   (unless (zerop (current-column))
 297     (insert "\n")))
 298
 299 (defun shr-ensure-paragraph ()
 300   (unless (bobp)
 301     (if (<= (current-column) shr-indentation)
 302         (unless (save-excursion
 303                   (forward-line -1)
 304                   (looking-at " *$"))
 305           (insert "\n"))
 306       (if (save-excursion
 307             (beginning-of-line)
 308             (looking-at " *$"))
 309           (insert "\n")
 310         (insert "\n\n")))))
 311
 312 (defun shr-indent ()
 313   (when (> shr-indentation 0)
 314     (insert (make-string shr-indentation ? ))))
 315
 316 (defun shr-fontize-cont (cont &rest types)
 317   (let (shr-start)
 318     (shr-generic cont)
 319     (dolist (type types)
 320       (shr-add-font (or shr-start (point)) (point) type))))
 321
 322 ;; Add an overlay in the region, but avoid putting the font properties
 323 ;; on blank text at the start of the line, and the newline at the end,
 324 ;; to avoid ugliness.
 325 (defun shr-add-font (start end type)
 326   (save-excursion
 327     (goto-char start)
 328     (while (< (point) end)
 329       (when (bolp)
 330         (skip-chars-forward " "))
 331       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 332         (overlay-put overlay 'face type))
 333       (if (< (line-end-position) end)
 334           (forward-line 1)
 335         (goto-char end)))))
 336
 337 (defun shr-browse-url ()
 338   "Browse the URL under point."
 339   (interactive)
 340   (let ((url (get-text-property (point) 'shr-url)))
 341     (if (not url)
 342         (message "No link under point")
 343       (browse-url url))))
 344
 345 (defun shr-save-contents (directory)
 346   "Save the contents from URL in a file."
 347   (interactive "DSave contents of URL to directory: ")
 348   (let ((url (get-text-property (point) 'shr-url)))
 349     (if (not url)
 350         (message "No link under point")
 351       (url-retrieve (shr-encode-url url)
 352                     'shr-store-contents (list url directory)))))
 353
 354 (defun shr-store-contents (status url directory)
 355   (unless (plist-get status :error)
 356     (when (or (search-forward "\n\n" nil t)
 357               (search-forward "\r\n\r\n" nil t))
 358       (write-region (point) (point-max)
 359                     (expand-file-name (file-name-nondirectory url)
 360                                       directory)))))
 361
 362 (defun shr-image-fetched (status buffer start end)
 363   (when (and (buffer-name buffer)
 364              (not (plist-get status :error)))
 365     (url-store-in-cache (current-buffer))
 366     (when (or (search-forward "\n\n" nil t)
 367               (search-forward "\r\n\r\n" nil t))
 368       (let ((data (buffer-substring (point) (point-max))))
 369         (with-current-buffer buffer
 370           (let ((alt (buffer-substring start end))
 371                 (inhibit-read-only t))
 372             (delete-region start end)
 373             (shr-put-image data start alt))))))
 374   (kill-buffer (current-buffer)))
 375
 376 (defun shr-put-image (data point alt)
 377   (if (display-graphic-p)
 378       (let ((image (ignore-errors
 379                      (shr-rescale-image data))))
 380         (when image
 381           (put-image image point alt)))
 382     (save-excursion
 383       (goto-char point)
 384       (insert alt))))
 385
 386 (defun shr-rescale-image (data)
 387   (if (or (not (fboundp 'imagemagick-types))
 388           (not (get-buffer-window (current-buffer))))
 389       (create-image data nil t)
 390     (let* ((image (create-image data nil t))
 391            (size (image-size image t))
 392            (width (car size))
 393            (height (cdr size))
 394            (edges (window-inside-pixel-edges
 395                    (get-buffer-window (current-buffer))))
 396            (window-width (truncate (* shr-max-image-proportion
 397                                       (- (nth 2 edges) (nth 0 edges)))))
 398            (window-height (truncate (* shr-max-image-proportion
 399                                        (- (nth 3 edges) (nth 1 edges)))))
 400            scaled-image)
 401       (when (> height window-height)
 402         (setq image (or (create-image data 'imagemagick t
 403                                       :height window-height)
 404                         image))
 405         (setq size (image-size image t)))
 406       (when (> (car size) window-width)
 407         (setq image (or
 408                      (create-image data 'imagemagick t
 409                                    :width window-width)
 410                      image)))
 411       image)))
 412
 413 (defun shr-get-image-data (url)
 414   "Get image data for URL.
 415 Return a string with image data."
 416   (with-temp-buffer
 417     (mm-disable-multibyte)
 418     (when (ignore-errors
 419             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 420             t)
 421       (when (or (search-forward "\n\n" nil t)
 422                 (search-forward "\r\n\r\n" nil t))
 423         (buffer-substring (point) (point-max))))))
 424
 425 (defun shr-heading (cont &rest types)
 426   (shr-ensure-paragraph)
 427   (apply #'shr-fontize-cont cont types)
 428   (shr-ensure-paragraph))
 429
 430 (defun shr-urlify (start url)
 431   (widget-convert-button
 432    'url-link start (point)
 433    :help-echo url
 434    :keymap shr-map
 435    url)
 436   (put-text-property start (point) 'shr-url url))
 437
 438 (defun shr-encode-url (url)
 439   "Encode URL."
 440   (browse-url-url-encode-chars url "[)$ ]"))
 441
 442 ;;; Tag-specific rendering rules.
 443
 444 (defun shr-tag-p (cont)
 445   (shr-ensure-paragraph)
 446   (shr-indent)
 447   (shr-generic cont)
 448   (shr-ensure-paragraph))
 449
 450 (defun shr-tag-div (cont)
 451   (shr-ensure-newline)
 452   (shr-indent)
 453   (shr-generic cont)
 454   (shr-ensure-newline))
 455
 456 (defun shr-tag-b (cont)
 457   (shr-fontize-cont cont 'bold))
 458
 459 (defun shr-tag-i (cont)
 460   (shr-fontize-cont cont 'italic))
 461
 462 (defun shr-tag-em (cont)
 463   (shr-fontize-cont cont 'bold))
 464
 465 (defun shr-tag-strong (cont)
 466   (shr-fontize-cont cont 'bold))
 467
 468 (defun shr-tag-u (cont)
 469   (shr-fontize-cont cont 'underline))
 470
 471 (defun shr-tag-s (cont)
 472   (shr-fontize-cont cont 'strike-through))
 473
 474 (defun shr-tag-span (cont)
 475   (let ((start (point))
 476         (color (cdr (assq 'color (shr-parse-style (cdr (assq :style cont)))))))
 477     (shr-generic cont)
 478     (when color
 479       (let ((overlay (make-overlay start (point))))
 480         (overlay-put overlay 'face (cons 'foreground-color color))))))
 481
 482 (defun shr-parse-style (style)
 483   (when style
 484     (let ((plist nil))
 485       (dolist (elem (split-string style ";"))
 486         (when elem
 487           (setq elem (split-string elem ":"))
 488           (when (and (car elem)
 489                      (cadr elem))
 490             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 491                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 492               (push (cons (intern name obarray)
 493                           value)
 494                     plist)))))
 495       plist)))
 496
 497 (defun shr-tag-a (cont)
 498   (let ((url (cdr (assq :href cont)))
 499         (start (point))
 500         shr-start)
 501     (shr-generic cont)
 502     (shr-urlify (or shr-start start) url)))
 503
 504 (defun shr-tag-object (cont)
 505   (let ((url (cdr (assq :src (cdr (assq 'embed cont)))))
 506         (start (point)))
 507     (when url
 508       (shr-insert " [multimedia] ")
 509       (shr-urlify start url))))
 510
 511 (defun shr-tag-img (cont)
 512   (when (and cont
 513              (cdr (assq :src cont)))
 514     (when (and (> (current-column) 0)
 515                (not (eq shr-state 'image)))
 516       (insert "\n"))
 517     (let ((alt (cdr (assq :alt cont)))
 518           (url (cdr (assq :src cont))))
 519       (let ((start (point-marker)))
 520         (when (zerop (length alt))
 521           (setq alt "[img]"))
 522         (cond
 523          ((and (not shr-inhibit-images)
 524                (string-match "\\`cid:" url))
 525           (let ((url (substring url (match-end 0)))
 526                 image)
 527             (if (or (not shr-content-function)
 528                     (not (setq image (funcall shr-content-function url))))
 529                 (insert alt)
 530               (shr-put-image image (point) alt))))
 531          ((or shr-inhibit-images
 532               (and shr-blocked-images
 533                    (string-match shr-blocked-images url)))
 534           (setq shr-start (point))
 535           (let ((shr-state 'space))
 536             (if (> (length alt) 8)
 537                 (shr-insert (substring alt 0 8))
 538               (shr-insert alt))))
 539          ((url-is-cached (shr-encode-url url))
 540           (shr-put-image (shr-get-image-data url) (point) alt))
 541          (t
 542           (insert alt)
 543           (ignore-errors
 544             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 545                           (list (current-buffer) start (point-marker))
 546                           t))))
 547         (insert " ")
 548         (put-text-property start (point) 'keymap shr-map)
 549         (put-text-property start (point) 'shr-alt alt)
 550         (put-text-property start (point) 'shr-image url)
 551         (setq shr-state 'image)))))
 552
 553 (defun shr-tag-pre (cont)
 554   (let ((shr-folding-mode 'none))
 555     (shr-ensure-newline)
 556     (shr-indent)
 557     (shr-generic cont)
 558     (shr-ensure-newline)))
 559
 560 (defun shr-tag-blockquote (cont)
 561   (shr-ensure-paragraph)
 562   (shr-indent)
 563   (let ((shr-indentation (+ shr-indentation 4)))
 564     (shr-generic cont))
 565   (shr-ensure-paragraph))
 566
 567 (defun shr-tag-ul (cont)
 568   (shr-ensure-paragraph)
 569   (let ((shr-list-mode 'ul))
 570     (shr-generic cont))
 571   (shr-ensure-paragraph))
 572
 573 (defun shr-tag-ol (cont)
 574   (shr-ensure-paragraph)
 575   (let ((shr-list-mode 1))
 576     (shr-generic cont))
 577   (shr-ensure-paragraph))
 578
 579 (defun shr-tag-li (cont)
 580   (shr-ensure-paragraph)
 581   (shr-indent)
 582   (let* ((bullet
 583           (if (numberp shr-list-mode)
 584               (prog1
 585                   (format "%d " shr-list-mode)
 586                 (setq shr-list-mode (1+ shr-list-mode)))
 587             "* "))
 588          (shr-indentation (+ shr-indentation (length bullet))))
 589     (insert bullet)
 590     (shr-generic cont)))
 591
 592 (defun shr-tag-br (cont)
 593   (unless (bobp)
 594     (insert "\n")
 595     (shr-indent))
 596   (shr-generic cont))
 597
 598 (defun shr-tag-h1 (cont)
 599   (shr-heading cont 'bold 'underline))
 600
 601 (defun shr-tag-h2 (cont)
 602   (shr-heading cont 'bold))
 603
 604 (defun shr-tag-h3 (cont)
 605   (shr-heading cont 'italic))
 606
 607 (defun shr-tag-h4 (cont)
 608   (shr-heading cont))
 609
 610 (defun shr-tag-h5 (cont)
 611   (shr-heading cont))
 612
 613 (defun shr-tag-h6 (cont)
 614   (shr-heading cont))
 615
 616 (defun shr-tag-hr (cont)
 617   (shr-ensure-newline)
 618   (insert (make-string shr-width shr-hr-line) "\n"))
 619
 620 ;;; Table rendering algorithm.
 621
 622 ;; Table rendering is the only complicated thing here.  We do this by
 623 ;; first counting how many TDs there are in each TR, and registering
 624 ;; how wide they think they should be ("width=45%", etc).  Then we
 625 ;; render each TD separately (this is done in temporary buffers, so
 626 ;; that we can use all the rendering machinery as if we were in the
 627 ;; main buffer).  Now we know how much space each TD really takes, so
 628 ;; we then render everything again with the new widths, and finally
 629 ;; insert all these boxes into the main buffer.
 630 (defun shr-tag-table-1 (cont)
 631   (setq cont (or (cdr (assq 'tbody cont))
 632                  cont))
 633   (let* ((shr-inhibit-images t)
 634          (shr-table-depth (1+ shr-table-depth))
 635          (shr-kinsoku-shorten t)
 636          ;; Find all suggested widths.
 637          (columns (shr-column-specs cont))
 638          ;; Compute how many characters wide each TD should be.
 639          (suggested-widths (shr-pro-rate-columns columns))
 640          ;; Do a "test rendering" to see how big each TD is (this can
 641          ;; be smaller (if there's little text) or bigger (if there's
 642          ;; unbreakable text).
 643          (sketch (shr-make-table cont suggested-widths))
 644          (sketch-widths (shr-table-widths sketch suggested-widths)))
 645     ;; This probably won't work very well.
 646     (when (> (+ (loop for width across sketch-widths
 647                       summing (1+ width))
 648                 shr-indentation 1)
 649              (frame-width))
 650       (setq truncate-lines t))
 651     ;; Then render the table again with these new "hard" widths.
 652     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 653   ;; Finally, insert all the images after the table.  The Emacs buffer
 654   ;; model isn't strong enough to allow us to put the images actually
 655   ;; into the tables.
 656   (when (zerop shr-table-depth)
 657     (dolist (elem (shr-find-elements cont 'img))
 658       (shr-tag-img (cdr elem)))))
 659
 660 (defun shr-tag-table (cont)
 661   (shr-ensure-paragraph)
 662   (let* ((caption (cdr (assq 'caption cont)))
 663          (header (cdr (assq 'thead cont)))
 664          (body (or (cdr (assq 'tbody cont)) cont))
 665          (footer (cdr (assq 'tfoot cont)))
 666          (nheader (if header (shr-max-columns header)))
 667          (nbody (if body (shr-max-columns body)))
 668          (nfooter (if footer (shr-max-columns footer))))
 669     (shr-tag-table-1
 670      (nconc
 671       (if caption `((tr (td ,@caption))))
 672       (if header
 673           (if footer
 674               ;; hader + body + footer
 675               (if (= nheader nbody)
 676                   (if (= nbody nfooter)
 677                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 678                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 679                            (if (= nfooter 1)
 680                                footer
 681                              `((tr (td (table (tbody ,@footer))))))))
 682                 (nconc `((tr (td (table (tbody ,@header)))))
 683                        (if (= nbody nfooter)
 684                            `((tr (td (table (tbody ,@body ,@footer)))))
 685                          (nconc `((tr (td (table (tbody ,@body)))))
 686                                 (if (= nfooter 1)
 687                                     footer
 688                                   `((tr (td (table (tbody ,@footer))))))))))
 689             ;; header + body
 690             (if (= nheader nbody)
 691                 `((tr (td (table (tbody ,@header ,@body)))))
 692               (if (= nheader 1)
 693                   `(,@header (tr (td (table (tbody ,@body)))))
 694                 `((tr (td (table (tbody ,@header))))
 695                   (tr (td (table (tbody ,@body))))))))
 696         (if footer
 697             ;; body + footer
 698             (if (= nbody nfooter)
 699                 `((tr (td (table (tbody ,@body ,@footer)))))
 700               (nconc `((tr (td (table (tbody ,@body)))))
 701                      (if (= nfooter 1)
 702                          footer
 703                        `((tr (td (table (tbody ,@footer))))))))
 704           (if caption
 705               `((tr (td (table (tbody ,@body)))))
 706             body)))))))
 707
 708 (defun shr-find-elements (cont type)
 709   (let (result)
 710     (dolist (elem cont)
 711       (cond ((eq (car elem) type)
 712              (push elem result))
 713             ((consp (cdr elem))
 714              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 715     (nreverse result)))
 716
 717 (defun shr-insert-table (table widths)
 718   (shr-insert-table-ruler widths)
 719   (dolist (row table)
 720     (let ((start (point))
 721           (height (let ((max 0))
 722                     (dolist (column row)
 723                       (setq max (max max (cadr column))))
 724                     max)))
 725       (dotimes (i height)
 726         (shr-indent)
 727         (insert "|\n"))
 728       (dolist (column row)
 729         (goto-char start)
 730         (let ((lines (nth 2 column))
 731               (overlay-lines (nth 3 column))
 732               overlay overlay-line)
 733           (dolist (line lines)
 734             (setq overlay-line (pop overlay-lines))
 735             (end-of-line)
 736             (insert line "|")
 737             (dolist (overlay overlay-line)
 738               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 739                                      (- (point) (nth 1 overlay) 1)))
 740                     (properties (nth 2 overlay)))
 741                 (while properties
 742                   (overlay-put o (pop properties) (pop properties)))))
 743             (forward-line 1))
 744           ;; Add blank lines at padding at the bottom of the TD,
 745           ;; possibly.
 746           (dotimes (i (- height (length lines)))
 747             (end-of-line)
 748             (insert (make-string (string-width (car lines)) ? ) "|")
 749             (forward-line 1)))))
 750     (shr-insert-table-ruler widths)))
 751
 752 (defun shr-insert-table-ruler (widths)
 753   (when (and (bolp)
 754              (> shr-indentation 0))
 755     (shr-indent))
 756   (insert shr-table-corner)
 757   (dotimes (i (length widths))
 758     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 759   (insert "\n"))
 760
 761 (defun shr-table-widths (table suggested-widths)
 762   (let* ((length (length suggested-widths))
 763          (widths (make-vector length 0))
 764          (natural-widths (make-vector length 0)))
 765     (dolist (row table)
 766       (let ((i 0))
 767         (dolist (column row)
 768           (aset widths i (max (aref widths i)
 769                               (car column)))
 770           (aset natural-widths i (max (aref natural-widths i)
 771                                       (cadr column)))
 772           (setq i (1+ i)))))
 773     (let ((extra (- (apply '+ (append suggested-widths nil))
 774                     (apply '+ (append widths nil))))
 775           (expanded-columns 0))
 776       (when (> extra 0)
 777         (dotimes (i length)
 778           ;; If the natural width is wider than the rendered width, we
 779           ;; want to allow the column to expand.
 780           (when (> (aref natural-widths i) (aref widths i))
 781             (setq expanded-columns (1+ expanded-columns))))
 782         (dotimes (i length)
 783           (when (> (aref natural-widths i) (aref widths i))
 784             (aset widths i (min
 785                             (1+ (aref natural-widths i))
 786                             (+ (/ extra expanded-columns)
 787                                (aref widths i))))))))
 788     widths))
 789
 790 (defun shr-make-table (cont widths &optional fill)
 791   (let ((trs nil))
 792     (dolist (row cont)
 793       (when (eq (car row) 'tr)
 794         (let ((tds nil)
 795               (columns (cdr row))
 796               (i 0)
 797               column)
 798           (while (< i (length widths))
 799             (setq column (pop columns))
 800             (when (or (memq (car column) '(td th))
 801                       (null column))
 802               (push (shr-render-td (cdr column) (aref widths i) fill)
 803                     tds)
 804               (setq i (1+ i))))
 805           (push (nreverse tds) trs))))
 806     (nreverse trs)))
 807
 808 (defun shr-render-td (cont width fill)
 809   (with-temp-buffer
 810     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 811       (if cache
 812           (insert cache)
 813         (let ((shr-width width)
 814               (shr-indentation 0))
 815           (shr-generic cont))
 816         (delete-region
 817          (point)
 818          (+ (point)
 819             (skip-chars-backward " \t\n")))
 820         (push (cons (cons width cont) (buffer-string))
 821               shr-content-cache)))
 822     (goto-char (point-min))
 823     (let ((max 0))
 824       (while (not (eobp))
 825         (end-of-line)
 826         (setq max (max max (current-column)))
 827         (forward-line 1))
 828       (when fill
 829         (goto-char (point-min))
 830         ;; If the buffer is totally empty, then put a single blank
 831         ;; line here.
 832         (if (zerop (buffer-size))
 833             (insert (make-string width ? ))
 834           ;; Otherwise, fill the buffer.
 835           (while (not (eobp))
 836             (end-of-line)
 837             (when (> (- width (current-column)) 0)
 838               (insert (make-string (- width (current-column)) ? )))
 839             (forward-line 1))))
 840       (if fill
 841           (list max
 842                 (count-lines (point-min) (point-max))
 843                 (split-string (buffer-string) "\n")
 844                 (shr-collect-overlays))
 845         (list max
 846               (shr-natural-width))))))
 847
 848 (defun shr-natural-width ()
 849   (goto-char (point-min))
 850   (let ((current 0)
 851         (max 0))
 852     (while (not (eobp))
 853       (end-of-line)
 854       (setq current (+ current (current-column)))
 855       (unless (get-text-property (point) 'shr-break)
 856         (setq max (max max current)
 857               current 0))
 858       (forward-line 1))
 859     max))
 860
 861 (defun shr-collect-overlays ()
 862   (save-excursion
 863     (goto-char (point-min))
 864     (let ((overlays nil))
 865       (while (not (eobp))
 866         (push (shr-overlays-in-region (point) (line-end-position))
 867               overlays)
 868         (forward-line 1))
 869       (nreverse overlays))))
 870
 871 (defun shr-overlays-in-region (start end)
 872   (let (result)
 873     (dolist (overlay (overlays-in start end))
 874       (push (list (if (> start (overlay-start overlay))
 875                       (- end start)
 876                     (- end (overlay-start overlay)))
 877                   (if (< end (overlay-end overlay))
 878                       0
 879                     (- end (overlay-end overlay)))
 880                   (overlay-properties overlay))
 881             result))
 882     (nreverse result)))
 883
 884 (defun shr-pro-rate-columns (columns)
 885   (let ((total-percentage 0)
 886         (widths (make-vector (length columns) 0)))
 887     (dotimes (i (length columns))
 888       (setq total-percentage (+ total-percentage (aref columns i))))
 889     (setq total-percentage (/ 1.0 total-percentage))
 890     (dotimes (i (length columns))
 891       (aset widths i (max (truncate (* (aref columns i)
 892                                        total-percentage
 893                                        (- shr-width (1+ (length columns)))))
 894                           10)))
 895     widths))
 896
 897 ;; Return a summary of the number and shape of the TDs in the table.
 898 (defun shr-column-specs (cont)
 899   (let ((columns (make-vector (shr-max-columns cont) 1)))
 900     (dolist (row cont)
 901       (when (eq (car row) 'tr)
 902         (let ((i 0))
 903           (dolist (column (cdr row))
 904             (when (memq (car column) '(td th))
 905               (let ((width (cdr (assq :width (cdr column)))))
 906                 (when (and width
 907                            (string-match "\\([0-9]+\\)%" width))
 908                   (aset columns i
 909                         (/ (string-to-number (match-string 1 width))
 910                            100.0))))
 911               (setq i (1+ i)))))))
 912     columns))
 913
 914 (defun shr-count (cont elem)
 915   (let ((i 0))
 916     (dolist (sub cont)
 917       (when (eq (car sub) elem)
 918         (setq i (1+ i))))
 919     i))
 920
 921 (defun shr-max-columns (cont)
 922   (let ((max 0))
 923     (dolist (row cont)
 924       (when (eq (car row) 'tr)
 925         (setq max (max max (+ (shr-count (cdr row) 'td)
 926                               (shr-count (cdr row) 'th))))))
 927     max))
 928
 929 (provide 'shr)
 930
 931 ;;; shr.el ends here