cgit.sxemacs.org Git - gnus/blob - lisp/sha1.el

   1 ;;; sha1.el --- SHA1 Secure Hash Algorithm in Emacs-Lisp
   2
   3 ;; Copyright (C) 1999, 2001, 2003, 2004 Free Software Foundation, Inc.
   4
   5 ;; Author: Shuhei KOBAYASHI <shuhei@aqua.ocn.ne.jp>
   6 ;; Keywords: SHA1, FIPS 180-1
   7
   8 ;; This file is part of FLIM (Faithful Library about Internet Message).
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This program is implemented from the definition of SHA-1 in FIPS PUB
  28 ;; 180-1 (Federal Information Processing Standards Publication 180-1),
  29 ;; "Announcing the Standard for SECURE HASH STANDARD".
  30 ;; <URL:http://www.itl.nist.gov/div897/pubs/fip180-1.htm>
  31 ;; (EXCEPTION; two optimizations taken from GnuPG/cipher/sha1.c)
  32 ;;
  33 ;; Test cases from FIPS PUB 180-1.
  34 ;;
  35 ;; (sha1 "abc")
  36 ;; => a9993e364706816aba3e25717850c26c9cd0d89d
  37 ;;
  38 ;; (sha1 "abcdbcdecdefdefgefghfghighijhijkijkljklmklmnlmnomnopnopq")
  39 ;; => 84983e441c3bd26ebaae4aa1f95129e5e54670f1
  40 ;;
  41 ;; (sha1 (make-string 1000000 ?a))
  42 ;; => 34aa973cd4c4daa4f61eeb2bdbad27316534016f
  43 ;;
  44 ;; BUGS:
  45 ;;  * It is assumed that length of input string is less than 2^29 bytes.
  46 ;;  * It is caller's responsibility to make string (or region) unibyte.
  47 ;;
  48 ;; TODO:
  49 ;;  * Rewrite from scratch!
  50 ;;    This version is much faster than Keiichi Suzuki's another sha1.el,
  51 ;;    but it is too dirty.
  52
  53 ;;; Code:
  54
  55 (require 'hex-util)
  56
  57 ;;;
  58 ;;; external SHA1 function.
  59 ;;;
  60
  61 (defgroup sha1 nil
  62   "Elisp interface for SHA1 hash computation."
  63   :version "22.1"
  64   :group 'extensions)
  65
  66 (defcustom sha1-maximum-internal-length 500
  67   "*Maximum length of message to use Lisp version of SHA1 function.
  68 If message is longer than this, `sha1-program' is used instead.
  69
  70 If this variable is set to 0, use external program only.
  71 If this variable is set to nil, use internal function only."
  72   :type 'integer
  73   :group 'sha1)
  74
  75 (defcustom sha1-program '("sha1sum")
  76   "*Name of program to compute SHA1.
  77 It must be a string \(program name\) or list of strings \(name and its args\)."
  78   :type '(repeat string)
  79   :group 'sha1)
  80
  81 (defcustom sha1-use-external (condition-case ()
  82                                  (executable-find (car sha1-program))
  83                                (error))
  84   "*Use external SHA1 program.
  85 If this variable is set to nil, use internal function only."
  86   :type 'boolean
  87   :group 'sha1)
  88
  89 (defun sha1-string-external (string &optional binary)
  90   (let (prog args digest default-enable-multibyte-characters)
  91     (if (consp sha1-program)
  92         (setq prog (car sha1-program)
  93               args (cdr sha1-program))
  94       (setq prog sha1-program
  95             args nil))
  96     (with-temp-buffer
  97       (insert string)
  98       (apply (function call-process-region)
  99              (point-min)(point-max)
 100              prog t t nil args)
 101       ;; SHA1 is 40 bytes long in hexadecimal form.
 102       (setq digest (buffer-substring (point-min)(+ (point-min) 40))))
 103     (if binary
 104         (decode-hex-string digest)
 105       digest)))
 106
 107 (defun sha1-region-external (beg end &optional binary)
 108   (sha1-string-external (buffer-substring-no-properties beg end) binary))
 109
 110 ;;;
 111 ;;; internal SHA1 function.
 112 ;;;
 113
 114 (eval-when-compile
 115   ;; optional second arg of string-to-number is new in v20.
 116   (defconst sha1-K0-high 23170)         ; (string-to-number "5A82" 16)
 117   (defconst sha1-K0-low  31129)         ; (string-to-number "7999" 16)
 118   (defconst sha1-K1-high 28377)         ; (string-to-number "6ED9" 16)
 119   (defconst sha1-K1-low  60321)         ; (string-to-number "EBA1" 16)
 120   (defconst sha1-K2-high 36635)         ; (string-to-number "8F1B" 16)
 121   (defconst sha1-K2-low  48348)         ; (string-to-number "BCDC" 16)
 122   (defconst sha1-K3-high 51810)         ; (string-to-number "CA62" 16)
 123   (defconst sha1-K3-low  49622)         ; (string-to-number "C1D6" 16)
 124
 125 ;;; original definition of sha1-F0.
 126 ;;; (defmacro sha1-F0 (B C D)
 127 ;;;   (` (logior (logand (, B) (, C))
 128 ;;;          (logand (lognot (, B)) (, D)))))
 129 ;;; a little optimization from GnuPG/cipher/sha1.c.
 130   (defmacro sha1-F0 (B C D)
 131     (` (logxor (, D) (logand (, B) (logxor (, C) (, D))))))
 132   (defmacro sha1-F1 (B C D)
 133     (` (logxor (, B) (, C) (, D))))
 134 ;;; original definition of sha1-F2.
 135 ;;; (defmacro sha1-F2 (B C D)
 136 ;;;   (` (logior (logand (, B) (, C))
 137 ;;;          (logand (, B) (, D))
 138 ;;;          (logand (, C) (, D)))))
 139 ;;; a little optimization from GnuPG/cipher/sha1.c.
 140   (defmacro sha1-F2 (B C D)
 141     (` (logior (logand (, B) (, C))
 142                (logand (, D) (logior (, B) (, C))))))
 143   (defmacro sha1-F3 (B C D)
 144     (` (logxor (, B) (, C) (, D))))
 145
 146   (defmacro sha1-S1  (W-high W-low)
 147     (` (let ((W-high (, W-high))
 148              (W-low  (, W-low)))
 149          (setq S1W-high (+ (% (* W-high 2) 65536)
 150                            (/ W-low (, (/ 65536 2)))))
 151          (setq S1W-low (+ (/ W-high (, (/ 65536 2)))
 152                           (% (* W-low 2) 65536))))))
 153   (defmacro sha1-S5  (A-high A-low)
 154     (` (progn
 155          (setq S5A-high (+ (% (* (, A-high) 32) 65536)
 156                            (/ (, A-low) (, (/ 65536 32)))))
 157          (setq S5A-low  (+ (/ (, A-high) (, (/ 65536 32)))
 158                            (% (* (, A-low) 32) 65536))))))
 159   (defmacro sha1-S30 (B-high B-low)
 160     (` (progn
 161          (setq S30B-high (+ (/ (, B-high) 4)
 162                             (* (% (, B-low) 4) (, (/ 65536 4)))))
 163          (setq S30B-low  (+ (/ (, B-low) 4)
 164                             (* (% (, B-high) 4) (, (/ 65536 4))))))))
 165
 166   (defmacro sha1-OP (round)
 167     (` (progn
 168          (sha1-S5 sha1-A-high sha1-A-low)
 169          (sha1-S30 sha1-B-high sha1-B-low)
 170          (setq sha1-A-low (+ ((, (intern (format "sha1-F%d" round)))
 171                               sha1-B-low sha1-C-low sha1-D-low)
 172                              sha1-E-low
 173                              (, (symbol-value
 174                                  (intern (format "sha1-K%d-low" round))))
 175                              (aref block-low idx)
 176                              (progn
 177                                (setq sha1-E-low sha1-D-low)
 178                                (setq sha1-D-low sha1-C-low)
 179                                (setq sha1-C-low S30B-low)
 180                                (setq sha1-B-low sha1-A-low)
 181                                S5A-low)))
 182          (setq carry (/ sha1-A-low 65536))
 183          (setq sha1-A-low (% sha1-A-low 65536))
 184          (setq sha1-A-high (% (+ ((, (intern (format "sha1-F%d" round)))
 185                                   sha1-B-high sha1-C-high sha1-D-high)
 186                                  sha1-E-high
 187                                  (, (symbol-value
 188                                      (intern (format "sha1-K%d-high" round))))
 189                                  (aref block-high idx)
 190                                  (progn
 191                                    (setq sha1-E-high sha1-D-high)
 192                                    (setq sha1-D-high sha1-C-high)
 193                                    (setq sha1-C-high S30B-high)
 194                                    (setq sha1-B-high sha1-A-high)
 195                                    S5A-high)
 196                                  carry)
 197                               65536)))))
 198
 199   (defmacro sha1-add-to-H (H X)
 200     (` (progn
 201          (setq (, (intern (format "sha1-%s-low" H)))
 202                (+ (, (intern (format "sha1-%s-low" H)))
 203                   (, (intern (format "sha1-%s-low" X)))))
 204          (setq carry (/ (, (intern (format "sha1-%s-low" H))) 65536))
 205          (setq (, (intern (format "sha1-%s-low" H)))
 206                (% (, (intern (format "sha1-%s-low" H))) 65536))
 207          (setq (, (intern (format "sha1-%s-high" H)))
 208                (% (+ (, (intern (format "sha1-%s-high" H)))
 209                      (, (intern (format "sha1-%s-high" X)))
 210                      carry)
 211                   65536)))))
 212   )
 213
 214 ;;; buffers (H0 H1 H2 H3 H4).
 215 (defvar sha1-H0-high)
 216 (defvar sha1-H0-low)
 217 (defvar sha1-H1-high)
 218 (defvar sha1-H1-low)
 219 (defvar sha1-H2-high)
 220 (defvar sha1-H2-low)
 221 (defvar sha1-H3-high)
 222 (defvar sha1-H3-low)
 223 (defvar sha1-H4-high)
 224 (defvar sha1-H4-low)
 225
 226 (defun sha1-block (block-high block-low)
 227   (let (;; step (c) --- initialize buffers (A B C D E).
 228         (sha1-A-high sha1-H0-high) (sha1-A-low sha1-H0-low)
 229         (sha1-B-high sha1-H1-high) (sha1-B-low sha1-H1-low)
 230         (sha1-C-high sha1-H2-high) (sha1-C-low sha1-H2-low)
 231         (sha1-D-high sha1-H3-high) (sha1-D-low sha1-H3-low)
 232         (sha1-E-high sha1-H4-high) (sha1-E-low sha1-H4-low)
 233         (idx 16))
 234     ;; step (b).
 235     (let (;; temporary variables used in sha1-S1 macro.
 236           S1W-high S1W-low)
 237       (while (< idx 80)
 238         (sha1-S1 (logxor (aref block-high (- idx 3))
 239                          (aref block-high (- idx 8))
 240                          (aref block-high (- idx 14))
 241                          (aref block-high (- idx 16)))
 242                  (logxor (aref block-low  (- idx 3))
 243                          (aref block-low  (- idx 8))
 244                          (aref block-low  (- idx 14))
 245                          (aref block-low  (- idx 16))))
 246         (aset block-high idx S1W-high)
 247         (aset block-low  idx S1W-low)
 248         (setq idx (1+ idx))))
 249     ;; step (d).
 250     (setq idx 0)
 251     (let (;; temporary variables used in sha1-OP macro.
 252           S5A-high S5A-low S30B-high S30B-low carry)
 253       (while (< idx 20) (sha1-OP 0) (setq idx (1+ idx)))
 254       (while (< idx 40) (sha1-OP 1) (setq idx (1+ idx)))
 255       (while (< idx 60) (sha1-OP 2) (setq idx (1+ idx)))
 256       (while (< idx 80) (sha1-OP 3) (setq idx (1+ idx))))
 257     ;; step (e).
 258     (let (;; temporary variables used in sha1-add-to-H macro.
 259           carry)
 260       (sha1-add-to-H H0 A)
 261       (sha1-add-to-H H1 B)
 262       (sha1-add-to-H H2 C)
 263       (sha1-add-to-H H3 D)
 264       (sha1-add-to-H H4 E))))
 265
 266 (defun sha1-binary (string)
 267   "Return the SHA1 of STRING in binary form."
 268   (let (;; prepare buffers for a block. byte-length of block is 64.
 269         ;; input block is split into two vectors.
 270         ;;
 271         ;; input block: 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F ...
 272         ;; block-high:  +-0-+       +-1-+       +-2-+       +-3-+
 273         ;; block-low:         +-0-+       +-1-+       +-2-+       +-3-+
 274         ;;
 275         ;; length of each vector is 80, and elements of each vector are
 276         ;; 16bit integers.  elements 0x10-0x4F of each vector are
 277         ;; assigned later in `sha1-block'.
 278         (block-high (eval-when-compile (make-vector 80 nil)))
 279         (block-low  (eval-when-compile (make-vector 80 nil))))
 280     (unwind-protect
 281         (let* (;; byte-length of input string.
 282                (len (length string))
 283                (lim (* (/ len 64) 64))
 284                (rem (% len 4))
 285                (idx 0)(pos 0))
 286           ;; initialize buffers (H0 H1 H2 H3 H4).
 287           (setq sha1-H0-high 26437      ; (string-to-number "6745" 16)
 288                 sha1-H0-low  8961       ; (string-to-number "2301" 16)
 289                 sha1-H1-high 61389      ; (string-to-number "EFCD" 16)
 290                 sha1-H1-low  43913      ; (string-to-number "AB89" 16)
 291                 sha1-H2-high 39098      ; (string-to-number "98BA" 16)
 292                 sha1-H2-low  56574      ; (string-to-number "DCFE" 16)
 293                 sha1-H3-high 4146       ; (string-to-number "1032" 16)
 294                 sha1-H3-low  21622      ; (string-to-number "5476" 16)
 295                 sha1-H4-high 50130      ; (string-to-number "C3D2" 16)
 296                 sha1-H4-low  57840)     ; (string-to-number "E1F0" 16)
 297           ;; loop for each 64 bytes block.
 298           (while (< pos lim)
 299             ;; step (a).
 300             (setq idx 0)
 301             (while (< idx 16)
 302               (aset block-high idx (+ (* (aref string pos) 256)
 303                                       (aref string (1+ pos))))
 304               (setq pos (+ pos 2))
 305               (aset block-low  idx (+ (* (aref string pos) 256)
 306                                       (aref string (1+ pos))))
 307               (setq pos (+ pos 2))
 308               (setq idx (1+ idx)))
 309             (sha1-block block-high block-low))
 310           ;; last block.
 311           (if (prog1
 312                   (< (- len lim) 56)
 313                 (setq lim (- len rem))
 314                 (setq idx 0)
 315                 (while (< pos lim)
 316                   (aset block-high idx (+ (* (aref string pos) 256)
 317                                           (aref string (1+ pos))))
 318                   (setq pos (+ pos 2))
 319                   (aset block-low  idx (+ (* (aref string pos) 256)
 320                                           (aref string (1+ pos))))
 321                   (setq pos (+ pos 2))
 322                   (setq idx (1+ idx)))
 323                 ;; this is the last (at most) 32bit word.
 324                 (cond
 325                  ((= rem 3)
 326                   (aset block-high idx (+ (* (aref string pos) 256)
 327                                           (aref string (1+ pos))))
 328                   (setq pos (+ pos 2))
 329                   (aset block-low  idx (+ (* (aref string pos) 256)
 330                                           128)))
 331                  ((= rem 2)
 332                   (aset block-high idx (+ (* (aref string pos) 256)
 333                                           (aref string (1+ pos))))
 334                   (aset block-low  idx 32768))
 335                  ((= rem 1)
 336                   (aset block-high idx (+ (* (aref string pos) 256)
 337                                           128))
 338                   (aset block-low  idx 0))
 339                  (t ;; (= rem 0)
 340                   (aset block-high idx 32768)
 341                   (aset block-low  idx 0)))
 342                 (setq idx (1+ idx))
 343                 (while (< idx 16)
 344                   (aset block-high idx 0)
 345                   (aset block-low  idx 0)
 346                   (setq idx (1+ idx))))
 347               ;; last block has enough room to write the length of string.
 348               (progn
 349                 ;; write bit length of string to last 4 bytes of the block.
 350                 (aset block-low  15 (* (% len 8192) 8))
 351                 (setq len (/ len 8192))
 352                 (aset block-high 15 (% len 65536))
 353                 ;; XXX: It is not practical to compute SHA1 of
 354                 ;;      such a huge message on emacs.
 355                 ;; (setq len (/ len 65536))     ; for 64bit emacs.
 356                 ;; (aset block-low  14 (% len 65536))
 357                 ;; (aset block-high 14 (/ len 65536))
 358                 (sha1-block block-high block-low))
 359             ;; need one more block.
 360             (sha1-block block-high block-low)
 361             (fillarray block-high 0)
 362             (fillarray block-low  0)
 363             ;; write bit length of string to last 4 bytes of the block.
 364             (aset block-low  15 (* (% len 8192) 8))
 365             (setq len (/ len 8192))
 366             (aset block-high 15 (% len 65536))
 367             ;; XXX: It is not practical to compute SHA1 of
 368             ;;      such a huge message on emacs.
 369             ;; (setq len (/ len 65536))         ; for 64bit emacs.
 370             ;; (aset block-low  14 (% len 65536))
 371             ;; (aset block-high 14 (/ len 65536))
 372             (sha1-block block-high block-low))
 373           ;; make output string (in binary form).
 374           (let ((result (make-string 20 0)))
 375             (aset result  0 (/ sha1-H0-high 256))
 376             (aset result  1 (% sha1-H0-high 256))
 377             (aset result  2 (/ sha1-H0-low  256))
 378             (aset result  3 (% sha1-H0-low  256))
 379             (aset result  4 (/ sha1-H1-high 256))
 380             (aset result  5 (% sha1-H1-high 256))
 381             (aset result  6 (/ sha1-H1-low  256))
 382             (aset result  7 (% sha1-H1-low  256))
 383             (aset result  8 (/ sha1-H2-high 256))
 384             (aset result  9 (% sha1-H2-high 256))
 385             (aset result 10 (/ sha1-H2-low  256))
 386             (aset result 11 (% sha1-H2-low  256))
 387             (aset result 12 (/ sha1-H3-high 256))
 388             (aset result 13 (% sha1-H3-high 256))
 389             (aset result 14 (/ sha1-H3-low  256))
 390             (aset result 15 (% sha1-H3-low  256))
 391             (aset result 16 (/ sha1-H4-high 256))
 392             (aset result 17 (% sha1-H4-high 256))
 393             (aset result 18 (/ sha1-H4-low  256))
 394             (aset result 19 (% sha1-H4-low  256))
 395             result))
 396       ;; do not leave a copy of input string.
 397       (fillarray block-high nil)
 398       (fillarray block-low  nil))))
 399
 400 (defun sha1-string-internal (string &optional binary)
 401   (if binary
 402       (sha1-binary string)
 403     (encode-hex-string (sha1-binary string))))
 404
 405 (defun sha1-region-internal (beg end &optional binary)
 406   (sha1-string-internal (buffer-substring-no-properties beg end) binary))
 407
 408 ;;;
 409 ;;; application interface.
 410 ;;;
 411
 412 (defun sha1-region (beg end &optional binary)
 413   (if (and sha1-use-external
 414            sha1-maximum-internal-length
 415            (> (abs (- end beg)) sha1-maximum-internal-length))
 416       (sha1-region-external beg end binary)
 417     (sha1-region-internal beg end binary)))
 418
 419 (defun sha1-string (string &optional binary)
 420   (if (and sha1-use-external
 421            sha1-maximum-internal-length
 422            (> (length string) sha1-maximum-internal-length))
 423       (sha1-string-external string binary)
 424     (sha1-string-internal string binary)))
 425
 426 ;;;###autoload
 427 (defun sha1 (object &optional beg end binary)
 428   "Return the SHA1 (Secure Hash Algorithm) of an object.
 429 OBJECT is either a string or a buffer.
 430 Optional arguments BEG and END denote buffer positions for computing the
 431 hash of a portion of OBJECT.
 432 If BINARY is non-nil, return a string in binary form."
 433   (if (stringp object)
 434       (sha1-string object binary)
 435     (save-excursion
 436       (set-buffer object)
 437       (sha1-region (or beg (point-min)) (or end (point-max)) binary))))
 438
 439 (provide 'sha1)
 440
 441 ;;; arch-tag: c0f9abd0-ffc1-4557-aac6-ece7f2d4c901
 442 ;;; sha1.el ends here