cgit.sxemacs.org Git - gnus/blob - lisp/score-mode.el

   1 ;;; score-mode.el --- mode for editing Gnus score files
   2
   3 ;; Copyright (C) 1996, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30 (require 'mm-util)                      ; for mm-universal-coding-system
  31
  32 (defvar gnus-score-mode-hook nil
  33   "*Hook run in score mode buffers.")
  34
  35 (defvar gnus-score-menu-hook nil
  36   "*Hook run after creating the score mode menu.")
  37
  38 (defvar gnus-score-edit-exit-function nil
  39   "Function run on exit from the score buffer.")
  40
  41 (defvar gnus-score-mode-map nil)
  42 (unless gnus-score-mode-map
  43   (setq gnus-score-mode-map (make-sparse-keymap))
  44   (set-keymap-parent gnus-score-mode-map emacs-lisp-mode-map)
  45   (define-key gnus-score-mode-map "\C-c\C-c" 'gnus-score-edit-exit)
  46   (define-key gnus-score-mode-map "\C-c\C-d" 'gnus-score-edit-insert-date)
  47   (define-key gnus-score-mode-map "\C-c\C-p" 'gnus-score-pretty-print))
  48
  49 (defvar score-mode-syntax-table
  50   (let ((table (copy-syntax-table lisp-mode-syntax-table)))
  51     (modify-syntax-entry ?| "w" table)
  52     table)
  53   "Syntax table used in score-mode buffers.")
  54
  55 ;; We need this to cope with non-ASCII scoring.
  56 (defvar score-mode-coding-system mm-universal-coding-system)
  57
  58 ;;;###autoload
  59 (defun gnus-score-mode ()
  60   "Mode for editing Gnus score files.
  61 This mode is an extended emacs-lisp mode.
  62
  63 \\{gnus-score-mode-map}"
  64   (interactive)
  65   (kill-all-local-variables)
  66   (use-local-map gnus-score-mode-map)
  67   (gnus-score-make-menu-bar)
  68   (set-syntax-table score-mode-syntax-table)
  69   (setq major-mode 'gnus-score-mode)
  70   (setq mode-name "Score")
  71   (lisp-mode-variables nil)
  72   (make-local-variable 'gnus-score-edit-exit-function)
  73   (run-hooks 'emacs-lisp-mode-hook 'gnus-score-mode-hook))
  74
  75 (defun gnus-score-make-menu-bar ()
  76   (unless (boundp 'gnus-score-menu)
  77     (easy-menu-define
  78      gnus-score-menu gnus-score-mode-map ""
  79      '("Score"
  80        ["Exit" gnus-score-edit-exit t]
  81        ["Insert date" gnus-score-edit-insert-date t]
  82        ["Format" gnus-score-pretty-print t]))
  83     (run-hooks 'gnus-score-menu-hook)))
  84
  85 (defun gnus-score-edit-insert-date ()
  86   "Insert date in numerical format."
  87   (interactive)
  88   (princ (time-to-days (current-time)) (current-buffer)))
  89
  90 (defun gnus-score-pretty-print ()
  91   "Format the current score file."
  92   (interactive)
  93   (goto-char (point-min))
  94   (let ((form (read (current-buffer))))
  95     (erase-buffer)
  96     (let ((emacs-lisp-mode-syntax-table score-mode-syntax-table))
  97       (pp form (current-buffer))))
  98   (goto-char (point-min)))
  99
 100 (defun gnus-score-edit-exit ()
 101   "Stop editing the score file."
 102   (interactive)
 103   (unless (file-exists-p (file-name-directory (buffer-file-name)))
 104     (make-directory (file-name-directory (buffer-file-name)) t))
 105   (let ((coding-system-for-write score-mode-coding-system))
 106     (save-buffer))
 107   (bury-buffer (current-buffer))
 108   (let ((buf (current-buffer)))
 109     (when gnus-score-edit-exit-function
 110       (funcall gnus-score-edit-exit-function))
 111     (when (eq buf (current-buffer))
 112       (switch-to-buffer (other-buffer (current-buffer))))))
 113
 114 (provide 'score-mode)
 115
 116 ;;; arch-tag: a74a416b-2505-4ad4-bc4e-a418c96b8845
 117 ;;; score-mode.el ends here