cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering."
  78   :type 'integer
  79   :group 'shr)
  80
  81 (defvar shr-content-function nil
  82   "If bound, this should be a function that will return the content.
  83 This is used for cid: URLs, and the function is called with the
  84 cid: URL as the argument.")
  85
  86 ;;; Internal variables.
  87
  88 (defvar shr-folding-mode nil)
  89 (defvar shr-state nil)
  90 (defvar shr-start nil)
  91 (defvar shr-indentation 0)
  92 (defvar shr-inhibit-images nil)
  93 (defvar shr-list-mode nil)
  94 (defvar shr-content-cache nil)
  95 (defvar shr-kinsoku-shorten nil)
  96 (defvar shr-table-depth 0)
  97 (defvar shr-stylesheet nil)
  98
  99 (defvar shr-map
 100   (let ((map (make-sparse-keymap)))
 101     (define-key map "a" 'shr-show-alt-text)
 102     (define-key map "i" 'shr-browse-image)
 103     (define-key map "I" 'shr-insert-image)
 104     (define-key map "u" 'shr-copy-url)
 105     (define-key map "v" 'shr-browse-url)
 106     (define-key map "o" 'shr-save-contents)
 107     (define-key map "\r" 'shr-browse-url)
 108     map))
 109
 110 ;; Public functions and commands.
 111
 112 ;;;###autoload
 113 (defun shr-insert-document (dom)
 114   (setq shr-content-cache nil)
 115   (let ((shr-state nil)
 116         (shr-start nil))
 117     (shr-descend (shr-transform-dom dom))))
 118
 119 (defun shr-copy-url ()
 120   "Copy the URL under point to the kill ring.
 121 If called twice, then try to fetch the URL and see whether it
 122 redirects somewhere else."
 123   (interactive)
 124   (let ((url (get-text-property (point) 'shr-url)))
 125     (cond
 126      ((not url)
 127       (message "No URL under point"))
 128      ;; Resolve redirected URLs.
 129      ((equal url (car kill-ring))
 130       (url-retrieve
 131        url
 132        (lambda (a)
 133          (when (and (consp a)
 134                     (eq (car a) :redirect))
 135            (with-temp-buffer
 136              (insert (cadr a))
 137              (goto-char (point-min))
 138              ;; Remove common tracking junk from the URL.
 139              (when (re-search-forward ".utm_.*" nil t)
 140                (replace-match "" t t))
 141              (message "Copied %s" (buffer-string))
 142              (copy-region-as-kill (point-min) (point-max)))))))
 143      ;; Copy the URL to the kill ring.
 144      (t
 145       (with-temp-buffer
 146         (insert url)
 147         (copy-region-as-kill (point-min) (point-max))
 148         (message "Copied %s" url))))))
 149
 150 (defun shr-show-alt-text ()
 151   "Show the ALT text of the image under point."
 152   (interactive)
 153   (let ((text (get-text-property (point) 'shr-alt)))
 154     (if (not text)
 155         (message "No image under point")
 156       (message "%s" text))))
 157
 158 (defun shr-browse-image ()
 159   "Browse the image under point."
 160   (interactive)
 161   (let ((url (get-text-property (point) 'image-url)))
 162     (if (not url)
 163         (message "No image under point")
 164       (message "Browsing %s..." url)
 165       (browse-url url))))
 166
 167 (defun shr-insert-image ()
 168   "Insert the image under point into the buffer."
 169   (interactive)
 170   (let ((url (get-text-property (point) 'image-url)))
 171     (if (not url)
 172         (message "No image under point")
 173       (message "Inserting %s..." url)
 174       (url-retrieve url 'shr-image-fetched
 175                     (list (current-buffer) (1- (point)) (point-marker))
 176                     t))))
 177
 178 ;;; Utility functions.
 179
 180 (defun shr-transform-dom (dom)
 181   (let ((result (list (pop dom))))
 182     (dolist (arg (pop dom))
 183       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 184                   (cdr arg))
 185             result))
 186     (dolist (sub dom)
 187       (if (stringp sub)
 188           (push (cons 'text sub) result)
 189         (push (shr-transform-dom sub) result)))
 190     (nreverse result)))
 191
 192 (defun shr-descend (dom)
 193   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 194         (style (cdr (assq :style (cdr dom))))
 195         (shr-stylesheet shr-stylesheet)
 196         (start (point)))
 197     (when style
 198       (if (string-match "color" style)
 199           (setq shr-stylesheet (nconc (shr-parse-style style)
 200                                       shr-stylesheet))
 201         (setq style nil)))
 202     (if (fboundp function)
 203         (funcall function (cdr dom))
 204       (shr-generic (cdr dom)))
 205     ;; If style is set, then this node has set the color.
 206     (when style
 207       (shr-colorize-region start (point)
 208                            (cdr (assq 'color shr-stylesheet))
 209                            (cdr (assq 'background-color shr-stylesheet))))))
 210
 211 (defun shr-generic (cont)
 212   (dolist (sub cont)
 213     (cond
 214      ((eq (car sub) 'text)
 215       (shr-insert (cdr sub)))
 216      ((listp (cdr sub))
 217       (shr-descend sub)))))
 218
 219 (defmacro shr-char-breakable-p (char)
 220   "Return non-nil if a line can be broken before and after CHAR."
 221   `(aref fill-find-break-point-function-table ,char))
 222 (defmacro shr-char-nospace-p (char)
 223   "Return non-nil if no space is required before and after CHAR."
 224   `(aref fill-nospace-between-words-table ,char))
 225
 226 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 227 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 228 ;; parentheses, and so on, that should not be placed in the beginning
 229 ;; of a line or the end of a line.
 230 (defmacro shr-char-kinsoku-bol-p (char)
 231   "Return non-nil if a line ought not to begin with CHAR."
 232   `(aref (char-category-set ,char) ?>))
 233 (defmacro shr-char-kinsoku-eol-p (char)
 234   "Return non-nil if a line ought not to end with CHAR."
 235   `(aref (char-category-set ,char) ?<))
 236 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 237   (load "kinsoku" nil t))
 238
 239 (defun shr-insert (text)
 240   (when (and (eq shr-state 'image)
 241              (not (string-match "\\`[ \t\n]+\\'" text)))
 242     (insert "\n")
 243     (setq shr-state nil))
 244   (cond
 245    ((eq shr-folding-mode 'none)
 246     (insert text))
 247    (t
 248     (when (and (string-match "\\`[ \t\n]" text)
 249                (not (bolp))
 250                (not (eq (char-after (1- (point))) ? )))
 251       (insert " "))
 252     (dolist (elem (split-string text))
 253       (when (and (bolp)
 254                  (> shr-indentation 0))
 255         (shr-indent))
 256       ;; The shr-start is a special variable that is used to pass
 257       ;; upwards the first point in the buffer where the text really
 258       ;; starts.
 259       (unless shr-start
 260         (setq shr-start (point)))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (eq (preceding-char) ? )
 266                    (or (= (line-beginning-position) (1- (point)))
 267                        (and (shr-char-breakable-p
 268                              (setq prev (char-after (- (point) 2))))
 269                             (shr-char-kinsoku-bol-p prev))
 270                        (and (shr-char-nospace-p prev)
 271                             (shr-char-nospace-p (aref elem 0)))))
 272           (delete-char -1)))
 273       (insert elem)
 274       (let (found)
 275         (while (and (> (current-column) shr-width)
 276                     (progn
 277                       (setq found (shr-find-fill-point))
 278                       (not (eolp))))
 279           (when (eq (preceding-char) ? )
 280             (delete-char -1))
 281           (insert "\n")
 282           (unless found
 283             (put-text-property (1- (point)) (point) 'shr-break t)
 284             ;; No space is needed at the beginning of a line.
 285             (when (eq (following-char) ? )
 286               (delete-char 1)))
 287           (when (> shr-indentation 0)
 288             (shr-indent))
 289           (end-of-line))
 290         (insert " ")))
 291     (unless (string-match "[ \t\n]\\'" text)
 292       (delete-char -1)))))
 293
 294 (defun shr-find-fill-point ()
 295   (when (> (move-to-column shr-width) shr-width)
 296     (backward-char 1))
 297   (let ((bp (point))
 298         failed)
 299     (while (not (or (setq failed (= (current-column) shr-indentation))
 300                     (eq (preceding-char) ? )
 301                     (eq (following-char) ? )
 302                     (shr-char-breakable-p (preceding-char))
 303                     (shr-char-breakable-p (following-char))
 304                     (if (eq (preceding-char) ?')
 305                         (not (memq (char-after (- (point) 2))
 306                                    (list nil ?\n ? )))
 307                       (and (shr-char-kinsoku-bol-p (preceding-char))
 308                            (shr-char-breakable-p (following-char))
 309                            (not (shr-char-kinsoku-bol-p (following-char)))))
 310                     (shr-char-kinsoku-eol-p (following-char))))
 311       (backward-char 1))
 312     (if (and (not (or failed (eolp)))
 313              (eq (preceding-char) ?'))
 314         (while (not (or (setq failed (eolp))
 315                         (eq (following-char) ? )
 316                         (shr-char-breakable-p (following-char))
 317                         (shr-char-kinsoku-eol-p (following-char))))
 318           (forward-char 1)))
 319     (if failed
 320         ;; There's no breakable point, so we give it up.
 321         (let (found)
 322           (goto-char bp)
 323           (unless shr-kinsoku-shorten
 324             (while (and (setq found (re-search-forward
 325                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 326                                      (line-end-position) 'move))
 327                         (eq (preceding-char) ?')))
 328             (if (and found (not (match-beginning 1)))
 329                 (goto-char (match-beginning 0)))))
 330       (or
 331        (eolp)
 332        ;; Don't put kinsoku-bol characters at the beginning of a line,
 333        ;; or kinsoku-eol characters at the end of a line.
 334        (cond
 335         (shr-kinsoku-shorten
 336          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 337                      (shr-char-kinsoku-eol-p (preceding-char)))
 338            (backward-char 1))
 339          (when (setq failed (= (current-column) shr-indentation))
 340            ;; There's no breakable point that doesn't violate kinsoku,
 341            ;; so we look for the second best position.
 342            (while (and (progn
 343                          (forward-char 1)
 344                          (<= (current-column) shr-width))
 345                        (progn
 346                          (setq bp (point))
 347                          (shr-char-kinsoku-eol-p (following-char)))))
 348            (goto-char bp)))
 349         ((shr-char-kinsoku-eol-p (preceding-char))
 350          (if (shr-char-kinsoku-eol-p (following-char))
 351              ;; There are consecutive kinsoku-eol characters.
 352              (setq failed t)
 353            (let ((count 4))
 354              (while
 355                  (progn
 356                    (backward-char 1)
 357                    (and (> (setq count (1- count)) 0)
 358                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 359                         (or (shr-char-kinsoku-eol-p (preceding-char))
 360                             (shr-char-kinsoku-bol-p (following-char)))))))
 361            (if (setq failed (= (current-column) shr-indentation))
 362                ;; There's no breakable point that doesn't violate kinsoku,
 363                ;; so we go to the second best position.
 364                (if (looking-at "\\(\\c<+\\)\\c<")
 365                    (goto-char (match-end 1))
 366                  (forward-char 1)))))
 367         (t
 368          (if (shr-char-kinsoku-bol-p (preceding-char))
 369              ;; There are consecutive kinsoku-bol characters.
 370              (setq failed t)
 371            (let ((count 4))
 372              (while (and (>= (setq count (1- count)) 0)
 373                          (shr-char-kinsoku-bol-p (following-char))
 374                          (shr-char-breakable-p (following-char)))
 375                (forward-char 1))))))
 376        (when (eq (following-char) ? )
 377          (forward-char 1))))
 378     (not failed)))
 379
 380 (defun shr-ensure-newline ()
 381   (unless (zerop (current-column))
 382     (insert "\n")))
 383
 384 (defun shr-ensure-paragraph ()
 385   (unless (bobp)
 386     (if (<= (current-column) shr-indentation)
 387         (unless (save-excursion
 388                   (forward-line -1)
 389                   (looking-at " *$"))
 390           (insert "\n"))
 391       (if (save-excursion
 392             (beginning-of-line)
 393             (looking-at " *$"))
 394           (insert "\n")
 395         (insert "\n\n")))))
 396
 397 (defun shr-indent ()
 398   (when (> shr-indentation 0)
 399     (insert (make-string shr-indentation ? ))))
 400
 401 (defun shr-fontize-cont (cont &rest types)
 402   (let (shr-start)
 403     (shr-generic cont)
 404     (dolist (type types)
 405       (shr-add-font (or shr-start (point)) (point) type))))
 406
 407 ;; Add an overlay in the region, but avoid putting the font properties
 408 ;; on blank text at the start of the line, and the newline at the end,
 409 ;; to avoid ugliness.
 410 (defun shr-add-font (start end type)
 411   (save-excursion
 412     (goto-char start)
 413     (while (< (point) end)
 414       (when (bolp)
 415         (skip-chars-forward " "))
 416       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 417         (overlay-put overlay 'face type))
 418       (if (< (line-end-position) end)
 419           (forward-line 1)
 420         (goto-char end)))))
 421
 422 (defun shr-browse-url ()
 423   "Browse the URL under point."
 424   (interactive)
 425   (let ((url (get-text-property (point) 'shr-url)))
 426     (cond
 427      ((not url)
 428       (message "No link under point"))
 429      ((string-match "^mailto:" url)
 430       (browse-url-mailto url))
 431      (t
 432       (browse-url url)))))
 433
 434 (defun shr-save-contents (directory)
 435   "Save the contents from URL in a file."
 436   (interactive "DSave contents of URL to directory: ")
 437   (let ((url (get-text-property (point) 'shr-url)))
 438     (if (not url)
 439         (message "No link under point")
 440       (url-retrieve (shr-encode-url url)
 441                     'shr-store-contents (list url directory)))))
 442
 443 (defun shr-store-contents (status url directory)
 444   (unless (plist-get status :error)
 445     (when (or (search-forward "\n\n" nil t)
 446               (search-forward "\r\n\r\n" nil t))
 447       (write-region (point) (point-max)
 448                     (expand-file-name (file-name-nondirectory url)
 449                                       directory)))))
 450
 451 (defun shr-image-fetched (status buffer start end)
 452   (when (and (buffer-name buffer)
 453              (not (plist-get status :error)))
 454     (url-store-in-cache (current-buffer))
 455     (when (or (search-forward "\n\n" nil t)
 456               (search-forward "\r\n\r\n" nil t))
 457       (let ((data (buffer-substring (point) (point-max))))
 458         (with-current-buffer buffer
 459           (let ((alt (buffer-substring start end))
 460                 (inhibit-read-only t))
 461             (delete-region start end)
 462             (goto-char start)
 463             (shr-put-image data alt))))))
 464   (kill-buffer (current-buffer)))
 465
 466 (defun shr-put-image (data alt)
 467   (if (display-graphic-p)
 468       (let ((image (ignore-errors
 469                      (shr-rescale-image data))))
 470         (when image
 471           ;; When inserting big-ish pictures, put them at the
 472           ;; beginning of the line.
 473           (when (and (> (current-column) 0)
 474                      (> (car (image-size image t)) 400))
 475             (insert "\n"))
 476           (insert-image image (or alt "*"))))
 477     (insert alt)))
 478
 479 (defun shr-rescale-image (data)
 480   (if (or (not (fboundp 'imagemagick-types))
 481           (not (get-buffer-window (current-buffer))))
 482       (create-image data nil t)
 483     (let* ((image (create-image data nil t))
 484            (size (image-size image t))
 485            (width (car size))
 486            (height (cdr size))
 487            (edges (window-inside-pixel-edges
 488                    (get-buffer-window (current-buffer))))
 489            (window-width (truncate (* shr-max-image-proportion
 490                                       (- (nth 2 edges) (nth 0 edges)))))
 491            (window-height (truncate (* shr-max-image-proportion
 492                                        (- (nth 3 edges) (nth 1 edges)))))
 493            scaled-image)
 494       (when (> height window-height)
 495         (setq image (or (create-image data 'imagemagick t
 496                                       :height window-height)
 497                         image))
 498         (setq size (image-size image t)))
 499       (when (> (car size) window-width)
 500         (setq image (or
 501                      (create-image data 'imagemagick t
 502                                    :width window-width)
 503                      image)))
 504       image)))
 505
 506 ;; url-cache-extract autoloads url-cache.
 507 (declare-function url-cache-create-filename "url-cache" (url))
 508 (autoload 'mm-disable-multibyte "mm-util")
 509 (autoload 'browse-url-mailto "browse-url")
 510
 511 (defun shr-get-image-data (url)
 512   "Get image data for URL.
 513 Return a string with image data."
 514   (with-temp-buffer
 515     (mm-disable-multibyte)
 516     (when (ignore-errors
 517             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 518             t)
 519       (when (or (search-forward "\n\n" nil t)
 520                 (search-forward "\r\n\r\n" nil t))
 521         (buffer-substring (point) (point-max))))))
 522
 523 (defun shr-image-displayer (content-function)
 524   "Return a function to display an image.
 525 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 526 is an argument.  The function to be returned takes three arguments URL,
 527 START, and END.  Note that START and END should be merkers."
 528   `(lambda (url start end)
 529      (when url
 530        (if (string-match "\\`cid:" url)
 531            ,(when content-function
 532               `(let ((image (funcall ,content-function
 533                                      (substring url (match-end 0)))))
 534                  (when image
 535                    (goto-char start)
 536                    (shr-put-image image
 537                                   (buffer-substring-no-properties start end))
 538                    (delete-region (point) end))))
 539          (url-retrieve url 'shr-image-fetched
 540                        (list (current-buffer) start end)
 541                        t)))))
 542
 543 (defun shr-heading (cont &rest types)
 544   (shr-ensure-paragraph)
 545   (apply #'shr-fontize-cont cont types)
 546   (shr-ensure-paragraph))
 547
 548 (autoload 'widget-convert-button "wid-edit")
 549
 550 (defun shr-urlify (start url &optional title)
 551   (widget-convert-button
 552    'url-link start (point)
 553    :help-echo (if title (format "%s (%s)" url title) url)
 554    :keymap shr-map
 555    url)
 556   (put-text-property start (point) 'shr-url url))
 557
 558 (defun shr-encode-url (url)
 559   "Encode URL."
 560   (browse-url-url-encode-chars url "[)$ ]"))
 561
 562 (autoload 'shr-color-visible "shr-color")
 563 (autoload 'shr-color->hexadecimal "shr-color")
 564
 565 (defun shr-color-check (fg bg)
 566   "Check that FG is visible on BG.
 567 Returns (fg bg) with corrected values.
 568 Returns nil if the colors that would be used are the default
 569 ones, in case fg and bg are nil."
 570   (when (or fg bg)
 571     (let ((fixed (cond ((null fg) 'fg)
 572                        ((null bg) 'bg))))
 573       ;; Convert colors to hexadecimal, or set them to default.
 574       (let ((fg (or (shr-color->hexadecimal fg)
 575                     (frame-parameter nil 'foreground-color)))
 576             (bg (or (shr-color->hexadecimal bg)
 577                     (frame-parameter nil 'background-color))))
 578         (cond ((eq fixed 'bg)
 579                ;; Only return the new fg
 580                (list nil (cadr (shr-color-visible bg fg t))))
 581               ((eq fixed 'fg)
 582                ;; Invert args and results and return only the new bg
 583                (list (cadr (shr-color-visible fg bg t)) nil))
 584               (t
 585                (shr-color-visible bg fg)))))))
 586
 587 (defun shr-colorize-region (start end fg &optional bg)
 588   (when (or fg bg)
 589     (let ((new-colors (shr-color-check fg bg)))
 590       (when new-colors
 591         (when fg
 592           (shr-put-color start end :foreground (cadr new-colors)))
 593         (when bg
 594           (shr-put-color start end :background (car new-colors)))))))
 595
 596 ;; Put a color in the region, but avoid putting colors on on blank
 597 ;; text at the start of the line, and the newline at the end, to avoid
 598 ;; ugliness.  Also, don't overwrite any existing color information,
 599 ;; since this can be called recursively, and we want the "inner" color
 600 ;; to win.
 601 (defun shr-put-color (start end type color)
 602   (save-excursion
 603     (goto-char start)
 604     (while (< (point) end)
 605       (when (bolp)
 606         (skip-chars-forward " "))
 607       (when (> (line-end-position) (point))
 608         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 609       (if (< (line-end-position) end)
 610           (forward-line 1)
 611         (goto-char end)))))
 612
 613 (defun shr-put-color-1 (start end type color)
 614   (let* ((old-props (get-text-property start 'face))
 615          (do-put (not (memq type old-props)))
 616          change)
 617     (while (< start end)
 618       (setq change (next-single-property-change start 'face nil end))
 619       (when do-put
 620         (put-text-property start change 'face
 621                            (nconc (list type color) old-props)))
 622       (setq old-props (get-text-property change 'face))
 623       (setq do-put (not (memq type old-props)))
 624       (setq start change))
 625     (when (and do-put
 626                (> end start))
 627       (put-text-property start end 'face
 628                          (nconc (list type color old-props))))))
 629
 630 ;;; Tag-specific rendering rules.
 631
 632 (defun shr-tag-body (cont)
 633   (let* ((start (point))
 634          (fgcolor (cdr (assq :fgcolor cont)))
 635          (bgcolor (cdr (assq :bgcolor cont)))
 636          (shr-stylesheet (list (cons 'color fgcolor)
 637                                (cons 'background-color bgcolor))))
 638     (shr-generic cont)
 639     (shr-colorize-region start (point) fgcolor bgcolor)))
 640
 641 (defun shr-tag-style (cont)
 642   )
 643
 644 (defun shr-tag-script (cont)
 645   )
 646
 647 (defun shr-tag-p (cont)
 648   (shr-ensure-paragraph)
 649   (shr-indent)
 650   (shr-generic cont)
 651   (shr-ensure-paragraph))
 652
 653 (defun shr-tag-div (cont)
 654   (shr-ensure-newline)
 655   (shr-indent)
 656   (shr-generic cont)
 657   (shr-ensure-newline))
 658
 659 (defun shr-tag-b (cont)
 660   (shr-fontize-cont cont 'bold))
 661
 662 (defun shr-tag-i (cont)
 663   (shr-fontize-cont cont 'italic))
 664
 665 (defun shr-tag-em (cont)
 666   (shr-fontize-cont cont 'bold))
 667
 668 (defun shr-tag-strong (cont)
 669   (shr-fontize-cont cont 'bold))
 670
 671 (defun shr-tag-u (cont)
 672   (shr-fontize-cont cont 'underline))
 673
 674 (defun shr-tag-s (cont)
 675   (shr-fontize-cont cont 'strike-through))
 676
 677 (defun shr-parse-style (style)
 678   (when style
 679     (save-match-data
 680       (when (string-match "\n" style)
 681         (setq style (replace-match " " t t style))))
 682     (let ((plist nil))
 683       (dolist (elem (split-string style ";"))
 684         (when elem
 685           (setq elem (split-string elem ":"))
 686           (when (and (car elem)
 687                      (cadr elem))
 688             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 689                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 690               (when (string-match " *!important\\'" value)
 691                 (setq value (substring value 0 (match-beginning 0))))
 692               (push (cons (intern name obarray)
 693                           value)
 694                     plist)))))
 695       plist)))
 696
 697 (defun shr-tag-a (cont)
 698   (let ((url (cdr (assq :href cont)))
 699         (title (cdr (assq :title cont)))
 700         (start (point))
 701         shr-start)
 702     (shr-generic cont)
 703     (shr-urlify (or shr-start start) url title)))
 704
 705 (defun shr-tag-object (cont)
 706   (let ((start (point))
 707         url)
 708     (dolist (elem cont)
 709       (when (eq (car elem) 'embed)
 710         (setq url (or url (cdr (assq :src (cdr elem))))))
 711       (when (and (eq (car elem) 'param)
 712                  (equal (cdr (assq :name (cdr elem))) "movie"))
 713         (setq url (or url (cdr (assq :value (cdr elem)))))))
 714     (when url
 715       (shr-insert " [multimedia] ")
 716       (shr-urlify start url))
 717     (shr-generic cont)))
 718
 719 (defun shr-tag-video (cont)
 720   (let ((image (cdr (assq :poster cont)))
 721         (url (cdr (assq :src cont)))
 722         (start (point)))
 723     (shr-tag-img nil image)
 724     (shr-urlify start url)))
 725
 726 (defun shr-tag-img (cont &optional url)
 727   (when (or url
 728             (and cont
 729                  (cdr (assq :src cont))))
 730     (when (and (> (current-column) 0)
 731                (not (eq shr-state 'image)))
 732       (insert "\n"))
 733     (let ((alt (cdr (assq :alt cont)))
 734           (url (or url (cdr (assq :src cont)))))
 735       (let ((start (point-marker)))
 736         (when (zerop (length alt))
 737           (setq alt "*"))
 738         (cond
 739          ((or (member (cdr (assq :height cont)) '("0" "1"))
 740               (member (cdr (assq :width cont)) '("0" "1")))
 741           ;; Ignore zero-sized or single-pixel images.
 742           )
 743          ((and (not shr-inhibit-images)
 744                (string-match "\\`cid:" url))
 745           (let ((url (substring url (match-end 0)))
 746                 image)
 747             (if (or (not shr-content-function)
 748                     (not (setq image (funcall shr-content-function url))))
 749                 (insert alt)
 750               (shr-put-image image alt))))
 751          ((or shr-inhibit-images
 752               (and shr-blocked-images
 753                    (string-match shr-blocked-images url)))
 754           (setq shr-start (point))
 755           (let ((shr-state 'space))
 756             (if (> (string-width alt) 8)
 757                 (shr-insert (truncate-string-to-width alt 8))
 758               (shr-insert alt))))
 759          ((url-is-cached (shr-encode-url url))
 760           (shr-put-image (shr-get-image-data url) alt))
 761          (t
 762           (insert alt)
 763           (ignore-errors
 764             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 765                           (list (current-buffer) start (point-marker))
 766                           t))))
 767         (put-text-property start (point) 'keymap shr-map)
 768         (put-text-property start (point) 'shr-alt alt)
 769         (put-text-property start (point) 'image-url url)
 770         (put-text-property start (point) 'image-displayer
 771                            (shr-image-displayer shr-content-function))
 772         (put-text-property start (point) 'help-echo alt)
 773         (setq shr-state 'image)))))
 774
 775 (defun shr-tag-pre (cont)
 776   (let ((shr-folding-mode 'none))
 777     (shr-ensure-newline)
 778     (shr-indent)
 779     (shr-generic cont)
 780     (shr-ensure-newline)))
 781
 782 (defun shr-tag-blockquote (cont)
 783   (shr-ensure-paragraph)
 784   (shr-indent)
 785   (let ((shr-indentation (+ shr-indentation 4)))
 786     (shr-generic cont))
 787   (shr-ensure-paragraph))
 788
 789 (defun shr-tag-ul (cont)
 790   (shr-ensure-paragraph)
 791   (let ((shr-list-mode 'ul))
 792     (shr-generic cont))
 793   (shr-ensure-paragraph))
 794
 795 (defun shr-tag-ol (cont)
 796   (shr-ensure-paragraph)
 797   (let ((shr-list-mode 1))
 798     (shr-generic cont))
 799   (shr-ensure-paragraph))
 800
 801 (defun shr-tag-li (cont)
 802   (shr-ensure-paragraph)
 803   (shr-indent)
 804   (let* ((bullet
 805           (if (numberp shr-list-mode)
 806               (prog1
 807                   (format "%d " shr-list-mode)
 808                 (setq shr-list-mode (1+ shr-list-mode)))
 809             "* "))
 810          (shr-indentation (+ shr-indentation (length bullet))))
 811     (insert bullet)
 812     (shr-generic cont)))
 813
 814 (defun shr-tag-br (cont)
 815   (unless (bobp)
 816     (insert "\n")
 817     (shr-indent))
 818   (shr-generic cont))
 819
 820 (defun shr-tag-h1 (cont)
 821   (shr-heading cont 'bold 'underline))
 822
 823 (defun shr-tag-h2 (cont)
 824   (shr-heading cont 'bold))
 825
 826 (defun shr-tag-h3 (cont)
 827   (shr-heading cont 'italic))
 828
 829 (defun shr-tag-h4 (cont)
 830   (shr-heading cont))
 831
 832 (defun shr-tag-h5 (cont)
 833   (shr-heading cont))
 834
 835 (defun shr-tag-h6 (cont)
 836   (shr-heading cont))
 837
 838 (defun shr-tag-hr (cont)
 839   (shr-ensure-newline)
 840   (insert (make-string shr-width shr-hr-line) "\n"))
 841
 842 (defun shr-tag-title (cont)
 843   (shr-heading cont 'bold 'underline))
 844
 845 (defun shr-tag-font (cont)
 846   (let* ((start (point))
 847          (color (cdr (assq :color cont)))
 848          (shr-stylesheet (nconc (list (cons 'color color))
 849                                 shr-stylesheet)))
 850     (shr-generic cont)
 851     (when color
 852       (shr-colorize-region start (point) color
 853                            (cdr (assq 'background-color shr-stylesheet))))))
 854
 855 ;;; Table rendering algorithm.
 856
 857 ;; Table rendering is the only complicated thing here.  We do this by
 858 ;; first counting how many TDs there are in each TR, and registering
 859 ;; how wide they think they should be ("width=45%", etc).  Then we
 860 ;; render each TD separately (this is done in temporary buffers, so
 861 ;; that we can use all the rendering machinery as if we were in the
 862 ;; main buffer).  Now we know how much space each TD really takes, so
 863 ;; we then render everything again with the new widths, and finally
 864 ;; insert all these boxes into the main buffer.
 865 (defun shr-tag-table-1 (cont)
 866   (setq cont (or (cdr (assq 'tbody cont))
 867                  cont))
 868   (let* ((shr-inhibit-images t)
 869          (shr-table-depth (1+ shr-table-depth))
 870          (shr-kinsoku-shorten t)
 871          ;; Find all suggested widths.
 872          (columns (shr-column-specs cont))
 873          ;; Compute how many characters wide each TD should be.
 874          (suggested-widths (shr-pro-rate-columns columns))
 875          ;; Do a "test rendering" to see how big each TD is (this can
 876          ;; be smaller (if there's little text) or bigger (if there's
 877          ;; unbreakable text).
 878          (sketch (shr-make-table cont suggested-widths))
 879          (sketch-widths (shr-table-widths sketch suggested-widths)))
 880     ;; This probably won't work very well.
 881     (when (> (+ (loop for width across sketch-widths
 882                       summing (1+ width))
 883                 shr-indentation 1)
 884              (frame-width))
 885       (setq truncate-lines t))
 886     ;; Then render the table again with these new "hard" widths.
 887     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 888   ;; Finally, insert all the images after the table.  The Emacs buffer
 889   ;; model isn't strong enough to allow us to put the images actually
 890   ;; into the tables.
 891   (when (zerop shr-table-depth)
 892     (dolist (elem (shr-find-elements cont 'img))
 893       (shr-tag-img (cdr elem)))))
 894
 895 (defun shr-tag-table (cont)
 896   (shr-ensure-paragraph)
 897   (let* ((caption (cdr (assq 'caption cont)))
 898          (header (cdr (assq 'thead cont)))
 899          (body (or (cdr (assq 'tbody cont)) cont))
 900          (footer (cdr (assq 'tfoot cont)))
 901          (bgcolor (cdr (assq :bgcolor cont)))
 902          (start (point))
 903          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
 904                                 shr-stylesheet))
 905          (nheader (if header (shr-max-columns header)))
 906          (nbody (if body (shr-max-columns body)))
 907          (nfooter (if footer (shr-max-columns footer))))
 908     (shr-tag-table-1
 909      (nconc
 910       (if caption `((tr (td ,@caption))))
 911       (if header
 912           (if footer
 913               ;; hader + body + footer
 914               (if (= nheader nbody)
 915                   (if (= nbody nfooter)
 916                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 917                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 918                            (if (= nfooter 1)
 919                                footer
 920                              `((tr (td (table (tbody ,@footer))))))))
 921                 (nconc `((tr (td (table (tbody ,@header)))))
 922                        (if (= nbody nfooter)
 923                            `((tr (td (table (tbody ,@body ,@footer)))))
 924                          (nconc `((tr (td (table (tbody ,@body)))))
 925                                 (if (= nfooter 1)
 926                                     footer
 927                                   `((tr (td (table (tbody ,@footer))))))))))
 928             ;; header + body
 929             (if (= nheader nbody)
 930                 `((tr (td (table (tbody ,@header ,@body)))))
 931               (if (= nheader 1)
 932                   `(,@header (tr (td (table (tbody ,@body)))))
 933                 `((tr (td (table (tbody ,@header))))
 934                   (tr (td (table (tbody ,@body))))))))
 935         (if footer
 936             ;; body + footer
 937             (if (= nbody nfooter)
 938                 `((tr (td (table (tbody ,@body ,@footer)))))
 939               (nconc `((tr (td (table (tbody ,@body)))))
 940                      (if (= nfooter 1)
 941                          footer
 942                        `((tr (td (table (tbody ,@footer))))))))
 943           (if caption
 944               `((tr (td (table (tbody ,@body)))))
 945             body)))))
 946     (when bgcolor
 947       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
 948                            bgcolor))))
 949
 950 (defun shr-find-elements (cont type)
 951   (let (result)
 952     (dolist (elem cont)
 953       (cond ((eq (car elem) type)
 954              (push elem result))
 955             ((consp (cdr elem))
 956              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 957     (nreverse result)))
 958
 959 (defun shr-insert-table (table widths)
 960   (shr-insert-table-ruler widths)
 961   (dolist (row table)
 962     (let ((start (point))
 963           (height (let ((max 0))
 964                     (dolist (column row)
 965                       (setq max (max max (cadr column))))
 966                     max)))
 967       (dotimes (i height)
 968         (shr-indent)
 969         (insert shr-table-vertical-line "\n"))
 970       (dolist (column row)
 971         (goto-char start)
 972         (let ((lines (nth 2 column))
 973               (overlay-lines (nth 3 column))
 974               overlay overlay-line)
 975           (dolist (line lines)
 976             (setq overlay-line (pop overlay-lines))
 977             (end-of-line)
 978             (insert line shr-table-vertical-line)
 979             (dolist (overlay overlay-line)
 980               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 981                                      (- (point) (nth 1 overlay) 1)))
 982                     (properties (nth 2 overlay)))
 983                 (while properties
 984                   (overlay-put o (pop properties) (pop properties)))))
 985             (forward-line 1))
 986           ;; Add blank lines at padding at the bottom of the TD,
 987           ;; possibly.
 988           (dotimes (i (- height (length lines)))
 989             (end-of-line)
 990             (insert (make-string (string-width (car lines)) ? )
 991                     shr-table-vertical-line)
 992             (forward-line 1)))))
 993     (shr-insert-table-ruler widths)))
 994
 995 (defun shr-insert-table-ruler (widths)
 996   (when (and (bolp)
 997              (> shr-indentation 0))
 998     (shr-indent))
 999   (insert shr-table-corner)
1000   (dotimes (i (length widths))
1001     (insert (make-string (aref widths i) shr-table-horizontal-line)
1002             shr-table-corner))
1003   (insert "\n"))
1004
1005 (defun shr-table-widths (table suggested-widths)
1006   (let* ((length (length suggested-widths))
1007          (widths (make-vector length 0))
1008          (natural-widths (make-vector length 0)))
1009     (dolist (row table)
1010       (let ((i 0))
1011         (dolist (column row)
1012           (aset widths i (max (aref widths i)
1013                               (car column)))
1014           (aset natural-widths i (max (aref natural-widths i)
1015                                       (cadr column)))
1016           (setq i (1+ i)))))
1017     (let ((extra (- (apply '+ (append suggested-widths nil))
1018                     (apply '+ (append widths nil))))
1019           (expanded-columns 0))
1020       (when (> extra 0)
1021         (dotimes (i length)
1022           ;; If the natural width is wider than the rendered width, we
1023           ;; want to allow the column to expand.
1024           (when (> (aref natural-widths i) (aref widths i))
1025             (setq expanded-columns (1+ expanded-columns))))
1026         (dotimes (i length)
1027           (when (> (aref natural-widths i) (aref widths i))
1028             (aset widths i (min
1029                             (1+ (aref natural-widths i))
1030                             (+ (/ extra expanded-columns)
1031                                (aref widths i))))))))
1032     widths))
1033
1034 (defun shr-make-table (cont widths &optional fill)
1035   (let ((trs nil))
1036     (dolist (row cont)
1037       (when (eq (car row) 'tr)
1038         (let ((tds nil)
1039               (columns (cdr row))
1040               (i 0)
1041               column)
1042           (while (< i (length widths))
1043             (setq column (pop columns))
1044             (when (or (memq (car column) '(td th))
1045                       (null column))
1046               (push (shr-render-td (cdr column) (aref widths i) fill)
1047                     tds)
1048               (setq i (1+ i))))
1049           (push (nreverse tds) trs))))
1050     (nreverse trs)))
1051
1052 (defun shr-render-td (cont width fill)
1053   (with-temp-buffer
1054     (let ((bgcolor (cdr (assq :bgcolor cont)))
1055           (fgcolor (cdr (assq :fgcolor cont)))
1056           (style (cdr (assq :style cont)))
1057           (shr-stylesheet shr-stylesheet)
1058           overlays)
1059       (when style
1060         (setq style (and (string-match "color" style)
1061                          (shr-parse-style style))))
1062       (when bgcolor
1063         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1064       (when fgcolor
1065         (setq style (nconc (list (cons 'color fgcolor)) style)))
1066       (when style
1067         (setq shr-stylesheet (append style shr-stylesheet)))
1068       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1069         (if cache
1070             (progn
1071               (insert (car cache))
1072               (let ((end (length (car cache))))
1073                 (dolist (overlay (cadr cache))
1074                   (let ((new-overlay
1075                          (make-overlay (1+ (- end (nth 0 overlay)))
1076                                        (1+ (- end (nth 1 overlay)))))
1077                         (properties (nth 2 overlay)))
1078                     (while properties
1079                       (overlay-put new-overlay
1080                                    (pop properties) (pop properties)))))))
1081           (let ((shr-width width)
1082                 (shr-indentation 0))
1083             (shr-descend (cons 'td cont)))
1084           (delete-region
1085            (point)
1086            (+ (point)
1087               (skip-chars-backward " \t\n")))
1088           (push (list (cons width cont) (buffer-string)
1089                       (shr-overlays-in-region (point-min) (point-max)))
1090                 shr-content-cache)))
1091       (goto-char (point-min))
1092       (let ((max 0))
1093         (while (not (eobp))
1094           (end-of-line)
1095           (setq max (max max (current-column)))
1096           (forward-line 1))
1097         (when fill
1098           (goto-char (point-min))
1099           ;; If the buffer is totally empty, then put a single blank
1100           ;; line here.
1101           (if (zerop (buffer-size))
1102               (insert (make-string width ? ))
1103             ;; Otherwise, fill the buffer.
1104             (while (not (eobp))
1105               (end-of-line)
1106               (when (> (- width (current-column)) 0)
1107                 (insert (make-string (- width (current-column)) ? )))
1108               (forward-line 1))))
1109         (when style
1110           (shr-colorize-region
1111            (point-min) (point-max)
1112            (cdr (assq 'color shr-stylesheet))
1113            (cdr (assq 'background-color shr-stylesheet))))
1114         (if fill
1115             (list max
1116                   (count-lines (point-min) (point-max))
1117                   (split-string (buffer-string) "\n")
1118                   (shr-collect-overlays))
1119           (list max
1120                 (shr-natural-width)))))))
1121
1122 (defun shr-natural-width ()
1123   (goto-char (point-min))
1124   (let ((current 0)
1125         (max 0))
1126     (while (not (eobp))
1127       (end-of-line)
1128       (setq current (+ current (current-column)))
1129       (unless (get-text-property (point) 'shr-break)
1130         (setq max (max max current)
1131               current 0))
1132       (forward-line 1))
1133     max))
1134
1135 (defun shr-collect-overlays ()
1136   (save-excursion
1137     (goto-char (point-min))
1138     (let ((overlays nil))
1139       (while (not (eobp))
1140         (push (shr-overlays-in-region (point) (line-end-position))
1141               overlays)
1142         (forward-line 1))
1143       (nreverse overlays))))
1144
1145 (defun shr-overlays-in-region (start end)
1146   (let (result)
1147     (dolist (overlay (overlays-in start end))
1148       (push (list (if (> start (overlay-start overlay))
1149                       (- end start)
1150                     (- end (overlay-start overlay)))
1151                   (if (< end (overlay-end overlay))
1152                       0
1153                     (- end (overlay-end overlay)))
1154                   (overlay-properties overlay))
1155             result))
1156     (nreverse result)))
1157
1158 (defun shr-pro-rate-columns (columns)
1159   (let ((total-percentage 0)
1160         (widths (make-vector (length columns) 0)))
1161     (dotimes (i (length columns))
1162       (setq total-percentage (+ total-percentage (aref columns i))))
1163     (setq total-percentage (/ 1.0 total-percentage))
1164     (dotimes (i (length columns))
1165       (aset widths i (max (truncate (* (aref columns i)
1166                                        total-percentage
1167                                        (- shr-width (1+ (length columns)))))
1168                           10)))
1169     widths))
1170
1171 ;; Return a summary of the number and shape of the TDs in the table.
1172 (defun shr-column-specs (cont)
1173   (let ((columns (make-vector (shr-max-columns cont) 1)))
1174     (dolist (row cont)
1175       (when (eq (car row) 'tr)
1176         (let ((i 0))
1177           (dolist (column (cdr row))
1178             (when (memq (car column) '(td th))
1179               (let ((width (cdr (assq :width (cdr column)))))
1180                 (when (and width
1181                            (string-match "\\([0-9]+\\)%" width))
1182                   (aset columns i
1183                         (/ (string-to-number (match-string 1 width))
1184                            100.0))))
1185               (setq i (1+ i)))))))
1186     columns))
1187
1188 (defun shr-count (cont elem)
1189   (let ((i 0))
1190     (dolist (sub cont)
1191       (when (eq (car sub) elem)
1192         (setq i (1+ i))))
1193     i))
1194
1195 (defun shr-max-columns (cont)
1196   (let ((max 0))
1197     (dolist (row cont)
1198       (when (eq (car row) 'tr)
1199         (setq max (max max (+ (shr-count (cdr row) 'td)
1200                               (shr-count (cdr row) 'th))))))
1201     max))
1202
1203 (provide 'shr)
1204
1205 ;;; shr.el ends here