cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :version "24.1"
  39   :group 'mail)
  40
  41 (defcustom shr-max-image-proportion 0.9
  42   "How big pictures displayed are in relation to the window they're in.
  43 A value of 0.7 means that they are allowed to take up 70% of the
  44 width and height of the window.  If they are larger than this,
  45 and Emacs supports it, then the images will be rescaled down to
  46 fit these criteria."
  47   :version "24.1"
  48   :group 'shr
  49   :type 'float)
  50
  51 (defcustom shr-blocked-images nil
  52   "Images that have URLs matching this regexp will be blocked."
  53   :version "24.1"
  54   :group 'shr
  55   :type 'regexp)
  56
  57 (defcustom shr-table-horizontal-line ?\s
  58   "Character used to draw horizontal table lines."
  59   :group 'shr
  60   :type 'character)
  61
  62 (defcustom shr-table-vertical-line ?\s
  63   "Character used to draw vertical table lines."
  64   :group 'shr
  65   :type 'character)
  66
  67 (defcustom shr-table-corner ?\s
  68   "Character used to draw table corners."
  69   :group 'shr
  70   :type 'character)
  71
  72 (defcustom shr-hr-line ?-
  73   "Character used to draw hr lines."
  74   :group 'shr
  75   :type 'character)
  76
  77 (defcustom shr-width fill-column
  78   "Frame width to use for rendering.
  79 May either be an integer specifying a fixed width in characters,
  80 or nil, meaning that the full width of the window should be
  81 used."
  82   :type '(choice (integer :tag "Fixed width in characters")
  83                  (const   :tag "Use the width of the window" nil))
  84   :group 'shr)
  85
  86 (defvar shr-content-function nil
  87   "If bound, this should be a function that will return the content.
  88 This is used for cid: URLs, and the function is called with the
  89 cid: URL as the argument.")
  90
  91 (defvar shr-put-image-function 'shr-put-image
  92   "Function called to put image and alt string.")
  93
  94 (defface shr-strike-through '((t (:strike-through t)))
  95   "Font for <s> elements."
  96   :group 'shr)
  97
  98 (defface shr-link
  99   '((t (:inherit link)))
 100   "Font for link elements."
 101   :group 'shr)
 102
 103 ;;; Internal variables.
 104
 105 (defvar shr-folding-mode nil)
 106 (defvar shr-state nil)
 107 (defvar shr-start nil)
 108 (defvar shr-indentation 0)
 109 (defvar shr-inhibit-images nil)
 110 (defvar shr-list-mode nil)
 111 (defvar shr-content-cache nil)
 112 (defvar shr-kinsoku-shorten nil)
 113 (defvar shr-table-depth 0)
 114 (defvar shr-stylesheet nil)
 115 (defvar shr-base nil)
 116 (defvar shr-ignore-cache nil)
 117
 118 (defvar shr-map
 119   (let ((map (make-sparse-keymap)))
 120     (define-key map "a" 'shr-show-alt-text)
 121     (define-key map "i" 'shr-browse-image)
 122     (define-key map "z" 'shr-zoom-image)
 123     (define-key map "I" 'shr-insert-image)
 124     (define-key map "u" 'shr-copy-url)
 125     (define-key map "v" 'shr-browse-url)
 126     (define-key map "o" 'shr-save-contents)
 127     (define-key map "\r" 'shr-browse-url)
 128     map))
 129
 130 ;; Public functions and commands.
 131
 132 (defun shr-render-buffer (buffer)
 133   "Display the HTML rendering of the current buffer."
 134   (interactive (list (current-buffer)))
 135   (pop-to-buffer "*html*")
 136   (erase-buffer)
 137   (shr-insert-document
 138    (with-current-buffer buffer
 139      (libxml-parse-html-region (point-min) (point-max))))
 140   (goto-char (point-min)))
 141
 142 (defun shr-visit-file (file)
 143   "Parse FILE as an HTML document, and render it in a new buffer."
 144   (interactive "fHTML file name: ")
 145   (with-temp-buffer
 146     (insert-file-contents file)
 147     (shr-render-buffer (current-buffer))))
 148
 149 ;;;###autoload
 150 (defun shr-insert-document (dom)
 151   "Render the parsed document DOM into the current buffer.
 152 DOM should be a parse tree as generated by
 153 `libxml-parse-html-region' or similar."
 154   (setq shr-content-cache nil)
 155   (let ((start (point))
 156         (shr-state nil)
 157         (shr-start nil)
 158         (shr-base nil)
 159         (shr-width (or shr-width (window-width))))
 160     (shr-descend (shr-transform-dom dom))
 161     (shr-remove-trailing-whitespace start (point))))
 162
 163 (defun shr-remove-trailing-whitespace (start end)
 164   (let ((width (window-width)))
 165     (save-restriction
 166       (narrow-to-region start end)
 167       (goto-char start)
 168       (while (not (eobp))
 169         (end-of-line)
 170         (when (> (shr-previous-newline-padding-width (current-column)) width)
 171           (dolist (overlay (overlays-at (point)))
 172             (when (overlay-get overlay 'before-string)
 173               (overlay-put overlay 'before-string nil))))
 174         (forward-line 1)))))
 175
 176 (defun shr-copy-url ()
 177   "Copy the URL under point to the kill ring.
 178 If called twice, then try to fetch the URL and see whether it
 179 redirects somewhere else."
 180   (interactive)
 181   (let ((url (get-text-property (point) 'shr-url)))
 182     (cond
 183      ((not url)
 184       (message "No URL under point"))
 185      ;; Resolve redirected URLs.
 186      ((equal url (car kill-ring))
 187       (url-retrieve
 188        url
 189        (lambda (a)
 190          (when (and (consp a)
 191                     (eq (car a) :redirect))
 192            (with-temp-buffer
 193              (insert (cadr a))
 194              (goto-char (point-min))
 195              ;; Remove common tracking junk from the URL.
 196              (when (re-search-forward ".utm_.*" nil t)
 197                (replace-match "" t t))
 198              (message "Copied %s" (buffer-string))
 199              (copy-region-as-kill (point-min) (point-max)))))
 200        nil t))
 201      ;; Copy the URL to the kill ring.
 202      (t
 203       (with-temp-buffer
 204         (insert url)
 205         (copy-region-as-kill (point-min) (point-max))
 206         (message "Copied %s" url))))))
 207
 208 (defun shr-show-alt-text ()
 209   "Show the ALT text of the image under point."
 210   (interactive)
 211   (let ((text (get-text-property (point) 'shr-alt)))
 212     (if (not text)
 213         (message "No image under point")
 214       (message "%s" text))))
 215
 216 (defun shr-browse-image (&optional copy-url)
 217   "Browse the image under point.
 218 If COPY-URL (the prefix if called interactively) is non-nil, copy
 219 the URL of the image to the kill buffer instead."
 220   (interactive "P")
 221   (let ((url (get-text-property (point) 'image-url)))
 222     (cond
 223      ((not url)
 224       (message "No image under point"))
 225      (copy-url
 226       (with-temp-buffer
 227         (insert url)
 228         (copy-region-as-kill (point-min) (point-max))
 229         (message "Copied %s" url)))
 230      (t
 231       (message "Browsing %s..." url)
 232       (browse-url url)))))
 233
 234 (defun shr-insert-image ()
 235   "Insert the image under point into the buffer."
 236   (interactive)
 237   (let ((url (get-text-property (point) 'image-url)))
 238     (if (not url)
 239         (message "No image under point")
 240       (message "Inserting %s..." url)
 241       (url-retrieve url 'shr-image-fetched
 242                     (list (current-buffer) (1- (point)) (point-marker))
 243                     t t))))
 244
 245 (defun shr-zoom-image ()
 246   "Toggle the image size.
 247 The size will be rotated between the default size, the original
 248 size, and full-buffer size."
 249   (interactive)
 250   (let ((url (get-text-property (point) 'image-url))
 251         (size (get-text-property (point) 'image-size))
 252         (buffer-read-only nil))
 253     (if (not url)
 254         (message "No image under point")
 255       ;; Delete the old picture.
 256       (while (get-text-property (point) 'image-url)
 257         (forward-char -1))
 258       (forward-char 1)
 259       (let ((start (point)))
 260         (while (get-text-property (point) 'image-url)
 261           (forward-char 1))
 262         (forward-char -1)
 263         (put-text-property start (point) 'display nil)
 264         (when (> (- (point) start) 2)
 265           (delete-region start (1- (point)))))
 266       (message "Inserting %s..." url)
 267       (url-retrieve url 'shr-image-fetched
 268                     (list (current-buffer) (1- (point)) (point-marker)
 269                           (list (cons 'size
 270                                       (cond ((or (eq size 'default)
 271                                                  (null size))
 272                                              'original)
 273                                             ((eq size 'original)
 274                                              'full)
 275                                             ((eq size 'full)
 276                                              'default)))))
 277                     t))))
 278
 279 ;;; Utility functions.
 280
 281 (defun shr-transform-dom (dom)
 282   (let ((result (list (pop dom))))
 283     (dolist (arg (pop dom))
 284       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 285                   (cdr arg))
 286             result))
 287     (dolist (sub dom)
 288       (if (stringp sub)
 289           (push (cons 'text sub) result)
 290         (push (shr-transform-dom sub) result)))
 291     (nreverse result)))
 292
 293 (defun shr-descend (dom)
 294   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 295         (style (cdr (assq :style (cdr dom))))
 296         (shr-stylesheet shr-stylesheet)
 297         (start (point)))
 298     (when style
 299       (if (string-match "color" style)
 300           (setq shr-stylesheet (nconc (shr-parse-style style)
 301                                       shr-stylesheet))
 302         (setq style nil)))
 303     (if (fboundp function)
 304         (funcall function (cdr dom))
 305       (shr-generic (cdr dom)))
 306     ;; If style is set, then this node has set the color.
 307     (when style
 308       (shr-colorize-region start (point)
 309                            (cdr (assq 'color shr-stylesheet))
 310                            (cdr (assq 'background-color shr-stylesheet))))))
 311
 312 (defun shr-generic (cont)
 313   (dolist (sub cont)
 314     (cond
 315      ((eq (car sub) 'text)
 316       (shr-insert (cdr sub)))
 317      ((listp (cdr sub))
 318       (shr-descend sub)))))
 319
 320 (defmacro shr-char-breakable-p (char)
 321   "Return non-nil if a line can be broken before and after CHAR."
 322   `(aref fill-find-break-point-function-table ,char))
 323 (defmacro shr-char-nospace-p (char)
 324   "Return non-nil if no space is required before and after CHAR."
 325   `(aref fill-nospace-between-words-table ,char))
 326
 327 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 328 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 329 ;; parentheses, and so on, that should not be placed in the beginning
 330 ;; of a line or the end of a line.
 331 (defmacro shr-char-kinsoku-bol-p (char)
 332   "Return non-nil if a line ought not to begin with CHAR."
 333   `(aref (char-category-set ,char) ?>))
 334 (defmacro shr-char-kinsoku-eol-p (char)
 335   "Return non-nil if a line ought not to end with CHAR."
 336   `(aref (char-category-set ,char) ?<))
 337 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 338   (load "kinsoku" nil t))
 339
 340 (defun shr-insert (text)
 341   (when (and (eq shr-state 'image)
 342              (not (bolp))
 343              (not (string-match "\\`[ \t\n]+\\'" text)))
 344     (insert "\n")
 345     (setq shr-state nil))
 346   (cond
 347    ((eq shr-folding-mode 'none)
 348     (insert text))
 349    (t
 350     (when (and (string-match "\\`[ \t\n ]" text)
 351                (not (bolp))
 352                (not (eq (char-after (1- (point))) ? )))
 353       (insert " "))
 354     (dolist (elem (split-string text "[ \f\t\n\r\v ]+" t))
 355       (when (and (bolp)
 356                  (> shr-indentation 0))
 357         (shr-indent))
 358       ;; No space is needed behind a wide character categorized as
 359       ;; kinsoku-bol, between characters both categorized as nospace,
 360       ;; or at the beginning of a line.
 361       (let (prev)
 362         (when (and (> (current-column) shr-indentation)
 363                    (eq (preceding-char) ? )
 364                    (or (= (line-beginning-position) (1- (point)))
 365                        (and (shr-char-breakable-p
 366                              (setq prev (char-after (- (point) 2))))
 367                             (shr-char-kinsoku-bol-p prev))
 368                        (and (shr-char-nospace-p prev)
 369                             (shr-char-nospace-p (aref elem 0)))))
 370           (delete-char -1)))
 371       ;; The shr-start is a special variable that is used to pass
 372       ;; upwards the first point in the buffer where the text really
 373       ;; starts.
 374       (unless shr-start
 375         (setq shr-start (point)))
 376       (insert elem)
 377       (setq shr-state nil)
 378       (let (found)
 379         (while (and (> (current-column) shr-width)
 380                     (progn
 381                       (setq found (shr-find-fill-point))
 382                       (not (eolp))))
 383           (when (eq (preceding-char) ? )
 384             (delete-char -1))
 385           (insert "\n")
 386           (unless found
 387             ;; No space is needed at the beginning of a line.
 388             (when (eq (following-char) ? )
 389               (delete-char 1)))
 390           (when (> shr-indentation 0)
 391             (shr-indent))
 392           (end-of-line))
 393         (insert " ")))
 394     (unless (string-match "[ \t\r\n ]\\'" text)
 395       (delete-char -1)))))
 396
 397 (defun shr-find-fill-point ()
 398   (when (> (move-to-column shr-width) shr-width)
 399     (backward-char 1))
 400   (let ((bp (point))
 401         failed)
 402     (while (not (or (setq failed (= (current-column) shr-indentation))
 403                     (eq (preceding-char) ? )
 404                     (eq (following-char) ? )
 405                     (shr-char-breakable-p (preceding-char))
 406                     (shr-char-breakable-p (following-char))
 407                     (if (eq (preceding-char) ?')
 408                         (not (memq (char-after (- (point) 2))
 409                                    (list nil ?\n ? )))
 410                       (and (shr-char-kinsoku-bol-p (preceding-char))
 411                            (shr-char-breakable-p (following-char))
 412                            (not (shr-char-kinsoku-bol-p (following-char)))))
 413                     (shr-char-kinsoku-eol-p (following-char))))
 414       (backward-char 1))
 415     (if (and (not (or failed (eolp)))
 416              (eq (preceding-char) ?'))
 417         (while (not (or (setq failed (eolp))
 418                         (eq (following-char) ? )
 419                         (shr-char-breakable-p (following-char))
 420                         (shr-char-kinsoku-eol-p (following-char))))
 421           (forward-char 1)))
 422     (if failed
 423         ;; There's no breakable point, so we give it up.
 424         (let (found)
 425           (goto-char bp)
 426           (unless shr-kinsoku-shorten
 427             (while (and (setq found (re-search-forward
 428                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 429                                      (line-end-position) 'move))
 430                         (eq (preceding-char) ?')))
 431             (if (and found (not (match-beginning 1)))
 432                 (goto-char (match-beginning 0)))))
 433       (or
 434        (eolp)
 435        ;; Don't put kinsoku-bol characters at the beginning of a line,
 436        ;; or kinsoku-eol characters at the end of a line.
 437        (cond
 438         (shr-kinsoku-shorten
 439          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 440                      (shr-char-kinsoku-eol-p (preceding-char)))
 441            (backward-char 1))
 442          (when (setq failed (= (current-column) shr-indentation))
 443            ;; There's no breakable point that doesn't violate kinsoku,
 444            ;; so we look for the second best position.
 445            (while (and (progn
 446                          (forward-char 1)
 447                          (<= (current-column) shr-width))
 448                        (progn
 449                          (setq bp (point))
 450                          (shr-char-kinsoku-eol-p (following-char)))))
 451            (goto-char bp)))
 452         ((shr-char-kinsoku-eol-p (preceding-char))
 453          ;; Find backward the point where kinsoku-eol characters begin.
 454          (let ((count 4))
 455            (while
 456                (progn
 457                  (backward-char 1)
 458                  (and (> (setq count (1- count)) 0)
 459                       (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 460                       (or (shr-char-kinsoku-eol-p (preceding-char))
 461                           (shr-char-kinsoku-bol-p (following-char)))))))
 462          (if (setq failed (= (current-column) shr-indentation))
 463              ;; There's no breakable point that doesn't violate kinsoku,
 464              ;; so we go to the second best position.
 465              (if (looking-at "\\(\\c<+\\)\\c<")
 466                  (goto-char (match-end 1))
 467                (forward-char 1))))
 468         ((shr-char-kinsoku-bol-p (following-char))
 469          ;; Find forward the point where kinsoku-bol characters end.
 470          (let ((count 4))
 471            (while (progn
 472                     (forward-char 1)
 473                     (and (>= (setq count (1- count)) 0)
 474                          (shr-char-kinsoku-bol-p (following-char))
 475                          (shr-char-breakable-p (following-char))))))))
 476        (when (eq (following-char) ? )
 477          (forward-char 1))))
 478     (not failed)))
 479
 480 (defun shr-expand-url (url)
 481   (cond
 482    ;; Absolute URL.
 483    ((or (not url)
 484         (string-match "\\`[a-z]*:" url)
 485         (not shr-base))
 486     url)
 487    ((and (string-match "\\`//" url)
 488          (string-match "\\`[a-z]*:" shr-base))
 489     (concat (match-string 0 shr-base) url))
 490    ((and (not (string-match "/\\'" shr-base))
 491          (not (string-match "\\`/" url)))
 492     (concat shr-base "/" url))
 493    (t
 494     (concat shr-base url))))
 495
 496 (defun shr-ensure-newline ()
 497   (unless (zerop (current-column))
 498     (insert "\n")))
 499
 500 (defun shr-ensure-paragraph ()
 501   (unless (bobp)
 502     (if (<= (current-column) shr-indentation)
 503         (unless (save-excursion
 504                   (forward-line -1)
 505                   (looking-at " *$"))
 506           (insert "\n"))
 507       (if (save-excursion
 508             (beginning-of-line)
 509             (looking-at " *$"))
 510           (delete-region (match-beginning 0) (match-end 0))
 511         (insert "\n\n")))))
 512
 513 (defun shr-indent ()
 514   (when (> shr-indentation 0)
 515     (insert (make-string shr-indentation ? ))))
 516
 517 (defun shr-fontize-cont (cont &rest types)
 518   (let (shr-start)
 519     (shr-generic cont)
 520     (dolist (type types)
 521       (shr-add-font (or shr-start (point)) (point) type))))
 522
 523 ;; Add an overlay in the region, but avoid putting the font properties
 524 ;; on blank text at the start of the line, and the newline at the end,
 525 ;; to avoid ugliness.
 526 (defun shr-add-font (start end type)
 527   (save-excursion
 528     (goto-char start)
 529     (while (< (point) end)
 530       (when (bolp)
 531         (skip-chars-forward " "))
 532       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 533         (overlay-put overlay 'face type))
 534       (if (< (line-end-position) end)
 535           (forward-line 1)
 536         (goto-char end)))))
 537
 538 (defun shr-browse-url ()
 539   "Browse the URL under point."
 540   (interactive)
 541   (let ((url (get-text-property (point) 'shr-url)))
 542     (cond
 543      ((not url)
 544       (message "No link under point"))
 545      ((string-match "^mailto:" url)
 546       (browse-url-mail url))
 547      (t
 548       (browse-url url)))))
 549
 550 (defun shr-save-contents (directory)
 551   "Save the contents from URL in a file."
 552   (interactive "DSave contents of URL to directory: ")
 553   (let ((url (get-text-property (point) 'shr-url)))
 554     (if (not url)
 555         (message "No link under point")
 556       (url-retrieve (shr-encode-url url)
 557                     'shr-store-contents (list url directory)
 558                     nil t))))
 559
 560 (defun shr-store-contents (status url directory)
 561   (unless (plist-get status :error)
 562     (when (or (search-forward "\n\n" nil t)
 563               (search-forward "\r\n\r\n" nil t))
 564       (write-region (point) (point-max)
 565                     (expand-file-name (file-name-nondirectory url)
 566                                       directory)))))
 567
 568 (defun shr-image-fetched (status buffer start end &optional flags)
 569   (let ((image-buffer (current-buffer)))
 570     (when (and (buffer-name buffer)
 571                (not (plist-get status :error)))
 572       (url-store-in-cache image-buffer)
 573       (when (or (search-forward "\n\n" nil t)
 574                 (search-forward "\r\n\r\n" nil t))
 575         (let ((data (buffer-substring (point) (point-max))))
 576           (with-current-buffer buffer
 577             (save-excursion
 578               (let ((alt (buffer-substring start end))
 579                     (properties (text-properties-at start))
 580                     (inhibit-read-only t))
 581                 (delete-region start end)
 582                 (goto-char start)
 583                 (funcall shr-put-image-function data alt flags)
 584                 (while properties
 585                   (let ((type (pop properties))
 586                         (value (pop properties)))
 587                     (unless (memq type '(display image-size))
 588                       (put-text-property start (point) type value))))))))))
 589     (kill-buffer image-buffer)))
 590
 591 (defun shr-put-image (data alt &optional flags)
 592   "Put image DATA with a string ALT.  Return image."
 593   (if (display-graphic-p)
 594       (let* ((size (cdr (assq 'size flags)))
 595              (start (point))
 596              (image (cond
 597                      ((eq size 'original)
 598                       (create-image data nil t :ascent 100))
 599                      ((eq size 'full)
 600                       (ignore-errors
 601                         (shr-rescale-image data t)))
 602                      (t
 603                       (ignore-errors
 604                         (shr-rescale-image data))))))
 605         (when image
 606           ;; When inserting big-ish pictures, put them at the
 607           ;; beginning of the line.
 608           (when (and (> (current-column) 0)
 609                      (> (car (image-size image t)) 400))
 610             (insert "\n"))
 611           (if (eq size 'original)
 612               (let ((overlays (overlays-at (point))))
 613                 (insert-sliced-image image (or alt "*") nil 20 1)
 614                 (dolist (overlay overlays)
 615                   (overlay-put overlay 'face 'default)))
 616             (insert-image image (or alt "*")))
 617           (put-text-property start (point) 'image-size size)
 618           (when (image-animated-p image)
 619             (image-animate image nil 60)))
 620         image)
 621     (insert alt)))
 622
 623 (defun shr-rescale-image (data &optional force)
 624   "Rescale DATA, if too big, to fit the current buffer.
 625 If FORCE, rescale the image anyway."
 626   (let ((image (create-image data nil t :ascent 100)))
 627     (if (or (not (fboundp 'imagemagick-types))
 628             (not (get-buffer-window (current-buffer))))
 629         image
 630       (let* ((size (image-size image t))
 631              (width (car size))
 632              (height (cdr size))
 633              (edges (window-inside-pixel-edges
 634                      (get-buffer-window (current-buffer))))
 635              (window-width (truncate (* shr-max-image-proportion
 636                                         (- (nth 2 edges) (nth 0 edges)))))
 637              (window-height (truncate (* shr-max-image-proportion
 638                                          (- (nth 3 edges) (nth 1 edges)))))
 639              scaled-image)
 640         (when (or force
 641                   (> height window-height))
 642           (setq image (or (create-image data 'imagemagick t
 643                                         :height window-height
 644                                         :ascent 100)
 645                           image))
 646           (setq size (image-size image t)))
 647         (when (> (car size) window-width)
 648           (setq image (or
 649                        (create-image data 'imagemagick t
 650                                      :width window-width
 651                                      :ascent 100)
 652                        image)))
 653         image))))
 654
 655 ;; url-cache-extract autoloads url-cache.
 656 (declare-function url-cache-create-filename "url-cache" (url))
 657 (autoload 'mm-disable-multibyte "mm-util")
 658 (autoload 'browse-url-mail "browse-url")
 659
 660 (defun shr-get-image-data (url)
 661   "Get image data for URL.
 662 Return a string with image data."
 663   (with-temp-buffer
 664     (mm-disable-multibyte)
 665     (when (ignore-errors
 666             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 667             t)
 668       (when (or (search-forward "\n\n" nil t)
 669                 (search-forward "\r\n\r\n" nil t))
 670         (buffer-substring (point) (point-max))))))
 671
 672 (defun shr-image-displayer (content-function)
 673   "Return a function to display an image.
 674 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 675 is an argument.  The function to be returned takes three arguments URL,
 676 START, and END.  Note that START and END should be markers."
 677   `(lambda (url start end)
 678      (when url
 679        (if (string-match "\\`cid:" url)
 680            ,(when content-function
 681               `(let ((image (funcall ,content-function
 682                                      (substring url (match-end 0)))))
 683                  (when image
 684                    (goto-char start)
 685                    (funcall shr-put-image-function
 686                             image (buffer-substring start end))
 687                    (delete-region (point) end))))
 688          (url-retrieve url 'shr-image-fetched
 689                        (list (current-buffer) start end)
 690                        t t)))))
 691
 692 (defun shr-heading (cont &rest types)
 693   (shr-ensure-paragraph)
 694   (apply #'shr-fontize-cont cont types)
 695   (shr-ensure-paragraph))
 696
 697 (autoload 'widget-convert-button "wid-edit")
 698
 699 (defun shr-urlify (start url &optional title)
 700   (widget-convert-button
 701    'url-link start (point)
 702    :help-echo (if title (format "%s (%s)" url title) url)
 703    :keymap shr-map
 704    url)
 705   (shr-add-font start (point) 'shr-link)
 706   (put-text-property start (point) 'shr-url url))
 707
 708 (defun shr-encode-url (url)
 709   "Encode URL."
 710   (browse-url-url-encode-chars url "[)$ ]"))
 711
 712 (autoload 'shr-color-visible "shr-color")
 713 (autoload 'shr-color->hexadecimal "shr-color")
 714
 715 (defun shr-color-check (fg bg)
 716   "Check that FG is visible on BG.
 717 Returns (fg bg) with corrected values.
 718 Returns nil if the colors that would be used are the default
 719 ones, in case fg and bg are nil."
 720   (when (or fg bg)
 721     (let ((fixed (cond ((null fg) 'fg)
 722                        ((null bg) 'bg))))
 723       ;; Convert colors to hexadecimal, or set them to default.
 724       (let ((fg (or (shr-color->hexadecimal fg)
 725                     (frame-parameter nil 'foreground-color)))
 726             (bg (or (shr-color->hexadecimal bg)
 727                     (frame-parameter nil 'background-color))))
 728         (cond ((eq fixed 'bg)
 729                ;; Only return the new fg
 730                (list nil (cadr (shr-color-visible bg fg t))))
 731               ((eq fixed 'fg)
 732                ;; Invert args and results and return only the new bg
 733                (list (cadr (shr-color-visible fg bg t)) nil))
 734               (t
 735                (shr-color-visible bg fg)))))))
 736
 737 (defun shr-colorize-region (start end fg &optional bg)
 738   (when (or fg bg)
 739     (let ((new-colors (shr-color-check fg bg)))
 740       (when new-colors
 741         (when fg
 742           (shr-put-color start end :foreground (cadr new-colors)))
 743         (when bg
 744           (shr-put-color start end :background (car new-colors))))
 745       new-colors)))
 746
 747 ;; Put a color in the region, but avoid putting colors on blank
 748 ;; text at the start of the line, and the newline at the end, to avoid
 749 ;; ugliness.  Also, don't overwrite any existing color information,
 750 ;; since this can be called recursively, and we want the "inner" color
 751 ;; to win.
 752 (defun shr-put-color (start end type color)
 753   (save-excursion
 754     (goto-char start)
 755     (while (< (point) end)
 756       (when (and (bolp)
 757                  (not (eq type :background)))
 758         (skip-chars-forward " "))
 759       (when (> (line-end-position) (point))
 760         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 761       (if (< (line-end-position) end)
 762           (forward-line 1)
 763         (goto-char end)))
 764     (when (and (eq type :background)
 765                (= shr-table-depth 0))
 766       (shr-expand-newlines start end color))))
 767
 768 (defun shr-expand-newlines (start end color)
 769   (save-restriction
 770     ;; Skip past all white space at the start and ends.
 771     (goto-char start)
 772     (skip-chars-forward " \t\n")
 773     (beginning-of-line)
 774     (setq start (point))
 775     (goto-char end)
 776     (skip-chars-backward " \t\n")
 777     (forward-line 1)
 778     (setq end (point))
 779     (narrow-to-region start end)
 780     (let ((width (shr-buffer-width))
 781           column)
 782       (goto-char (point-min))
 783       (while (not (eobp))
 784         (end-of-line)
 785         (when (and (< (setq column (current-column)) width)
 786                    (< (setq column (shr-previous-newline-padding-width column))
 787                       width))
 788           (let ((overlay (make-overlay (point) (1+ (point)))))
 789             (overlay-put overlay 'before-string
 790                          (concat
 791                           (mapconcat
 792                            (lambda (overlay)
 793                              (let ((string (plist-get
 794                                             (overlay-properties overlay)
 795                                             'before-string)))
 796                                (if (not string)
 797                                    ""
 798                                  (overlay-put overlay 'before-string "")
 799                                  string)))
 800                            (overlays-at (point))
 801                            "")
 802                           (propertize (make-string (- width column) ? )
 803                                       'face (list :background color))))))
 804         (forward-line 1)))))
 805
 806 (defun shr-previous-newline-padding-width (width)
 807   (let ((overlays (overlays-at (point)))
 808         (previous-width 0))
 809     (if (null overlays)
 810         width
 811       (dolist (overlay overlays)
 812         (setq previous-width
 813               (+ previous-width
 814                  (length (plist-get (overlay-properties overlay)
 815                                     'before-string)))))
 816       (+ width previous-width))))
 817
 818 (defun shr-put-color-1 (start end type color)
 819   (let* ((old-props (get-text-property start 'face))
 820          (do-put (and (listp old-props)
 821                       (not (memq type old-props))))
 822          change)
 823     (while (< start end)
 824       (setq change (next-single-property-change start 'face nil end))
 825       (when do-put
 826         (put-text-property start change 'face
 827                            (nconc (list type color) old-props)))
 828       (setq old-props (get-text-property change 'face))
 829       (setq do-put (and (listp old-props)
 830                         (not (memq type old-props))))
 831       (setq start change))
 832     (when (and do-put
 833                (> end start))
 834       (put-text-property start end 'face
 835                          (nconc (list type color old-props))))))
 836
 837 ;;; Tag-specific rendering rules.
 838
 839 (defun shr-tag-body (cont)
 840   (let* ((start (point))
 841          (fgcolor (cdr (or (assq :fgcolor cont)
 842                            (assq :text cont))))
 843          (bgcolor (cdr (assq :bgcolor cont)))
 844          (shr-stylesheet (list (cons 'color fgcolor)
 845                                (cons 'background-color bgcolor))))
 846     (shr-generic cont)
 847     (shr-colorize-region start (point) fgcolor bgcolor)))
 848
 849 (defun shr-tag-style (cont)
 850   )
 851
 852 (defun shr-tag-script (cont)
 853   )
 854
 855 (defun shr-tag-comment (cont)
 856   )
 857
 858 (defun shr-tag-sup (cont)
 859   (let ((start (point)))
 860     (shr-generic cont)
 861     (put-text-property start (point) 'display '(raise 0.5))))
 862
 863 (defun shr-tag-sub (cont)
 864   (let ((start (point)))
 865     (shr-generic cont)
 866     (put-text-property start (point) 'display '(raise -0.5))))
 867
 868 (defun shr-tag-label (cont)
 869   (shr-generic cont)
 870   (shr-ensure-paragraph))
 871
 872 (defun shr-tag-p (cont)
 873   (shr-ensure-paragraph)
 874   (shr-indent)
 875   (shr-generic cont)
 876   (shr-ensure-paragraph))
 877
 878 (defun shr-tag-div (cont)
 879   (shr-ensure-newline)
 880   (shr-indent)
 881   (shr-generic cont)
 882   (shr-ensure-newline))
 883
 884 (defun shr-tag-s (cont)
 885   (shr-fontize-cont cont 'shr-strike-through))
 886
 887 (defun shr-tag-del (cont)
 888   (shr-fontize-cont cont 'shr-strike-through))
 889
 890 (defun shr-tag-b (cont)
 891   (shr-fontize-cont cont 'bold))
 892
 893 (defun shr-tag-i (cont)
 894   (shr-fontize-cont cont 'italic))
 895
 896 (defun shr-tag-em (cont)
 897   (shr-fontize-cont cont 'bold))
 898
 899 (defun shr-tag-strong (cont)
 900   (shr-fontize-cont cont 'bold))
 901
 902 (defun shr-tag-u (cont)
 903   (shr-fontize-cont cont 'underline))
 904
 905 (defun shr-parse-style (style)
 906   (when style
 907     (save-match-data
 908       (when (string-match "\n" style)
 909         (setq style (replace-match " " t t style))))
 910     (let ((plist nil))
 911       (dolist (elem (split-string style ";"))
 912         (when elem
 913           (setq elem (split-string elem ":"))
 914           (when (and (car elem)
 915                      (cadr elem))
 916             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 917                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 918               (when (string-match " *!important\\'" value)
 919                 (setq value (substring value 0 (match-beginning 0))))
 920               (push (cons (intern name obarray)
 921                           value)
 922                     plist)))))
 923       plist)))
 924
 925 (defun shr-tag-base (cont)
 926   (setq shr-base (cdr (assq :href cont))))
 927
 928 (defun shr-tag-a (cont)
 929   (let ((url (cdr (assq :href cont)))
 930         (title (cdr (assq :title cont)))
 931         (start (point))
 932         shr-start)
 933     (shr-generic cont)
 934     (shr-urlify (or shr-start start) (shr-expand-url url) title)))
 935
 936 (defun shr-tag-object (cont)
 937   (let ((start (point))
 938         url)
 939     (dolist (elem cont)
 940       (when (eq (car elem) 'embed)
 941         (setq url (or url (cdr (assq :src (cdr elem))))))
 942       (when (and (eq (car elem) 'param)
 943                  (equal (cdr (assq :name (cdr elem))) "movie"))
 944         (setq url (or url (cdr (assq :value (cdr elem)))))))
 945     (when url
 946       (shr-insert " [multimedia] ")
 947       (shr-urlify start (shr-expand-url url)))
 948     (shr-generic cont)))
 949
 950 (defun shr-tag-video (cont)
 951   (let ((image (cdr (assq :poster cont)))
 952         (url (cdr (assq :src cont)))
 953         (start (point)))
 954     (shr-tag-img nil image)
 955     (shr-urlify start (shr-expand-url url))))
 956
 957 (defun shr-tag-img (cont &optional url)
 958   (when (or url
 959             (and cont
 960                  (cdr (assq :src cont))))
 961     (when (and (> (current-column) 0)
 962                (not (eq shr-state 'image)))
 963       (insert "\n"))
 964     (let ((alt (cdr (assq :alt cont)))
 965           (url (shr-expand-url (or url (cdr (assq :src cont))))))
 966       (let ((start (point-marker)))
 967         (when (zerop (length alt))
 968           (setq alt "*"))
 969         (cond
 970          ((or (member (cdr (assq :height cont)) '("0" "1"))
 971               (member (cdr (assq :width cont)) '("0" "1")))
 972           ;; Ignore zero-sized or single-pixel images.
 973           )
 974          ((and (not shr-inhibit-images)
 975                (string-match "\\`cid:" url))
 976           (let ((url (substring url (match-end 0)))
 977                 image)
 978             (if (or (not shr-content-function)
 979                     (not (setq image (funcall shr-content-function url))))
 980                 (insert alt)
 981               (funcall shr-put-image-function image alt))))
 982          ((or shr-inhibit-images
 983               (and shr-blocked-images
 984                    (string-match shr-blocked-images url)))
 985           (setq shr-start (point))
 986           (let ((shr-state 'space))
 987             (if (> (string-width alt) 8)
 988                 (shr-insert (truncate-string-to-width alt 8))
 989               (shr-insert alt))))
 990          ((and (not shr-ignore-cache)
 991                (url-is-cached (shr-encode-url url)))
 992           (funcall shr-put-image-function (shr-get-image-data url) alt))
 993          (t
 994           (insert alt " ")
 995           (when (and shr-ignore-cache
 996                      (url-is-cached (shr-encode-url url)))
 997             (let ((file (url-cache-create-filename (shr-encode-url url))))
 998               (when (file-exists-p file)
 999                 (delete-file file))))
1000           (url-queue-retrieve
1001            (shr-encode-url url) 'shr-image-fetched
1002            (list (current-buffer) start (set-marker (make-marker) (1- (point))))
1003            t t)))
1004         (when (zerop shr-table-depth) ;; We are not in a table.
1005           (put-text-property start (point) 'keymap shr-map)
1006           (put-text-property start (point) 'shr-alt alt)
1007           (put-text-property start (point) 'image-url url)
1008           (put-text-property start (point) 'image-displayer
1009                              (shr-image-displayer shr-content-function))
1010           (put-text-property start (point) 'help-echo alt))
1011         (setq shr-state 'image)))))
1012
1013 (defun shr-tag-pre (cont)
1014   (let ((shr-folding-mode 'none))
1015     (shr-ensure-newline)
1016     (shr-indent)
1017     (shr-generic cont)
1018     (shr-ensure-newline)))
1019
1020 (defun shr-tag-blockquote (cont)
1021   (shr-ensure-paragraph)
1022   (shr-indent)
1023   (let ((shr-indentation (+ shr-indentation 4)))
1024     (shr-generic cont))
1025   (shr-ensure-paragraph))
1026
1027 (defun shr-tag-ul (cont)
1028   (shr-ensure-paragraph)
1029   (let ((shr-list-mode 'ul))
1030     (shr-generic cont))
1031   (shr-ensure-paragraph))
1032
1033 (defun shr-tag-ol (cont)
1034   (shr-ensure-paragraph)
1035   (let ((shr-list-mode 1))
1036     (shr-generic cont))
1037   (shr-ensure-paragraph))
1038
1039 (defun shr-tag-li (cont)
1040   (shr-ensure-paragraph)
1041   (shr-indent)
1042   (let* ((bullet
1043           (if (numberp shr-list-mode)
1044               (prog1
1045                   (format "%d " shr-list-mode)
1046                 (setq shr-list-mode (1+ shr-list-mode)))
1047             "* "))
1048          (shr-indentation (+ shr-indentation (length bullet))))
1049     (insert bullet)
1050     (shr-generic cont)))
1051
1052 (defun shr-tag-br (cont)
1053   (when (and (not (bobp))
1054              ;; Only add a newline if we break the current line, or
1055              ;; the previous line isn't a blank line.
1056              (or (not (bolp))
1057                  (and (> (- (point) 2) (point-min))
1058                       (not (= (char-after (- (point) 2)) ?\n)))))
1059     (insert "\n")
1060     (shr-indent))
1061   (shr-generic cont))
1062
1063 (defun shr-tag-h1 (cont)
1064   (shr-heading cont 'bold 'underline))
1065
1066 (defun shr-tag-h2 (cont)
1067   (shr-heading cont 'bold))
1068
1069 (defun shr-tag-h3 (cont)
1070   (shr-heading cont 'italic))
1071
1072 (defun shr-tag-h4 (cont)
1073   (shr-heading cont))
1074
1075 (defun shr-tag-h5 (cont)
1076   (shr-heading cont))
1077
1078 (defun shr-tag-h6 (cont)
1079   (shr-heading cont))
1080
1081 (defun shr-tag-hr (cont)
1082   (shr-ensure-newline)
1083   (insert (make-string shr-width shr-hr-line) "\n"))
1084
1085 (defun shr-tag-title (cont)
1086   (shr-heading cont 'bold 'underline))
1087
1088 (defun shr-tag-font (cont)
1089   (let* ((start (point))
1090          (color (cdr (assq :color cont)))
1091          (shr-stylesheet (nconc (list (cons 'color color))
1092                                 shr-stylesheet)))
1093     (shr-generic cont)
1094     (when color
1095       (shr-colorize-region start (point) color
1096                            (cdr (assq 'background-color shr-stylesheet))))))
1097
1098 ;;; Table rendering algorithm.
1099
1100 ;; Table rendering is the only complicated thing here.  We do this by
1101 ;; first counting how many TDs there are in each TR, and registering
1102 ;; how wide they think they should be ("width=45%", etc).  Then we
1103 ;; render each TD separately (this is done in temporary buffers, so
1104 ;; that we can use all the rendering machinery as if we were in the
1105 ;; main buffer).  Now we know how much space each TD really takes, so
1106 ;; we then render everything again with the new widths, and finally
1107 ;; insert all these boxes into the main buffer.
1108 (defun shr-tag-table-1 (cont)
1109   (setq cont (or (cdr (assq 'tbody cont))
1110                  cont))
1111   (let* ((shr-inhibit-images t)
1112          (shr-table-depth (1+ shr-table-depth))
1113          (shr-kinsoku-shorten t)
1114          ;; Find all suggested widths.
1115          (columns (shr-column-specs cont))
1116          ;; Compute how many characters wide each TD should be.
1117          (suggested-widths (shr-pro-rate-columns columns))
1118          ;; Do a "test rendering" to see how big each TD is (this can
1119          ;; be smaller (if there's little text) or bigger (if there's
1120          ;; unbreakable text).
1121          (sketch (shr-make-table cont suggested-widths))
1122          ;; Compute the "natural" width by setting each column to 500
1123          ;; characters and see how wide they really render.
1124          (natural (shr-make-table cont (make-vector (length columns) 500)))
1125          (sketch-widths (shr-table-widths sketch natural suggested-widths)))
1126     ;; This probably won't work very well.
1127     (when (> (+ (loop for width across sketch-widths
1128                       summing (1+ width))
1129                 shr-indentation 1)
1130              (frame-width))
1131       (setq truncate-lines t))
1132     ;; Then render the table again with these new "hard" widths.
1133     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
1134   ;; Finally, insert all the images after the table.  The Emacs buffer
1135   ;; model isn't strong enough to allow us to put the images actually
1136   ;; into the tables.
1137   (when (zerop shr-table-depth)
1138     (dolist (elem (shr-find-elements cont 'img))
1139       (shr-tag-img (cdr elem)))))
1140
1141 (defun shr-tag-table (cont)
1142   (shr-ensure-paragraph)
1143   (let* ((caption (cdr (assq 'caption cont)))
1144          (header (cdr (assq 'thead cont)))
1145          (body (or (cdr (assq 'tbody cont)) cont))
1146          (footer (cdr (assq 'tfoot cont)))
1147          (bgcolor (cdr (assq :bgcolor cont)))
1148          (start (point))
1149          (shr-stylesheet (nconc (list (cons 'background-color bgcolor))
1150                                 shr-stylesheet))
1151          (nheader (if header (shr-max-columns header)))
1152          (nbody (if body (shr-max-columns body)))
1153          (nfooter (if footer (shr-max-columns footer))))
1154     (if (and (not caption)
1155              (not header)
1156              (not (cdr (assq 'tbody cont)))
1157              (not (cdr (assq 'tr cont)))
1158              (not footer))
1159         ;; The table is totally invalid and just contains random junk.
1160         ;; Try to output it anyway.
1161         (shr-generic cont)
1162       ;; It's a real table, so render it.
1163       (shr-tag-table-1
1164        (nconc
1165         (if caption `((tr (td ,@caption))))
1166         (if header
1167             (if footer
1168                 ;; hader + body + footer
1169                 (if (= nheader nbody)
1170                     (if (= nbody nfooter)
1171                         `((tr (td (table (tbody ,@header ,@body ,@footer)))))
1172                       (nconc `((tr (td (table (tbody ,@header ,@body)))))
1173                              (if (= nfooter 1)
1174                                  footer
1175                                `((tr (td (table (tbody ,@footer))))))))
1176                   (nconc `((tr (td (table (tbody ,@header)))))
1177                          (if (= nbody nfooter)
1178                              `((tr (td (table (tbody ,@body ,@footer)))))
1179                            (nconc `((tr (td (table (tbody ,@body)))))
1180                                   (if (= nfooter 1)
1181                                       footer
1182                                     `((tr (td (table (tbody ,@footer))))))))))
1183               ;; header + body
1184               (if (= nheader nbody)
1185                   `((tr (td (table (tbody ,@header ,@body)))))
1186                 (if (= nheader 1)
1187                     `(,@header (tr (td (table (tbody ,@body)))))
1188                   `((tr (td (table (tbody ,@header))))
1189                     (tr (td (table (tbody ,@body))))))))
1190           (if footer
1191               ;; body + footer
1192               (if (= nbody nfooter)
1193                   `((tr (td (table (tbody ,@body ,@footer)))))
1194                 (nconc `((tr (td (table (tbody ,@body)))))
1195                        (if (= nfooter 1)
1196                            footer
1197                          `((tr (td (table (tbody ,@footer))))))))
1198             (if caption
1199                 `((tr (td (table (tbody ,@body)))))
1200               body))))))
1201     (when bgcolor
1202       (shr-colorize-region start (point) (cdr (assq 'color shr-stylesheet))
1203                            bgcolor))))
1204
1205 (defun shr-find-elements (cont type)
1206   (let (result)
1207     (dolist (elem cont)
1208       (cond ((eq (car elem) type)
1209              (push elem result))
1210             ((consp (cdr elem))
1211              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
1212     (nreverse result)))
1213
1214 (defun shr-insert-table (table widths)
1215   (shr-insert-table-ruler widths)
1216   (dolist (row table)
1217     (let ((start (point))
1218           (height (let ((max 0))
1219                     (dolist (column row)
1220                       (setq max (max max (cadr column))))
1221                     max)))
1222       (dotimes (i height)
1223         (shr-indent)
1224         (insert shr-table-vertical-line "\n"))
1225       (dolist (column row)
1226         (goto-char start)
1227         (let ((lines (nth 2 column))
1228               (overlay-lines (nth 3 column))
1229               overlay overlay-line)
1230           (dolist (line lines)
1231             (setq overlay-line (pop overlay-lines))
1232             (end-of-line)
1233             (insert line shr-table-vertical-line)
1234             (dolist (overlay overlay-line)
1235               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
1236                                      (- (point) (nth 1 overlay) 1)))
1237                     (properties (nth 2 overlay)))
1238                 (while properties
1239                   (overlay-put o (pop properties) (pop properties)))))
1240             (forward-line 1))
1241           ;; Add blank lines at padding at the bottom of the TD,
1242           ;; possibly.
1243           (dotimes (i (- height (length lines)))
1244             (end-of-line)
1245             (let ((start (point)))
1246               (insert (make-string (string-width (car lines)) ? )
1247                       shr-table-vertical-line)
1248               (when (nth 4 column)
1249                 (shr-put-color start (1- (point)) :background (nth 4 column))))
1250             (forward-line 1)))))
1251     (shr-insert-table-ruler widths)))
1252
1253 (defun shr-insert-table-ruler (widths)
1254   (when (and (bolp)
1255              (> shr-indentation 0))
1256     (shr-indent))
1257   (insert shr-table-corner)
1258   (dotimes (i (length widths))
1259     (insert (make-string (aref widths i) shr-table-horizontal-line)
1260             shr-table-corner))
1261   (insert "\n"))
1262
1263 (defun shr-table-widths (table natural-table suggested-widths)
1264   (let* ((length (length suggested-widths))
1265          (widths (make-vector length 0))
1266          (natural-widths (make-vector length 0)))
1267     (dolist (row table)
1268       (let ((i 0))
1269         (dolist (column row)
1270           (aset widths i (max (aref widths i) column))
1271           (setq i (1+ i)))))
1272     (dolist (row natural-table)
1273       (let ((i 0))
1274         (dolist (column row)
1275           (aset natural-widths i (max (aref natural-widths i) column))
1276           (setq i (1+ i)))))
1277     (let ((extra (- (apply '+ (append suggested-widths nil))
1278                     (apply '+ (append widths nil))))
1279           (expanded-columns 0))
1280       ;; We have extra, unused space, so divide this space amongst the
1281       ;; columns.
1282       (when (> extra 0)
1283         ;; If the natural width is wider than the rendered width, we
1284         ;; want to allow the column to expand.
1285         (dotimes (i length)
1286           (when (> (aref natural-widths i) (aref widths i))
1287             (setq expanded-columns (1+ expanded-columns))))
1288         (dotimes (i length)
1289           (when (> (aref natural-widths i) (aref widths i))
1290             (aset widths i (min
1291                             (aref natural-widths i)
1292                             (+ (/ extra expanded-columns)
1293                                (aref widths i))))))))
1294     widths))
1295
1296 (defun shr-make-table (cont widths &optional fill)
1297   (let ((trs nil))
1298     (dolist (row cont)
1299       (when (eq (car row) 'tr)
1300         (let ((tds nil)
1301               (columns (cdr row))
1302               (i 0)
1303               column)
1304           (while (< i (length widths))
1305             (setq column (pop columns))
1306             (when (or (memq (car column) '(td th))
1307                       (null column))
1308               (push (shr-render-td (cdr column) (aref widths i) fill)
1309                     tds)
1310               (setq i (1+ i))))
1311           (push (nreverse tds) trs))))
1312     (nreverse trs)))
1313
1314 (defun shr-render-td (cont width fill)
1315   (with-temp-buffer
1316     (let ((bgcolor (cdr (assq :bgcolor cont)))
1317           (fgcolor (cdr (assq :fgcolor cont)))
1318           (style (cdr (assq :style cont)))
1319           (shr-stylesheet shr-stylesheet)
1320           overlays actual-colors)
1321       (when style
1322         (setq style (and (string-match "color" style)
1323                          (shr-parse-style style))))
1324       (when bgcolor
1325         (setq style (nconc (list (cons 'background-color bgcolor)) style)))
1326       (when fgcolor
1327         (setq style (nconc (list (cons 'color fgcolor)) style)))
1328       (when style
1329         (setq shr-stylesheet (append style shr-stylesheet)))
1330       (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1331         (if cache
1332             (progn
1333               (insert (car cache))
1334               (let ((end (length (car cache))))
1335                 (dolist (overlay (cadr cache))
1336                   (let ((new-overlay
1337                          (make-overlay (1+ (- end (nth 0 overlay)))
1338                                        (1+ (- end (nth 1 overlay)))))
1339                         (properties (nth 2 overlay)))
1340                     (while properties
1341                       (overlay-put new-overlay
1342                                    (pop properties) (pop properties)))))))
1343           (let ((shr-width width)
1344                 (shr-indentation 0))
1345             (shr-descend (cons 'td cont)))
1346           ;; Delete padding at the bottom of the TDs.
1347           (delete-region
1348            (point)
1349            (progn
1350              (skip-chars-backward " \t\n")
1351              (end-of-line)
1352              (point)))
1353           (push (list (cons width cont) (buffer-string)
1354                       (shr-overlays-in-region (point-min) (point-max)))
1355                 shr-content-cache)))
1356       (goto-char (point-min))
1357       (let ((max 0))
1358         (while (not (eobp))
1359           (end-of-line)
1360           (setq max (max max (current-column)))
1361           (forward-line 1))
1362         (when fill
1363           (goto-char (point-min))
1364           ;; If the buffer is totally empty, then put a single blank
1365           ;; line here.
1366           (if (zerop (buffer-size))
1367               (insert (make-string width ? ))
1368             ;; Otherwise, fill the buffer.
1369             (while (not (eobp))
1370               (end-of-line)
1371               (when (> (- width (current-column)) 0)
1372                 (insert (make-string (- width (current-column)) ? )))
1373               (forward-line 1)))
1374           (when style
1375             (setq actual-colors
1376                   (shr-colorize-region
1377                    (point-min) (point-max)
1378                    (cdr (assq 'color shr-stylesheet))
1379                    (cdr (assq 'background-color shr-stylesheet))))))
1380         (if fill
1381             (list max
1382                   (count-lines (point-min) (point-max))
1383                   (split-string (buffer-string) "\n")
1384                   (shr-collect-overlays)
1385                   (car actual-colors))
1386           max)))))
1387
1388 (defun shr-buffer-width ()
1389   (goto-char (point-min))
1390   (let ((max 0))
1391     (while (not (eobp))
1392       (end-of-line)
1393       (setq max (max max (current-column)))
1394       (forward-line 1))
1395     max))
1396
1397 (defun shr-collect-overlays ()
1398   (save-excursion
1399     (goto-char (point-min))
1400     (let ((overlays nil))
1401       (while (not (eobp))
1402         (push (shr-overlays-in-region (point) (line-end-position))
1403               overlays)
1404         (forward-line 1))
1405       (nreverse overlays))))
1406
1407 (defun shr-overlays-in-region (start end)
1408   (let (result)
1409     (dolist (overlay (overlays-in start end))
1410       (push (list (if (> start (overlay-start overlay))
1411                       (- end start)
1412                     (- end (overlay-start overlay)))
1413                   (if (< end (overlay-end overlay))
1414                       0
1415                     (- end (overlay-end overlay)))
1416                   (overlay-properties overlay))
1417             result))
1418     (nreverse result)))
1419
1420 (defun shr-pro-rate-columns (columns)
1421   (let ((total-percentage 0)
1422         (widths (make-vector (length columns) 0)))
1423     (dotimes (i (length columns))
1424       (setq total-percentage (+ total-percentage (aref columns i))))
1425     (setq total-percentage (/ 1.0 total-percentage))
1426     (dotimes (i (length columns))
1427       (aset widths i (max (truncate (* (aref columns i)
1428                                        total-percentage
1429                                        (- shr-width (1+ (length columns)))))
1430                           10)))
1431     widths))
1432
1433 ;; Return a summary of the number and shape of the TDs in the table.
1434 (defun shr-column-specs (cont)
1435   (let ((columns (make-vector (shr-max-columns cont) 1)))
1436     (dolist (row cont)
1437       (when (eq (car row) 'tr)
1438         (let ((i 0))
1439           (dolist (column (cdr row))
1440             (when (memq (car column) '(td th))
1441               (let ((width (cdr (assq :width (cdr column)))))
1442                 (when (and width
1443                            (string-match "\\([0-9]+\\)%" width)
1444                            (not (zerop (setq width (string-to-number
1445                                                     (match-string 1 width))))))
1446                   (aset columns i (/ width 100.0))))
1447               (setq i (1+ i)))))))
1448     columns))
1449
1450 (defun shr-count (cont elem)
1451   (let ((i 0))
1452     (dolist (sub cont)
1453       (when (eq (car sub) elem)
1454         (setq i (1+ i))))
1455     i))
1456
1457 (defun shr-max-columns (cont)
1458   (let ((max 0))
1459     (dolist (row cont)
1460       (when (eq (car row) 'tr)
1461         (setq max (max max (+ (shr-count (cdr row) 'td)
1462                               (shr-count (cdr row) 'th))))))
1463     max))
1464
1465 (provide 'shr)
1466
1467 ;; Local Variables:
1468 ;; coding: iso-8859-1
1469 ;; End:
1470
1471 ;;; shr.el ends here